t/83cache.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use lib qw(t/lib);
   6 use DBICTest;
   7
   8 my $schema = DBICTest->init_schema();
   9
  10 my $queries;
  11 my $debugcb = sub{ $queries++ };
  12 my $sdebug = $schema->storage->debug;
  13
  14 plan tests => 23;
  15
  16 my $rs = $schema->resultset("Artist")->search(
  17   { artistid => 1 }
  18 );
  19
  20 my $artist = $rs->first;
  21
  22 ok( !defined($rs->get_cache), 'cache is not populated without cache attribute' );
  23
  24 $rs = $schema->resultset('Artist')->search( undef, { cache => 1 } );
  25 my $artists = [ $rs->all ];
  26
  27 is( scalar @{$rs->get_cache}, 3, 'all() populates cache for search with cache attribute' );
  28
  29 $rs->clear_cache;
  30
  31 ok( !defined($rs->get_cache), 'clear_cache is functional' );
  32
  33 $rs->next;
  34
  35 is( scalar @{$rs->get_cache}, 3, 'next() populates cache for search with cache attribute' );
  36
  37 pop( @$artists );
  38 $rs->set_cache( $artists );
  39
  40 is( scalar @{$rs->get_cache}, 2, 'set_cache() is functional' );
  41
  42 my $cd = $schema->resultset('CD')->find(1);
  43
  44 $rs->clear_cache;
  45
  46 $queries = 0;
  47 $schema->storage->debug(1);
  48 $schema->storage->debugcb ($debugcb);
  49
  50 $rs = $schema->resultset('Artist')->search( undef, { cache => 1 } );
  51 while( $artist = $rs->next ) {}
  52 $artist = $rs->first();
  53
  54 is( $queries, 1, 'revisiting a row does not issue a query when cache => 1' );
  55
  56 $schema->storage->debug($sdebug);
  57 $schema->storage->debugcb (undef);
  58
  59 my @a = $schema->resultset("Artist")->search(
  60   { },
  61   {
  62     join => [ qw/ cds /],
  63     prefetch => [qw/ cds /],
  64   }
  65 );
  66
  67 is(scalar @a, 3, 'artist with cds: count parent objects');
  68
  69 $rs = $schema->resultset("Artist")->search(
  70   { 'artistid' => 1 },
  71   {
  72     join => [ qw/ cds /],
  73     prefetch => [qw/ cds /],
  74   }
  75 );
  76
  77 # start test for prefetch SELECT count
  78 $queries = 0;
  79 $schema->storage->debug(1);
  80 $schema->storage->debugcb ($debugcb);
  81
  82 $artist = $rs->first;
  83 $rs->reset();
  84
  85 # make sure artist contains a related resultset for cds
  86 isa_ok( $artist->{related_resultsets}{cds}, 'DBIx::Class::ResultSet', 'artist has a related_resultset for cds' );
  87
  88 # check if $artist->cds->get_cache is populated
  89 is( scalar @{$artist->cds->get_cache}, 3, 'cache for artist->cds contains correct number of records');
  90
  91 # ensure that $artist->cds returns correct number of objects
  92 is( scalar ($artist->cds), 3, 'artist->cds returns correct number of objects' );
  93
  94 # ensure that $artist->cds->count returns correct value
  95 is( $artist->cds->count, 3, 'artist->cds->count returns correct value' );
  96
  97 # ensure that $artist->count_related('cds') returns correct value
  98 is( $artist->count_related('cds'), 3, 'artist->count_related returns correct value' );
  99
 100 is($queries, 1, 'only one SQL statement executed');
 101
 102 $schema->storage->debug($sdebug);
 103 $schema->storage->debugcb (undef);
 104
 105 # make sure related_resultset is deleted after object is updated
 106 $artist->set_column('name', 'New Name');
 107 $artist->update();
 108
 109 is( scalar keys %{$artist->{related_resultsets}}, 0, 'related resultsets deleted after update' );
 110
 111 # todo: make sure caching works with nested prefetch e.g. $artist->cds->tracks
 112 $rs = $schema->resultset("Artist")->search(
 113   { artistid => 1 },
 114   {
 115     join => { cds => 'tags' },
 116     prefetch => {
 117       cds => 'tags'
 118     },
 119     order_by => { -desc => 'cds.cdid' },
 120   }
 121 );
 122 {
 123 my $artist_count_before = $schema->resultset('Artist')->count;
 124 $schema->resultset("Artist")->create({artistid=>4,name=>qq{Humoungous Hamsters}});
 125 is($schema->resultset('Artist')->count, $artist_count_before + 1, 'count() reflects new artist');
 126 my $artist = $schema->resultset("Artist")->search(
 127   { artistid => 4 },{prefetch=>[qw/cds/]}
 128 )->first;
 129
 130 is($artist->cds, 0, 'No cds for this artist');
 131 }
 132
 133 # SELECT count for nested has_many prefetch
 134 $queries = 0;
 135 $schema->storage->debug(1);
 136 $schema->storage->debugcb ($debugcb);
 137
 138 $artist = ($rs->all)[0];
 139
 140 is($queries, 1, 'only one SQL statement executed');
 141
 142 $queries = 0;
 143
 144 my @objs;
 145 my $cds = $artist->cds;
 146 my $tags = $cds->next->tags;
 147 while( my $tag = $tags->next ) {
 148   push @objs, $tag->tagid; #warn "tag:", $tag->ID, " => ", $tag->tag;
 149 }
 150
 151 is_deeply( \@objs, [ 3 ], 'first cd has correct tags' );
 152
 153 $tags = $cds->next->tags;
 154 @objs = ();
 155 while( my $tag = $tags->next ) {
 156   push @objs, $tag->id; #warn "tag: ", $tag->ID;
 157 }
 158
 159 is_deeply( [ sort @objs] , [ 2, 5, 8 ], 'third cd has correct tags' );
 160
 161 $tags = $cds->next->tags;
 162 @objs = ();
 163 while( my $tag = $tags->next ) {
 164   push @objs, $tag->id; #warn "tag: ", $tag->ID;
 165 }
 166
 167 is_deeply( \@objs, [ 1 ], 'second cd has correct tags' );
 168
 169 is( $queries, 0, 'no additional SQL statements while checking nested data' );
 170
 171 # start test for prefetch SELECT count
 172 $queries = 0;
 173
 174 $artist = $schema->resultset('Artist')->find(1, { prefetch => [qw/cds/] });
 175
 176 is( $queries, 1, 'only one select statement on find with inline has_many prefetch' );
 177
 178 # start test for prefetch SELECT count
 179 $queries = 0;
 180
 181 $rs = $schema->resultset('Artist')->search(undef, { prefetch => [qw/cds/] });
 182 $artist = $rs->find(1);
 183
 184 is( $queries, 1, 'only one select statement on find with has_many prefetch on resultset' );
 185
 186 $schema->storage->debug($sdebug);
 187 $schema->storage->debugcb (undef);