t/icdt/engine_specific/firebird.t

   1 use DBIx::Class::Optional::Dependencies -skip_all_without => qw( ic_dt _rdbms_firebird_common );
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More;
   7 use lib qw(t/lib);
   8 use DBICTest;
   9 use Scope::Guard ();
  10
  11 my $env2optdep = {
  12   DBICTEST_FIREBIRD => 'test_rdbms_firebird',
  13   DBICTEST_FIREBIRD_INTERBASE => 'test_rdbms_firebird_interbase',
  14   DBICTEST_FIREBIRD_ODBC => 'test_rdbms_firebird_odbc',
  15 };
  16
  17 my @tdeps = values %$env2optdep;
  18 plan skip_all => 'Test needs  ' . (join '  OR  ', map
  19   { "[ @{[ DBIx::Class::Optional::Dependencies->req_missing_for( $_ ) ]} ]" }
  20   @tdeps
  21 ) unless scalar grep
  22   { DBIx::Class::Optional::Dependencies->req_ok_for( $_ ) }
  23   @tdeps
  24 ;
  25
  26 my $schema;
  27
  28 for my $prefix (keys %$env2optdep) { SKIP: {
  29
  30   my ($dsn, $user, $pass) = map { $ENV{"${prefix}_$_"} } qw/DSN USER PASS/;
  31
  32   next unless $dsn;
  33
  34   note "Testing with ${prefix}_DSN";
  35
  36   skip ("Testing with ${prefix}_DSN needs " . DBIx::Class::Optional::Dependencies->req_missing_for( $env2optdep->{$prefix} ), 1)
  37     unless  DBIx::Class::Optional::Dependencies->req_ok_for($env2optdep->{$prefix});
  38
  39   $schema = DBICTest::Schema->connect($dsn, $user, $pass, {
  40     quote_char => '"',
  41     name_sep   => '.',
  42     on_connect_call => [ 'datetime_setup' ],
  43   });
  44
  45   my $sg = Scope::Guard->new(sub { cleanup($schema) } );
  46
  47   eval { $schema->storage->dbh->do('DROP TABLE "event"') };
  48   $schema->storage->dbh->do(<<'SQL');
  49   CREATE TABLE "event" (
  50     "id" INT PRIMARY KEY,
  51     "starts_at" DATE,
  52     "created_on" TIMESTAMP
  53   )
  54 SQL
  55   my $rs = $schema->resultset('Event');
  56
  57   my $dt = DateTime->now;
  58   $dt->set_nanosecond(555600000);
  59
  60   my $date_only = DateTime->new(
  61     year => $dt->year, month => $dt->month, day => $dt->day
  62   );
  63
  64   my $row;
  65   ok( $row = $rs->create({
  66     id => 1,
  67     starts_at => $date_only,
  68     created_on => $dt,
  69   }));
  70   ok( $row = $rs->search({ id => 1 }, { select => [qw/starts_at created_on/] })
  71     ->first
  72   );
  73   is $row->created_on, $dt, 'TIMESTAMP as DateTime roundtrip';
  74
  75   cmp_ok $row->created_on->nanosecond, '==', $dt->nanosecond,
  76     'fractional part of a second survived';
  77
  78   is $row->starts_at, $date_only, 'DATE as DateTime roundtrip';
  79 } }
  80
  81 done_testing;
  82
  83 # clean up our mess
  84 sub cleanup {
  85   my $schema = shift;
  86   my $dbh;
  87   eval {
  88     $schema->storage->disconnect; # to avoid object FOO is in use errors
  89     $dbh = $schema->storage->dbh;
  90   };
  91   return unless $dbh;
  92
  93   eval { $dbh->do(qq{DROP TABLE "$_"}) } for qw/event/;
  94 }