t/inflate/datetime_informix.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use DBIx::Class::Optional::Dependencies ();
   7 use lib qw(t/lib);
   8 use DBICTest;
   9 use Scope::Guard ();
  10
  11 plan skip_all => 'Test needs ' . DBIx::Class::Optional::Dependencies->req_missing_for ('test_dt')
  12 . ' and ' .
  13 DBIx::Class::Optional::Dependencies->req_missing_for ('test_rdbms_informix')
  14   unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_dt')
  15     && DBIx::Class::Optional::Dependencies->req_ok_for ('test_rdbms_informix');
  16
  17 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_INFORMIX_${_}" } qw/DSN USER PASS/};
  18
  19 if (not $dsn) {
  20   plan skip_all => <<'EOF';
  21 Set $ENV{DBICTEST_INFORMIX_DSN} _USER and _PASS to run this test'.
  22 Warning: This test drops and creates a table called 'event'";
  23 EOF
  24 }
  25
  26 my $schema;
  27
  28 {
  29   $schema = DBICTest::Schema->connect($dsn, $user, $pass, {
  30     on_connect_call => [ 'datetime_setup' ],
  31   });
  32
  33   my $sg = Scope::Guard->new(sub { cleanup($schema) } );
  34
  35   eval { $schema->storage->dbh->do('DROP TABLE event') };
  36   $schema->storage->dbh->do(<<'SQL');
  37   CREATE TABLE event (
  38     id INT PRIMARY KEY,
  39     starts_at DATE,
  40     created_on DATETIME YEAR TO FRACTION(5)
  41   );
  42 SQL
  43   my $rs = $schema->resultset('Event');
  44
  45   my $dt = DateTime->now;
  46   $dt->set_nanosecond(555640000);
  47
  48   my $date_only = DateTime->new(
  49     year => $dt->year, month => $dt->month, day => $dt->day
  50   );
  51
  52   my $row;
  53   ok( $row = $rs->create({
  54     id => 1,
  55     starts_at => $date_only,
  56     created_on => $dt,
  57   }));
  58   ok( $row = $rs->search({ id => 1 }, { select => [qw/starts_at created_on/] })
  59     ->first
  60   );
  61   is $row->created_on, $dt, 'TIMESTAMP as DateTime roundtrip';
  62
  63   cmp_ok $row->created_on->nanosecond, '==', $dt->nanosecond,
  64     'fractional part of a second survived';
  65
  66   is $row->starts_at, $date_only, 'DATE as DateTime roundtrip';
  67 }
  68
  69 done_testing;
  70
  71 # clean up our mess
  72 sub cleanup {
  73   my $schema = shift;
  74   my $dbh;
  75   eval {
  76     $dbh = $schema->storage->dbh;
  77   };
  78   return unless $dbh;
  79
  80   eval { $dbh->do(qq{DROP TABLE $_}) } for qw/event/;
  81 }