t/admin/02ddl.t

   1 use DBIx::Class::Optional::Dependencies -skip_all_without => qw( admin deploy );
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More;
   7 use Test::Exception;
   8 use Test::Warn;
   9
  10 use Path::Class;
  11
  12 use lib qw(t/lib);
  13 use DBICTest;
  14 use DBIx::Class::_Util 'sigwarn_silencer';
  15
  16 use DBIx::Class::Admin;
  17
  18 # lock early
  19 DBICTest->init_schema(no_deploy => 1, no_populate => 1);
  20
  21 my $db_fn = DBICTest->_sqlite_dbfilename;
  22 my @connect_info = (
  23   "dbi:SQLite:$db_fn",
  24   undef,
  25   undef,
  26   { on_connect_do => 'PRAGMA synchronous = OFF' },
  27 );
  28 my $ddl_dir = dir(qw/t var/, "admin_ddl-$$");
  29
  30 { # create the schema
  31
  32 #  make sure we are  clean
  33 clean_dir($ddl_dir);
  34
  35
  36 my $admin = DBIx::Class::Admin->new(
  37   schema_class=> "DBICTest::Schema",
  38   sql_dir=> $ddl_dir,
  39   connect_info => \@connect_info,
  40 );
  41 isa_ok ($admin, 'DBIx::Class::Admin', 'create the admin object');
  42 lives_ok { $admin->create('MySQL'); } 'Can create MySQL sql';
  43 lives_ok { $admin->create('SQLite'); } 'Can Create SQLite sql';
  44 lives_ok {
  45   local $SIG{__WARN__} = sigwarn_silencer( qr/no such table.+DROP TABLE/s );
  46   $admin->deploy()
  47 } 'Can Deploy schema';
  48 }
  49
  50 { # upgrade schema
  51
  52 clean_dir($ddl_dir);
  53 require DBICVersion_v1;
  54
  55 my $admin = DBIx::Class::Admin->new(
  56   schema_class => 'DBICVersion::Schema',
  57   sql_dir =>  $ddl_dir,
  58   connect_info => \@connect_info,
  59 );
  60
  61 my $schema = $admin->schema();
  62
  63 lives_ok { $admin->create($schema->storage->sqlt_type(), {add_drop_table=>0}); } 'Can create DBICVersionOrig sql in ' . $schema->storage->sqlt_type;
  64 lives_ok { $admin->deploy(  ) } 'Can Deploy schema';
  65
  66 # connect to now deployed schema
  67 lives_ok { $schema = DBICVersion::Schema->connect(@{$schema->storage->connect_info()}); } 'Connect to deployed Database';
  68
  69 is($schema->get_db_version, $DBICVersion::Schema::VERSION, 'Schema deployed and versions match');
  70
  71
  72 require DBICVersion_v2;
  73 DBICVersion::Schema->upgrade_directory (undef);  # so that we can test use of $ddl_dir
  74
  75 $admin = DBIx::Class::Admin->new(
  76   schema_class => 'DBICVersion::Schema',
  77   sql_dir =>  $ddl_dir,
  78   connect_info => \@connect_info
  79 );
  80
  81 lives_ok { $admin->create($schema->storage->sqlt_type(), {}, "1.0" ); } 'Can create diff for ' . $schema->storage->sqlt_type;
  82 {
  83   local $SIG{__WARN__} = sigwarn_silencer( qr/DB version .+? is lower than the schema version/ );
  84   lives_ok { $admin->upgrade() } 'upgrade the schema';
  85   dies_ok { $admin->deploy } 'cannot deploy installed schema, should upgrade instead';
  86 }
  87
  88 is($schema->get_db_version, $DBICVersion::Schema::VERSION, 'Schema and db versions match');
  89
  90 }
  91
  92 { # install
  93
  94 clean_dir($ddl_dir);
  95
  96 my $admin = DBIx::Class::Admin->new(
  97   schema_class  => 'DBICVersion::Schema',
  98   sql_dir      => $ddl_dir,
  99   _confirm    => 1,
 100   connect_info  => \@connect_info,
 101 );
 102
 103 $admin->version("3.0");
 104 $admin->install;
 105 is($admin->schema->get_db_version, "3.0", 'db thinks its version 3.0');
 106 throws_ok {
 107   $admin->install("4.0")
 108 } qr/Schema already has a version. Try upgrade instead/, 'cannot install to allready existing version';
 109
 110 $admin->force(1);
 111 warnings_exist ( sub {
 112   $admin->install("4.0")
 113 }, qr/Forcing install may not be a good idea/, 'Force warning emitted' );
 114 is($admin->schema->get_db_version, "4.0", 'db thinks its version 4.0');
 115 }
 116
 117 sub clean_dir {
 118   my ($dir) = @_;
 119   $dir->rmtree if -d $dir;
 120   unlink $db_fn;
 121 }
 122
 123 END {
 124   clean_dir($ddl_dir);
 125 }
 126
 127 done_testing;