t/86sqlt.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use lib qw(t/lib);
   6 use DBICTest;
   7
   8 BEGIN {
   9   require DBIx::Class;
  10   plan skip_all =>
  11       'Test needs ' . DBIx::Class::Optional::Dependencies->req_missing_for ('deploy')
  12     unless DBIx::Class::Optional::Dependencies->req_ok_for ('deploy')
  13 }
  14
  15 my $schema = DBICTest->init_schema (no_deploy => 1);
  16
  17
  18 # Check deployment statements ctx sensitivity
  19 {
  20   my $not_first_table_creation_re = qr/CREATE TABLE fourkeys_to_twokeys/;
  21
  22
  23   my $statements = $schema->deployment_statements;
  24   like (
  25     $statements,
  26     $not_first_table_creation_re,
  27     'All create statements returned in 1 string in scalar ctx'
  28   );
  29
  30   my @statements = $schema->deployment_statements;
  31   cmp_ok (scalar @statements, '>', 1, 'Multiple statement lines in array ctx');
  32
  33   my $i = 0;
  34   while ($i <= $#statements) {
  35     last if $statements[$i] =~ $not_first_table_creation_re;
  36     $i++;
  37   }
  38
  39   ok (
  40     ($i > 0) && ($i <= $#statements),
  41     "Creation statement was found somewherere within array ($i)"
  42   );
  43 }
  44
  45
  46
  47 {
  48   my $deploy_hook_called = 0;
  49
  50   # replace the sqlt calback with a custom version ading an index
  51   $schema->source('Track')->sqlt_deploy_callback(sub {
  52     my ($self, $sqlt_table) = @_;
  53
  54     $deploy_hook_called = 1;
  55
  56     is (
  57       $sqlt_table->schema->translator->producer_type,
  58       join ('::', 'SQL::Translator::Producer', $schema->storage->sqlt_type),
  59       'Production type passed to translator object',
  60     );
  61
  62     if ($schema->storage->sqlt_type eq 'SQLite' ) {
  63       $sqlt_table->add_index( name => 'track_title', fields => ['title'] )
  64         or die $sqlt_table->error;
  65     }
  66
  67     $self->default_sqlt_deploy_hook($sqlt_table);
  68   });
  69
  70   $schema->deploy; # do not remove, this fires the is() test in the callback above
  71   ok($deploy_hook_called, 'deploy hook got called');
  72 }
  73
  74
  75 my $translator = SQL::Translator->new(
  76   parser_args => {
  77     'DBIx::Schema' => $schema,
  78   },
  79   producer_args => {},
  80 );
  81
  82 {
  83     my $warn = '';
  84     local $SIG{__WARN__} = sub { $warn = shift };
  85
  86     my $relinfo = $schema->source('Artist')->relationship_info ('cds');
  87     local $relinfo->{attrs}{on_delete} = 'restrict';
  88
  89
  90     $translator->parser('SQL::Translator::Parser::DBIx::Class');
  91     $translator->producer('SQLite');
  92
  93     my $output = $translator->translate();
  94
  95     ok($output, "SQLT produced someoutput")
  96       or diag($translator->error);
  97
  98
  99     like (
 100       $warn,
 101       qr/SQLT attribute .+? was supplied for relationship .+? which does not appear to be a foreign constraint/,
 102       'Warn about dubious on_delete/on_update attributes',
 103     );
 104 }
 105
 106 # Note that the constraints listed here are the only ones that are tested -- if
 107 # more exist in the Schema than are listed here and all listed constraints are
 108 # correct, the test will still pass. If you add a class with UNIQUE or FOREIGN
 109 # KEY constraints to DBICTest::Schema, add tests here if you think the existing
 110 # test coverage is not sufficient
 111
 112 my %fk_constraints = (
 113
 114   # TwoKeys
 115   twokeys => [
 116     {
 117       'display' => 'twokeys->cd',
 118       'name' => 'twokeys_fk_cd', 'index_name' => 'twokeys_idx_cd',
 119       'selftable' => 'twokeys', 'foreigntable' => 'cd',
 120       'selfcols'  => ['cd'], 'foreigncols' => ['cdid'],
 121       'noindex'  => 1,
 122       on_delete => '', on_update => '', deferrable => 0,
 123     },
 124     {
 125       'display' => 'twokeys->artist',
 126       'name' => 'twokeys_fk_artist', 'index_name' => 'twokeys_idx_artist',
 127       'selftable' => 'twokeys', 'foreigntable' => 'artist',
 128       'selfcols'  => ['artist'], 'foreigncols' => ['artistid'],
 129       on_delete => 'CASCADE', on_update => 'CASCADE', deferrable => 1,
 130     },
 131   ],
 132
 133   # FourKeys_to_TwoKeys
 134   fourkeys_to_twokeys => [
 135     {
 136       'display' => 'fourkeys_to_twokeys->twokeys',
 137       'name' => 'fourkeys_to_twokeys_fk_t_artist_t_cd', 'index_name' => 'fourkeys_to_twokeys_idx_t_artist_t_cd',
 138       'selftable' => 'fourkeys_to_twokeys', 'foreigntable' => 'twokeys',
 139       'selfcols'  => ['t_artist', 't_cd'], 'foreigncols' => ['artist', 'cd'],
 140       on_delete => 'CASCADE', on_update => 'CASCADE', deferrable => 1,
 141     },
 142     {
 143       'display' => 'fourkeys_to_twokeys->fourkeys', 'index_name' => 'fourkeys_to_twokeys_idx_f_foo_f_bar_f_hello_f_goodbye',
 144       'name' => 'fourkeys_to_twokeys_fk_f_foo_f_bar_f_hello_f_goodbye',
 145       'selftable' => 'fourkeys_to_twokeys', 'foreigntable' => 'fourkeys',
 146       'selfcols'  => [qw(f_foo f_bar f_hello f_goodbye)],
 147       'foreigncols' => [qw(foo bar hello goodbye)],
 148       on_delete => 'CASCADE', on_update => 'CASCADE', deferrable => 1,
 149     },
 150   ],
 151
 152   # CD_to_Producer
 153   cd_to_producer => [
 154     {
 155       'display' => 'cd_to_producer->cd',
 156       'name' => 'cd_to_producer_fk_cd', 'index_name' => 'cd_to_producer_idx_cd',
 157       'selftable' => 'cd_to_producer', 'foreigntable' => 'cd',
 158       'selfcols'  => ['cd'], 'foreigncols' => ['cdid'],
 159       on_delete => 'CASCADE', on_update => 'CASCADE', deferrable => 1,
 160     },
 161     {
 162       'display' => 'cd_to_producer->producer',
 163       'name' => 'cd_to_producer_fk_producer', 'index_name' => 'cd_to_producer_idx_producer',
 164       'selftable' => 'cd_to_producer', 'foreigntable' => 'producer',
 165       'selfcols'  => ['producer'], 'foreigncols' => ['producerid'],
 166       on_delete => '', on_update => '', deferrable => 1,
 167     },
 168   ],
 169
 170   # Self_ref_alias
 171   self_ref_alias => [
 172     {
 173       'display' => 'self_ref_alias->self_ref for self_ref',
 174       'name' => 'self_ref_alias_fk_self_ref', 'index_name' => 'self_ref_alias_idx_self_ref',
 175       'selftable' => 'self_ref_alias', 'foreigntable' => 'self_ref',
 176       'selfcols'  => ['self_ref'], 'foreigncols' => ['id'],
 177       on_delete => 'CASCADE', on_update => 'CASCADE', deferrable => 1,
 178     },
 179     {
 180       'display' => 'self_ref_alias->self_ref for alias',
 181       'name' => 'self_ref_alias_fk_alias', 'index_name' => 'self_ref_alias_idx_alias',
 182       'selftable' => 'self_ref_alias', 'foreigntable' => 'self_ref',
 183       'selfcols'  => ['alias'], 'foreigncols' => ['id'],
 184       on_delete => '', on_update => '', deferrable => 1,
 185     },
 186   ],
 187
 188   # CD
 189   cd => [
 190     {
 191       'display' => 'cd->artist',
 192       'name' => 'cd_fk_artist', 'index_name' => 'cd_idx_artist',
 193       'selftable' => 'cd', 'foreigntable' => 'artist',
 194       'selfcols'  => ['artist'], 'foreigncols' => ['artistid'],
 195       on_delete => 'CASCADE', on_update => 'CASCADE', deferrable => 1,
 196     },
 197   ],
 198
 199   # Artist_undirected_map
 200   artist_undirected_map => [
 201     {
 202       'display' => 'artist_undirected_map->artist for id1',
 203       'name' => 'artist_undirected_map_fk_id1', 'index_name' => 'artist_undirected_map_idx_id1',
 204       'selftable' => 'artist_undirected_map', 'foreigntable' => 'artist',
 205       'selfcols'  => ['id1'], 'foreigncols' => ['artistid'],
 206       on_delete => 'RESTRICT', on_update => 'CASCADE', deferrable => 1,
 207     },
 208     {
 209       'display' => 'artist_undirected_map->artist for id2',
 210       'name' => 'artist_undirected_map_fk_id2', 'index_name' => 'artist_undirected_map_idx_id2',
 211       'selftable' => 'artist_undirected_map', 'foreigntable' => 'artist',
 212       'selfcols'  => ['id2'], 'foreigncols' => ['artistid'],
 213       on_delete => '', on_update => '', deferrable => 1,
 214     },
 215   ],
 216
 217   # Track
 218   track => [
 219     {
 220       'display' => 'track->cd',
 221       'name' => 'track_fk_cd', 'index_name' => 'track_idx_cd',
 222       'selftable' => 'track', 'foreigntable' => 'cd',
 223       'selfcols'  => ['cd'], 'foreigncols' => ['cdid'],
 224       on_delete => 'CASCADE', on_update => 'CASCADE', deferrable => 1,
 225     },
 226   ],
 227
 228   # TreeLike
 229   treelike => [
 230     {
 231       'display' => 'treelike->treelike for parent',
 232       'name' => 'treelike_fk_parent', 'index_name' => 'treelike_idx_parent',
 233       'selftable' => 'treelike', 'foreigntable' => 'treelike',
 234       'selfcols'  => ['parent'], 'foreigncols' => ['id'],
 235       on_delete => 'CASCADE', on_update => 'CASCADE', deferrable => 1,
 236     },
 237   ],
 238
 239   # TwoKeyTreeLike
 240   twokeytreelike => [
 241     {
 242       'display' => 'twokeytreelike->twokeytreelike for parent1,parent2',
 243       'name' => 'twokeytreelike_fk_parent1_parent2', 'index_name' => 'twokeytreelike_idx_parent1_parent2',
 244       'selftable' => 'twokeytreelike', 'foreigntable' => 'twokeytreelike',
 245       'selfcols'  => ['parent1', 'parent2'], 'foreigncols' => ['id1','id2'],
 246       on_delete => '', on_update => '', deferrable => 1,
 247     },
 248   ],
 249
 250   # Tags
 251   tags => [
 252     {
 253       'display' => 'tags->cd',
 254       'name' => 'tags_fk_cd', 'index_name' => 'tags_idx_cd',
 255       'selftable' => 'tags', 'foreigntable' => 'cd',
 256       'selfcols'  => ['cd'], 'foreigncols' => ['cdid'],
 257       on_delete => 'CASCADE', on_update => 'CASCADE', deferrable => 1,
 258     },
 259   ],
 260
 261   # Bookmark
 262   bookmark => [
 263     {
 264       'display' => 'bookmark->link',
 265       'name' => 'bookmark_fk_link', 'index_name' => 'bookmark_idx_link',
 266       'selftable' => 'bookmark', 'foreigntable' => 'link',
 267       'selfcols'  => ['link'], 'foreigncols' => ['id'],
 268       on_delete => 'SET NULL', on_update => 'CASCADE', deferrable => 1,
 269     },
 270   ],
 271   # ForceForeign
 272   forceforeign => [
 273     {
 274       'display' => 'forceforeign->artist',
 275       'name' => 'forceforeign_fk_artist', 'index_name' => 'forceforeign_idx_artist',
 276       'selftable' => 'forceforeign', 'foreigntable' => 'artist',
 277       'selfcols'  => ['artist'], 'foreigncols' => ['artistid'],
 278       'noindex'  => 1,
 279       on_delete => '', on_update => '', deferrable => 1,
 280     },
 281   ],
 282 );
 283
 284 my %unique_constraints = (
 285   # CD
 286   cd => [
 287     {
 288       'display' => 'cd artist and title unique',
 289       'name' => 'cd_artist_title',
 290       'table' => 'cd', 'cols' => ['artist', 'title'],
 291     },
 292   ],
 293
 294   # Producer
 295   producer => [
 296     {
 297       'display' => 'producer name unique',
 298       'name' => 'prod_name', # explicit name
 299       'table' => 'producer', 'cols' => ['name'],
 300     },
 301   ],
 302
 303   # TwoKeyTreeLike
 304   twokeytreelike => [
 305     {
 306       'display' => 'twokeytreelike name unique',
 307       'name' => 'tktlnameunique', # explicit name
 308       'table' => 'twokeytreelike', 'cols'  => ['name'],
 309     },
 310   ],
 311
 312   # Employee
 313 # Constraint is commented out in DBICTest/Schema/Employee.pm
 314 #  employee => [
 315 #    {
 316 #      'display' => 'employee position and group_id unique',
 317 #      'name' => 'position_group',
 318 #      'table' => 'employee', cols => ['position', 'group_id'],
 319 #    },
 320 #  ],
 321 );
 322
 323 my %indexes = (
 324   artist => [
 325     {
 326       'fields' => ['name']
 327     },
 328   ],
 329   track => [
 330     {
 331       'fields' => ['title']
 332     }
 333   ],
 334 );
 335
 336 my $tschema = $translator->schema();
 337 # Test that the $schema->sqlt_deploy_hook was called okay and that it removed
 338 # the 'dummy' table
 339 ok( !defined($tschema->get_table('dummy')), "Dummy table was removed by hook");
 340
 341 # Test that the Artist resultsource sqlt_deploy_hook was called okay and added
 342 # an index
 343 SKIP: {
 344     skip ('Artist sqlt_deploy_hook is only called with an SQLite backend', 1)
 345         if $schema->storage->sqlt_type ne 'SQLite';
 346
 347     ok( ( grep
 348         { $_->name eq 'artist_name_hookidx' }
 349         $tschema->get_table('artist')->get_indices
 350     ), 'sqlt_deploy_hook fired within a resultsource');
 351 }
 352
 353 # Test that nonexistent constraints are not found
 354 my $constraint = get_constraint('FOREIGN KEY', 'cd', ['title'], 'cd', ['year']);
 355 ok( !defined($constraint), 'nonexistent FOREIGN KEY constraint not found' );
 356 $constraint = get_constraint('UNIQUE', 'cd', ['artist']);
 357 ok( !defined($constraint), 'nonexistent UNIQUE constraint not found' );
 358 $constraint = get_constraint('FOREIGN KEY', 'forceforeign', ['cd'], 'cd', ['cdid']);
 359 ok( !defined($constraint), 'forced nonexistent FOREIGN KEY constraint not found' );
 360
 361 for my $expected_constraints (keys %fk_constraints) {
 362   for my $expected_constraint (@{ $fk_constraints{$expected_constraints} }) {
 363     my $desc = $expected_constraint->{display};
 364     my $constraint = get_constraint(
 365       'FOREIGN KEY',
 366       $expected_constraint->{selftable}, $expected_constraint->{selfcols},
 367       $expected_constraint->{foreigntable}, $expected_constraint->{foreigncols},
 368     );
 369     ok( defined($constraint), "FOREIGN KEY constraint matching `$desc' found" );
 370     test_fk($expected_constraint, $constraint);
 371   }
 372 }
 373
 374 for my $expected_constraints (keys %unique_constraints) {
 375   for my $expected_constraint (@{ $unique_constraints{$expected_constraints} }) {
 376     my $desc = $expected_constraint->{display};
 377     my $constraint = get_constraint(
 378       'UNIQUE', $expected_constraint->{table}, $expected_constraint->{cols},
 379     );
 380     ok( defined($constraint), "UNIQUE constraint matching `$desc' found" );
 381     test_unique($expected_constraint, $constraint);
 382   }
 383 }
 384
 385 for my $table_index (keys %indexes) {
 386   for my $expected_index ( @{ $indexes{$table_index} } ) {
 387     ok ( get_index($table_index, $expected_index), "Got a matching index on $table_index table");
 388   }
 389 }
 390
 391 # Returns the Constraint object for the specified constraint type, table and
 392 # columns from the SQL::Translator schema, or undef if no matching constraint
 393 # is found.
 394 #
 395 # NB: $type is either 'FOREIGN KEY' or 'UNIQUE'. In UNIQUE constraints the last
 396 # two parameters are not used.
 397 sub get_constraint {
 398   my ($type, $table_name, $cols, $f_table, $f_cols) = @_;
 399   $f_table ||= ''; # For UNIQUE constraints, reference_table is ''
 400   $f_cols ||= [];
 401
 402   my $table = $tschema->get_table($table_name);
 403
 404   my %fields = map { $_ => 1 } @$cols;
 405   my %f_fields = map { $_ => 1 } @$f_cols;
 406
 407   die "No $table_name" unless $table;
 408  CONSTRAINT:
 409   for my $constraint ( $table->get_constraints ) {
 410     next unless $constraint->type eq $type;
 411     next unless $constraint->reference_table eq $f_table;
 412
 413     my %rev_fields = map { $_ => 1 } $constraint->fields;
 414     my %rev_f_fields = map { $_ => 1 } $constraint->reference_fields;
 415
 416     # Check that the given fields are a subset of the constraint's fields
 417     for my $field ($constraint->fields) {
 418       next CONSTRAINT unless $fields{$field};
 419     }
 420     if ($type eq 'FOREIGN KEY') {
 421       for my $f_field ($constraint->reference_fields) {
 422         next CONSTRAINT unless $f_fields{$f_field};
 423       }
 424     }
 425
 426     # Check that the constraint's fields are a subset of the given fields
 427     for my $field (@$cols) {
 428       next CONSTRAINT unless $rev_fields{$field};
 429     }
 430     if ($type eq 'FOREIGN KEY') {
 431       for my $f_field (@$f_cols) {
 432         next CONSTRAINT unless $rev_f_fields{$f_field};
 433       }
 434     }
 435
 436     return $constraint; # everything passes, found the constraint
 437   }
 438   return undef; # didn't find a matching constraint
 439 }
 440
 441 sub get_index {
 442   my ($table_name, $index) = @_;
 443
 444   my $table = $tschema->get_table($table_name);
 445
 446  CAND_INDEX:
 447   for my $cand_index ( $table->get_indices ) {
 448
 449     next CAND_INDEX if $index->{name} && $cand_index->name ne $index->{name}
 450                     || $index->{type} && $cand_index->type ne $index->{type};
 451
 452     my %idx_fields = map { $_ => 1 } $cand_index->fields;
 453
 454     for my $field ( @{ $index->{fields} } ) {
 455       next CAND_INDEX unless $idx_fields{$field};
 456     }
 457
 458     %idx_fields = map { $_ => 1 } @{$index->{fields}};
 459     for my $field ( $cand_index->fields) {
 460       next CAND_INDEX unless $idx_fields{$field};
 461     }
 462
 463     return $cand_index;
 464   }
 465
 466   return undef; # No matching idx
 467 }
 468
 469 # Test parameters in a FOREIGN KEY constraint other than columns
 470 sub test_fk {
 471   my ($expected, $got) = @_;
 472   my $desc = $expected->{display};
 473   is( $got->name, $expected->{name},
 474       "name parameter correct for '$desc'" );
 475   is( $got->on_delete, $expected->{on_delete},
 476       "on_delete parameter correct for '$desc'" );
 477   is( $got->on_update, $expected->{on_update},
 478       "on_update parameter correct for '$desc'" );
 479   is( $got->deferrable, $expected->{deferrable},
 480       "is_deferrable parameter correct for '$desc'" );
 481
 482   my $index = get_index( $got->table, { fields => $expected->{selfcols} } );
 483
 484   if ($expected->{noindex}) {
 485       ok( !defined $index, "index doesn't for '$desc'" );
 486   } else {
 487       ok( defined $index, "index exists for '$desc'" );
 488       is( $index->name, $expected->{index_name}, "index has correct name for '$desc'" );
 489   }
 490 }
 491
 492 sub test_unique {
 493   my ($expected, $got) = @_;
 494   my $desc = $expected->{display};
 495   is( $got->name, $expected->{name},
 496       "name parameter correct for '$desc'" );
 497 }
 498
 499 done_testing;