t/inflate/datetime_firebird.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use DBIx::Class::Optional::Dependencies ();
   6 use lib qw(t/lib);
   7 use DBICTest;
   8 use Scope::Guard ();
   9
  10 my $env2optdep = {
  11   DBICTEST_FIREBIRD => 'test_rdbms_firebird',
  12   DBICTEST_FIREBIRD_INTERBASE => 'test_rdbms_firebird_interbase',
  13   DBICTEST_FIREBIRD_ODBC => 'test_rdbms_firebird_odbc',
  14 };
  15
  16 plan skip_all => join (' ',
  17   'Set $ENV{DBICTEST_FIREBIRD_DSN} and/or $ENV{DBICTEST_FIREBIRD_INTERBASE_DSN}',
  18   'and/or $ENV{DBICTEST_FIREBIRD_ODBC_DSN},',
  19   '_USER and _PASS to run these tests.',
  20
  21   "WARNING: This test drops and creates a table called 'event'",
  22 ) unless grep { $ENV{"${_}_DSN"} } keys %$env2optdep;
  23
  24 plan skip_all => ( 'Test needs ' . DBIx::Class::Optional::Dependencies->req_missing_for('test_dt') )
  25   unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_dt');
  26
  27 my $schema;
  28
  29 for my $prefix (keys %$env2optdep) { SKIP: {
  30
  31   my ($dsn, $user, $pass) = map { $ENV{"${prefix}_$_"} } qw/DSN USER PASS/;
  32
  33   next unless $dsn;
  34
  35   note "Testing with ${prefix}_DSN";
  36
  37   skip ("Testing with ${prefix}_DSN needs " . DBIx::Class::Optional::Dependencies->req_missing_for( $env2optdep->{$prefix} ), 1)
  38     unless  DBIx::Class::Optional::Dependencies->req_ok_for($env2optdep->{$prefix});
  39
  40   $schema = DBICTest::Schema->connect($dsn, $user, $pass, {
  41     quote_char => '"',
  42     name_sep   => '.',
  43     on_connect_call => [ 'datetime_setup' ],
  44   });
  45
  46   my $sg = Scope::Guard->new(sub { cleanup($schema) } );
  47
  48   eval { $schema->storage->dbh->do('DROP TABLE "event"') };
  49   $schema->storage->dbh->do(<<'SQL');
  50   CREATE TABLE "event" (
  51     "id" INT PRIMARY KEY,
  52     "starts_at" DATE,
  53     "created_on" TIMESTAMP
  54   )
  55 SQL
  56   my $rs = $schema->resultset('Event');
  57
  58   my $dt = DateTime->now;
  59   $dt->set_nanosecond(555600000);
  60
  61   my $date_only = DateTime->new(
  62     year => $dt->year, month => $dt->month, day => $dt->day
  63   );
  64
  65   my $row;
  66   ok( $row = $rs->create({
  67     id => 1,
  68     starts_at => $date_only,
  69     created_on => $dt,
  70   }));
  71   ok( $row = $rs->search({ id => 1 }, { select => [qw/starts_at created_on/] })
  72     ->first
  73   );
  74   is $row->created_on, $dt, 'TIMESTAMP as DateTime roundtrip';
  75
  76   cmp_ok $row->created_on->nanosecond, '==', $dt->nanosecond,
  77     'fractional part of a second survived';
  78
  79   is $row->starts_at, $date_only, 'DATE as DateTime roundtrip';
  80 } }
  81
  82 done_testing;
  83
  84 # clean up our mess
  85 sub cleanup {
  86   my $schema = shift;
  87   my $dbh;
  88   eval {
  89     $schema->storage->disconnect; # to avoid object FOO is in use errors
  90     $dbh = $schema->storage->dbh;
  91   };
  92   return unless $dbh;
  93
  94   eval { $dbh->do(qq{DROP TABLE "$_"}) } for qw/event/;
  95 }