t/inflate/datetime_mssql.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use Scope::Guard ();
   7 use Try::Tiny;
   8 use DBIx::Class::Optional::Dependencies ();
   9 use lib qw(t/lib);
  10 use DBICTest;
  11
  12 my ($dsn,  $user,  $pass)  = @ENV{map { "DBICTEST_MSSQL_ODBC_${_}" } qw/DSN USER PASS/};
  13 my ($dsn2, $user2, $pass2) = @ENV{map { "DBICTEST_MSSQL_${_}" }      qw/DSN USER PASS/};
  14 my ($dsn3, $user3, $pass3) = @ENV{map { "DBICTEST_MSSQL_ADO_${_}" }  qw/DSN USER PASS/};
  15
  16 plan skip_all => 'Test needs ' .
  17   (join ' and ', map { $_ ? $_ : () }
  18     DBIx::Class::Optional::Dependencies->req_missing_for('test_dt'),
  19     (join ' or ', map { $_ ? $_ : () }
  20       DBIx::Class::Optional::Dependencies->req_missing_for('test_rdbms_mssql_odbc'),
  21       DBIx::Class::Optional::Dependencies->req_missing_for('test_rdbms_mssql_sybase'),
  22       DBIx::Class::Optional::Dependencies->req_missing_for('test_rdbms_mssql_ado')))
  23   unless
  24     DBIx::Class::Optional::Dependencies->req_ok_for ('test_dt') && (
  25     $dsn && DBIx::Class::Optional::Dependencies->req_ok_for('test_rdbms_mssql_odbc')
  26     or
  27     $dsn2 && DBIx::Class::Optional::Dependencies->req_ok_for('test_rdbms_mssql_sybase')
  28     or
  29     $dsn3 && DBIx::Class::Optional::Dependencies->req_ok_for('test_rdbms_mssql_ado'))
  30       or (not $dsn || $dsn2 || $dsn3);
  31
  32 if (not ($dsn || $dsn2 || $dsn3)) {
  33   plan skip_all =>
  34     'Set $ENV{DBICTEST_MSSQL_ODBC_DSN} and/or $ENV{DBICTEST_MSSQL_DSN} and/or '
  35     .'$ENV{DBICTEST_MSSQL_ADO_DSN} _USER and _PASS to run this test' .
  36     "\nWarning: This test drops and creates tables called 'event_small_dt' and"
  37     ." 'track'.";
  38 }
  39
  40 DBICTest::Schema->load_classes('EventSmallDT');
  41
  42 my @connect_info = (
  43   [ $dsn,  $user,  $pass ],
  44   [ $dsn2, $user2, $pass2 ],
  45   [ $dsn3, $user3, $pass3 ],
  46 );
  47
  48 my $schema;
  49
  50 SKIP:
  51 for my $connect_info (@connect_info) {
  52   my ($dsn, $user, $pass) = @$connect_info;
  53
  54   next unless $dsn;
  55
  56   $schema = DBICTest::Schema->connect($dsn, $user, $pass, {
  57     on_connect_call => 'datetime_setup'
  58   });
  59
  60   {
  61     my $w;
  62     local $SIG{__WARN__} = sub { $w = shift };
  63     $schema->storage->ensure_connected;
  64     if ($w =~ /Your DBD::Sybase is too old to support DBIx::Class::InflateColumn::DateTime/) {
  65       skip "Skipping tests on old DBD::Sybase " . DBD::Sybase->VERSION, 1;
  66     }
  67   }
  68
  69   my $guard = Scope::Guard->new(sub{ cleanup($schema) });
  70
  71   # $^W because DBD::ADO is a piece of crap
  72   try { local $^W = 0; $schema->storage->dbh->do("DROP TABLE track") };
  73   $schema->storage->dbh->do(<<"SQL");
  74 CREATE TABLE track (
  75  trackid INT IDENTITY PRIMARY KEY,
  76  cd INT,
  77  position INT,
  78  last_updated_at DATETIME,
  79 )
  80 SQL
  81   try { local $^W = 0; $schema->storage->dbh->do("DROP TABLE event_small_dt") };
  82   $schema->storage->dbh->do(<<"SQL");
  83 CREATE TABLE event_small_dt (
  84  id INT IDENTITY PRIMARY KEY,
  85  small_dt SMALLDATETIME,
  86 )
  87 SQL
  88   try { local $^W = 0; $schema->storage->dbh->do("DROP TABLE event") };
  89   $schema->storage->dbh->do(<<"SQL");
  90 CREATE TABLE event (
  91    id int IDENTITY(1,1) NOT NULL,
  92    starts_at smalldatetime NULL,
  93    created_on datetime NULL,
  94    varchar_date varchar(20) NULL,
  95    varchar_datetime varchar(20) NULL,
  96    skip_inflation datetime NULL,
  97    ts_without_tz datetime NULL
  98 )
  99 SQL
 100
 101 # coltype, column, source, pk, create_extra, datehash
 102   my @dt_types = (
 103     ['DATETIME',
 104      'last_updated_at',
 105      'Track',
 106      'trackid',
 107      { cd => 1 },
 108      {
 109       year => 2004,
 110       month => 8,
 111       day => 21,
 112       hour => 14,
 113       minute => 36,
 114       second => 48,
 115       nanosecond => 500000000,
 116     }],
 117     ['SMALLDATETIME', # minute precision
 118      'small_dt',
 119      'EventSmallDT',
 120      'id',
 121      {},
 122      {
 123       year => 2004,
 124       month => 8,
 125       day => 21,
 126       hour => 14,
 127       minute => 36,
 128     }],
 129   );
 130
 131   for my $dt_type (@dt_types) {
 132     my ($type, $col, $source, $pk, $create_extra, $sample_dt) = @$dt_type;
 133
 134     delete $sample_dt->{nanosecond} if $dsn =~ /:ADO:/;
 135
 136     ok(my $dt = DateTime->new($sample_dt));
 137
 138     my $row;
 139     ok( $row = $schema->resultset($source)->create({
 140           $col => $dt,
 141           %$create_extra,
 142         }));
 143     ok( $row = $schema->resultset($source)
 144       ->search({ $pk => $row->$pk }, { select => [$col] })
 145       ->first
 146     );
 147     is( $row->$col, $dt, "$type roundtrip" );
 148
 149     cmp_ok( $row->$col->nanosecond, '==', $sample_dt->{nanosecond},
 150       'DateTime fractional portion roundtrip' )
 151       if exists $sample_dt->{nanosecond};
 152   }
 153
 154   # Check for bulk insert SQL_DATE funtimes when using DBD::ODBC and sqlncli
 155   # dbi:ODBC:driver=SQL Server Native Client 10.0;server=10.6.0.9;database=odbctest;
 156   lives_ok {
 157     $schema->resultset('Event')->populate([{
 158       id => 1,
 159       starts_at => undef,
 160     },{
 161       id => 2,
 162       starts_at => '2011-03-22',
 163     }])
 164   } 'populate with datetime does not throw';
 165   ok ( my $row = $schema->resultset('Event')->find(2), 'SQL_DATE bulk insert check' );
 166 }
 167
 168
 169 done_testing;
 170
 171 # clean up our mess
 172 sub cleanup {
 173   my $schema = shift;
 174   if (my $dbh = eval { $schema->storage->dbh }) {
 175     $dbh->do('DROP TABLE track');
 176     $dbh->do('DROP TABLE event_small_dt');
 177     $dbh->do('DROP TABLE event');
 178   }
 179 }