t/inflate/datetime_firebird.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use DBIx::Class::Optional::Dependencies ();
   7 use lib qw(t/lib);
   8 use DBICTest;
   9 use Scope::Guard ();
  10
  11 my ($dsn, $user, $pass)    = @ENV{map { "DBICTEST_FIREBIRD_${_}" }      qw/DSN USER PASS/};
  12 my ($dsn2, $user2, $pass2) = @ENV{map { "DBICTEST_FIREBIRD_INTERBASE_${_}" } qw/DSN USER PASS/};
  13 my ($dsn3, $user3, $pass3) = @ENV{map { "DBICTEST_FIREBIRD_ODBC_${_}" } qw/DSN USER PASS/};
  14
  15 plan skip_all => 'Test needs ' .
  16   (join ' and ', map { $_ ? $_ : () }
  17     DBIx::Class::Optional::Dependencies->req_missing_for('test_dt'),
  18     (join ' or ', map { $_ ? $_ : () }
  19       DBIx::Class::Optional::Dependencies->req_missing_for('test_rdbms_firebird'),
  20       DBIx::Class::Optional::Dependencies->req_missing_for('test_rdbms_firebird_interbase'),
  21       DBIx::Class::Optional::Dependencies->req_missing_for('test_rdbms_firebird_odbc')))
  22   unless
  23     DBIx::Class::Optional::Dependencies->req_ok_for ('test_dt') && (
  24     $dsn && DBIx::Class::Optional::Dependencies->req_ok_for('test_rdbms_firebird')
  25     or
  26     $dsn2 && DBIx::Class::Optional::Dependencies->req_ok_for('test_rdbms_firebird_interbase')
  27     or
  28     $dsn3 && DBIx::Class::Optional::Dependencies->req_ok_for('test_rdbms_firebird_odbc'))
  29       or (not $dsn || $dsn2 || $dsn3);
  30
  31 if (not ($dsn || $dsn2)) {
  32   plan skip_all => <<'EOF';
  33 Set $ENV{DBICTEST_FIREBIRD_DSN} and/or $ENV{DBICTEST_FIREBIRD_INTERBASE_DSN}
  34 and/or $ENV{DBICTEST_FIREBIRD_ODBC_DSN}
  35 _USER and _PASS to run this test'.
  36 Warning: This test drops and creates a table called 'event'";
  37 EOF
  38 }
  39
  40 my @info = (
  41   [ $dsn,  $user,  $pass  ],
  42   [ $dsn2, $user2, $pass2 ],
  43   [ $dsn3, $user3, $pass3 ],
  44 );
  45
  46 my $schema;
  47
  48 foreach my $conn_idx (0..$#info) {
  49   my ($dsn, $user, $pass) = @{ $info[$conn_idx] || [] };
  50
  51   next unless $dsn;
  52
  53   $schema = DBICTest::Schema->connect($dsn, $user, $pass, {
  54     quote_char => '"',
  55     name_sep   => '.',
  56     on_connect_call => [ 'datetime_setup' ],
  57   });
  58
  59   my $sg = Scope::Guard->new(\&cleanup);
  60
  61   eval { $schema->storage->dbh->do('DROP TABLE "event"') };
  62   $schema->storage->dbh->do(<<'SQL');
  63   CREATE TABLE "event" (
  64     "id" INT PRIMARY KEY,
  65     "starts_at" DATE,
  66     "created_on" TIMESTAMP
  67   )
  68 SQL
  69   my $rs = $schema->resultset('Event');
  70
  71   my $dt = DateTime->now;
  72   $dt->set_nanosecond(555600000);
  73
  74   my $date_only = DateTime->new(
  75     year => $dt->year, month => $dt->month, day => $dt->day
  76   );
  77
  78   my $row;
  79   ok( $row = $rs->create({
  80     id => 1,
  81     starts_at => $date_only,
  82     created_on => $dt,
  83   }));
  84   ok( $row = $rs->search({ id => 1 }, { select => [qw/starts_at created_on/] })
  85     ->first
  86   );
  87   is $row->created_on, $dt, 'TIMESTAMP as DateTime roundtrip';
  88
  89   cmp_ok $row->created_on->nanosecond, '==', $dt->nanosecond,
  90     'fractional part of a second survived';
  91
  92   is $row->starts_at, $date_only, 'DATE as DateTime roundtrip';
  93 }
  94
  95 done_testing;
  96
  97 # clean up our mess
  98 sub cleanup {
  99   my $dbh;
 100   eval {
 101     $schema->storage->disconnect; # to avoid object FOO is in use errors
 102     $dbh = $schema->storage->dbh;
 103   };
 104   return unless $dbh;
 105
 106   eval { $dbh->do(qq{DROP TABLE "$_"}) } for qw/event/;
 107 }