t/admin/10script.t

   1 # vim: filetype=perl
   2 use strict;
   3 use warnings;
   4
   5 use Test::More;
   6 use Config;
   7 use lib qw(t/lib);
   8 $ENV{PERL5LIB} = join ($Config{path_sep}, @INC);
   9 use DBICTest;
  10
  11
  12 BEGIN {
  13     require DBIx::Class;
  14     plan skip_all => 'Test needs ' . DBIx::Class::Optional::Dependencies->req_missing_for('admin_script')
  15       unless DBIx::Class::Optional::Dependencies->req_ok_for('admin_script');
  16 }
  17
  18 my @json_backends = qw/XS JSON DWIW/;
  19 my $tests_per_run = 5;
  20
  21 plan tests => $tests_per_run * @json_backends;
  22
  23 for my $js (@json_backends) {
  24
  25     eval {JSON::Any->import ($js) };
  26     SKIP: {
  27         skip ("Json backend $js is not available, skip testing", $tests_per_run) if $@;
  28
  29         $ENV{JSON_ANY_ORDER} = $js;
  30         eval { test_dbicadmin () };
  31         diag $@ if $@;
  32     }
  33 }
  34
  35 sub test_dbicadmin {
  36     my $schema = DBICTest->init_schema( sqlite_use_file => 1 );  # reinit a fresh db for every run
  37
  38     my $employees = $schema->resultset('Employee');
  39
  40     system( _prepare_system_args( qw|--op=insert --set={"name":"Matt"}| ) );
  41     ok( ($employees->count()==1), "$ENV{JSON_ANY_ORDER}: insert count" );
  42
  43     my $employee = $employees->find(1);
  44     ok( ($employee->name() eq 'Matt'), "$ENV{JSON_ANY_ORDER}: insert valid" );
  45
  46     system( _prepare_system_args( qw|--op=update --set={"name":"Trout"}| ) );
  47     $employee = $employees->find(1);
  48     ok( ($employee->name() eq 'Trout'), "$ENV{JSON_ANY_ORDER}: update" );
  49
  50     system( _prepare_system_args( qw|--op=insert --set={"name":"Aran"}| ) );
  51
  52     SKIP: {
  53         skip ("MSWin32 doesn't support -| either", 1) if $^O eq 'MSWin32';
  54
  55         open(my $fh, "-|",  _prepare_system_args( qw|--op=select --attrs={"order_by":"name"}| ) ) or die $!;
  56         my $data = do { local $/; <$fh> };
  57         close($fh);
  58         if (!ok( ($data=~/Aran.*Trout/s), "$ENV{JSON_ANY_ORDER}: select with attrs" )) {
  59           diag ("data from select is $data")
  60         };
  61     }
  62
  63     system( _prepare_system_args( qw|--op=delete --where={"name":"Trout"}| ) );
  64     ok( ($employees->count()==1), "$ENV{JSON_ANY_ORDER}: delete" );
  65 }
  66
  67 # Why do we need this crap? Apparently MSWin32 can not pass through quotes properly
  68 # (sometimes it will and sometimes not, depending on what compiler was used to build
  69 # perl). So we go the extra mile to escape all the quotes. We can't also use ' instead
  70 # of ", because JSON::XS (proudly) does not support "malformed JSON" as the author
  71 # calls it. Bleh.
  72 #
  73 sub _prepare_system_args {
  74     my $perl = $^X;
  75
  76     my @args = (
  77         qw|script/dbicadmin --quiet --schema=DBICTest::Schema --class=Employee|,
  78         q|--connect=["dbi:SQLite:dbname=t/var/DBIxClass.db","","",{"AutoCommit":1}]|,
  79         qw|--force|,
  80         @_,
  81     );
  82
  83     if ( $^O eq 'MSWin32' ) {
  84         $perl = qq|"$perl"|;    # execution will fail if $^X contains paths
  85         for (@args) {
  86             $_ =~ s/"/\\"/g;
  87         }
  88     }
  89
  90     return ($perl, @args);
  91 }