t/lib/DBICTest.pm

   1 package # hide from PAUSE
   2     DBICTest;
   3
   4 use strict;
   5 use warnings;
   6
   7 # this noop trick initializes the STDOUT, so that the TAP::Harness
   8 # issued IO::Select->can_read calls (which are blocking wtf wtf wtf)
   9 # keep spinning and scheduling jobs
  10 # This results in an overall much smoother job-queue drainage, since
  11 # the Harness blocks less
  12 # (ideally this needs to be addressed in T::H, but a quick patchjob
  13 # broke everything so tabling it for now)
  14 BEGIN {
  15   if ($INC{'Test/Builder.pm'}) {
  16     local $| = 1;
  17     print "#\n";
  18   }
  19 }
  20
  21 use Module::Runtime 'module_notional_filename';
  22 BEGIN {
  23   for my $mod (qw( DBIC::SqlMakerTest SQL::Abstract )) {
  24     if ( $INC{ module_notional_filename($mod) } ) {
  25       # FIXME this does not seem to work in BEGIN - why?!
  26       #require Carp;
  27       #$Carp::Internal{ (__PACKAGE__) }++;
  28       #Carp::croak( __PACKAGE__ . " must be loaded before $mod" );
  29
  30       my ($fr, @frame) = 1;
  31       while (@frame = caller($fr++)) {
  32         last if $frame[1] !~ m|^t/lib/DBICTest|;
  33       }
  34
  35       die __PACKAGE__ . " must be loaded before $mod (or modules using $mod) at $frame[1] line $frame[2]\n";
  36     }
  37   }
  38 }
  39
  40 use DBICTest::RunMode;
  41 use DBICTest::Schema;
  42 use DBICTest::Util::LeakTracer qw/populate_weakregistry assert_empty_weakregistry/;
  43 use DBICTest::Util 'local_umask';
  44 use Carp;
  45 use Path::Class::File ();
  46 use File::Spec;
  47 use Fcntl qw/:DEFAULT :flock/;
  48 use Config;
  49
  50 =head1 NAME
  51
  52 DBICTest - Library to be used by DBIx::Class test scripts.
  53
  54 =head1 SYNOPSIS
  55
  56   use lib qw(t/lib);
  57   use DBICTest;
  58   use Test::More;
  59
  60   my $schema = DBICTest->init_schema();
  61
  62 =head1 DESCRIPTION
  63
  64 This module provides the basic utilities to write tests against
  65 DBIx::Class.
  66
  67 =head1 METHODS
  68
  69 =head2 init_schema
  70
  71   my $schema = DBICTest->init_schema(
  72     no_deploy=>1,
  73     no_populate=>1,
  74     storage_type=>'::DBI::Replicated',
  75     storage_type_args=>{
  76       balancer_type=>'DBIx::Class::Storage::DBI::Replicated::Balancer::Random'
  77     },
  78   );
  79
  80 This method removes the test SQLite database in t/var/DBIxClass.db
  81 and then creates a new, empty database.
  82
  83 This method will call deploy_schema() by default, unless the
  84 no_deploy flag is set.
  85
  86 Also, by default, this method will call populate_schema() by
  87 default, unless the no_deploy or no_populate flags are set.
  88
  89 =cut
  90
  91 # some tests are very time sensitive and need to run on their own, without
  92 # being disturbed by anything else grabbing CPU or disk IO. Hence why everything
  93 # using DBICTest grabs a shared lock, and the few tests that request a :GlobalLock
  94 # will ask for an exclusive one and block until they can get it
  95 our ($global_lock_fh, $global_exclusive_lock);
  96 sub import {
  97     my $self = shift;
  98
  99     my $tmpdir = DBICTest::RunMode->tmpdir;
 100     my $lockpath = $tmpdir->file('.dbictest_global.lock');
 101
 102     {
 103       my $u = local_umask(0); # so that the file opens as 666, and any user can lock
 104       sysopen ($global_lock_fh, $lockpath, O_RDWR|O_CREAT) or do {
 105         my $err = $!;
 106
 107         my @x_tests = map { (defined $_) ? ( $_ ? 1 : 0 ) : 'U' } map {(-e, -d, -f, -r, -w, -x, -o)} ($tmpdir, $lockpath);
 108
 109         die sprintf <<"EOE", $lockpath, $err, scalar $>, scalar $), (stat($tmpdir))[4,5,2], @x_tests;
 110 Unable to open %s: %s
 111 Process EUID/EGID: %s / %s
 112 TmpDir UID/GID:    %s / %s
 113 TmpDir StatMode:   %o
 114 TmpDir X-tests:    -e:%s -d:%s -f:%s -r:%s -w:%s -x:%s -o:%s
 115 TmpFile X-tests:   -e:%s -d:%s -f:%s -r:%s -w:%s -x:%s -o:%s
 116 EOE
 117       };
 118     }
 119
 120     for (@_) {
 121         if ($_ eq ':GlobalLock') {
 122             flock ($global_lock_fh, LOCK_EX) or die "Unable to lock $lockpath: $!";
 123             $global_exclusive_lock = 1;
 124         }
 125         else {
 126             croak "Unknown export $_ requested from $self";
 127         }
 128     }
 129
 130     unless ($global_exclusive_lock) {
 131         flock ($global_lock_fh, LOCK_SH) or die "Unable to lock $lockpath: $!";
 132     }
 133 }
 134
 135 END {
 136     if ($global_lock_fh) {
 137         # delay destruction even more
 138     }
 139 }
 140
 141 {
 142     my $dir = Path::Class::File->new(__FILE__)->dir->parent->subdir('var');
 143     $dir->mkpath unless -d "$dir";
 144     $dir = "$dir";
 145
 146     sub _sqlite_dbfilename {
 147         my $holder = $ENV{DBICTEST_LOCK_HOLDER} || $$;
 148         $holder = $$ if $holder == -1;
 149
 150         # useful for missing cleanup debugging
 151         #if ( $holder == $$) {
 152         #  my $x = $0;
 153         #  $x =~ s/\//#/g;
 154         #  $holder .= "-$x";
 155         #}
 156
 157         return "$dir/DBIxClass-$holder.db";
 158     }
 159
 160     END {
 161         _cleanup_dbfile();
 162     }
 163 }
 164
 165 $SIG{INT} = sub { _cleanup_dbfile(); exit 1 };
 166
 167 sub _cleanup_dbfile {
 168     # cleanup if this is us
 169     if (
 170       ! $ENV{DBICTEST_LOCK_HOLDER}
 171         or
 172       $ENV{DBICTEST_LOCK_HOLDER} == -1
 173         or
 174       $ENV{DBICTEST_LOCK_HOLDER} == $$
 175     ) {
 176         my $db_file = _sqlite_dbfilename();
 177         unlink $_ for ($db_file, "${db_file}-journal");
 178     }
 179 }
 180
 181 sub has_custom_dsn {
 182     return $ENV{"DBICTEST_DSN"} ? 1:0;
 183 }
 184
 185 sub _sqlite_dbname {
 186     my $self = shift;
 187     my %args = @_;
 188     return $self->_sqlite_dbfilename if (
 189       defined $args{sqlite_use_file} ? $args{sqlite_use_file} : $ENV{'DBICTEST_SQLITE_USE_FILE'}
 190     );
 191     return ":memory:";
 192 }
 193
 194 sub _database {
 195     my $self = shift;
 196     my %args = @_;
 197
 198     if ($ENV{DBICTEST_DSN}) {
 199       return (
 200         (map { $ENV{"DBICTEST_${_}"} || '' } qw/DSN DBUSER DBPASS/),
 201         { AutoCommit => 1, %args },
 202       );
 203     }
 204     my $db_file = $self->_sqlite_dbname(%args);
 205
 206     for ($db_file, "${db_file}-journal") {
 207       next unless -e $_;
 208       unlink ($_) or carp (
 209         "Unable to unlink existing test database file $_ ($!), creation of fresh database / further tests may fail!"
 210       );
 211     }
 212
 213     return ("dbi:SQLite:${db_file}", '', '', {
 214       AutoCommit => 1,
 215
 216       # this is executed on every connect, and thus installs a disconnect/DESTROY
 217       # guard for every new $dbh
 218       on_connect_do => sub {
 219
 220         my $storage = shift;
 221         my $dbh = $storage->_get_dbh;
 222
 223         # no fsync on commit
 224         $dbh->do ('PRAGMA synchronous = OFF');
 225
 226         if ($ENV{DBICTEST_SQLITE_REVERSE_DEFAULT_ORDER}) {
 227
 228           $storage->throw_exception(
 229             'PRAGMA reverse_unordered_selects does not work correctly before libsqlite 3.7.9'
 230           ) if $storage->_server_info->{normalized_dbms_version} < 3.007009;
 231
 232           $dbh->do ('PRAGMA reverse_unordered_selects = ON');
 233         }
 234
 235         # set a *DBI* disconnect callback, to make sure the physical SQLite
 236         # file is still there (i.e. the test does not attempt to delete
 237         # an open database, which fails on Win32)
 238         if (my $guard_cb = __mk_disconnect_guard($db_file)) {
 239           $dbh->{Callbacks} = {
 240             connect => sub { $guard_cb->('connect') },
 241             disconnect => sub { $guard_cb->('disconnect') },
 242             DESTROY => sub { $guard_cb->('DESTROY') },
 243           };
 244         }
 245       },
 246       %args,
 247     });
 248 }
 249
 250 sub __mk_disconnect_guard {
 251   return if DBIx::Class::_ENV_::PEEPEENESS; # leaks handles, delaying DESTROY, can't work right
 252
 253   my $db_file = shift;
 254   return unless -f $db_file;
 255
 256   my $orig_inode = (stat($db_file))[1]
 257     or return;
 258
 259   my $clan_connect_caller = '*UNKNOWN*';
 260   my $i;
 261   while ( my ($pack, $file, $line) = caller(++$i) ) {
 262     next if $file eq __FILE__;
 263     next if $pack =~ /^DBIx::Class|^Try::Tiny/;
 264     $clan_connect_caller = "$file line $line";
 265   }
 266
 267   my $failed_once = 0;
 268   my $connected = 1;
 269
 270   return sub {
 271     return if $failed_once;
 272
 273     my $event = shift;
 274     if ($event eq 'connect') {
 275       # this is necessary in case we are disconnected and connected again, all within the same $dbh object
 276       $connected = 1;
 277       return;
 278     }
 279     elsif ($event eq 'disconnect') {
 280       $connected = 0;
 281     }
 282     elsif ($event eq 'DESTROY' and ! $connected ) {
 283       return;
 284     }
 285
 286     my $fail_reason;
 287     if (! -e $db_file) {
 288       $fail_reason = 'is missing';
 289     }
 290     else {
 291       my $cur_inode = (stat($db_file))[1];
 292
 293       if ($orig_inode != $cur_inode) {
 294         my @inodes = ($orig_inode, $cur_inode);
 295         # unless this is a fixed perl (P5RT#84590) pack/unpack before display
 296         # to match the unsigned longs returned by `stat`
 297         @inodes = map { unpack ('L', pack ('l', $_) ) } @inodes
 298           unless $Config{st_ino_size};
 299
 300         $fail_reason = sprintf
 301           'was recreated (initially inode %s, now %s)',
 302           @inodes
 303         ;
 304       }
 305     }
 306
 307     if ($fail_reason) {
 308       $failed_once++;
 309
 310       require Test::Builder;
 311       my $t = Test::Builder->new;
 312       local $Test::Builder::Level = $Test::Builder::Level + 3;
 313       $t->ok (0,
 314         "$db_file originally created at $clan_connect_caller $fail_reason before $event "
 315       . 'of DBI handle - a strong indicator that the database file was tampered with while '
 316       . 'still being open. This action would fail massively if running under Win32, hence '
 317       . 'we make sure it fails on any OS :)'
 318       );
 319     }
 320
 321     return; # this empty return is a DBI requirement
 322   };
 323 }
 324
 325 my $weak_registry = {};
 326
 327 sub init_schema {
 328     my $self = shift;
 329     my %args = @_;
 330
 331     my $schema;
 332
 333     if ($args{compose_connection}) {
 334       $schema = DBICTest::Schema->compose_connection(
 335                   'DBICTest', $self->_database(%args)
 336                 );
 337     } else {
 338       $schema = DBICTest::Schema->compose_namespace('DBICTest');
 339     }
 340
 341     if( $args{storage_type}) {
 342       $schema->storage_type($args{storage_type});
 343     }
 344
 345     if ( !$args{no_connect} ) {
 346       $schema = $schema->connect($self->_database(%args));
 347     }
 348
 349     if ( !$args{no_deploy} ) {
 350         __PACKAGE__->deploy_schema( $schema, $args{deploy_args} );
 351         __PACKAGE__->populate_schema( $schema )
 352          if( !$args{no_populate} );
 353     }
 354
 355     populate_weakregistry ( $weak_registry, $schema->storage )
 356       if $INC{'Test/Builder.pm'} and $schema->storage;
 357
 358     return $schema;
 359 }
 360
 361 END {
 362     assert_empty_weakregistry($weak_registry, 'quiet');
 363 }
 364
 365 =head2 deploy_schema
 366
 367   DBICTest->deploy_schema( $schema );
 368
 369 This method does one of two things to the schema.  It can either call
 370 the experimental $schema->deploy() if the DBICTEST_SQLT_DEPLOY environment
 371 variable is set, otherwise the default is to read in the t/lib/sqlite.sql
 372 file and execute the SQL within. Either way you end up with a fresh set
 373 of tables for testing.
 374
 375 =cut
 376
 377 sub deploy_schema {
 378     my $self = shift;
 379     my $schema = shift;
 380     my $args = shift || {};
 381
 382     local $schema->storage->{debug}
 383       if ($ENV{TRAVIS}||'') eq 'true';
 384
 385     if ($ENV{"DBICTEST_SQLT_DEPLOY"}) {
 386         $schema->deploy($args);
 387     } else {
 388         my $filename = Path::Class::File->new(__FILE__)->dir
 389           ->file('sqlite.sql')->stringify;
 390         my $sql = do { local (@ARGV, $/) = $filename ; <> };
 391         for my $chunk ( split (/;\s*\n+/, $sql) ) {
 392           if ( $chunk =~ / ^ (?! --\s* ) \S /xm ) {  # there is some real sql in the chunk - a non-space at the start of the string which is not a comment
 393             $schema->storage->dbh_do(sub { $_[1]->do($chunk) }) or print "Error on SQL: $chunk\n";
 394           }
 395         }
 396     }
 397     return;
 398 }
 399
 400 =head2 populate_schema
 401
 402   DBICTest->populate_schema( $schema );
 403
 404 After you deploy your schema you can use this method to populate
 405 the tables with test data.
 406
 407 =cut
 408
 409 sub populate_schema {
 410     my $self = shift;
 411     my $schema = shift;
 412
 413     local $schema->storage->{debug}
 414       if ($ENV{TRAVIS}||'') eq 'true';
 415
 416     $schema->populate('Genre', [
 417       [qw/genreid name/],
 418       [qw/1       emo  /],
 419     ]);
 420
 421     $schema->populate('Artist', [
 422         [ qw/artistid name/ ],
 423         [ 1, 'Caterwauler McCrae' ],
 424         [ 2, 'Random Boy Band' ],
 425         [ 3, 'We Are Goth' ],
 426     ]);
 427
 428     $schema->populate('CD', [
 429         [ qw/cdid artist title year genreid/ ],
 430         [ 1, 1, "Spoonful of bees", 1999, 1 ],
 431         [ 2, 1, "Forkful of bees", 2001 ],
 432         [ 3, 1, "Caterwaulin' Blues", 1997 ],
 433         [ 4, 2, "Generic Manufactured Singles", 2001 ],
 434         [ 5, 3, "Come Be Depressed With Us", 1998 ],
 435     ]);
 436
 437     $schema->populate('LinerNotes', [
 438         [ qw/liner_id notes/ ],
 439         [ 2, "Buy Whiskey!" ],
 440         [ 4, "Buy Merch!" ],
 441         [ 5, "Kill Yourself!" ],
 442     ]);
 443
 444     $schema->populate('Tag', [
 445         [ qw/tagid cd tag/ ],
 446         [ 1, 1, "Blue" ],
 447         [ 2, 2, "Blue" ],
 448         [ 3, 3, "Blue" ],
 449         [ 4, 5, "Blue" ],
 450         [ 5, 2, "Cheesy" ],
 451         [ 6, 4, "Cheesy" ],
 452         [ 7, 5, "Cheesy" ],
 453         [ 8, 2, "Shiny" ],
 454         [ 9, 4, "Shiny" ],
 455     ]);
 456
 457     $schema->populate('TwoKeys', [
 458         [ qw/artist cd/ ],
 459         [ 1, 1 ],
 460         [ 1, 2 ],
 461         [ 2, 2 ],
 462     ]);
 463
 464     $schema->populate('FourKeys', [
 465         [ qw/foo bar hello goodbye sensors/ ],
 466         [ 1, 2, 3, 4, 'online' ],
 467         [ 5, 4, 3, 6, 'offline' ],
 468     ]);
 469
 470     $schema->populate('OneKey', [
 471         [ qw/id artist cd/ ],
 472         [ 1, 1, 1 ],
 473         [ 2, 1, 2 ],
 474         [ 3, 2, 2 ],
 475     ]);
 476
 477     $schema->populate('SelfRef', [
 478         [ qw/id name/ ],
 479         [ 1, 'First' ],
 480         [ 2, 'Second' ],
 481     ]);
 482
 483     $schema->populate('SelfRefAlias', [
 484         [ qw/self_ref alias/ ],
 485         [ 1, 2 ]
 486     ]);
 487
 488     $schema->populate('ArtistUndirectedMap', [
 489         [ qw/id1 id2/ ],
 490         [ 1, 2 ]
 491     ]);
 492
 493     $schema->populate('Producer', [
 494         [ qw/producerid name/ ],
 495         [ 1, 'Matt S Trout' ],
 496         [ 2, 'Bob The Builder' ],
 497         [ 3, 'Fred The Phenotype' ],
 498     ]);
 499
 500     $schema->populate('CD_to_Producer', [
 501         [ qw/cd producer/ ],
 502         [ 1, 1 ],
 503         [ 1, 2 ],
 504         [ 1, 3 ],
 505     ]);
 506
 507     $schema->populate('TreeLike', [
 508         [ qw/id parent name/ ],
 509         [ 1, undef, 'root' ],
 510         [ 2, 1, 'foo'  ],
 511         [ 3, 2, 'bar'  ],
 512         [ 6, 2, 'blop' ],
 513         [ 4, 3, 'baz'  ],
 514         [ 5, 4, 'quux' ],
 515         [ 7, 3, 'fong'  ],
 516     ]);
 517
 518     $schema->populate('Track', [
 519         [ qw/trackid cd  position title/ ],
 520         [ 4, 2, 1, "Stung with Success"],
 521         [ 5, 2, 2, "Stripy"],
 522         [ 6, 2, 3, "Sticky Honey"],
 523         [ 7, 3, 1, "Yowlin"],
 524         [ 8, 3, 2, "Howlin"],
 525         [ 9, 3, 3, "Fowlin"],
 526         [ 10, 4, 1, "Boring Name"],
 527         [ 11, 4, 2, "Boring Song"],
 528         [ 12, 4, 3, "No More Ideas"],
 529         [ 13, 5, 1, "Sad"],
 530         [ 14, 5, 2, "Under The Weather"],
 531         [ 15, 5, 3, "Suicidal"],
 532         [ 16, 1, 1, "The Bees Knees"],
 533         [ 17, 1, 2, "Apiary"],
 534         [ 18, 1, 3, "Beehind You"],
 535     ]);
 536
 537     $schema->populate('Event', [
 538         [ qw/id starts_at created_on varchar_date varchar_datetime skip_inflation/ ],
 539         [ 1, '2006-04-25 22:24:33', '2006-06-22 21:00:05', '2006-07-23', '2006-05-22 19:05:07', '2006-04-21 18:04:06'],
 540     ]);
 541
 542     $schema->populate('Link', [
 543         [ qw/id url title/ ],
 544         [ 1, '', 'aaa' ]
 545     ]);
 546
 547     $schema->populate('Bookmark', [
 548         [ qw/id link/ ],
 549         [ 1, 1 ]
 550     ]);
 551
 552     $schema->populate('Collection', [
 553         [ qw/collectionid name/ ],
 554         [ 1, "Tools" ],
 555         [ 2, "Body Parts" ],
 556     ]);
 557
 558     $schema->populate('TypedObject', [
 559         [ qw/objectid type value/ ],
 560         [ 1, "pointy", "Awl" ],
 561         [ 2, "round", "Bearing" ],
 562         [ 3, "pointy", "Knife" ],
 563         [ 4, "pointy", "Tooth" ],
 564         [ 5, "round", "Head" ],
 565     ]);
 566     $schema->populate('CollectionObject', [
 567         [ qw/collection object/ ],
 568         [ 1, 1 ],
 569         [ 1, 2 ],
 570         [ 1, 3 ],
 571         [ 2, 4 ],
 572         [ 2, 5 ],
 573     ]);
 574
 575     $schema->populate('Owners', [
 576         [ qw/id name/ ],
 577         [ 1, "Newton" ],
 578         [ 2, "Waltham" ],
 579     ]);
 580
 581     $schema->populate('BooksInLibrary', [
 582         [ qw/id owner title source price/ ],
 583         [ 1, 1, "Programming Perl", "Library", 23 ],
 584         [ 2, 1, "Dynamical Systems", "Library",  37 ],
 585         [ 3, 2, "Best Recipe Cookbook", "Library", 65 ],
 586     ]);
 587 }
 588
 589 1;