t/lib/DBICTest.pm

   1 package # hide from PAUSE
   2     DBICTest;
   3
   4 use strict;
   5 use warnings;
   6 use DBICTest::RunMode;
   7 use DBICTest::Schema;
   8 use DBICTest::Util::LeakTracer qw/populate_weakregistry assert_empty_weakregistry/;
   9 use DBICTest::Util 'local_umask';
  10 use Carp;
  11 use Path::Class::File ();
  12 use File::Spec;
  13 use Fcntl qw/:DEFAULT :flock/;
  14
  15 =head1 NAME
  16
  17 DBICTest - Library to be used by DBIx::Class test scripts.
  18
  19 =head1 SYNOPSIS
  20
  21   use lib qw(t/lib);
  22   use DBICTest;
  23   use Test::More;
  24
  25   my $schema = DBICTest->init_schema();
  26
  27 =head1 DESCRIPTION
  28
  29 This module provides the basic utilities to write tests against
  30 DBIx::Class.
  31
  32 =head1 METHODS
  33
  34 =head2 init_schema
  35
  36   my $schema = DBICTest->init_schema(
  37     no_deploy=>1,
  38     no_populate=>1,
  39     storage_type=>'::DBI::Replicated',
  40     storage_type_args=>{
  41       balancer_type=>'DBIx::Class::Storage::DBI::Replicated::Balancer::Random'
  42     },
  43   );
  44
  45 This method removes the test SQLite database in t/var/DBIxClass.db
  46 and then creates a new, empty database.
  47
  48 This method will call deploy_schema() by default, unless the
  49 no_deploy flag is set.
  50
  51 Also, by default, this method will call populate_schema() by
  52 default, unless the no_deploy or no_populate flags are set.
  53
  54 =cut
  55
  56 # some tests are very time sensitive and need to run on their own, without
  57 # being disturbed by anything else grabbing CPU or disk IO. Hence why everything
  58 # using DBICTest grabs a shared lock, and the few tests that request a :GlobalLock
  59 # will ask for an exclusive one and block until they can get it
  60 our ($global_lock_fh, $global_exclusive_lock);
  61 sub import {
  62     my $self = shift;
  63
  64     my $tmpdir = DBICTest::RunMode->tmpdir;
  65     my $lockpath = $tmpdir->file('.dbictest_global.lock');
  66
  67     {
  68       my $u = local_umask(0); # so that the file opens as 666, and any user can lock
  69       sysopen ($global_lock_fh, $lockpath, O_RDWR|O_CREAT) or do {
  70         my $err = $!;
  71
  72         my @x_tests = map { (defined $_) ? ( $_ ? 1 : 0 ) : 'U' } map {(-e, -d, -f, -r, -w, -x, -o)} ($tmpdir, $lockpath);
  73
  74         die sprintf <<"EOE", $lockpath, $err, scalar $>, scalar $), (stat($tmpdir))[4,5,2], @x_tests;
  75 Unable to open %s: %s
  76 Process EUID/EGID: %s / %s
  77 TmpDir UID/GID:    %s / %s
  78 TmpDir StatMode:   %o
  79 TmpDir X-tests:    -e:%s -d:%s -f:%s -r:%s -w:%s -x:%s -o:%s
  80 TmpFile X-tests:   -e:%s -d:%s -f:%s -r:%s -w:%s -x:%s -o:%s
  81 EOE
  82       };
  83     }
  84
  85     for (@_) {
  86         if ($_ eq ':GlobalLock') {
  87             flock ($global_lock_fh, LOCK_EX) or die "Unable to lock $lockpath: $!";
  88             $global_exclusive_lock = 1;
  89         }
  90         else {
  91             croak "Unknown export $_ requested from $self";
  92         }
  93     }
  94
  95     unless ($global_exclusive_lock) {
  96         flock ($global_lock_fh, LOCK_SH) or die "Unable to lock $lockpath: $!";
  97     }
  98 }
  99
 100 END {
 101     if ($global_lock_fh) {
 102         # delay destruction even more
 103     }
 104 }
 105
 106 {
 107     my $dir = Path::Class::File->new(__FILE__)->dir->parent->subdir('var');
 108     $dir->mkpath unless -d "$dir";
 109     $dir = "$dir";
 110
 111     sub _sqlite_dbfilename {
 112         my $holder = $ENV{DBICTEST_LOCK_HOLDER} || $$;
 113         $holder = $$ if $holder == -1;
 114
 115         # useful for missing cleanup debugging
 116         #if ( $holder == $$) {
 117         #  my $x = $0;
 118         #  $x =~ s/\//#/g;
 119         #  $holder .= "-$x";
 120         #}
 121
 122         return "$dir/DBIxClass-$holder.db";
 123     }
 124
 125     END {
 126         _cleanup_dbfile();
 127     }
 128 }
 129
 130 $SIG{INT} = sub { _cleanup_dbfile(); exit 1 };
 131
 132 sub _cleanup_dbfile {
 133     # cleanup if this is us
 134     if (
 135       ! $ENV{DBICTEST_LOCK_HOLDER}
 136         or
 137       $ENV{DBICTEST_LOCK_HOLDER} == -1
 138         or
 139       $ENV{DBICTEST_LOCK_HOLDER} == $$
 140     ) {
 141         my $db_file = _sqlite_dbfilename();
 142         unlink $_ for ($db_file, "${db_file}-journal");
 143     }
 144 }
 145
 146 sub has_custom_dsn {
 147     return $ENV{"DBICTEST_DSN"} ? 1:0;
 148 }
 149
 150 sub _sqlite_dbname {
 151     my $self = shift;
 152     my %args = @_;
 153     return $self->_sqlite_dbfilename if (
 154       defined $args{sqlite_use_file} ? $args{sqlite_use_file} : $ENV{'DBICTEST_SQLITE_USE_FILE'}
 155     );
 156     return ":memory:";
 157 }
 158
 159 sub _database {
 160     my $self = shift;
 161     my %args = @_;
 162
 163     if ($ENV{DBICTEST_DSN}) {
 164       return (
 165         (map { $ENV{"DBICTEST_${_}"} || '' } qw/DSN DBUSER DBPASS/),
 166         { AutoCommit => 1, %args },
 167       );
 168     }
 169     my $db_file = $self->_sqlite_dbname(%args);
 170
 171     for ($db_file, "${db_file}-journal") {
 172       next unless -e $_;
 173       unlink ($_) or carp (
 174         "Unable to unlink existing test database file $_ ($!), creation of fresh database / further tests may fail!"
 175       );
 176     }
 177
 178     return ("dbi:SQLite:${db_file}", '', '', {
 179       AutoCommit => 1,
 180
 181       # this is executed on every connect, and thus installs a disconnect/DESTROY
 182       # guard for every new $dbh
 183       on_connect_do => sub {
 184         my $storage = shift;
 185         my $dbh = $storage->_get_dbh;
 186
 187         # no fsync on commit
 188         $dbh->do ('PRAGMA synchronous = OFF');
 189
 190         if ($ENV{DBICTEST_SQLITE_REVERSE_DEFAULT_ORDER}) {
 191
 192           $storage->throw_exception(
 193             'PRAGMA reverse_unordered_selects does not work correctly before libsqlite 3.7.9'
 194           ) if $storage->_server_info->{normalized_dbms_version} < 3.007009;
 195
 196           $dbh->do ('PRAGMA reverse_unordered_selects = ON');
 197         }
 198
 199         # set a *DBI* disconnect callback, to make sure the physical SQLite
 200         # file is still there (i.e. the test does not attempt to delete
 201         # an open database, which fails on Win32)
 202         if (my $guard_cb = __mk_disconnect_guard($db_file)) {
 203           $dbh->{Callbacks} = {
 204             connect => sub { $guard_cb->('connect') },
 205             disconnect => sub { $guard_cb->('disconnect') },
 206             DESTROY => sub { $guard_cb->('DESTROY') },
 207           };
 208         }
 209       },
 210       %args,
 211     });
 212 }
 213
 214 sub __mk_disconnect_guard {
 215   return if DBIx::Class::_ENV_::PEEPEENESS; # leaks handles, delaying DESTROY, can't work right
 216
 217   my $db_file = shift;
 218   return unless -f $db_file;
 219
 220   my $orig_inode = (stat($db_file))[1]
 221     or return;
 222
 223   my $clan_connect_caller = '*UNKNOWN*';
 224   my $i;
 225   while ( my ($pack, $file, $line) = caller(++$i) ) {
 226     next if $file eq __FILE__;
 227     next if $pack =~ /^DBIx::Class|^Try::Tiny/;
 228     $clan_connect_caller = "$file line $line";
 229   }
 230
 231   my $failed_once = 0;
 232   my $connected = 1;
 233
 234   return sub {
 235     return if $failed_once;
 236
 237     my $event = shift;
 238     if ($event eq 'connect') {
 239       # this is necessary in case we are disconnected and connected again, all within the same $dbh object
 240       $connected = 1;
 241       return;
 242     }
 243     elsif ($event eq 'disconnect') {
 244       $connected = 0;
 245     }
 246     elsif ($event eq 'DESTROY' and ! $connected ) {
 247       return;
 248     }
 249
 250     my $fail_reason;
 251     if (! -e $db_file) {
 252       $fail_reason = 'is missing';
 253     }
 254     else {
 255       my $cur_inode = (stat($db_file))[1];
 256
 257       if ($orig_inode != $cur_inode) {
 258         # pack/unpack to match the unsigned longs returned by `stat`
 259         $fail_reason = sprintf 'was recreated (initially inode %s, now %s)', (
 260           map { unpack ('L', pack ('l', $_) ) } ($orig_inode, $cur_inode )
 261         );
 262       }
 263     }
 264
 265     if ($fail_reason) {
 266       $failed_once++;
 267
 268       require Test::Builder;
 269       my $t = Test::Builder->new;
 270       local $Test::Builder::Level = $Test::Builder::Level + 3;
 271       $t->ok (0,
 272         "$db_file originally created at $clan_connect_caller $fail_reason before $event "
 273       . 'of DBI handle - a strong indicator that the database file was tampered with while '
 274       . 'still being open. This action would fail massively if running under Win32, hence '
 275       . 'we make sure it fails on any OS :)'
 276       );
 277     }
 278
 279     return; # this empty return is a DBI requirement
 280   };
 281 }
 282
 283 my $weak_registry = {};
 284
 285 sub init_schema {
 286     my $self = shift;
 287     my %args = @_;
 288
 289     my $schema;
 290
 291     if ($args{compose_connection}) {
 292       $schema = DBICTest::Schema->compose_connection(
 293                   'DBICTest', $self->_database(%args)
 294                 );
 295     } else {
 296       $schema = DBICTest::Schema->compose_namespace('DBICTest');
 297     }
 298
 299     if( $args{storage_type}) {
 300       $schema->storage_type($args{storage_type});
 301     }
 302
 303     if ( !$args{no_connect} ) {
 304       $schema = $schema->connect($self->_database(%args));
 305     }
 306
 307     if ( !$args{no_deploy} ) {
 308         __PACKAGE__->deploy_schema( $schema, $args{deploy_args} );
 309         __PACKAGE__->populate_schema( $schema )
 310          if( !$args{no_populate} );
 311     }
 312
 313     populate_weakregistry ( $weak_registry, $schema->storage )
 314       if $INC{'Test/Builder.pm'} and $schema->storage;
 315
 316     return $schema;
 317 }
 318
 319 END {
 320     assert_empty_weakregistry($weak_registry, 'quiet');
 321 }
 322
 323 =head2 deploy_schema
 324
 325   DBICTest->deploy_schema( $schema );
 326
 327 This method does one of two things to the schema.  It can either call
 328 the experimental $schema->deploy() if the DBICTEST_SQLT_DEPLOY environment
 329 variable is set, otherwise the default is to read in the t/lib/sqlite.sql
 330 file and execute the SQL within. Either way you end up with a fresh set
 331 of tables for testing.
 332
 333 =cut
 334
 335 sub deploy_schema {
 336     my $self = shift;
 337     my $schema = shift;
 338     my $args = shift || {};
 339
 340     local $schema->storage->{debug}
 341       if ($ENV{TRAVIS}||'') eq 'true';
 342
 343     if ($ENV{"DBICTEST_SQLT_DEPLOY"}) {
 344         $schema->deploy($args);
 345     } else {
 346         my $filename = Path::Class::File->new(__FILE__)->dir
 347           ->file('sqlite.sql')->stringify;
 348         my $sql = do { local (@ARGV, $/) = $filename ; <> };
 349         for my $chunk ( split (/;\s*\n+/, $sql) ) {
 350           if ( $chunk =~ / ^ (?! --\s* ) \S /xm ) {  # there is some real sql in the chunk - a non-space at the start of the string which is not a comment
 351             $schema->storage->dbh_do(sub { $_[1]->do($chunk) }) or print "Error on SQL: $chunk\n";
 352           }
 353         }
 354     }
 355     return;
 356 }
 357
 358 =head2 populate_schema
 359
 360   DBICTest->populate_schema( $schema );
 361
 362 After you deploy your schema you can use this method to populate
 363 the tables with test data.
 364
 365 =cut
 366
 367 sub populate_schema {
 368     my $self = shift;
 369     my $schema = shift;
 370
 371     local $schema->storage->{debug}
 372       if ($ENV{TRAVIS}||'') eq 'true';
 373
 374     $schema->populate('Genre', [
 375       [qw/genreid name/],
 376       [qw/1       emo  /],
 377     ]);
 378
 379     $schema->populate('Artist', [
 380         [ qw/artistid name/ ],
 381         [ 1, 'Caterwauler McCrae' ],
 382         [ 2, 'Random Boy Band' ],
 383         [ 3, 'We Are Goth' ],
 384     ]);
 385
 386     $schema->populate('CD', [
 387         [ qw/cdid artist title year genreid/ ],
 388         [ 1, 1, "Spoonful of bees", 1999, 1 ],
 389         [ 2, 1, "Forkful of bees", 2001 ],
 390         [ 3, 1, "Caterwaulin' Blues", 1997 ],
 391         [ 4, 2, "Generic Manufactured Singles", 2001 ],
 392         [ 5, 3, "Come Be Depressed With Us", 1998 ],
 393     ]);
 394
 395     $schema->populate('LinerNotes', [
 396         [ qw/liner_id notes/ ],
 397         [ 2, "Buy Whiskey!" ],
 398         [ 4, "Buy Merch!" ],
 399         [ 5, "Kill Yourself!" ],
 400     ]);
 401
 402     $schema->populate('Tag', [
 403         [ qw/tagid cd tag/ ],
 404         [ 1, 1, "Blue" ],
 405         [ 2, 2, "Blue" ],
 406         [ 3, 3, "Blue" ],
 407         [ 4, 5, "Blue" ],
 408         [ 5, 2, "Cheesy" ],
 409         [ 6, 4, "Cheesy" ],
 410         [ 7, 5, "Cheesy" ],
 411         [ 8, 2, "Shiny" ],
 412         [ 9, 4, "Shiny" ],
 413     ]);
 414
 415     $schema->populate('TwoKeys', [
 416         [ qw/artist cd/ ],
 417         [ 1, 1 ],
 418         [ 1, 2 ],
 419         [ 2, 2 ],
 420     ]);
 421
 422     $schema->populate('FourKeys', [
 423         [ qw/foo bar hello goodbye sensors/ ],
 424         [ 1, 2, 3, 4, 'online' ],
 425         [ 5, 4, 3, 6, 'offline' ],
 426     ]);
 427
 428     $schema->populate('OneKey', [
 429         [ qw/id artist cd/ ],
 430         [ 1, 1, 1 ],
 431         [ 2, 1, 2 ],
 432         [ 3, 2, 2 ],
 433     ]);
 434
 435     $schema->populate('SelfRef', [
 436         [ qw/id name/ ],
 437         [ 1, 'First' ],
 438         [ 2, 'Second' ],
 439     ]);
 440
 441     $schema->populate('SelfRefAlias', [
 442         [ qw/self_ref alias/ ],
 443         [ 1, 2 ]
 444     ]);
 445
 446     $schema->populate('ArtistUndirectedMap', [
 447         [ qw/id1 id2/ ],
 448         [ 1, 2 ]
 449     ]);
 450
 451     $schema->populate('Producer', [
 452         [ qw/producerid name/ ],
 453         [ 1, 'Matt S Trout' ],
 454         [ 2, 'Bob The Builder' ],
 455         [ 3, 'Fred The Phenotype' ],
 456     ]);
 457
 458     $schema->populate('CD_to_Producer', [
 459         [ qw/cd producer/ ],
 460         [ 1, 1 ],
 461         [ 1, 2 ],
 462         [ 1, 3 ],
 463     ]);
 464
 465     $schema->populate('TreeLike', [
 466         [ qw/id parent name/ ],
 467         [ 1, undef, 'root' ],
 468         [ 2, 1, 'foo'  ],
 469         [ 3, 2, 'bar'  ],
 470         [ 6, 2, 'blop' ],
 471         [ 4, 3, 'baz'  ],
 472         [ 5, 4, 'quux' ],
 473         [ 7, 3, 'fong'  ],
 474     ]);
 475
 476     $schema->populate('Track', [
 477         [ qw/trackid cd  position title/ ],
 478         [ 4, 2, 1, "Stung with Success"],
 479         [ 5, 2, 2, "Stripy"],
 480         [ 6, 2, 3, "Sticky Honey"],
 481         [ 7, 3, 1, "Yowlin"],
 482         [ 8, 3, 2, "Howlin"],
 483         [ 9, 3, 3, "Fowlin"],
 484         [ 10, 4, 1, "Boring Name"],
 485         [ 11, 4, 2, "Boring Song"],
 486         [ 12, 4, 3, "No More Ideas"],
 487         [ 13, 5, 1, "Sad"],
 488         [ 14, 5, 2, "Under The Weather"],
 489         [ 15, 5, 3, "Suicidal"],
 490         [ 16, 1, 1, "The Bees Knees"],
 491         [ 17, 1, 2, "Apiary"],
 492         [ 18, 1, 3, "Beehind You"],
 493     ]);
 494
 495     $schema->populate('Event', [
 496         [ qw/id starts_at created_on varchar_date varchar_datetime skip_inflation/ ],
 497         [ 1, '2006-04-25 22:24:33', '2006-06-22 21:00:05', '2006-07-23', '2006-05-22 19:05:07', '2006-04-21 18:04:06'],
 498     ]);
 499
 500     $schema->populate('Link', [
 501         [ qw/id url title/ ],
 502         [ 1, '', 'aaa' ]
 503     ]);
 504
 505     $schema->populate('Bookmark', [
 506         [ qw/id link/ ],
 507         [ 1, 1 ]
 508     ]);
 509
 510     $schema->populate('Collection', [
 511         [ qw/collectionid name/ ],
 512         [ 1, "Tools" ],
 513         [ 2, "Body Parts" ],
 514     ]);
 515
 516     $schema->populate('TypedObject', [
 517         [ qw/objectid type value/ ],
 518         [ 1, "pointy", "Awl" ],
 519         [ 2, "round", "Bearing" ],
 520         [ 3, "pointy", "Knife" ],
 521         [ 4, "pointy", "Tooth" ],
 522         [ 5, "round", "Head" ],
 523     ]);
 524     $schema->populate('CollectionObject', [
 525         [ qw/collection object/ ],
 526         [ 1, 1 ],
 527         [ 1, 2 ],
 528         [ 1, 3 ],
 529         [ 2, 4 ],
 530         [ 2, 5 ],
 531     ]);
 532
 533     $schema->populate('Owners', [
 534         [ qw/id name/ ],
 535         [ 1, "Newton" ],
 536         [ 2, "Waltham" ],
 537     ]);
 538
 539     $schema->populate('BooksInLibrary', [
 540         [ qw/id owner title source price/ ],
 541         [ 1, 1, "Programming Perl", "Library", 23 ],
 542         [ 2, 1, "Dynamical Systems", "Library",  37 ],
 543         [ 3, 2, "Best Recipe Cookbook", "Library", 65 ],
 544     ]);
 545 }
 546
 547 1;