t/count/prefetch.t

   1 use strict;
   2 use warnings;
   3
   4 use lib qw(t/lib);
   5
   6 use Test::More;
   7 use DBICTest;
   8 use DBIC::SqlMakerTest;
   9
  10 my $schema = DBICTest->init_schema();
  11
  12 # collapsing prefetch
  13 {
  14   my $rs = $schema->resultset("Artist")
  15             ->search_related('cds',
  16                 { 'tracks.position' => [1,2] },
  17                 { prefetch => [qw/tracks artist/] },
  18             );
  19   is ($rs->all, 5, 'Correct number of objects');
  20   is ($rs->count, 5, 'Correct count');
  21
  22   is_same_sql_bind (
  23     $rs->count_rs->as_query,
  24     '(
  25       SELECT COUNT( * )
  26         FROM (
  27           SELECT cds.cdid
  28             FROM artist me
  29             JOIN cd cds ON cds.artist = me.artistid
  30             LEFT JOIN track tracks ON tracks.cd = cds.cdid
  31             JOIN artist artist ON artist.artistid = cds.artist
  32           WHERE tracks.position = ? OR tracks.position = ?
  33           GROUP BY cds.cdid
  34         ) count_subq
  35     )',
  36     [ map { [ 'tracks.position' => $_ ] } (1, 2) ],
  37   );
  38 }
  39
  40 # collapsing prefetch with distinct
  41 {
  42   my $rs = $schema->resultset("Artist")->search(undef, {distinct => 1})
  43             ->search_related('cds')->search_related('genre',
  44                 { 'genre.name' => 'emo' },
  45                 { prefetch => q(cds) },
  46             );
  47   is ($rs->all, 1, 'Correct number of objects');
  48   is ($rs->count, 1, 'Correct count');
  49
  50   is_same_sql_bind (
  51     $rs->count_rs->as_query,
  52     '(
  53       SELECT COUNT( * )
  54         FROM (
  55           SELECT genre.genreid
  56             FROM (
  57               SELECT me.artistid, me.name, me.rank, me.charfield
  58                 FROM artist me
  59               GROUP BY me.artistid, me.name, me.rank, me.charfield
  60             ) me
  61             JOIN cd cds ON cds.artist = me.artistid
  62             JOIN genre genre ON genre.genreid = cds.genreid
  63           WHERE ( genre.name = ? )
  64           GROUP BY genre.genreid
  65         )
  66       count_subq
  67     )',
  68     [ [ 'genre.name' => 'emo' ] ],
  69   );
  70 }
  71
  72 # non-collapsing prefetch (no multi prefetches)
  73 {
  74   my $rs = $schema->resultset("CD")
  75             ->search_related('tracks',
  76                 { position => [1,2], 'lyrics.lyric_id' => undef },
  77                 { prefetch => [qw/disc lyrics/] },
  78             );
  79   is ($rs->all, 10, 'Correct number of objects');
  80
  81
  82   is ($rs->count, 10, 'Correct count');
  83
  84   is_same_sql_bind (
  85     $rs->count_rs->as_query,
  86     '(
  87       SELECT COUNT( * )
  88         FROM cd me
  89         JOIN track tracks ON tracks.cd = me.cdid
  90         JOIN cd disc ON disc.cdid = tracks.cd
  91         LEFT JOIN lyrics lyrics ON lyrics.track_id = tracks.trackid
  92       WHERE lyrics.lyric_id IS NULL AND (position = ? OR position = ?)
  93     )',
  94     [ map { [ position => $_ ] } (1, 2) ],
  95   );
  96 }
  97
  98 done_testing;