t/icdt/engine_specific/sqlite.t

   1 use DBIx::Class::Optional::Dependencies -skip_all_without => qw( icdt test_rdbms_sqlite );
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More;
   7 use Test::Warn;
   8 use Try::Tiny;
   9 use lib qw(t/lib);
  10 use DBICTest;
  11
  12 # Test offline parser determination (formerly t/inflate/datetime_determine_parser.t)
  13 {
  14   my $schema = DBICTest->init_schema(
  15     no_deploy => 1, # Deploying would cause an early rebless
  16   );
  17
  18   my $storage = $schema->storage;
  19
  20   is(
  21     ref $storage, 'DBIx::Class::Storage::DBI',
  22     'Starting with generic storage'
  23   );
  24
  25   # Calling date_time_parser should cause the storage to be reblessed,
  26   # so that we can pick up datetime_parser_type from subclasses
  27   my $parser = $storage->datetime_parser();
  28
  29   is($parser, 'DateTime::Format::SQLite', 'Got expected storage-set datetime_parser');
  30   isa_ok($storage, 'DBIx::Class::Storage::DBI::SQLite', 'storage');
  31
  32   ok(! $storage->connected, 'Not yet connected');
  33 }
  34
  35 # so user's env doesn't screw us
  36 delete $ENV{DBIC_DT_SEARCH_OK};
  37
  38 my $schema = DBICTest->init_schema();
  39
  40 # inflation test
  41 my $event = $schema->resultset("Event")->find(1);
  42
  43 isa_ok($event->starts_at, 'DateTime', 'DateTime returned');
  44
  45 # klunky, but makes older Test::More installs happy
  46 my $starts = $event->starts_at;
  47 is("$starts", '2006-04-25T22:24:33', 'Correct date/time');
  48
  49 my $dt_warn_re = qr/DateTime objects.+not supported properly/;
  50
  51 my $row;
  52
  53 {
  54   local $ENV{DBIC_DT_SEARCH_OK} = 1;
  55   local $SIG{__WARN__} = sub {
  56     fail('Disabled warning still issued') if $_[0] =~ $dt_warn_re;
  57     warn @_;
  58   };
  59   $row = $schema->resultset('Event')->search({ starts_at => $starts })->single
  60 }
  61
  62 warnings_exist {
  63   $row = $schema->resultset('Event')->search({ starts_at => $starts })->single
  64 } [$dt_warn_re],
  65   'using a DateTime object in ->search generates a warning';
  66
  67 {
  68   local $TODO = "This stuff won't work without a -dt operator of some sort"
  69     unless eval { require DBIx::Class::SQLMaker::DateOps };
  70
  71   is(eval { $row->id }, 1, 'DT in search');
  72
  73   local $ENV{DBIC_DT_SEARCH_OK} = 1;
  74
  75   ok($row =
  76     $schema->resultset('Event')->search({ starts_at => { '>=' => $starts } })
  77     ->single);
  78
  79   is(eval { $row->id }, 1, 'DT in search with condition');
  80 }
  81
  82 # create using DateTime
  83 my $created = $schema->resultset('Event')->create({
  84     starts_at => DateTime->new(year=>2006, month=>6, day=>18),
  85     created_on => DateTime->new(year=>2006, month=>6, day=>23)
  86 });
  87 my $created_start = $created->starts_at;
  88
  89 isa_ok($created->starts_at, 'DateTime', 'DateTime returned');
  90 is("$created_start", '2006-06-18T00:00:00', 'Correct date/time');
  91
  92 ## timestamp field
  93 isa_ok($event->created_on, 'DateTime', 'DateTime returned');
  94
  95 ## varchar fields
  96 isa_ok($event->varchar_date, 'DateTime', 'DateTime returned');
  97 isa_ok($event->varchar_datetime, 'DateTime', 'DateTime returned');
  98
  99 ## skip inflation field
 100 isnt(ref($event->skip_inflation), 'DateTime', 'No DateTime returned for skip inflation column');
 101
 102 # klunky, but makes older Test::More installs happy
 103 my $createo = $event->created_on;
 104 is("$createo", '2006-06-22T21:00:05', 'Correct date/time');
 105
 106 my $created_cron = $created->created_on;
 107
 108 isa_ok($created->created_on, 'DateTime', 'DateTime returned');
 109 is("$created_cron", '2006-06-23T00:00:00', 'Correct date/time');
 110
 111 ## varchar field using inflate_date => 1
 112 my $varchar_date = $event->varchar_date;
 113 is("$varchar_date", '2006-07-23T00:00:00', 'Correct date/time');
 114
 115 ## varchar field using inflate_datetime => 1
 116 my $varchar_datetime = $event->varchar_datetime;
 117 is("$varchar_datetime", '2006-05-22T19:05:07', 'Correct date/time');
 118
 119 ## skip inflation field
 120 my $skip_inflation = $event->skip_inflation;
 121 is ("$skip_inflation", '2006-04-21 18:04:06', 'Correct date/time');
 122
 123 # extra accessor tests with update_or_insert
 124 {
 125   my $new = $schema->resultset("Track")->new( {
 126     trackid => 100,
 127     cd => 1,
 128     title => 'Insert or Update',
 129     last_updated_on => '1973-07-19 12:01:02'
 130   } );
 131   $new->update_or_insert;
 132   ok($new->in_storage, 'update_or_insert insert ok');
 133
 134   # test in update mode
 135   $new->title('Insert or Update - updated');
 136   $new->update_or_insert;
 137   is( $schema->resultset("Track")->find(100)->title, 'Insert or Update - updated', 'update_or_insert update ok');
 138
 139   # test get_inflated_columns with objects
 140   my $event = $schema->resultset('Event')->search->first;
 141   my %edata = $event->get_inflated_columns;
 142   is($edata{'id'}, $event->id, 'got id');
 143   isa_ok($edata{'starts_at'}, 'DateTime', 'start_at is DateTime object');
 144   isa_ok($edata{'created_on'}, 'DateTime', 'create_on DateTime object');
 145   is($edata{'starts_at'}, $event->starts_at, 'got start date');
 146   is($edata{'created_on'}, $event->created_on, 'got created date');
 147
 148   # get_inflated_columns w/relation and accessor alias
 149   isa_ok($new->updated_date, 'DateTime', 'have inflated object via accessor');
 150   my %tdata = $new->get_inflated_columns;
 151   is($tdata{'trackid'}, 100, 'got id');
 152   isa_ok($tdata{'cd'}, 'DBICTest::CD', 'cd is CD object');
 153   is($tdata{'cd'}->id, 1, 'cd object is id 1');
 154   is(
 155     $tdata{'position'},
 156     $schema->resultset ('Track')->search ({cd => 1})->count,
 157     'Ordered assigned proper position',
 158   );
 159   is($tdata{'title'}, 'Insert or Update - updated');
 160   is($tdata{'last_updated_on'}, '1973-07-19T12:01:02');
 161   isa_ok($tdata{'last_updated_on'}, 'DateTime', 'inflated accessored column');
 162 }
 163
 164 # create and update with literals
 165 {
 166   my $d = {
 167     created_on => \ '2001-09-11',
 168     starts_at => \[ '?' => '2001-10-26' ],
 169   };
 170
 171   my $ev = $schema->resultset('Event')->create($d);
 172
 173   for my $col (qw(created_on starts_at)) {
 174     ok (ref $ev->$col, "literal untouched in $col");
 175     is_deeply( $ev->$col, $d->{$col});
 176     is_deeply( $ev->get_inflated_column($col), $d->{$col});
 177     is_deeply( $ev->get_column($col), $d->{$col});
 178   }
 179
 180   $ev->discard_changes;
 181
 182   is_deeply(
 183     { $ev->get_dirty_columns },
 184     {}
 185   );
 186
 187   for my $col (qw(created_on starts_at)) {
 188     isa_ok ($ev->$col, "DateTime", "$col properly inflated on retrieve");
 189   }
 190
 191   for my $meth (qw(set_inflated_columns set_columns)) {
 192
 193     $ev->$meth({%$d});
 194
 195     is_deeply(
 196       { $ev->get_dirty_columns },
 197       $d,
 198       "Expected dirty cols after setting literals via $meth",
 199     );
 200
 201     $ev->update;
 202
 203     for my $col (qw(created_on starts_at)) {
 204       ok (ref $ev->$col, "literal untouched in $col updated via $meth");
 205       is_deeply( $ev->$col, $d->{$col});
 206       is_deeply( $ev->get_inflated_column($col), $d->{$col});
 207       is_deeply( $ev->get_column($col), $d->{$col});
 208     }
 209   }
 210 }
 211
 212 done_testing;