t/88result_set_column.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Warn;
   6 use Test::Exception;
   7 use lib qw(t/lib);
   8 use DBICTest;
   9 use DBIC::SqlMakerTest;
  10
  11 my $schema = DBICTest->init_schema();
  12
  13 my $rs = $schema->resultset("CD");
  14
  15 cmp_ok (
  16   $rs->count,
  17     '>',
  18   $rs->search ({}, {columns => ['year'], distinct => 1})->count,
  19   'At least one year is the same in rs'
  20 );
  21
  22 my $rs_title = $rs->get_column('title');
  23 my $rs_year = $rs->get_column('year');
  24 my $max_year = $rs->get_column(\'MAX (year)');
  25
  26 my @all_titles = $rs_title->all;
  27 cmp_ok(scalar @all_titles, '==', 5, "five titles returned");
  28
  29 my @nexted_titles;
  30 while (my $r = $rs_title->next) {
  31   push @nexted_titles, $r;
  32 }
  33
  34 is_deeply (\@all_titles, \@nexted_titles, 'next works');
  35
  36 is_deeply( [ sort $rs_year->func('DISTINCT') ], [ 1997, 1998, 1999, 2001 ],  "wantarray context okay");
  37 ok ($max_year->next == $rs_year->max, q/get_column (\'FUNC') ok/);
  38
  39 cmp_ok($rs_year->max, '==', 2001, "max okay for year");
  40 is($rs_title->min, 'Caterwaulin\' Blues', "min okay for title");
  41
  42 cmp_ok($rs_year->sum, '==', 9996, "three artists returned");
  43
  44 my $rso_year = $rs->search({}, { order_by => 'cdid' })->get_column('year');
  45 is($rso_year->next, 1999, "reset okay");
  46
  47 is($rso_year->first, 1999, "first okay");
  48
  49 warnings_exist (sub {
  50   is($rso_year->single, 1999, "single okay");
  51 }, qr/Query returned more than one row/, 'single warned');
  52
  53
  54 # test distinct propagation
  55 is_deeply (
  56   [sort $rs->search ({}, { distinct => 1 })->get_column ('year')->all],
  57   [sort $rs_year->func('distinct')],
  58   'distinct => 1 is passed through properly',
  59 );
  60
  61 # test +select/+as for single column
  62 my $psrs = $schema->resultset('CD')->search({},
  63     {
  64         '+select'   => \'MAX(year)',
  65         '+as'       => 'last_year'
  66     }
  67 );
  68 lives_ok(sub { $psrs->get_column('last_year')->next }, '+select/+as additional column "last_year" present (scalar)');
  69 dies_ok(sub { $psrs->get_column('noSuchColumn')->next }, '+select/+as nonexistent column throws exception');
  70
  71 # test +select/+as for overriding a column
  72 $psrs = $schema->resultset('CD')->search({},
  73     {
  74         'select'   => \"'The Final Countdown'",
  75         'as'       => 'title'
  76     }
  77 );
  78 is($psrs->get_column('title')->next, 'The Final Countdown', '+select/+as overridden column "title"');
  79
  80
  81 # test +select/+as for multiple columns
  82 $psrs = $schema->resultset('CD')->search({},
  83     {
  84         '+select'   => [ \'LENGTH(title) AS title_length', 'title' ],
  85         '+as'       => [ 'tlength', 'addedtitle' ]
  86     }
  87 );
  88 lives_ok(sub { $psrs->get_column('tlength')->next }, '+select/+as multiple additional columns, "tlength" column present');
  89 lives_ok(sub { $psrs->get_column('addedtitle')->next }, '+select/+as multiple additional columns, "addedtitle" column present');
  90
  91 # test that +select/+as specs do not leak
  92 is_same_sql_bind (
  93   $psrs->get_column('year')->as_query,
  94   '(SELECT me.year FROM cd me)',
  95   [],
  96   'Correct SQL for get_column/as'
  97 );
  98
  99 is_same_sql_bind (
 100   $psrs->get_column('addedtitle')->as_query,
 101   '(SELECT me.title FROM cd me)',
 102   [],
 103   'Correct SQL for get_column/+as col'
 104 );
 105
 106 is_same_sql_bind (
 107   $psrs->get_column('tlength')->as_query,
 108   '(SELECT LENGTH(title) AS title_length FROM cd me)',
 109   [],
 110   'Correct SQL for get_column/+as func'
 111 );
 112
 113 # test that order_by over a function forces a subquery
 114 lives_ok ( sub {
 115   is_deeply (
 116     [ $psrs->search ({}, { order_by => { -desc => 'title_length' } })->get_column ('title')->all ],
 117     [
 118       "Generic Manufactured Singles",
 119       "Come Be Depressed With Us",
 120       "Caterwaulin' Blues",
 121       "Spoonful of bees",
 122       "Forkful of bees",
 123     ],
 124     'Subquery count induced by aliased ordering function',
 125   );
 126 });
 127
 128 # test for prefetch not leaking
 129 {
 130   my $rs = $schema->resultset("CD")->search({}, { prefetch => 'artist' });
 131   my $rsc = $rs->get_column('year');
 132   is( $rsc->{_parent_resultset}->{attrs}->{prefetch}, undef, 'prefetch wiped' );
 133 }
 134
 135 # test sum()
 136 is ($schema->resultset('BooksInLibrary')->get_column ('price')->sum, 125, 'Sum of a resultset works correctly');
 137
 138 # test sum over search_related
 139 my $owner = $schema->resultset('Owners')->find ({ name => 'Newton' });
 140 ok ($owner->books->count > 1, 'Owner Newton has multiple books');
 141 is ($owner->search_related ('books')->get_column ('price')->sum, 60, 'Correctly calculated price of all owned books');
 142
 143
 144 # make sure joined/prefetched get_column of a PK dtrt
 145 $rs->reset;
 146 my $j_rs = $rs->search ({}, { join => 'tracks' })->get_column ('cdid');
 147 is_deeply (
 148   [ sort $j_rs->all ],
 149   [ sort map { my $c = $rs->next; ( ($c->id) x $c->tracks->count ) } (1 .. $rs->count) ],
 150   'join properly explodes amount of rows from get_column',
 151 );
 152
 153 $rs->reset;
 154 my $p_rs = $rs->search ({}, { prefetch => 'tracks' })->get_column ('cdid');
 155 is_deeply (
 156   [ sort $p_rs->all ],
 157   [ sort $rs->get_column ('cdid')->all ],
 158   'prefetch properly collapses amount of rows from get_column',
 159 );
 160
 161 $rs->reset;
 162 my $pob_rs = $rs->search({}, {
 163   select   => ['me.title', 'tracks.title'],
 164   prefetch => 'tracks',
 165   order_by => [{-asc => ['position']}],
 166   group_by => ['me.title', 'tracks.title'],
 167 });
 168 is_same_sql_bind (
 169   $pob_rs->get_column("me.title")->as_query,
 170   '(SELECT me.title FROM (SELECT me.title, tracks.title FROM cd me LEFT JOIN track tracks ON tracks.cd = me.cdid GROUP BY me.title, tracks.title ORDER BY position ASC) me)',
 171   [],
 172   'Correct SQL for prefetch/order_by/group_by'
 173 );
 174
 175 # test aggregate on a function
 176 {
 177   my $tr_rs = $schema->resultset("Track");
 178   $tr_rs->create({ cd => 2, title => 'dealbreaker' });
 179
 180   is(
 181     $tr_rs->get_column('cd')->max,
 182     5,
 183     "Correct: Max cd in Track is 5"
 184   );
 185
 186   my $track_counts_per_cd_via_group_by = $tr_rs->search({}, {
 187     columns => [ 'cd', { cnt => { count => 'trackid', -as => 'cnt' } } ],
 188     group_by => 'cd',
 189   })->get_column('cnt');
 190
 191   is ($track_counts_per_cd_via_group_by->max, 4, 'Correct max tracks per cd');
 192   is ($track_counts_per_cd_via_group_by->min, 3, 'Correct min tracks per cd');
 193   is (
 194     sprintf('%0.1f', $track_counts_per_cd_via_group_by->func('avg') ),
 195     '3.2',
 196     'Correct avg tracks per cd'
 197   );
 198 }
 199
 200 done_testing;