t/90join_torture.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6
   7 use lib qw(t/lib);
   8 use DBICTest;
   9 use DBIC::SqlMakerTest;
  10 my $schema = DBICTest->init_schema();
  11
  12 lives_ok (sub {
  13   my $rs = $schema->resultset( 'CD' )->search(
  14     {
  15       'producer.name'   => 'blah',
  16       'producer_2.name' => 'foo',
  17     },
  18     {
  19       'join' => [
  20         { cd_to_producer => 'producer' },
  21         { cd_to_producer => 'producer' },
  22       ],
  23       'prefetch' => [
  24         'artist',
  25         { cd_to_producer => { producer => 'producer_to_cd' } },
  26       ],
  27     }
  28   );
  29
  30   my @executed = $rs->all();
  31
  32   is_same_sql_bind (
  33     $rs->as_query,
  34     '(
  35       SELECT  me.cdid, me.artist, me.title, me.year, me.genreid, me.single_track,
  36               artist.artistid, artist.name, artist.rank, artist.charfield,
  37               cd_to_producer.cd, cd_to_producer.producer, cd_to_producer.attribute,
  38               producer.producerid, producer.name,
  39               producer_to_cd.cd, producer_to_cd.producer, producer_to_cd.attribute
  40         FROM cd me
  41         LEFT JOIN cd_to_producer cd_to_producer
  42           ON cd_to_producer.cd = me.cdid
  43         LEFT JOIN producer producer
  44           ON producer.producerid = cd_to_producer.producer
  45         LEFT JOIN cd_to_producer producer_to_cd
  46           ON producer_to_cd.producer = producer.producerid
  47         LEFT JOIN cd_to_producer cd_to_producer_2
  48           ON cd_to_producer_2.cd = me.cdid
  49         LEFT JOIN producer producer_2
  50           ON producer_2.producerid = cd_to_producer_2.producer
  51         JOIN artist artist ON artist.artistid = me.artist
  52       WHERE ( ( producer.name = ? AND producer_2.name = ? ) )
  53       ORDER BY me.cdid
  54     )',
  55     [
  56       [ { sqlt_datatype => 'varchar', dbic_colname => 'producer.name', sqlt_size => 100 }
  57           => 'blah' ],
  58       [ { sqlt_datatype => 'varchar', dbic_colname => 'producer_2.name', sqlt_size => 100 }
  59           => 'foo' ],
  60     ],
  61   );
  62
  63 }, 'Complex join parsed/executed properly');
  64
  65 my @rs1a_results = $schema->resultset("Artist")->search_related('cds', {title => 'Forkful of bees'}, {order_by => 'title'});
  66 is($rs1a_results[0]->title, 'Forkful of bees', "bare field conditions okay after search related");
  67 my $rs1 = $schema->resultset("Artist")->search({ 'tags.tag' => 'Blue' }, { join => {'cds' => 'tracks'}, prefetch => {'cds' => 'tags'} });
  68 my @artists = $rs1->all;
  69 cmp_ok(@artists, '==', 2, "Two artists returned");
  70
  71 my $rs2 = $rs1->search({ artistid => '1' }, { join => {'cds' => {'cd_to_producer' => 'producer'} } });
  72 my @artists2 = $rs2->search({ 'producer.name' => 'Matt S Trout' });
  73 my @cds = $artists2[0]->cds;
  74 cmp_ok(scalar @cds, '==', 1, "condition based on inherited join okay");
  75
  76 my $rs3 = $rs2->search_related('cds');
  77
  78 cmp_ok(scalar($rs3->all), '==', 15, "All cds for artist returned");
  79
  80 cmp_ok($rs3->count, '==', 15, "All cds for artist returned via count");
  81
  82 my $rs4 = $schema->resultset("CD")->search({ 'artist.artistid' => '1' }, { join => ['tracks', 'artist'], prefetch => 'artist' });
  83 my @rs4_results = $rs4->all;
  84
  85 is($rs4_results[0]->cdid, 1, "correct artist returned");
  86
  87 my $rs5 = $rs4->search({'tracks.title' => 'Sticky Honey'});
  88 is($rs5->count, 1, "search without using previous joins okay");
  89
  90 my $record_rs = $schema->resultset("Artist")->search(undef, { join => 'cds' })->search(undef, { prefetch => { 'cds' => 'tracks' }});
  91 my $record_jp = $record_rs->next;
  92 ok($record_jp, "prefetch on same rel okay");
  93
  94 my $artist = $schema->resultset("Artist")->find(1);
  95 my $cds = $artist->cds;
  96 is($cds->find(2)->title, 'Forkful of bees', "find on has many rs okay");
  97
  98 my $cd = $cds->search({'me.title' => 'Forkful of bees'}, { prefetch => 'tracks' })->first;
  99 my @tracks = $cd->tracks->all;
 100 is(scalar(@tracks), 3, 'right number of prefetched tracks after has many');
 101
 102 #causes ambig col error due to order_by
 103 #my $tracks_rs = $cds->search_related('tracks', { 'tracks.position' => '2', 'disc.title' => 'Forkful of bees' });
 104 #my $first_tracks_rs = $tracks_rs->first;
 105
 106 my $related_rs = $schema->resultset("Artist")->search({ name => 'Caterwauler McCrae' })->search_related('cds', { year => '2001'})->search_related('tracks', { 'position' => '2' });
 107 is($related_rs->first->trackid, '5', 'search related on search related okay');
 108
 109 #causes ambig col error due to order_by
 110 #$related_rs->search({'cd.year' => '2001'}, {join => ['cd', 'cd']})->all;
 111
 112 my $title = $schema->resultset("Artist")->search_related('twokeys')->search_related('cd')->search({'tracks.position' => '2'}, {join => 'tracks', order_by => 'tracks.trackid'})->next->title;
 113 is($title, 'Forkful of bees', 'search relateds with order by okay');
 114
 115 my $prod_rs = $schema->resultset("CD")->find(1)->producers_sorted;
 116 my $prod_rs2 = $prod_rs->search({ name => 'Matt S Trout' });
 117 my $prod_first = $prod_rs2->first;
 118 is($prod_first->id, '1', 'somewhat pointless search on rel with order_by on it okay');
 119
 120 my $prod_map_rs = $schema->resultset("Artist")->find(1)->cds->search_related('cd_to_producer', {}, { join => 'producer', prefetch => 'producer' });
 121 ok($prod_map_rs->next->producer, 'search related with prefetch okay');
 122
 123 my $stupid = $schema->resultset("Artist")->search_related('artist_undirected_maps', {}, { prefetch => 'artist1' })->search_related('mapped_artists')->search_related('cds', {'cds.cdid' => '2'}, { prefetch => 'tracks' });
 124
 125 my $cd_final = $schema->resultset("Artist")->search_related('artist_undirected_maps', {}, { prefetch => 'artist1' })->search_related('mapped_artists')->search_related('cds', {'cds.cdid' => '2'}, { prefetch => 'tracks' })->first;
 126 is($cd_final->cdid, '2', 'bonkers search_related-with-join-midway okay');
 127
 128 # should end up with cds and cds_2 joined
 129 my $merge_rs_1 = $schema->resultset("Artist")->search({ 'cds_2.cdid' => '2' }, { join => ['cds', 'cds'] });
 130 is(scalar(@{$merge_rs_1->{attrs}->{join}}), 2, 'both joins kept');
 131 ok($merge_rs_1->next, 'query on double joined rel runs okay');
 132
 133 # should only end up with cds joined
 134 my $merge_rs_2 = $schema->resultset("Artist")->search({ }, { join => 'cds' })->search({ 'cds.cdid' => '2' }, { join => 'cds' });
 135 is(scalar(@{$merge_rs_2->{attrs}->{join}}), 1, 'only one join kept when inherited');
 136 my $merge_rs_2_cd = $merge_rs_2->next;
 137
 138 lives_ok (sub {
 139
 140   my @rs_with_prefetch = $schema->resultset('TreeLike')
 141                                 ->search(
 142     {'me.id' => 1},
 143     {
 144     prefetch => [ 'parent', { 'children' => 'parent' } ],
 145     });
 146
 147 }, 'pathological prefetch ok');
 148
 149 my $rs = $schema->resultset("Artist")->search({}, { join => 'twokeys' });
 150 my $second_search_rs = $rs->search({ 'cds_2.cdid' => '2' }, { join =>
 151 ['cds', 'cds'] });
 152 is(scalar(@{$second_search_rs->{attrs}->{join}}), 3, 'both joins kept');
 153 ok($second_search_rs->next, 'query on double joined rel runs okay');
 154
 155 # test joinmap pruner
 156 lives_ok ( sub {
 157   my $rs = $schema->resultset('Artwork')->search (
 158     {
 159     },
 160     {
 161       distinct => 1,
 162       join => [
 163         { artwork_to_artist => 'artist' },
 164         { cd => 'artist' },
 165       ],
 166     },
 167   );
 168
 169   is_same_sql_bind (
 170     $rs->count_rs->as_query,
 171     '(
 172       SELECT COUNT( * )
 173         FROM (
 174           SELECT me.cd_id
 175             FROM cd_artwork me
 176             JOIN cd cd ON cd.cdid = me.cd_id
 177             JOIN artist artist_2 ON artist_2.artistid = cd.artist
 178           GROUP BY me.cd_id
 179         ) me
 180     )',
 181     [],
 182   );
 183
 184   ok (defined $rs->count);
 185 });
 186
 187 # make sure multiplying endpoints do not lose heir join-path
 188 lives_ok (sub {
 189   my $rs = $schema->resultset('CD')->search (
 190     { },
 191     { join => { artwork => 'images' } },
 192   )->get_column('cdid');
 193
 194   is_same_sql_bind (
 195     $rs->as_query,
 196     '(
 197       SELECT me.cdid
 198         FROM cd me
 199         LEFT JOIN cd_artwork artwork
 200           ON artwork.cd_id = me.cdid
 201         LEFT JOIN images images
 202           ON images.artwork_id = artwork.cd_id
 203     )',
 204     [],
 205   );
 206
 207   # execution
 208   $rs->next;
 209 });
 210
 211 done_testing;