t/cdbi/testlib/DBIC/Test/SQLite.pm

   1 package # hide from PAUSE
   2     DBIC::Test::SQLite;
   3
   4 use strict;
   5 use warnings;
   6
   7 =head1 NAME
   8
   9 DBIx::Class::Test::SQLite - Base class for running Class::DBI tests against DBIx::Class compat layer, shamelessly ripped from Class::DBI::Test::SQLite
  10
  11 =head1 SYNOPSIS
  12
  13   use base 'DBIx::Class::Test::SQLite';
  14
  15   __PACKAGE__->set_table('test');
  16   __PACKAGE__->columns(All => qw/id name film salary/);
  17
  18   sub create_sql {
  19       return q{
  20           id     INTEGER PRIMARY KEY,
  21           name   CHAR(40),
  22           film   VARCHAR(255),
  23           salary INT
  24       }
  25   }
  26
  27 =head1 DESCRIPTION
  28
  29 This provides a simple base class for DBIx::Class::CDBICompat tests using
  30 SQLite.  Each class for the test should inherit from this, provide a
  31 create_sql() method which returns a string representing the SQL used to
  32 create the table for the class, and then call set_table() to create the
  33 table, and tie it to the class.
  34
  35 =cut
  36
  37 # adding implicit search criteria to the iterator will alter the test
  38 # mechanics - leave everything as-is instead, and hope SQLite won't
  39 # change too much
  40 BEGIN { $ENV{DBIC_SHUFFLE_UNORDERED_RESULTSETS} = 0 }
  41
  42 use lib 't/lib';
  43 use DBICTest;
  44
  45 use base qw/DBIx::Class/;
  46
  47 __PACKAGE__->load_components(qw/CDBICompat Core DB/);
  48
  49 my $DB = DBICTest->_sqlite_dbfilename;
  50 my @DSN = ("dbi:SQLite:dbname=$DB", '', '', { AutoCommit => 1, RaiseError => 1 });
  51
  52 __PACKAGE__->connection(@DSN);
  53 __PACKAGE__->set_sql(_table_pragma => 'PRAGMA table_info(__TABLE__)');
  54 __PACKAGE__->set_sql(_create_me    => 'CREATE TABLE __TABLE__ (%s)');
  55 __PACKAGE__->storage->dbh->do("PRAGMA synchronous = OFF");
  56
  57 =head1 METHODS
  58
  59 =head2 set_table
  60
  61     __PACKAGE__->set_table('test');
  62
  63 This combines creating the table with the normal DBIx::Class table()
  64 call.
  65
  66 =cut
  67
  68 sub set_table {
  69     my ($class, $table) = @_;
  70     $class->table($table);
  71     $class->_create_test_table;
  72 }
  73
  74 sub _create_test_table {
  75     my $class = shift;
  76     my @vals  = $class->sql__table_pragma->select_row;
  77     $class->sql__create_me($class->create_sql)->execute unless @vals;
  78 }
  79
  80 =head2 create_sql
  81
  82 This is an abstract method you must override.
  83
  84   sub create_sql {
  85       return q{
  86           id     INTEGER PRIMARY KEY,
  87           name   CHAR(40),
  88           film   VARCHAR(255),
  89           salary INT
  90       }
  91   }
  92
  93 This should return, as a text string, the schema for the table represented
  94 by this class.
  95
  96 =cut
  97
  98 sub create_sql { die "create_sql() not implemented by $_[0]\n" }
  99
 100 1;