t/icdt/engine_specific/sqlite.t

   1 use DBIx::Class::Optional::Dependencies -skip_all_without => 'test_dt_sqlite';
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More;
   7 use Test::Warn;
   8 use Try::Tiny;
   9 use lib qw(t/lib);
  10 use DBICTest;
  11
  12 # Test offline parser determination (formerly t/inflate/datetime_determine_parser.t)
  13 {
  14   my $schema = DBICTest->init_schema(
  15     no_deploy => 1, # Deploying would cause an early rebless
  16   );
  17
  18   is(
  19     ref $schema->storage, 'DBIx::Class::Storage::DBI',
  20     'Starting with generic storage'
  21   );
  22
  23   # Calling date_time_parser should cause the storage to be reblessed,
  24   # so that we can pick up datetime_parser_type from subclasses
  25   my $parser = $schema->storage->datetime_parser();
  26
  27   is($parser, 'DateTime::Format::SQLite', 'Got expected storage-set datetime_parser');
  28   isa_ok($schema->storage, 'DBIx::Class::Storage::DBI::SQLite', 'storage');
  29
  30   ok(! $schema->storage->connected, 'Not yet connected');
  31 }
  32
  33 # so user's env doesn't screw us
  34 delete $ENV{DBIC_DT_SEARCH_OK};
  35
  36 my $schema = DBICTest->init_schema();
  37
  38 # inflation test
  39 my $event = $schema->resultset("Event")->find(1);
  40
  41 isa_ok($event->starts_at, 'DateTime', 'DateTime returned');
  42
  43 # klunky, but makes older Test::More installs happy
  44 my $starts = $event->starts_at;
  45 is("$starts", '2006-04-25T22:24:33', 'Correct date/time');
  46
  47 my $dt_warn_re = qr/DateTime objects.+not supported properly/;
  48
  49 my $row;
  50
  51 {
  52   local $ENV{DBIC_DT_SEARCH_OK} = 1;
  53   local $SIG{__WARN__} = sub {
  54     fail('Disabled warning still issued') if $_[0] =~ $dt_warn_re;
  55     warn @_;
  56   };
  57   $row = $schema->resultset('Event')->search({ starts_at => $starts })->single
  58 }
  59
  60 warnings_exist {
  61   $row = $schema->resultset('Event')->search({ starts_at => $starts })->single
  62 } [$dt_warn_re],
  63   'using a DateTime object in ->search generates a warning';
  64
  65 {
  66   local $TODO = "This stuff won't work without a -dt operator of some sort"
  67     unless eval { require DBIx::Class::SQLMaker::DateOps };
  68
  69   is(eval { $row->id }, 1, 'DT in search');
  70
  71   local $ENV{DBIC_DT_SEARCH_OK} = 1;
  72
  73   ok($row =
  74     $schema->resultset('Event')->search({ starts_at => { '>=' => $starts } })
  75     ->single);
  76
  77   is(eval { $row->id }, 1, 'DT in search with condition');
  78 }
  79
  80 # create using DateTime
  81 my $created = $schema->resultset('Event')->create({
  82     starts_at => DateTime->new(year=>2006, month=>6, day=>18),
  83     created_on => DateTime->new(year=>2006, month=>6, day=>23)
  84 });
  85 my $created_start = $created->starts_at;
  86
  87 isa_ok($created->starts_at, 'DateTime', 'DateTime returned');
  88 is("$created_start", '2006-06-18T00:00:00', 'Correct date/time');
  89
  90 ## timestamp field
  91 isa_ok($event->created_on, 'DateTime', 'DateTime returned');
  92
  93 ## varchar fields
  94 isa_ok($event->varchar_date, 'DateTime', 'DateTime returned');
  95 isa_ok($event->varchar_datetime, 'DateTime', 'DateTime returned');
  96
  97 ## skip inflation field
  98 isnt(ref($event->skip_inflation), 'DateTime', 'No DateTime returned for skip inflation column');
  99
 100 # klunky, but makes older Test::More installs happy
 101 my $createo = $event->created_on;
 102 is("$createo", '2006-06-22T21:00:05', 'Correct date/time');
 103
 104 my $created_cron = $created->created_on;
 105
 106 isa_ok($created->created_on, 'DateTime', 'DateTime returned');
 107 is("$created_cron", '2006-06-23T00:00:00', 'Correct date/time');
 108
 109 ## varchar field using inflate_date => 1
 110 my $varchar_date = $event->varchar_date;
 111 is("$varchar_date", '2006-07-23T00:00:00', 'Correct date/time');
 112
 113 ## varchar field using inflate_datetime => 1
 114 my $varchar_datetime = $event->varchar_datetime;
 115 is("$varchar_datetime", '2006-05-22T19:05:07', 'Correct date/time');
 116
 117 ## skip inflation field
 118 my $skip_inflation = $event->skip_inflation;
 119 is ("$skip_inflation", '2006-04-21 18:04:06', 'Correct date/time');
 120
 121 # extra accessor tests with update_or_insert
 122 {
 123   my $new = $schema->resultset("Track")->new( {
 124     trackid => 100,
 125     cd => 1,
 126     title => 'Insert or Update',
 127     last_updated_on => '1973-07-19 12:01:02'
 128   } );
 129   $new->update_or_insert;
 130   ok($new->in_storage, 'update_or_insert insert ok');
 131
 132   # test in update mode
 133   $new->title('Insert or Update - updated');
 134   $new->update_or_insert;
 135   is( $schema->resultset("Track")->find(100)->title, 'Insert or Update - updated', 'update_or_insert update ok');
 136
 137   # test get_inflated_columns with objects
 138   my $event = $schema->resultset('Event')->search->first;
 139   my %edata = $event->get_inflated_columns;
 140   is($edata{'id'}, $event->id, 'got id');
 141   isa_ok($edata{'starts_at'}, 'DateTime', 'start_at is DateTime object');
 142   isa_ok($edata{'created_on'}, 'DateTime', 'create_on DateTime object');
 143   is($edata{'starts_at'}, $event->starts_at, 'got start date');
 144   is($edata{'created_on'}, $event->created_on, 'got created date');
 145
 146   # get_inflated_columns w/relation and accessor alias
 147   isa_ok($new->updated_date, 'DateTime', 'have inflated object via accessor');
 148   my %tdata = $new->get_inflated_columns;
 149   is($tdata{'trackid'}, 100, 'got id');
 150   isa_ok($tdata{'cd'}, 'DBICTest::CD', 'cd is CD object');
 151   is($tdata{'cd'}->id, 1, 'cd object is id 1');
 152   is(
 153     $tdata{'position'},
 154     $schema->resultset ('Track')->search ({cd => 1})->count,
 155     'Ordered assigned proper position',
 156   );
 157   is($tdata{'title'}, 'Insert or Update - updated');
 158   is($tdata{'last_updated_on'}, '1973-07-19T12:01:02');
 159   isa_ok($tdata{'last_updated_on'}, 'DateTime', 'inflated accessored column');
 160 }
 161
 162 # create and update with literals
 163 {
 164   my $d = {
 165     created_on => \ '2001-09-11',
 166     starts_at => \[ '?' => '2001-10-26' ],
 167   };
 168
 169   my $ev = $schema->resultset('Event')->create($d);
 170
 171   for my $col (qw(created_on starts_at)) {
 172     ok (ref $ev->$col, "literal untouched in $col");
 173     is_deeply( $ev->$col, $d->{$col});
 174     is_deeply( $ev->get_inflated_column($col), $d->{$col});
 175     is_deeply( $ev->get_column($col), $d->{$col});
 176   }
 177
 178   $ev->discard_changes;
 179
 180   is_deeply(
 181     { $ev->get_dirty_columns },
 182     {}
 183   );
 184
 185   for my $col (qw(created_on starts_at)) {
 186     isa_ok ($ev->$col, "DateTime", "$col properly inflated on retrieve");
 187   }
 188
 189   for my $meth (qw(set_inflated_columns set_columns)) {
 190
 191     $ev->$meth({%$d});
 192
 193     is_deeply(
 194       { $ev->get_dirty_columns },
 195       $d,
 196       "Expected dirty cols after setting literals via $meth",
 197     );
 198
 199     $ev->update;
 200
 201     for my $col (qw(created_on starts_at)) {
 202       ok (ref $ev->$col, "literal untouched in $col updated via $meth");
 203       is_deeply( $ev->$col, $d->{$col});
 204       is_deeply( $ev->get_inflated_column($col), $d->{$col});
 205       is_deeply( $ev->get_column($col), $d->{$col});
 206     }
 207   }
 208 }
 209
 210 done_testing;