t/lib/DBICTest.pm

   1 package # hide from PAUSE
   2     DBICTest;
   3
   4 use strict;
   5 use warnings;
   6
   7 # this noop trick initializes the STDOUT, so that the TAP::Harness
   8 # issued IO::Select->can_read calls (which are blocking wtf wtf wtf)
   9 # keep spinning and scheduling jobs
  10 # This results in an overall much smoother job-queue drainage, since
  11 # the Harness blocks less
  12 # (ideally this needs to be addressed in T::H, but a quick patchjob
  13 # broke everything so tabling it for now)
  14 BEGIN {
  15   if ($INC{'Test/Builder.pm'}) {
  16     local $| = 1;
  17     print "#\n";
  18   }
  19 }
  20
  21 use Module::Runtime 'module_notional_filename';
  22 BEGIN {
  23   for my $mod (qw( DBIC::SqlMakerTest SQL::Abstract )) {
  24     if ( $INC{ module_notional_filename($mod) } ) {
  25       # FIXME this does not seem to work in BEGIN - why?!
  26       #require Carp;
  27       #$Carp::Internal{ (__PACKAGE__) }++;
  28       #Carp::croak( __PACKAGE__ . " must be loaded before $mod" );
  29
  30       my ($fr, @frame) = 1;
  31       while (@frame = caller($fr++)) {
  32         last if $frame[1] !~ m|^t/lib/DBICTest|;
  33       }
  34
  35       die __PACKAGE__ . " must be loaded before $mod (or modules using $mod) at $frame[1] line $frame[2]\n";
  36     }
  37   }
  38 }
  39
  40 use DBICTest::RunMode;
  41 use DBICTest::Schema;
  42 use DBICTest::Util::LeakTracer qw/populate_weakregistry assert_empty_weakregistry/;
  43 use DBICTest::Util 'local_umask';
  44 use Carp;
  45 use Path::Class::File ();
  46 use File::Spec;
  47 use Fcntl qw/:DEFAULT :flock/;
  48
  49 =head1 NAME
  50
  51 DBICTest - Library to be used by DBIx::Class test scripts.
  52
  53 =head1 SYNOPSIS
  54
  55   use lib qw(t/lib);
  56   use DBICTest;
  57   use Test::More;
  58
  59   my $schema = DBICTest->init_schema();
  60
  61 =head1 DESCRIPTION
  62
  63 This module provides the basic utilities to write tests against
  64 DBIx::Class.
  65
  66 =head1 METHODS
  67
  68 =head2 init_schema
  69
  70   my $schema = DBICTest->init_schema(
  71     no_deploy=>1,
  72     no_populate=>1,
  73     storage_type=>'::DBI::Replicated',
  74     storage_type_args=>{
  75       balancer_type=>'DBIx::Class::Storage::DBI::Replicated::Balancer::Random'
  76     },
  77   );
  78
  79 This method removes the test SQLite database in t/var/DBIxClass.db
  80 and then creates a new, empty database.
  81
  82 This method will call deploy_schema() by default, unless the
  83 no_deploy flag is set.
  84
  85 Also, by default, this method will call populate_schema() by
  86 default, unless the no_deploy or no_populate flags are set.
  87
  88 =cut
  89
  90 # some tests are very time sensitive and need to run on their own, without
  91 # being disturbed by anything else grabbing CPU or disk IO. Hence why everything
  92 # using DBICTest grabs a shared lock, and the few tests that request a :GlobalLock
  93 # will ask for an exclusive one and block until they can get it
  94 our ($global_lock_fh, $global_exclusive_lock);
  95 sub import {
  96     my $self = shift;
  97
  98     my $tmpdir = DBICTest::RunMode->tmpdir;
  99     my $lockpath = $tmpdir->file('.dbictest_global.lock');
 100
 101     {
 102       my $u = local_umask(0); # so that the file opens as 666, and any user can lock
 103       sysopen ($global_lock_fh, $lockpath, O_RDWR|O_CREAT) or do {
 104         my $err = $!;
 105
 106         my @x_tests = map { (defined $_) ? ( $_ ? 1 : 0 ) : 'U' } map {(-e, -d, -f, -r, -w, -x, -o)} ($tmpdir, $lockpath);
 107
 108         die sprintf <<"EOE", $lockpath, $err, scalar $>, scalar $), (stat($tmpdir))[4,5,2], @x_tests;
 109 Unable to open %s: %s
 110 Process EUID/EGID: %s / %s
 111 TmpDir UID/GID:    %s / %s
 112 TmpDir StatMode:   %o
 113 TmpDir X-tests:    -e:%s -d:%s -f:%s -r:%s -w:%s -x:%s -o:%s
 114 TmpFile X-tests:   -e:%s -d:%s -f:%s -r:%s -w:%s -x:%s -o:%s
 115 EOE
 116       };
 117     }
 118
 119     for (@_) {
 120         if ($_ eq ':GlobalLock') {
 121             flock ($global_lock_fh, LOCK_EX) or die "Unable to lock $lockpath: $!";
 122             $global_exclusive_lock = 1;
 123         }
 124         else {
 125             croak "Unknown export $_ requested from $self";
 126         }
 127     }
 128
 129     unless ($global_exclusive_lock) {
 130         flock ($global_lock_fh, LOCK_SH) or die "Unable to lock $lockpath: $!";
 131     }
 132 }
 133
 134 END {
 135     if ($global_lock_fh) {
 136         # delay destruction even more
 137     }
 138 }
 139
 140 {
 141     my $dir = Path::Class::File->new(__FILE__)->dir->parent->subdir('var');
 142     $dir->mkpath unless -d "$dir";
 143     $dir = "$dir";
 144
 145     sub _sqlite_dbfilename {
 146         my $holder = $ENV{DBICTEST_LOCK_HOLDER} || $$;
 147         $holder = $$ if $holder == -1;
 148
 149         # useful for missing cleanup debugging
 150         #if ( $holder == $$) {
 151         #  my $x = $0;
 152         #  $x =~ s/\//#/g;
 153         #  $holder .= "-$x";
 154         #}
 155
 156         return "$dir/DBIxClass-$holder.db";
 157     }
 158
 159     END {
 160         _cleanup_dbfile();
 161     }
 162 }
 163
 164 $SIG{INT} = sub { _cleanup_dbfile(); exit 1 };
 165
 166 sub _cleanup_dbfile {
 167     # cleanup if this is us
 168     if (
 169       ! $ENV{DBICTEST_LOCK_HOLDER}
 170         or
 171       $ENV{DBICTEST_LOCK_HOLDER} == -1
 172         or
 173       $ENV{DBICTEST_LOCK_HOLDER} == $$
 174     ) {
 175         my $db_file = _sqlite_dbfilename();
 176         unlink $_ for ($db_file, "${db_file}-journal");
 177     }
 178 }
 179
 180 sub has_custom_dsn {
 181     return $ENV{"DBICTEST_DSN"} ? 1:0;
 182 }
 183
 184 sub _sqlite_dbname {
 185     my $self = shift;
 186     my %args = @_;
 187     return $self->_sqlite_dbfilename if (
 188       defined $args{sqlite_use_file} ? $args{sqlite_use_file} : $ENV{'DBICTEST_SQLITE_USE_FILE'}
 189     );
 190     return ":memory:";
 191 }
 192
 193 sub _database {
 194     my $self = shift;
 195     my %args = @_;
 196
 197     if ($ENV{DBICTEST_DSN}) {
 198       return (
 199         (map { $ENV{"DBICTEST_${_}"} || '' } qw/DSN DBUSER DBPASS/),
 200         { AutoCommit => 1, %args },
 201       );
 202     }
 203     my $db_file = $self->_sqlite_dbname(%args);
 204
 205     for ($db_file, "${db_file}-journal") {
 206       next unless -e $_;
 207       unlink ($_) or carp (
 208         "Unable to unlink existing test database file $_ ($!), creation of fresh database / further tests may fail!"
 209       );
 210     }
 211
 212     return ("dbi:SQLite:${db_file}", '', '', {
 213       AutoCommit => 1,
 214
 215       # this is executed on every connect, and thus installs a disconnect/DESTROY
 216       # guard for every new $dbh
 217       on_connect_do => sub {
 218         my $storage = shift;
 219         my $dbh = $storage->_get_dbh;
 220
 221         # no fsync on commit
 222         $dbh->do ('PRAGMA synchronous = OFF');
 223
 224         if ($ENV{DBICTEST_SQLITE_REVERSE_DEFAULT_ORDER}) {
 225
 226           $storage->throw_exception(
 227             'PRAGMA reverse_unordered_selects does not work correctly before libsqlite 3.7.9'
 228           ) if $storage->_server_info->{normalized_dbms_version} < 3.007009;
 229
 230           $dbh->do ('PRAGMA reverse_unordered_selects = ON');
 231         }
 232
 233         # set a *DBI* disconnect callback, to make sure the physical SQLite
 234         # file is still there (i.e. the test does not attempt to delete
 235         # an open database, which fails on Win32)
 236         if (my $guard_cb = __mk_disconnect_guard($db_file)) {
 237           $dbh->{Callbacks} = {
 238             connect => sub { $guard_cb->('connect') },
 239             disconnect => sub { $guard_cb->('disconnect') },
 240             DESTROY => sub { $guard_cb->('DESTROY') },
 241           };
 242         }
 243       },
 244       %args,
 245     });
 246 }
 247
 248 sub __mk_disconnect_guard {
 249   return if DBIx::Class::_ENV_::PEEPEENESS; # leaks handles, delaying DESTROY, can't work right
 250
 251   my $db_file = shift;
 252   return unless -f $db_file;
 253
 254   my $orig_inode = (stat($db_file))[1]
 255     or return;
 256
 257   my $clan_connect_caller = '*UNKNOWN*';
 258   my $i;
 259   while ( my ($pack, $file, $line) = caller(++$i) ) {
 260     next if $file eq __FILE__;
 261     next if $pack =~ /^DBIx::Class|^Try::Tiny/;
 262     $clan_connect_caller = "$file line $line";
 263   }
 264
 265   my $failed_once = 0;
 266   my $connected = 1;
 267
 268   return sub {
 269     return if $failed_once;
 270
 271     my $event = shift;
 272     if ($event eq 'connect') {
 273       # this is necessary in case we are disconnected and connected again, all within the same $dbh object
 274       $connected = 1;
 275       return;
 276     }
 277     elsif ($event eq 'disconnect') {
 278       $connected = 0;
 279     }
 280     elsif ($event eq 'DESTROY' and ! $connected ) {
 281       return;
 282     }
 283
 284     my $fail_reason;
 285     if (! -e $db_file) {
 286       $fail_reason = 'is missing';
 287     }
 288     else {
 289       my $cur_inode = (stat($db_file))[1];
 290
 291       if ($orig_inode != $cur_inode) {
 292         # pack/unpack to match the unsigned longs returned by `stat`
 293         $fail_reason = sprintf 'was recreated (initially inode %s, now %s)', (
 294           map { unpack ('L', pack ('l', $_) ) } ($orig_inode, $cur_inode )
 295         );
 296       }
 297     }
 298
 299     if ($fail_reason) {
 300       $failed_once++;
 301
 302       require Test::Builder;
 303       my $t = Test::Builder->new;
 304       local $Test::Builder::Level = $Test::Builder::Level + 3;
 305       $t->ok (0,
 306         "$db_file originally created at $clan_connect_caller $fail_reason before $event "
 307       . 'of DBI handle - a strong indicator that the database file was tampered with while '
 308       . 'still being open. This action would fail massively if running under Win32, hence '
 309       . 'we make sure it fails on any OS :)'
 310       );
 311     }
 312
 313     return; # this empty return is a DBI requirement
 314   };
 315 }
 316
 317 my $weak_registry = {};
 318
 319 sub init_schema {
 320     my $self = shift;
 321     my %args = @_;
 322
 323     my $schema;
 324
 325     if ($args{compose_connection}) {
 326       $schema = DBICTest::Schema->compose_connection(
 327                   'DBICTest', $self->_database(%args)
 328                 );
 329     } else {
 330       $schema = DBICTest::Schema->compose_namespace('DBICTest');
 331     }
 332
 333     if( $args{storage_type}) {
 334       $schema->storage_type($args{storage_type});
 335     }
 336
 337     if ( !$args{no_connect} ) {
 338       $schema = $schema->connect($self->_database(%args));
 339     }
 340
 341     if ( !$args{no_deploy} ) {
 342         __PACKAGE__->deploy_schema( $schema, $args{deploy_args} );
 343         __PACKAGE__->populate_schema( $schema )
 344          if( !$args{no_populate} );
 345     }
 346
 347     populate_weakregistry ( $weak_registry, $schema->storage )
 348       if $INC{'Test/Builder.pm'} and $schema->storage;
 349
 350     return $schema;
 351 }
 352
 353 END {
 354     assert_empty_weakregistry($weak_registry, 'quiet');
 355 }
 356
 357 =head2 deploy_schema
 358
 359   DBICTest->deploy_schema( $schema );
 360
 361 This method does one of two things to the schema.  It can either call
 362 the experimental $schema->deploy() if the DBICTEST_SQLT_DEPLOY environment
 363 variable is set, otherwise the default is to read in the t/lib/sqlite.sql
 364 file and execute the SQL within. Either way you end up with a fresh set
 365 of tables for testing.
 366
 367 =cut
 368
 369 sub deploy_schema {
 370     my $self = shift;
 371     my $schema = shift;
 372     my $args = shift || {};
 373
 374     local $schema->storage->{debug}
 375       if ($ENV{TRAVIS}||'') eq 'true';
 376
 377     if ($ENV{"DBICTEST_SQLT_DEPLOY"}) {
 378         $schema->deploy($args);
 379     } else {
 380         my $filename = Path::Class::File->new(__FILE__)->dir
 381           ->file('sqlite.sql')->stringify;
 382         my $sql = do { local (@ARGV, $/) = $filename ; <> };
 383         for my $chunk ( split (/;\s*\n+/, $sql) ) {
 384           if ( $chunk =~ / ^ (?! --\s* ) \S /xm ) {  # there is some real sql in the chunk - a non-space at the start of the string which is not a comment
 385             $schema->storage->dbh_do(sub { $_[1]->do($chunk) }) or print "Error on SQL: $chunk\n";
 386           }
 387         }
 388     }
 389     return;
 390 }
 391
 392 =head2 populate_schema
 393
 394   DBICTest->populate_schema( $schema );
 395
 396 After you deploy your schema you can use this method to populate
 397 the tables with test data.
 398
 399 =cut
 400
 401 sub populate_schema {
 402     my $self = shift;
 403     my $schema = shift;
 404
 405     local $schema->storage->{debug}
 406       if ($ENV{TRAVIS}||'') eq 'true';
 407
 408     $schema->populate('Genre', [
 409       [qw/genreid name/],
 410       [qw/1       emo  /],
 411     ]);
 412
 413     $schema->populate('Artist', [
 414         [ qw/artistid name/ ],
 415         [ 1, 'Caterwauler McCrae' ],
 416         [ 2, 'Random Boy Band' ],
 417         [ 3, 'We Are Goth' ],
 418     ]);
 419
 420     $schema->populate('CD', [
 421         [ qw/cdid artist title year genreid/ ],
 422         [ 1, 1, "Spoonful of bees", 1999, 1 ],
 423         [ 2, 1, "Forkful of bees", 2001 ],
 424         [ 3, 1, "Caterwaulin' Blues", 1997 ],
 425         [ 4, 2, "Generic Manufactured Singles", 2001 ],
 426         [ 5, 3, "Come Be Depressed With Us", 1998 ],
 427     ]);
 428
 429     $schema->populate('LinerNotes', [
 430         [ qw/liner_id notes/ ],
 431         [ 2, "Buy Whiskey!" ],
 432         [ 4, "Buy Merch!" ],
 433         [ 5, "Kill Yourself!" ],
 434     ]);
 435
 436     $schema->populate('Tag', [
 437         [ qw/tagid cd tag/ ],
 438         [ 1, 1, "Blue" ],
 439         [ 2, 2, "Blue" ],
 440         [ 3, 3, "Blue" ],
 441         [ 4, 5, "Blue" ],
 442         [ 5, 2, "Cheesy" ],
 443         [ 6, 4, "Cheesy" ],
 444         [ 7, 5, "Cheesy" ],
 445         [ 8, 2, "Shiny" ],
 446         [ 9, 4, "Shiny" ],
 447     ]);
 448
 449     $schema->populate('TwoKeys', [
 450         [ qw/artist cd/ ],
 451         [ 1, 1 ],
 452         [ 1, 2 ],
 453         [ 2, 2 ],
 454     ]);
 455
 456     $schema->populate('FourKeys', [
 457         [ qw/foo bar hello goodbye sensors/ ],
 458         [ 1, 2, 3, 4, 'online' ],
 459         [ 5, 4, 3, 6, 'offline' ],
 460     ]);
 461
 462     $schema->populate('OneKey', [
 463         [ qw/id artist cd/ ],
 464         [ 1, 1, 1 ],
 465         [ 2, 1, 2 ],
 466         [ 3, 2, 2 ],
 467     ]);
 468
 469     $schema->populate('SelfRef', [
 470         [ qw/id name/ ],
 471         [ 1, 'First' ],
 472         [ 2, 'Second' ],
 473     ]);
 474
 475     $schema->populate('SelfRefAlias', [
 476         [ qw/self_ref alias/ ],
 477         [ 1, 2 ]
 478     ]);
 479
 480     $schema->populate('ArtistUndirectedMap', [
 481         [ qw/id1 id2/ ],
 482         [ 1, 2 ]
 483     ]);
 484
 485     $schema->populate('Producer', [
 486         [ qw/producerid name/ ],
 487         [ 1, 'Matt S Trout' ],
 488         [ 2, 'Bob The Builder' ],
 489         [ 3, 'Fred The Phenotype' ],
 490     ]);
 491
 492     $schema->populate('CD_to_Producer', [
 493         [ qw/cd producer/ ],
 494         [ 1, 1 ],
 495         [ 1, 2 ],
 496         [ 1, 3 ],
 497     ]);
 498
 499     $schema->populate('TreeLike', [
 500         [ qw/id parent name/ ],
 501         [ 1, undef, 'root' ],
 502         [ 2, 1, 'foo'  ],
 503         [ 3, 2, 'bar'  ],
 504         [ 6, 2, 'blop' ],
 505         [ 4, 3, 'baz'  ],
 506         [ 5, 4, 'quux' ],
 507         [ 7, 3, 'fong'  ],
 508     ]);
 509
 510     $schema->populate('Track', [
 511         [ qw/trackid cd  position title/ ],
 512         [ 4, 2, 1, "Stung with Success"],
 513         [ 5, 2, 2, "Stripy"],
 514         [ 6, 2, 3, "Sticky Honey"],
 515         [ 7, 3, 1, "Yowlin"],
 516         [ 8, 3, 2, "Howlin"],
 517         [ 9, 3, 3, "Fowlin"],
 518         [ 10, 4, 1, "Boring Name"],
 519         [ 11, 4, 2, "Boring Song"],
 520         [ 12, 4, 3, "No More Ideas"],
 521         [ 13, 5, 1, "Sad"],
 522         [ 14, 5, 2, "Under The Weather"],
 523         [ 15, 5, 3, "Suicidal"],
 524         [ 16, 1, 1, "The Bees Knees"],
 525         [ 17, 1, 2, "Apiary"],
 526         [ 18, 1, 3, "Beehind You"],
 527     ]);
 528
 529     $schema->populate('Event', [
 530         [ qw/id starts_at created_on varchar_date varchar_datetime skip_inflation/ ],
 531         [ 1, '2006-04-25 22:24:33', '2006-06-22 21:00:05', '2006-07-23', '2006-05-22 19:05:07', '2006-04-21 18:04:06'],
 532     ]);
 533
 534     $schema->populate('Link', [
 535         [ qw/id url title/ ],
 536         [ 1, '', 'aaa' ]
 537     ]);
 538
 539     $schema->populate('Bookmark', [
 540         [ qw/id link/ ],
 541         [ 1, 1 ]
 542     ]);
 543
 544     $schema->populate('Collection', [
 545         [ qw/collectionid name/ ],
 546         [ 1, "Tools" ],
 547         [ 2, "Body Parts" ],
 548     ]);
 549
 550     $schema->populate('TypedObject', [
 551         [ qw/objectid type value/ ],
 552         [ 1, "pointy", "Awl" ],
 553         [ 2, "round", "Bearing" ],
 554         [ 3, "pointy", "Knife" ],
 555         [ 4, "pointy", "Tooth" ],
 556         [ 5, "round", "Head" ],
 557     ]);
 558     $schema->populate('CollectionObject', [
 559         [ qw/collection object/ ],
 560         [ 1, 1 ],
 561         [ 1, 2 ],
 562         [ 1, 3 ],
 563         [ 2, 4 ],
 564         [ 2, 5 ],
 565     ]);
 566
 567     $schema->populate('Owners', [
 568         [ qw/id name/ ],
 569         [ 1, "Newton" ],
 570         [ 2, "Waltham" ],
 571     ]);
 572
 573     $schema->populate('BooksInLibrary', [
 574         [ qw/id owner title source price/ ],
 575         [ 1, 1, "Programming Perl", "Library", 23 ],
 576         [ 2, 1, "Dynamical Systems", "Library",  37 ],
 577         [ 3, 2, "Best Recipe Cookbook", "Library", 65 ],
 578     ]);
 579 }
 580
 581 1;