t/89inflate_datetime.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use lib qw(t/lib);
   6 use DBICTest;
   7
   8 my $schema = DBICTest->init_schema();
   9
  10 eval { require DateTime::Format::MySQL };
  11 plan skip_all => "Need DateTime::Format::MySQL for inflation tests" if $@;
  12
  13 plan tests => 32;
  14
  15 # inflation test
  16 my $event = $schema->resultset("Event")->find(1);
  17
  18 isa_ok($event->starts_at, 'DateTime', 'DateTime returned');
  19
  20 # klunky, but makes older Test::More installs happy
  21 my $starts = $event->starts_at;
  22 is("$starts", '2006-04-25T22:24:33', 'Correct date/time');
  23
  24 # create using DateTime
  25 my $created = $schema->resultset('Event')->create({
  26     starts_at => DateTime->new(year=>2006, month=>6, day=>18),
  27     created_on => DateTime->new(year=>2006, month=>6, day=>23)
  28 });
  29 my $created_start = $created->starts_at;
  30
  31 isa_ok($created->starts_at, 'DateTime', 'DateTime returned');
  32 is("$created_start", '2006-06-18T00:00:00', 'Correct date/time');
  33
  34 ## timestamp field
  35 isa_ok($event->created_on, 'DateTime', 'DateTime returned');
  36
  37 ## varchar fields
  38 isa_ok($event->varchar_date, 'DateTime', 'DateTime returned');
  39 isa_ok($event->varchar_datetime, 'DateTime', 'DateTime returned');
  40
  41 ## skip inflation field
  42 isnt(ref($event->skip_inflation), 'DateTime', 'No DateTime returned for skip inflation column');
  43
  44 # klunky, but makes older Test::More installs happy
  45 my $createo = $event->created_on;
  46 is("$createo", '2006-06-22T21:00:05', 'Correct date/time');
  47
  48 my $created_cron = $created->created_on;
  49
  50 isa_ok($created->created_on, 'DateTime', 'DateTime returned');
  51 is("$created_cron", '2006-06-23T00:00:00', 'Correct date/time');
  52
  53
  54 # Test "timezone" parameter
  55 my $event_tz = $schema->resultset('EventTZ')->create({
  56     starts_at => DateTime->new(year=>2007, month=>12, day=>31, time_zone => "America/Chicago" ),
  57     created_on => DateTime->new(year=>2006, month=>1, day=>31,
  58         hour => 13, minute => 34, second => 56, time_zone => "America/New_York" ),
  59 });
  60
  61 is ($event_tz->starts_at->day_name, "Montag", 'Locale de_DE loaded: day_name');
  62 is ($event_tz->starts_at->month_name, "Dezember", 'Locale de_DE loaded: month_name');
  63 is ($event_tz->created_on->day_name, "Tuesday", 'Default locale loaded: day_name');
  64 is ($event_tz->created_on->month_name, "January", 'Default locale loaded: month_name');
  65
  66 my $starts_at = $event_tz->starts_at;
  67 is("$starts_at", '2007-12-31T00:00:00', 'Correct date/time using timezone');
  68
  69 my $created_on = $event_tz->created_on;
  70 is("$created_on", '2006-01-31T12:34:56', 'Correct timestamp using timezone');
  71 is($event_tz->created_on->time_zone->name, "America/Chicago", "Correct timezone");
  72
  73 my $loaded_event = $schema->resultset('EventTZ')->find( $event_tz->id );
  74
  75 isa_ok($loaded_event->starts_at, 'DateTime', 'DateTime returned');
  76 $starts_at = $loaded_event->starts_at;
  77 is("$starts_at", '2007-12-31T00:00:00', 'Loaded correct date/time using timezone');
  78 is($starts_at->time_zone->name, 'America/Chicago', 'Correct timezone');
  79
  80 isa_ok($loaded_event->created_on, 'DateTime', 'DateTime returned');
  81 $created_on = $loaded_event->created_on;
  82 is("$created_on", '2006-01-31T12:34:56', 'Loaded correct timestamp using timezone');
  83 is($created_on->time_zone->name, 'America/Chicago', 'Correct timezone');
  84
  85 # Test floating timezone warning
  86 # We expect one warning
  87 SKIP: {
  88     skip "ENV{DBIC_FLOATING_TZ_OK} was set, skipping", 1 if $ENV{DBIC_FLOATING_TZ_OK};
  89     local $SIG{__WARN__} = sub {
  90         like(
  91             shift,
  92             qr/You're using a floating timezone, please see the documentation of DBIx::Class::InflateColumn::DateTime for an explanation/,
  93             'Floating timezone warning'
  94         );
  95     };
  96     my $event_tz_floating = $schema->resultset('EventTZ')->create({
  97         starts_at => DateTime->new(year=>2007, month=>12, day=>31, ),
  98         created_on => DateTime->new(year=>2006, month=>1, day=>31,
  99             hour => 13, minute => 34, second => 56, ),
 100     });
 101     delete $SIG{__WARN__};
 102 };
 103
 104 # This should fail to set
 105 my $prev_str = "$created_on";
 106 $loaded_event->update({ created_on => '0000-00-00' });
 107 is("$created_on", $prev_str, "Don't update invalid dates");
 108
 109 my $invalid = $schema->resultset('Event')->create({
 110     starts_at  => '0000-00-00',
 111     created_on => $created_on
 112 });
 113
 114 is( $invalid->get_column('starts_at'), '0000-00-00', "Invalid date stored" );
 115 is( $invalid->starts_at, undef, "Inflate to undef" );
 116
 117 $invalid->created_on('0000-00-00');
 118 $invalid->update;
 119
 120 {
 121     local $@;
 122     eval { $invalid->created_on };
 123     like( $@, qr/invalid date format/i, "Invalid date format exception");
 124 }
 125
 126 ## varchar field using inflate_date => 1
 127 my $varchar_date = $event->varchar_date;
 128 is("$varchar_date", '2006-07-23T00:00:00', 'Correct date/time');
 129
 130 ## varchar field using inflate_datetime => 1
 131 my $varchar_datetime = $event->varchar_datetime;
 132 is("$varchar_datetime", '2006-05-22T19:05:07', 'Correct date/time');
 133
 134 ## skip inflation field
 135 my $skip_inflation = $event->skip_inflation;
 136 is ("$skip_inflation", '2006-04-21 18:04:06', 'Correct date/time');