t/lib/DBICTest.pm

   1 package # hide from PAUSE
   2     DBICTest;
   3
   4 use strict;
   5 use warnings;
   6 use DBICTest::RunMode;
   7 use DBICTest::Schema;
   8 use DBICTest::Util::LeakTracer qw/populate_weakregistry assert_empty_weakregistry/;
   9 use DBICTest::Util 'local_umask';
  10 use Carp;
  11 use Path::Class::File ();
  12 use File::Spec;
  13 use Fcntl qw/:DEFAULT :flock/;
  14
  15 =head1 NAME
  16
  17 DBICTest - Library to be used by DBIx::Class test scripts.
  18
  19 =head1 SYNOPSIS
  20
  21   use lib qw(t/lib);
  22   use DBICTest;
  23   use Test::More;
  24
  25   my $schema = DBICTest->init_schema();
  26
  27 =head1 DESCRIPTION
  28
  29 This module provides the basic utilities to write tests against
  30 DBIx::Class.
  31
  32 =head1 METHODS
  33
  34 =head2 init_schema
  35
  36   my $schema = DBICTest->init_schema(
  37     no_deploy=>1,
  38     no_populate=>1,
  39     storage_type=>'::DBI::Replicated',
  40     storage_type_args=>{
  41       balancer_type=>'DBIx::Class::Storage::DBI::Replicated::Balancer::Random'
  42     },
  43   );
  44
  45 This method removes the test SQLite database in t/var/DBIxClass.db
  46 and then creates a new, empty database.
  47
  48 This method will call deploy_schema() by default, unless the
  49 no_deploy flag is set.
  50
  51 Also, by default, this method will call populate_schema() by
  52 default, unless the no_deploy or no_populate flags are set.
  53
  54 =cut
  55
  56 # some tests are very time sensitive and need to run on their own, without
  57 # being disturbed by anything else grabbing CPU or disk IO. Hence why everything
  58 # using DBICTest grabs a shared lock, and the few tests that request a :GlobalLock
  59 # will ask for an exclusive one and block until they can get it
  60 our ($global_lock_fh, $global_exclusive_lock);
  61 sub import {
  62     my $self = shift;
  63
  64     my $tmpdir = DBICTest::RunMode->tmpdir;
  65     my $lockpath = $tmpdir->file('.dbictest_global.lock');
  66
  67     {
  68       my $u = local_umask(0); # so that the file opens as 666, and any user can lock
  69       sysopen ($global_lock_fh, $lockpath, O_RDWR|O_CREAT) or do {
  70         my $err = $!;
  71
  72         my @x_tests = map { (defined $_) ? ( $_ ? 1 : 0 ) : 'U' } map {(-e, -d, -f, -r, -w, -x, -o)} ($tmpdir, $lockpath);
  73
  74         die sprintf <<"EOE", $lockpath, $err, scalar $>, scalar $), (stat($tmpdir))[4,5,2], @x_tests;
  75 Unable to open %s: %s
  76 Process EUID/EGID: %s / %s
  77 TmpDir UID/GID:    %s / %s
  78 TmpDir StatMode:   %o
  79 TmpDir X-tests:    -e:%s -d:%s -f:%s -r:%s -w:%s -x:%s -o:%s
  80 TmpFile X-tests:   -e:%s -d:%s -f:%s -r:%s -w:%s -x:%s -o:%s
  81 EOE
  82       };
  83     }
  84
  85     for (@_) {
  86         if ($_ eq ':GlobalLock') {
  87             flock ($global_lock_fh, LOCK_EX) or die "Unable to lock $lockpath: $!";
  88             $global_exclusive_lock = 1;
  89         }
  90         else {
  91             croak "Unknown export $_ requested from $self";
  92         }
  93     }
  94
  95     unless ($global_exclusive_lock) {
  96         flock ($global_lock_fh, LOCK_SH) or die "Unable to lock $lockpath: $!";
  97     }
  98 }
  99
 100 END {
 101     if ($global_lock_fh) {
 102         # delay destruction even more
 103     }
 104 }
 105
 106 {
 107     my $dir = Path::Class::File->new(__FILE__)->dir->parent->subdir('var');
 108     $dir->mkpath unless -d "$dir";
 109     $dir = "$dir";
 110
 111     sub _sqlite_dbfilename {
 112         my $holder = $ENV{DBICTEST_LOCK_HOLDER} || $$;
 113         $holder = $$ if $holder == -1;
 114
 115         # useful for missing cleanup debugging
 116         #if ( $holder == $$) {
 117         #  my $x = $0;
 118         #  $x =~ s/\//#/g;
 119         #  $holder .= "-$x";
 120         #}
 121
 122         return "$dir/DBIxClass-$holder.db";
 123     }
 124
 125     END {
 126         _cleanup_dbfile();
 127     }
 128 }
 129
 130 $SIG{INT} = sub { _cleanup_dbfile(); exit 1 };
 131
 132 sub _cleanup_dbfile {
 133     # cleanup if this is us
 134     if (
 135       ! $ENV{DBICTEST_LOCK_HOLDER}
 136         or
 137       $ENV{DBICTEST_LOCK_HOLDER} == -1
 138         or
 139       $ENV{DBICTEST_LOCK_HOLDER} == $$
 140     ) {
 141         my $db_file = _sqlite_dbfilename();
 142         unlink $_ for ($db_file, "${db_file}-journal");
 143     }
 144 }
 145
 146 sub has_custom_dsn {
 147     return $ENV{"DBICTEST_DSN"} ? 1:0;
 148 }
 149
 150 sub _sqlite_dbname {
 151     my $self = shift;
 152     my %args = @_;
 153     return $self->_sqlite_dbfilename if (
 154       defined $args{sqlite_use_file} ? $args{sqlite_use_file} : $ENV{'DBICTEST_SQLITE_USE_FILE'}
 155     );
 156     return ":memory:";
 157 }
 158
 159 sub _database {
 160     my $self = shift;
 161     my %args = @_;
 162
 163     if ($ENV{DBICTEST_DSN}) {
 164       return (
 165         (map { $ENV{"DBICTEST_${_}"} || '' } qw/DSN DBUSER DBPASS/),
 166         { AutoCommit => 1, %args },
 167       );
 168     }
 169     my $db_file = $self->_sqlite_dbname(%args);
 170
 171     for ($db_file, "${db_file}-journal") {
 172       next unless -e $_;
 173       unlink ($_) or carp (
 174         "Unable to unlink existing test database file $_ ($!), creation of fresh database / further tests may fail!"
 175       );
 176     }
 177
 178     return ("dbi:SQLite:${db_file}", '', '', {
 179       AutoCommit => 1,
 180
 181       # this is executed on every connect, and thus installs a disconnect/DESTROY
 182       # guard for every new $dbh
 183       on_connect_do => sub {
 184         my $storage = shift;
 185         my $dbh = $storage->_get_dbh;
 186
 187         # no fsync on commit
 188         $dbh->do ('PRAGMA synchronous = OFF');
 189
 190         # set a *DBI* disconnect callback, to make sure the physical SQLite
 191         # file is still there (i.e. the test does not attempt to delete
 192         # an open database, which fails on Win32)
 193         if (my $guard_cb = __mk_disconnect_guard($db_file)) {
 194           $dbh->{Callbacks} = {
 195             connect => sub { $guard_cb->('connect') },
 196             disconnect => sub { $guard_cb->('disconnect') },
 197             DESTROY => sub { $guard_cb->('DESTROY') },
 198           };
 199         }
 200       },
 201       %args,
 202     });
 203 }
 204
 205 sub __mk_disconnect_guard {
 206   return if DBIx::Class::_ENV_::PEEPEENESS; # leaks handles, delaying DESTROY, can't work right
 207
 208   my $db_file = shift;
 209   return unless -f $db_file;
 210
 211   my $orig_inode = (stat($db_file))[1]
 212     or return;
 213
 214   my $clan_connect_caller = '*UNKNOWN*';
 215   my $i;
 216   while ( my ($pack, $file, $line) = caller(++$i) ) {
 217     next if $file eq __FILE__;
 218     next if $pack =~ /^DBIx::Class|^Try::Tiny/;
 219     $clan_connect_caller = "$file line $line";
 220   }
 221
 222   my $failed_once = 0;
 223   my $connected = 1;
 224
 225   return sub {
 226     return if $failed_once;
 227
 228     my $event = shift;
 229     if ($event eq 'connect') {
 230       # this is necessary in case we are disconnected and connected again, all within the same $dbh object
 231       $connected = 1;
 232       return;
 233     }
 234     elsif ($event eq 'disconnect') {
 235       $connected = 0;
 236     }
 237     elsif ($event eq 'DESTROY' and ! $connected ) {
 238       return;
 239     }
 240
 241     my $fail_reason;
 242     if (! -e $db_file) {
 243       $fail_reason = 'is missing';
 244     }
 245     else {
 246       my $cur_inode = (stat($db_file))[1];
 247
 248       if ($orig_inode != $cur_inode) {
 249         # pack/unpack to match the unsigned longs returned by `stat`
 250         $fail_reason = sprintf 'was recreated (initially inode %s, now %s)', (
 251           map { unpack ('L', pack ('l', $_) ) } ($orig_inode, $cur_inode )
 252         );
 253       }
 254     }
 255
 256     if ($fail_reason) {
 257       $failed_once++;
 258
 259       require Test::Builder;
 260       my $t = Test::Builder->new;
 261       local $Test::Builder::Level = $Test::Builder::Level + 3;
 262       $t->ok (0,
 263         "$db_file originally created at $clan_connect_caller $fail_reason before $event "
 264       . 'of DBI handle - a strong indicator that the database file was tampered with while '
 265       . 'still being open. This action would fail massively if running under Win32, hence '
 266       . 'we make sure it fails on any OS :)'
 267       );
 268     }
 269
 270     return; # this empty return is a DBI requirement
 271   };
 272 }
 273
 274 my $weak_registry = {};
 275
 276 sub init_schema {
 277     my $self = shift;
 278     my %args = @_;
 279
 280     my $schema;
 281
 282     if ($args{compose_connection}) {
 283       $schema = DBICTest::Schema->compose_connection(
 284                   'DBICTest', $self->_database(%args)
 285                 );
 286     } else {
 287       $schema = DBICTest::Schema->compose_namespace('DBICTest');
 288     }
 289
 290     if( $args{storage_type}) {
 291       $schema->storage_type($args{storage_type});
 292     }
 293
 294     if ( !$args{no_connect} ) {
 295       $schema = $schema->connect($self->_database(%args));
 296     }
 297
 298     if ( !$args{no_deploy} ) {
 299         __PACKAGE__->deploy_schema( $schema, $args{deploy_args} );
 300         __PACKAGE__->populate_schema( $schema )
 301          if( !$args{no_populate} );
 302     }
 303
 304     populate_weakregistry ( $weak_registry, $schema->storage )
 305       if $INC{'Test/Builder.pm'} and $schema->storage;
 306
 307     return $schema;
 308 }
 309
 310 END {
 311     assert_empty_weakregistry($weak_registry, 'quiet');
 312 }
 313
 314 =head2 deploy_schema
 315
 316   DBICTest->deploy_schema( $schema );
 317
 318 This method does one of two things to the schema.  It can either call
 319 the experimental $schema->deploy() if the DBICTEST_SQLT_DEPLOY environment
 320 variable is set, otherwise the default is to read in the t/lib/sqlite.sql
 321 file and execute the SQL within. Either way you end up with a fresh set
 322 of tables for testing.
 323
 324 =cut
 325
 326 sub deploy_schema {
 327     my $self = shift;
 328     my $schema = shift;
 329     my $args = shift || {};
 330
 331     local $schema->storage->{debug}
 332       if ($ENV{TRAVIS}||'') eq 'true';
 333
 334     if ($ENV{"DBICTEST_SQLT_DEPLOY"}) {
 335         $schema->deploy($args);
 336     } else {
 337         my $filename = Path::Class::File->new(__FILE__)->dir
 338           ->file('sqlite.sql')->stringify;
 339         my $sql = do { local (@ARGV, $/) = $filename ; <> };
 340         for my $chunk ( split (/;\s*\n+/, $sql) ) {
 341           if ( $chunk =~ / ^ (?! --\s* ) \S /xm ) {  # there is some real sql in the chunk - a non-space at the start of the string which is not a comment
 342             $schema->storage->dbh_do(sub { $_[1]->do($chunk) }) or print "Error on SQL: $chunk\n";
 343           }
 344         }
 345     }
 346     return;
 347 }
 348
 349 =head2 populate_schema
 350
 351   DBICTest->populate_schema( $schema );
 352
 353 After you deploy your schema you can use this method to populate
 354 the tables with test data.
 355
 356 =cut
 357
 358 sub populate_schema {
 359     my $self = shift;
 360     my $schema = shift;
 361
 362     local $schema->storage->{debug}
 363       if ($ENV{TRAVIS}||'') eq 'true';
 364
 365     $schema->populate('Genre', [
 366       [qw/genreid name/],
 367       [qw/1       emo  /],
 368     ]);
 369
 370     $schema->populate('Artist', [
 371         [ qw/artistid name/ ],
 372         [ 1, 'Caterwauler McCrae' ],
 373         [ 2, 'Random Boy Band' ],
 374         [ 3, 'We Are Goth' ],
 375     ]);
 376
 377     $schema->populate('CD', [
 378         [ qw/cdid artist title year genreid/ ],
 379         [ 1, 1, "Spoonful of bees", 1999, 1 ],
 380         [ 2, 1, "Forkful of bees", 2001 ],
 381         [ 3, 1, "Caterwaulin' Blues", 1997 ],
 382         [ 4, 2, "Generic Manufactured Singles", 2001 ],
 383         [ 5, 3, "Come Be Depressed With Us", 1998 ],
 384     ]);
 385
 386     $schema->populate('LinerNotes', [
 387         [ qw/liner_id notes/ ],
 388         [ 2, "Buy Whiskey!" ],
 389         [ 4, "Buy Merch!" ],
 390         [ 5, "Kill Yourself!" ],
 391     ]);
 392
 393     $schema->populate('Tag', [
 394         [ qw/tagid cd tag/ ],
 395         [ 1, 1, "Blue" ],
 396         [ 2, 2, "Blue" ],
 397         [ 3, 3, "Blue" ],
 398         [ 4, 5, "Blue" ],
 399         [ 5, 2, "Cheesy" ],
 400         [ 6, 4, "Cheesy" ],
 401         [ 7, 5, "Cheesy" ],
 402         [ 8, 2, "Shiny" ],
 403         [ 9, 4, "Shiny" ],
 404     ]);
 405
 406     $schema->populate('TwoKeys', [
 407         [ qw/artist cd/ ],
 408         [ 1, 1 ],
 409         [ 1, 2 ],
 410         [ 2, 2 ],
 411     ]);
 412
 413     $schema->populate('FourKeys', [
 414         [ qw/foo bar hello goodbye sensors/ ],
 415         [ 1, 2, 3, 4, 'online' ],
 416         [ 5, 4, 3, 6, 'offline' ],
 417     ]);
 418
 419     $schema->populate('OneKey', [
 420         [ qw/id artist cd/ ],
 421         [ 1, 1, 1 ],
 422         [ 2, 1, 2 ],
 423         [ 3, 2, 2 ],
 424     ]);
 425
 426     $schema->populate('SelfRef', [
 427         [ qw/id name/ ],
 428         [ 1, 'First' ],
 429         [ 2, 'Second' ],
 430     ]);
 431
 432     $schema->populate('SelfRefAlias', [
 433         [ qw/self_ref alias/ ],
 434         [ 1, 2 ]
 435     ]);
 436
 437     $schema->populate('ArtistUndirectedMap', [
 438         [ qw/id1 id2/ ],
 439         [ 1, 2 ]
 440     ]);
 441
 442     $schema->populate('Producer', [
 443         [ qw/producerid name/ ],
 444         [ 1, 'Matt S Trout' ],
 445         [ 2, 'Bob The Builder' ],
 446         [ 3, 'Fred The Phenotype' ],
 447     ]);
 448
 449     $schema->populate('CD_to_Producer', [
 450         [ qw/cd producer/ ],
 451         [ 1, 1 ],
 452         [ 1, 2 ],
 453         [ 1, 3 ],
 454     ]);
 455
 456     $schema->populate('TreeLike', [
 457         [ qw/id parent name/ ],
 458         [ 1, undef, 'root' ],
 459         [ 2, 1, 'foo'  ],
 460         [ 3, 2, 'bar'  ],
 461         [ 6, 2, 'blop' ],
 462         [ 4, 3, 'baz'  ],
 463         [ 5, 4, 'quux' ],
 464         [ 7, 3, 'fong'  ],
 465     ]);
 466
 467     $schema->populate('Track', [
 468         [ qw/trackid cd  position title/ ],
 469         [ 4, 2, 1, "Stung with Success"],
 470         [ 5, 2, 2, "Stripy"],
 471         [ 6, 2, 3, "Sticky Honey"],
 472         [ 7, 3, 1, "Yowlin"],
 473         [ 8, 3, 2, "Howlin"],
 474         [ 9, 3, 3, "Fowlin"],
 475         [ 10, 4, 1, "Boring Name"],
 476         [ 11, 4, 2, "Boring Song"],
 477         [ 12, 4, 3, "No More Ideas"],
 478         [ 13, 5, 1, "Sad"],
 479         [ 14, 5, 2, "Under The Weather"],
 480         [ 15, 5, 3, "Suicidal"],
 481         [ 16, 1, 1, "The Bees Knees"],
 482         [ 17, 1, 2, "Apiary"],
 483         [ 18, 1, 3, "Beehind You"],
 484     ]);
 485
 486     $schema->populate('Event', [
 487         [ qw/id starts_at created_on varchar_date varchar_datetime skip_inflation/ ],
 488         [ 1, '2006-04-25 22:24:33', '2006-06-22 21:00:05', '2006-07-23', '2006-05-22 19:05:07', '2006-04-21 18:04:06'],
 489     ]);
 490
 491     $schema->populate('Link', [
 492         [ qw/id url title/ ],
 493         [ 1, '', 'aaa' ]
 494     ]);
 495
 496     $schema->populate('Bookmark', [
 497         [ qw/id link/ ],
 498         [ 1, 1 ]
 499     ]);
 500
 501     $schema->populate('Collection', [
 502         [ qw/collectionid name/ ],
 503         [ 1, "Tools" ],
 504         [ 2, "Body Parts" ],
 505     ]);
 506
 507     $schema->populate('TypedObject', [
 508         [ qw/objectid type value/ ],
 509         [ 1, "pointy", "Awl" ],
 510         [ 2, "round", "Bearing" ],
 511         [ 3, "pointy", "Knife" ],
 512         [ 4, "pointy", "Tooth" ],
 513         [ 5, "round", "Head" ],
 514     ]);
 515     $schema->populate('CollectionObject', [
 516         [ qw/collection object/ ],
 517         [ 1, 1 ],
 518         [ 1, 2 ],
 519         [ 1, 3 ],
 520         [ 2, 4 ],
 521         [ 2, 5 ],
 522     ]);
 523
 524     $schema->populate('Owners', [
 525         [ qw/id name/ ],
 526         [ 1, "Newton" ],
 527         [ 2, "Waltham" ],
 528     ]);
 529
 530     $schema->populate('BooksInLibrary', [
 531         [ qw/id owner title source price/ ],
 532         [ 1, 1, "Programming Perl", "Library", 23 ],
 533         [ 2, 1, "Dynamical Systems", "Library",  37 ],
 534         [ 3, 2, "Best Recipe Cookbook", "Library", 65 ],
 535     ]);
 536 }
 537
 538 1;