t/bind/bindtype_columns.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use lib qw(t/lib);
   6 use DBICTest;
   7
   8 my ($dsn, $dbuser, $dbpass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
   9
  10 plan skip_all => 'Set $ENV{DBICTEST_PG_DSN}, _USER and _PASS to run this test'
  11   unless ($dsn && $dbuser);
  12
  13 plan tests => 6;
  14
  15 my $schema = DBICTest::Schema->connection($dsn, $dbuser, $dbpass, { AutoCommit => 1 });
  16
  17 my $dbh = $schema->storage->dbh;
  18
  19 {
  20     local $SIG{__WARN__} = sub {};
  21     $dbh->do('DROP TABLE IF EXISTS bindtype_test');
  22
  23     # the blob/clob are for reference only, will be useful when we switch to SQLT and can test Oracle along the way
  24     $dbh->do(qq[
  25         CREATE TABLE bindtype_test
  26         (
  27             id              serial       NOT NULL   PRIMARY KEY,
  28             bytea           bytea        NULL,
  29             blob            bytea        NULL,
  30             clob            text         NULL
  31         );
  32     ],{ RaiseError => 1, PrintError => 1 });
  33 }
  34
  35 $schema->storage->debug(0); # these tests spew up way too much stuff, disable trace
  36
  37 my $big_long_string = "\x00\x01\x02 abcd" x 125000;
  38
  39 my $new;
  40 # test inserting a row
  41 {
  42   $new = $schema->resultset('BindType')->create({ bytea => $big_long_string });
  43
  44   ok($new->id, "Created a bytea row");
  45   is($new->bytea, $big_long_string, "Set the blob correctly.");
  46 }
  47
  48 # test retrieval of the bytea column
  49 {
  50   my $row = $schema->resultset('BindType')->find({ id => $new->id });
  51   is($row->get_column('bytea'), $big_long_string, "Created the blob correctly.");
  52 }
  53
  54 {
  55   my $rs = $schema->resultset('BindType')->search({ bytea => $big_long_string });
  56
  57   # search on the bytea column (select)
  58   {
  59     my $row = $rs->first;
  60     is($row ? $row->id : undef, $new->id, "Found the row searching on the bytea column.");
  61   }
  62
  63   # search on the bytea column (update)
  64   {
  65     my $new_big_long_string = $big_long_string . "2";
  66     $schema->txn_do(sub {
  67       $rs->update({ bytea => $new_big_long_string });
  68       my $row = $schema->resultset('BindType')->find({ id => $new->id });
  69       is($row ? $row->get_column('bytea') : undef, $new_big_long_string,
  70         "Updated the row correctly (searching on the bytea column)."
  71       );
  72       $schema->txn_rollback;
  73     });
  74   }
  75
  76   # search on the bytea column (delete)
  77   {
  78     $schema->txn_do(sub {
  79       $rs->delete;
  80       my $row = $schema->resultset('BindType')->find({ id => $new->id });
  81       is($row, undef, "Deleted the row correctly (searching on the bytea column).");
  82       $schema->txn_rollback;
  83     });
  84   }
  85 }
  86
  87 $dbh->do("DROP TABLE bindtype_test");