t/lib/DBICTest.pm

   1 package # hide from PAUSE
   2     DBICTest;
   3
   4 use strict;
   5 use warnings;
   6
   7 # this noop trick initializes the STDOUT, so that the TAP::Harness
   8 # issued IO::Select->can_read calls (which are blocking wtf wtf wtf)
   9 # keep spinning and scheduling jobs
  10 # This results in an overall much smoother job-queue drainage, since
  11 # the Harness blocks less
  12 # (ideally this needs to be addressed in T::H, but a quick patchjob
  13 # broke everything so tabling it for now)
  14 BEGIN {
  15   if ($INC{'Test/Builder.pm'}) {
  16     local $| = 1;
  17     print "#\n";
  18   }
  19 }
  20
  21 use Module::Runtime 'module_notional_filename';
  22 BEGIN {
  23   for my $mod (qw( DBIC::SqlMakerTest SQL::Abstract )) {
  24     if ( $INC{ module_notional_filename($mod) } ) {
  25       # FIXME this does not seem to work in BEGIN - why?!
  26       #require Carp;
  27       #$Carp::Internal{ (__PACKAGE__) }++;
  28       #Carp::croak( __PACKAGE__ . " must be loaded before $mod" );
  29
  30       my ($fr, @frame) = 1;
  31       while (@frame = caller($fr++)) {
  32         last if $frame[1] !~ m|^t/lib/DBICTest|;
  33       }
  34
  35       die __PACKAGE__ . " must be loaded before $mod (or modules using $mod) at $frame[1] line $frame[2]\n";
  36     }
  37   }
  38 }
  39
  40 use DBICTest::RunMode;
  41 use DBICTest::Schema;
  42 use DBICTest::Util::LeakTracer qw/populate_weakregistry assert_empty_weakregistry/;
  43 use DBICTest::Util 'local_umask';
  44 use Carp;
  45 use Path::Class::File ();
  46 use File::Spec;
  47 use Fcntl qw/:DEFAULT :flock/;
  48 use Config;
  49
  50 =head1 NAME
  51
  52 DBICTest - Library to be used by DBIx::Class test scripts.
  53
  54 =head1 SYNOPSIS
  55
  56   use lib qw(t/lib);
  57   use DBICTest;
  58   use Test::More;
  59
  60   my $schema = DBICTest->init_schema();
  61
  62 =head1 DESCRIPTION
  63
  64 This module provides the basic utilities to write tests against
  65 DBIx::Class.
  66
  67 =head1 METHODS
  68
  69 =head2 init_schema
  70
  71   my $schema = DBICTest->init_schema(
  72     no_deploy=>1,
  73     no_populate=>1,
  74     storage_type=>'::DBI::Replicated',
  75     storage_type_args=>{
  76       balancer_type=>'DBIx::Class::Storage::DBI::Replicated::Balancer::Random'
  77     },
  78   );
  79
  80 This method removes the test SQLite database in t/var/DBIxClass.db
  81 and then creates a new, empty database.
  82
  83 This method will call deploy_schema() by default, unless the
  84 no_deploy flag is set.
  85
  86 Also, by default, this method will call populate_schema() by
  87 default, unless the no_deploy or no_populate flags are set.
  88
  89 =cut
  90
  91 # some tests are very time sensitive and need to run on their own, without
  92 # being disturbed by anything else grabbing CPU or disk IO. Hence why everything
  93 # using DBICTest grabs a shared lock, and the few tests that request a :GlobalLock
  94 # will ask for an exclusive one and block until they can get it
  95 our ($global_lock_fh, $global_exclusive_lock);
  96 sub import {
  97     my $self = shift;
  98
  99     my $lockpath = DBICTest::RunMode->tmpdir->file('_dbictest_global.lock');
 100
 101     {
 102       my $u = local_umask(0); # so that the file opens as 666, and any user can lock
 103       sysopen ($global_lock_fh, $lockpath, O_RDWR|O_CREAT)
 104         or die "Unable to open $lockpath: $!";
 105     }
 106
 107     for (@_) {
 108         if ($_ eq ':GlobalLock') {
 109             flock ($global_lock_fh, LOCK_EX) or die "Unable to lock $lockpath: $!";
 110             $global_exclusive_lock = 1;
 111         }
 112         else {
 113             croak "Unknown export $_ requested from $self";
 114         }
 115     }
 116
 117     unless ($global_exclusive_lock) {
 118         flock ($global_lock_fh, LOCK_SH) or die "Unable to lock $lockpath: $!";
 119     }
 120 }
 121
 122 END {
 123     if ($global_lock_fh) {
 124         # delay destruction even more
 125     }
 126 }
 127
 128 {
 129     my $dir = Path::Class::File->new(__FILE__)->dir->parent->subdir('var');
 130     $dir->mkpath unless -d "$dir";
 131     $dir = "$dir";
 132
 133     sub _sqlite_dbfilename {
 134         my $holder = $ENV{DBICTEST_LOCK_HOLDER} || $$;
 135         $holder = $$ if $holder == -1;
 136
 137         # useful for missing cleanup debugging
 138         #if ( $holder == $$) {
 139         #  my $x = $0;
 140         #  $x =~ s/\//#/g;
 141         #  $holder .= "-$x";
 142         #}
 143
 144         return "$dir/DBIxClass-$holder.db";
 145     }
 146
 147     END {
 148         _cleanup_dbfile();
 149     }
 150 }
 151
 152 $SIG{INT} = sub { _cleanup_dbfile(); exit 1 };
 153
 154 sub _cleanup_dbfile {
 155     # cleanup if this is us
 156     if (
 157       ! $ENV{DBICTEST_LOCK_HOLDER}
 158         or
 159       $ENV{DBICTEST_LOCK_HOLDER} == -1
 160         or
 161       $ENV{DBICTEST_LOCK_HOLDER} == $$
 162     ) {
 163         my $db_file = _sqlite_dbfilename();
 164         unlink $_ for ($db_file, "${db_file}-journal");
 165     }
 166 }
 167
 168 sub has_custom_dsn {
 169     return $ENV{"DBICTEST_DSN"} ? 1:0;
 170 }
 171
 172 sub _sqlite_dbname {
 173     my $self = shift;
 174     my %args = @_;
 175     return $self->_sqlite_dbfilename if (
 176       defined $args{sqlite_use_file} ? $args{sqlite_use_file} : $ENV{'DBICTEST_SQLITE_USE_FILE'}
 177     );
 178     return ":memory:";
 179 }
 180
 181 sub _database {
 182     my $self = shift;
 183     my %args = @_;
 184
 185     if ($ENV{DBICTEST_DSN}) {
 186       return (
 187         (map { $ENV{"DBICTEST_${_}"} || '' } qw/DSN DBUSER DBPASS/),
 188         { AutoCommit => 1, %args },
 189       );
 190     }
 191     my $db_file = $self->_sqlite_dbname(%args);
 192
 193     for ($db_file, "${db_file}-journal") {
 194       next unless -e $_;
 195       unlink ($_) or carp (
 196         "Unable to unlink existing test database file $_ ($!), creation of fresh database / further tests may fail!"
 197       );
 198     }
 199
 200     return ("dbi:SQLite:${db_file}", '', '', {
 201       AutoCommit => 1,
 202
 203       # this is executed on every connect, and thus installs a disconnect/DESTROY
 204       # guard for every new $dbh
 205       on_connect_do => sub {
 206
 207         my $storage = shift;
 208         my $dbh = $storage->_get_dbh;
 209
 210         # no fsync on commit
 211         $dbh->do ('PRAGMA synchronous = OFF');
 212
 213         if ($ENV{DBICTEST_SQLITE_REVERSE_DEFAULT_ORDER}) {
 214
 215           $storage->throw_exception(
 216             'PRAGMA reverse_unordered_selects does not work correctly before libsqlite 3.7.9'
 217           ) if $storage->_server_info->{normalized_dbms_version} < 3.007009;
 218
 219           $dbh->do ('PRAGMA reverse_unordered_selects = ON');
 220         }
 221
 222         # set a *DBI* disconnect callback, to make sure the physical SQLite
 223         # file is still there (i.e. the test does not attempt to delete
 224         # an open database, which fails on Win32)
 225         if (my $guard_cb = __mk_disconnect_guard($db_file)) {
 226           $dbh->{Callbacks} = {
 227             connect => sub { $guard_cb->('connect') },
 228             disconnect => sub { $guard_cb->('disconnect') },
 229             DESTROY => sub { $guard_cb->('DESTROY') },
 230           };
 231         }
 232       },
 233       %args,
 234     });
 235 }
 236
 237 sub __mk_disconnect_guard {
 238   return if DBIx::Class::_ENV_::PEEPEENESS; # leaks handles, delaying DESTROY, can't work right
 239
 240   my $db_file = shift;
 241   return unless -f $db_file;
 242
 243   my $orig_inode = (stat($db_file))[1]
 244     or return;
 245
 246   my $clan_connect_caller = '*UNKNOWN*';
 247   my $i;
 248   while ( my ($pack, $file, $line) = caller(++$i) ) {
 249     next if $file eq __FILE__;
 250     next if $pack =~ /^DBIx::Class|^Try::Tiny/;
 251     $clan_connect_caller = "$file line $line";
 252   }
 253
 254   my $failed_once = 0;
 255   my $connected = 1;
 256
 257   return sub {
 258     return if $failed_once;
 259
 260     my $event = shift;
 261     if ($event eq 'connect') {
 262       # this is necessary in case we are disconnected and connected again, all within the same $dbh object
 263       $connected = 1;
 264       return;
 265     }
 266     elsif ($event eq 'disconnect') {
 267       $connected = 0;
 268     }
 269     elsif ($event eq 'DESTROY' and ! $connected ) {
 270       return;
 271     }
 272
 273     my $fail_reason;
 274     if (! -e $db_file) {
 275       $fail_reason = 'is missing';
 276     }
 277     else {
 278       my $cur_inode = (stat($db_file))[1];
 279
 280       if ($orig_inode != $cur_inode) {
 281         my @inodes = ($orig_inode, $cur_inode);
 282         # unless this is a fixed perl (P5RT#84590) pack/unpack before display
 283         # to match the unsigned longs returned by `stat`
 284         @inodes = map { unpack ('L', pack ('l', $_) ) } @inodes
 285           unless $Config{st_ino_size};
 286
 287         $fail_reason = sprintf
 288           'was recreated (initially inode %s, now %s)',
 289           @inodes
 290         ;
 291       }
 292     }
 293
 294     if ($fail_reason) {
 295       $failed_once++;
 296
 297       require Test::Builder;
 298       my $t = Test::Builder->new;
 299       local $Test::Builder::Level = $Test::Builder::Level + 3;
 300       $t->ok (0,
 301         "$db_file originally created at $clan_connect_caller $fail_reason before $event "
 302       . 'of DBI handle - a strong indicator that the database file was tampered with while '
 303       . 'still being open. This action would fail massively if running under Win32, hence '
 304       . 'we make sure it fails on any OS :)'
 305       );
 306     }
 307
 308     return; # this empty return is a DBI requirement
 309   };
 310 }
 311
 312 my $weak_registry = {};
 313
 314 sub init_schema {
 315     my $self = shift;
 316     my %args = @_;
 317
 318     my $schema;
 319
 320     if ($args{compose_connection}) {
 321       $schema = DBICTest::Schema->compose_connection(
 322                   'DBICTest', $self->_database(%args)
 323                 );
 324     } else {
 325       $schema = DBICTest::Schema->compose_namespace('DBICTest');
 326     }
 327
 328     if( $args{storage_type}) {
 329       $schema->storage_type($args{storage_type});
 330     }
 331
 332     if ( !$args{no_connect} ) {
 333       $schema = $schema->connect($self->_database(%args));
 334     }
 335
 336     if ( !$args{no_deploy} ) {
 337         __PACKAGE__->deploy_schema( $schema, $args{deploy_args} );
 338         __PACKAGE__->populate_schema( $schema )
 339          if( !$args{no_populate} );
 340     }
 341
 342     populate_weakregistry ( $weak_registry, $schema->storage )
 343       if $INC{'Test/Builder.pm'} and $schema->storage;
 344
 345     return $schema;
 346 }
 347
 348 END {
 349     assert_empty_weakregistry($weak_registry, 'quiet');
 350 }
 351
 352 =head2 deploy_schema
 353
 354   DBICTest->deploy_schema( $schema );
 355
 356 This method does one of two things to the schema.  It can either call
 357 the experimental $schema->deploy() if the DBICTEST_SQLT_DEPLOY environment
 358 variable is set, otherwise the default is to read in the t/lib/sqlite.sql
 359 file and execute the SQL within. Either way you end up with a fresh set
 360 of tables for testing.
 361
 362 =cut
 363
 364 sub deploy_schema {
 365     my $self = shift;
 366     my $schema = shift;
 367     my $args = shift || {};
 368
 369     local $schema->storage->{debug}
 370       if ($ENV{TRAVIS}||'') eq 'true';
 371
 372     if ($ENV{"DBICTEST_SQLT_DEPLOY"}) {
 373         $schema->deploy($args);
 374     } else {
 375         my $filename = Path::Class::File->new(__FILE__)->dir
 376           ->file('sqlite.sql')->stringify;
 377         my $sql = do { local (@ARGV, $/) = $filename ; <> };
 378         for my $chunk ( split (/;\s*\n+/, $sql) ) {
 379           if ( $chunk =~ / ^ (?! --\s* ) \S /xm ) {  # there is some real sql in the chunk - a non-space at the start of the string which is not a comment
 380             $schema->storage->dbh_do(sub { $_[1]->do($chunk) }) or print "Error on SQL: $chunk\n";
 381           }
 382         }
 383     }
 384     return;
 385 }
 386
 387 =head2 populate_schema
 388
 389   DBICTest->populate_schema( $schema );
 390
 391 After you deploy your schema you can use this method to populate
 392 the tables with test data.
 393
 394 =cut
 395
 396 sub populate_schema {
 397     my $self = shift;
 398     my $schema = shift;
 399
 400     local $schema->storage->{debug}
 401       if ($ENV{TRAVIS}||'') eq 'true';
 402
 403     $schema->populate('Genre', [
 404       [qw/genreid name/],
 405       [qw/1       emo  /],
 406     ]);
 407
 408     $schema->populate('Artist', [
 409         [ qw/artistid name/ ],
 410         [ 1, 'Caterwauler McCrae' ],
 411         [ 2, 'Random Boy Band' ],
 412         [ 3, 'We Are Goth' ],
 413     ]);
 414
 415     $schema->populate('CD', [
 416         [ qw/cdid artist title year genreid/ ],
 417         [ 1, 1, "Spoonful of bees", 1999, 1 ],
 418         [ 2, 1, "Forkful of bees", 2001 ],
 419         [ 3, 1, "Caterwaulin' Blues", 1997 ],
 420         [ 4, 2, "Generic Manufactured Singles", 2001 ],
 421         [ 5, 3, "Come Be Depressed With Us", 1998 ],
 422     ]);
 423
 424     $schema->populate('LinerNotes', [
 425         [ qw/liner_id notes/ ],
 426         [ 2, "Buy Whiskey!" ],
 427         [ 4, "Buy Merch!" ],
 428         [ 5, "Kill Yourself!" ],
 429     ]);
 430
 431     $schema->populate('Tag', [
 432         [ qw/tagid cd tag/ ],
 433         [ 1, 1, "Blue" ],
 434         [ 2, 2, "Blue" ],
 435         [ 3, 3, "Blue" ],
 436         [ 4, 5, "Blue" ],
 437         [ 5, 2, "Cheesy" ],
 438         [ 6, 4, "Cheesy" ],
 439         [ 7, 5, "Cheesy" ],
 440         [ 8, 2, "Shiny" ],
 441         [ 9, 4, "Shiny" ],
 442     ]);
 443
 444     $schema->populate('TwoKeys', [
 445         [ qw/artist cd/ ],
 446         [ 1, 1 ],
 447         [ 1, 2 ],
 448         [ 2, 2 ],
 449     ]);
 450
 451     $schema->populate('FourKeys', [
 452         [ qw/foo bar hello goodbye sensors/ ],
 453         [ 1, 2, 3, 4, 'online' ],
 454         [ 5, 4, 3, 6, 'offline' ],
 455     ]);
 456
 457     $schema->populate('OneKey', [
 458         [ qw/id artist cd/ ],
 459         [ 1, 1, 1 ],
 460         [ 2, 1, 2 ],
 461         [ 3, 2, 2 ],
 462     ]);
 463
 464     $schema->populate('SelfRef', [
 465         [ qw/id name/ ],
 466         [ 1, 'First' ],
 467         [ 2, 'Second' ],
 468     ]);
 469
 470     $schema->populate('SelfRefAlias', [
 471         [ qw/self_ref alias/ ],
 472         [ 1, 2 ]
 473     ]);
 474
 475     $schema->populate('ArtistUndirectedMap', [
 476         [ qw/id1 id2/ ],
 477         [ 1, 2 ]
 478     ]);
 479
 480     $schema->populate('Producer', [
 481         [ qw/producerid name/ ],
 482         [ 1, 'Matt S Trout' ],
 483         [ 2, 'Bob The Builder' ],
 484         [ 3, 'Fred The Phenotype' ],
 485     ]);
 486
 487     $schema->populate('CD_to_Producer', [
 488         [ qw/cd producer/ ],
 489         [ 1, 1 ],
 490         [ 1, 2 ],
 491         [ 1, 3 ],
 492     ]);
 493
 494     $schema->populate('TreeLike', [
 495         [ qw/id parent name/ ],
 496         [ 1, undef, 'root' ],
 497         [ 2, 1, 'foo'  ],
 498         [ 3, 2, 'bar'  ],
 499         [ 6, 2, 'blop' ],
 500         [ 4, 3, 'baz'  ],
 501         [ 5, 4, 'quux' ],
 502         [ 7, 3, 'fong'  ],
 503     ]);
 504
 505     $schema->populate('Track', [
 506         [ qw/trackid cd  position title/ ],
 507         [ 4, 2, 1, "Stung with Success"],
 508         [ 5, 2, 2, "Stripy"],
 509         [ 6, 2, 3, "Sticky Honey"],
 510         [ 7, 3, 1, "Yowlin"],
 511         [ 8, 3, 2, "Howlin"],
 512         [ 9, 3, 3, "Fowlin"],
 513         [ 10, 4, 1, "Boring Name"],
 514         [ 11, 4, 2, "Boring Song"],
 515         [ 12, 4, 3, "No More Ideas"],
 516         [ 13, 5, 1, "Sad"],
 517         [ 14, 5, 2, "Under The Weather"],
 518         [ 15, 5, 3, "Suicidal"],
 519         [ 16, 1, 1, "The Bees Knees"],
 520         [ 17, 1, 2, "Apiary"],
 521         [ 18, 1, 3, "Beehind You"],
 522     ]);
 523
 524     $schema->populate('Event', [
 525         [ qw/id starts_at created_on varchar_date varchar_datetime skip_inflation/ ],
 526         [ 1, '2006-04-25 22:24:33', '2006-06-22 21:00:05', '2006-07-23', '2006-05-22 19:05:07', '2006-04-21 18:04:06'],
 527     ]);
 528
 529     $schema->populate('Link', [
 530         [ qw/id url title/ ],
 531         [ 1, '', 'aaa' ]
 532     ]);
 533
 534     $schema->populate('Bookmark', [
 535         [ qw/id link/ ],
 536         [ 1, 1 ]
 537     ]);
 538
 539     $schema->populate('Collection', [
 540         [ qw/collectionid name/ ],
 541         [ 1, "Tools" ],
 542         [ 2, "Body Parts" ],
 543     ]);
 544
 545     $schema->populate('TypedObject', [
 546         [ qw/objectid type value/ ],
 547         [ 1, "pointy", "Awl" ],
 548         [ 2, "round", "Bearing" ],
 549         [ 3, "pointy", "Knife" ],
 550         [ 4, "pointy", "Tooth" ],
 551         [ 5, "round", "Head" ],
 552     ]);
 553     $schema->populate('CollectionObject', [
 554         [ qw/collection object/ ],
 555         [ 1, 1 ],
 556         [ 1, 2 ],
 557         [ 1, 3 ],
 558         [ 2, 4 ],
 559         [ 2, 5 ],
 560     ]);
 561
 562     $schema->populate('Owners', [
 563         [ qw/id name/ ],
 564         [ 1, "Newton" ],
 565         [ 2, "Waltham" ],
 566     ]);
 567
 568     $schema->populate('BooksInLibrary', [
 569         [ qw/id owner title source price/ ],
 570         [ 1, 1, "Programming Perl", "Library", 23 ],
 571         [ 2, 1, "Dynamical Systems", "Library",  37 ],
 572         [ 3, 2, "Best Recipe Cookbook", "Library", 65 ],
 573     ]);
 574 }
 575
 576 1;