t/lib/DBICTest.pm

   1 package # hide from PAUSE
   2     DBICTest;
   3
   4 use strict;
   5 use warnings;
   6 use DBICTest::RunMode;
   7 use DBICTest::Schema;
   8 use Carp;
   9
  10 =head1 NAME
  11
  12 DBICTest - Library to be used by DBIx::Class test scripts.
  13
  14 =head1 SYNOPSIS
  15
  16   use lib qw(t/lib);
  17   use DBICTest;
  18   use Test::More;
  19
  20   my $schema = DBICTest->init_schema();
  21
  22 =head1 DESCRIPTION
  23
  24 This module provides the basic utilities to write tests against
  25 DBIx::Class.
  26
  27 =head1 METHODS
  28
  29 =head2 init_schema
  30
  31   my $schema = DBICTest->init_schema(
  32     no_deploy=>1,
  33     no_populate=>1,
  34     storage_type=>'::DBI::Replicated',
  35     storage_type_args=>{
  36       balancer_type=>'DBIx::Class::Storage::DBI::Replicated::Balancer::Random'
  37     },
  38   );
  39
  40 This method removes the test SQLite database in t/var/DBIxClass.db
  41 and then creates a new, empty database.
  42
  43 This method will call deploy_schema() by default, unless the
  44 no_deploy flag is set.
  45
  46 Also, by default, this method will call populate_schema() by
  47 default, unless the no_deploy or no_populate flags are set.
  48
  49 =cut
  50
  51 sub has_custom_dsn {
  52     return $ENV{"DBICTEST_DSN"} ? 1:0;
  53 }
  54
  55 sub _sqlite_dbfilename {
  56     return "t/var/DBIxClass.db";
  57 }
  58
  59 sub _sqlite_dbname {
  60     my $self = shift;
  61     my %args = @_;
  62     return $self->_sqlite_dbfilename if $args{sqlite_use_file} or $ENV{"DBICTEST_SQLITE_USE_FILE"};
  63     return ":memory:";
  64 }
  65
  66 sub _database {
  67     my $self = shift;
  68     my %args = @_;
  69
  70     if ($ENV{DBICTEST_DSN}) {
  71       return (
  72         (map { $ENV{"DBICTEST_${_}"} || '' } qw/DSN DBUSER DBPASS/),
  73         { AutoCommit => 1, %args },
  74       );
  75     }
  76     my $db_file = $self->_sqlite_dbname(%args);
  77
  78     for ($db_file, "${db_file}-journal") {
  79       next unless -e $_;
  80       unlink ($_) or carp (
  81         "Unable to unlink existing test database file $_ ($!), creation of fresh database / further tests may fail!\n"
  82       );
  83     }
  84
  85     mkdir("t/var") unless -d "t/var";
  86
  87     return ("dbi:SQLite:${db_file}", '', '', {
  88       AutoCommit => 1,
  89
  90       # this is executed on every connect, and thus installs a disconnect/DESTROY
  91       # guard for every new $dbh
  92       on_connect_do => sub {
  93         my $storage = shift;
  94         my $dbh = $storage->_get_dbh;
  95
  96         # no fsync on commit
  97         $dbh->do ('PRAGMA synchronous = OFF');
  98
  99         # set a *DBI* disconnect callback, to make sure the physical SQLite
 100         # file is still there (i.e. the test does not attempt to delete
 101         # an open database, which fails on Win32)
 102         if (my $guard_cb = __mk_disconnect_guard($db_file)) {
 103           $dbh->{Callbacks} = {
 104             connect => sub { $guard_cb->('connect') },
 105             disconnect => sub { $guard_cb->('disconnect') },
 106             DESTROY => sub { $guard_cb->('DESTROY') },
 107           };
 108         }
 109       },
 110       %args,
 111     });
 112 }
 113
 114 sub __mk_disconnect_guard {
 115   return if $] == '5.013006'; # leaks handles, delaying DESTROY, can't work right
 116
 117   my $db_file = shift;
 118   return unless -f $db_file;
 119
 120   my $orig_inode = (stat($db_file))[1]
 121     or return;
 122
 123   my $clan_connect_caller = '*UNKNOWN*';
 124   my $i;
 125   while ( my ($pack, $file, $line) = caller(++$i) ) {
 126     next if $file eq __FILE__;
 127     next if $pack =~ /^DBIx::Class|^Try::Tiny/;
 128     $clan_connect_caller = "$file line $line";
 129   }
 130
 131   my $failed_once = 0;
 132   my $connected = 1;
 133
 134   return sub {
 135     return if $failed_once;
 136
 137     my $event = shift;
 138     if ($event eq 'connect') {
 139       # this is necessary in case we are disconnected and connected again, all within the same $dbh object
 140       $connected = 1;
 141       return;
 142     }
 143     elsif ($event eq 'disconnect') {
 144       $connected = 0;
 145     }
 146     elsif ($event eq 'DESTROY' and ! $connected ) {
 147       return;
 148     }
 149
 150     my $fail_reason;
 151     if (! -e $db_file) {
 152       $fail_reason = 'is missing';
 153     }
 154     else {
 155       my $cur_inode = (stat($db_file))[1];
 156
 157       if ($orig_inode != $cur_inode) {
 158         # pack/unpack to match the unsigned longs returned by `stat`
 159         $fail_reason = sprintf 'was recreated (initially inode %s, now %s)', (
 160           map { unpack ('L', pack ('l', $_) ) } ($orig_inode, $cur_inode )
 161         );
 162       }
 163     }
 164
 165     if ($fail_reason) {
 166       $failed_once++;
 167
 168       require Test::Builder;
 169       my $t = Test::Builder->new;
 170       local $Test::Builder::Level = $Test::Builder::Level + 3;
 171       $t->ok (0,
 172         "$db_file originally created at $clan_connect_caller $fail_reason before $event "
 173       . 'of DBI handle - a strong indicator that the database file was tampered with while '
 174       . 'still being open. This action would fail massively if running under Win32, hence '
 175       . 'we make sure it fails on any OS :)'
 176       );
 177     }
 178
 179     return; # this empty return is a DBI requirement
 180   };
 181 }
 182
 183 sub init_schema {
 184     my $self = shift;
 185     my %args = @_;
 186
 187     my $schema;
 188
 189     if ($args{compose_connection}) {
 190       $schema = DBICTest::Schema->compose_connection(
 191                   'DBICTest', $self->_database(%args)
 192                 );
 193     } else {
 194       $schema = DBICTest::Schema->compose_namespace('DBICTest');
 195     }
 196
 197     if( $args{storage_type}) {
 198       $schema->storage_type($args{storage_type});
 199     }
 200
 201     if ( !$args{no_connect} ) {
 202       $schema = $schema->connect($self->_database(%args));
 203     }
 204
 205     if ( !$args{no_deploy} ) {
 206         __PACKAGE__->deploy_schema( $schema, $args{deploy_args} );
 207         __PACKAGE__->populate_schema( $schema )
 208          if( !$args{no_populate} );
 209     }
 210     return $schema;
 211 }
 212
 213 =head2 deploy_schema
 214
 215   DBICTest->deploy_schema( $schema );
 216
 217 This method does one of two things to the schema.  It can either call
 218 the experimental $schema->deploy() if the DBICTEST_SQLT_DEPLOY environment
 219 variable is set, otherwise the default is to read in the t/lib/sqlite.sql
 220 file and execute the SQL within. Either way you end up with a fresh set
 221 of tables for testing.
 222
 223 =cut
 224
 225 sub deploy_schema {
 226     my $self = shift;
 227     my $schema = shift;
 228     my $args = shift || {};
 229
 230     if ($ENV{"DBICTEST_SQLT_DEPLOY"}) {
 231         $schema->deploy($args);
 232     } else {
 233         open IN, "t/lib/sqlite.sql";
 234         my $sql;
 235         { local $/ = undef; $sql = <IN>; }
 236         close IN;
 237         for my $chunk ( split (/;\s*\n+/, $sql) ) {
 238           if ( $chunk =~ / ^ (?! --\s* ) \S /xm ) {  # there is some real sql in the chunk - a non-space at the start of the string which is not a comment
 239             $schema->storage->dbh_do(sub { $_[1]->do($chunk) }) or print "Error on SQL: $chunk\n";
 240           }
 241         }
 242     }
 243     return;
 244 }
 245
 246 =head2 populate_schema
 247
 248   DBICTest->populate_schema( $schema );
 249
 250 After you deploy your schema you can use this method to populate
 251 the tables with test data.
 252
 253 =cut
 254
 255 sub populate_schema {
 256     my $self = shift;
 257     my $schema = shift;
 258
 259     $schema->populate('Genre', [
 260       [qw/genreid name/],
 261       [qw/1       emo  /],
 262     ]);
 263
 264     $schema->populate('Artist', [
 265         [ qw/artistid name/ ],
 266         [ 1, 'Caterwauler McCrae' ],
 267         [ 2, 'Random Boy Band' ],
 268         [ 3, 'We Are Goth' ],
 269     ]);
 270
 271     $schema->populate('CD', [
 272         [ qw/cdid artist title year genreid/ ],
 273         [ 1, 1, "Spoonful of bees", 1999, 1 ],
 274         [ 2, 1, "Forkful of bees", 2001 ],
 275         [ 3, 1, "Caterwaulin' Blues", 1997 ],
 276         [ 4, 2, "Generic Manufactured Singles", 2001 ],
 277         [ 5, 3, "Come Be Depressed With Us", 1998 ],
 278     ]);
 279
 280     $schema->populate('LinerNotes', [
 281         [ qw/liner_id notes/ ],
 282         [ 2, "Buy Whiskey!" ],
 283         [ 4, "Buy Merch!" ],
 284         [ 5, "Kill Yourself!" ],
 285     ]);
 286
 287     $schema->populate('Tag', [
 288         [ qw/tagid cd tag/ ],
 289         [ 1, 1, "Blue" ],
 290         [ 2, 2, "Blue" ],
 291         [ 3, 3, "Blue" ],
 292         [ 4, 5, "Blue" ],
 293         [ 5, 2, "Cheesy" ],
 294         [ 6, 4, "Cheesy" ],
 295         [ 7, 5, "Cheesy" ],
 296         [ 8, 2, "Shiny" ],
 297         [ 9, 4, "Shiny" ],
 298     ]);
 299
 300     $schema->populate('TwoKeys', [
 301         [ qw/artist cd/ ],
 302         [ 1, 1 ],
 303         [ 1, 2 ],
 304         [ 2, 2 ],
 305     ]);
 306
 307     $schema->populate('FourKeys', [
 308         [ qw/foo bar hello goodbye sensors/ ],
 309         [ 1, 2, 3, 4, 'online' ],
 310         [ 5, 4, 3, 6, 'offline' ],
 311     ]);
 312
 313     $schema->populate('OneKey', [
 314         [ qw/id artist cd/ ],
 315         [ 1, 1, 1 ],
 316         [ 2, 1, 2 ],
 317         [ 3, 2, 2 ],
 318     ]);
 319
 320     $schema->populate('SelfRef', [
 321         [ qw/id name/ ],
 322         [ 1, 'First' ],
 323         [ 2, 'Second' ],
 324     ]);
 325
 326     $schema->populate('SelfRefAlias', [
 327         [ qw/self_ref alias/ ],
 328         [ 1, 2 ]
 329     ]);
 330
 331     $schema->populate('ArtistUndirectedMap', [
 332         [ qw/id1 id2/ ],
 333         [ 1, 2 ]
 334     ]);
 335
 336     $schema->populate('Producer', [
 337         [ qw/producerid name/ ],
 338         [ 1, 'Matt S Trout' ],
 339         [ 2, 'Bob The Builder' ],
 340         [ 3, 'Fred The Phenotype' ],
 341     ]);
 342
 343     $schema->populate('CD_to_Producer', [
 344         [ qw/cd producer/ ],
 345         [ 1, 1 ],
 346         [ 1, 2 ],
 347         [ 1, 3 ],
 348     ]);
 349
 350     $schema->populate('TreeLike', [
 351         [ qw/id parent name/ ],
 352         [ 1, undef, 'root' ],
 353         [ 2, 1, 'foo'  ],
 354         [ 3, 2, 'bar'  ],
 355         [ 6, 2, 'blop' ],
 356         [ 4, 3, 'baz'  ],
 357         [ 5, 4, 'quux' ],
 358         [ 7, 3, 'fong'  ],
 359     ]);
 360
 361     $schema->populate('Track', [
 362         [ qw/trackid cd  position title/ ],
 363         [ 4, 2, 1, "Stung with Success"],
 364         [ 5, 2, 2, "Stripy"],
 365         [ 6, 2, 3, "Sticky Honey"],
 366         [ 7, 3, 1, "Yowlin"],
 367         [ 8, 3, 2, "Howlin"],
 368         [ 9, 3, 3, "Fowlin"],
 369         [ 10, 4, 1, "Boring Name"],
 370         [ 11, 4, 2, "Boring Song"],
 371         [ 12, 4, 3, "No More Ideas"],
 372         [ 13, 5, 1, "Sad"],
 373         [ 14, 5, 2, "Under The Weather"],
 374         [ 15, 5, 3, "Suicidal"],
 375         [ 16, 1, 1, "The Bees Knees"],
 376         [ 17, 1, 2, "Apiary"],
 377         [ 18, 1, 3, "Beehind You"],
 378     ]);
 379
 380     $schema->populate('Event', [
 381         [ qw/id starts_at created_on varchar_date varchar_datetime skip_inflation/ ],
 382         [ 1, '2006-04-25 22:24:33', '2006-06-22 21:00:05', '2006-07-23', '2006-05-22 19:05:07', '2006-04-21 18:04:06'],
 383     ]);
 384
 385     $schema->populate('Link', [
 386         [ qw/id url title/ ],
 387         [ 1, '', 'aaa' ]
 388     ]);
 389
 390     $schema->populate('Bookmark', [
 391         [ qw/id link/ ],
 392         [ 1, 1 ]
 393     ]);
 394
 395     $schema->populate('Collection', [
 396         [ qw/collectionid name/ ],
 397         [ 1, "Tools" ],
 398         [ 2, "Body Parts" ],
 399     ]);
 400
 401     $schema->populate('TypedObject', [
 402         [ qw/objectid type value/ ],
 403         [ 1, "pointy", "Awl" ],
 404         [ 2, "round", "Bearing" ],
 405         [ 3, "pointy", "Knife" ],
 406         [ 4, "pointy", "Tooth" ],
 407         [ 5, "round", "Head" ],
 408     ]);
 409     $schema->populate('CollectionObject', [
 410         [ qw/collection object/ ],
 411         [ 1, 1 ],
 412         [ 1, 2 ],
 413         [ 1, 3 ],
 414         [ 2, 4 ],
 415         [ 2, 5 ],
 416     ]);
 417
 418     $schema->populate('Owners', [
 419         [ qw/id name/ ],
 420         [ 1, "Newton" ],
 421         [ 2, "Waltham" ],
 422     ]);
 423
 424     $schema->populate('BooksInLibrary', [
 425         [ qw/id owner title source price/ ],
 426         [ 1, 1, "Programming Perl", "Library", 23 ],
 427         [ 2, 1, "Dynamical Systems", "Library",  37 ],
 428         [ 3, 2, "Best Recipe Cookbook", "Library", 65 ],
 429     ]);
 430 }
 431
 432 1;