t/80unique.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use lib qw(t/lib);
   7 use DBICTest;
   8 use DBIC::SqlMakerTest;
   9 use DBIC::DebugObj;
  10
  11 my $schema = DBICTest->init_schema();
  12
  13 # Check the defined unique constraints
  14 is_deeply(
  15   [ sort $schema->source('CD')->unique_constraint_names ],
  16   [ qw/cd_artist_title primary/ ],
  17   'CD source has an automatically named unique constraint'
  18 );
  19 is_deeply(
  20   [ sort $schema->source('Producer')->unique_constraint_names ],
  21   [ qw/primary prod_name/ ],
  22   'Producer source has a named unique constraint'
  23 );
  24 is_deeply(
  25   [ sort $schema->source('Track')->unique_constraint_names ],
  26   [ qw/primary track_cd_position track_cd_title/ ],
  27   'Track source has three unique constraints'
  28 );
  29 is_deeply(
  30   [ sort $schema->source('Tag')->unique_constraint_names ],
  31   [ qw/primary tagid_cd tagid_cd_tag tags_tagid_tag tags_tagid_tag_cd/ ],
  32   'Tag source has five unique constraints (from add_unique_constraings)'
  33 );
  34
  35 my $artistid = 1;
  36 my $title    = 'UNIQUE Constraint';
  37
  38 my $cd1 = $schema->resultset('CD')->find_or_create({
  39   artist => $artistid,
  40   title  => $title,
  41   year   => 2005,
  42 });
  43
  44 my $cd2 = $schema->resultset('CD')->find(
  45   {
  46     artist => $artistid,
  47     title  => $title,
  48   },
  49   { key => 'cd_artist_title' }
  50 );
  51
  52 is($cd2->get_column('artist'), $cd1->get_column('artist'), 'find by specific key: artist is correct');
  53 is($cd2->title, $cd1->title, 'title is correct');
  54 is($cd2->year, $cd1->year, 'year is correct');
  55
  56 my $cd3 = $schema->resultset('CD')->find($artistid, $title, { key => 'cd_artist_title' });
  57
  58 is($cd3->get_column('artist'), $cd1->get_column('artist'), 'find by specific key, ordered columns: artist is correct');
  59 is($cd3->title, $cd1->title, 'title is correct');
  60 is($cd3->year, $cd1->year, 'year is correct');
  61
  62 my $cd4 = $schema->resultset('CD')->update_or_create(
  63   {
  64     artist => $artistid,
  65     title  => $title,
  66     year   => 2007,
  67   },
  68 );
  69
  70 ok(! $cd4->is_changed, 'update_or_create without key: row is clean');
  71 is($cd4->cdid, $cd2->cdid, 'cdid is correct');
  72 is($cd4->get_column('artist'), $cd2->get_column('artist'), 'artist is correct');
  73 is($cd4->title, $cd2->title, 'title is correct');
  74 is($cd4->year, 2007, 'updated year is correct');
  75
  76 my $cd5 = $schema->resultset('CD')->update_or_create(
  77   {
  78     artist => $artistid,
  79     title  => $title,
  80     year   => 2007,
  81   },
  82   { key => 'cd_artist_title' }
  83 );
  84
  85 ok(! $cd5->is_changed, 'update_or_create by specific key: row is clean');
  86 is($cd5->cdid, $cd2->cdid, 'cdid is correct');
  87 is($cd5->get_column('artist'), $cd2->get_column('artist'), 'artist is correct');
  88 is($cd5->title, $cd2->title, 'title is correct');
  89 is($cd5->year, 2007, 'updated year is correct');
  90
  91 my $cd6 = $schema->resultset('CD')->update_or_create(
  92   {
  93     cdid   => $cd2->cdid,
  94     artist => 1,
  95     title  => $cd2->title,
  96     year   => 2005,
  97   },
  98   { key => 'primary' }
  99 );
 100
 101 ok(! $cd6->is_changed, 'update_or_create by PK: row is clean');
 102 is($cd6->cdid, $cd2->cdid, 'cdid is correct');
 103 is($cd6->get_column('artist'), $cd2->get_column('artist'), 'artist is correct');
 104 is($cd6->title, $cd2->title, 'title is correct');
 105 is($cd6->year, 2005, 'updated year is correct');
 106
 107 my $cd7 = $schema->resultset('CD')->find_or_create(
 108   {
 109     artist => $artistid,
 110     title  => $title,
 111     year   => 2010,
 112   },
 113   { key => 'cd_artist_title' }
 114 );
 115
 116 is($cd7->cdid, $cd1->cdid, 'find_or_create by specific key: cdid is correct');
 117 is($cd7->get_column('artist'), $cd1->get_column('artist'), 'artist is correct');
 118 is($cd7->title, $cd1->title, 'title is correct');
 119 is($cd7->year, $cd1->year, 'year is correct');
 120
 121 my $artist = $schema->resultset('Artist')->find($artistid);
 122 my $cd8 = $artist->find_or_create_related('cds',
 123   {
 124     title  => $title,
 125     year   => 2020,
 126   },
 127   { key => 'cd_artist_title' }
 128 );
 129
 130 is($cd8->cdid, $cd1->cdid, 'find_or_create related by specific key: cdid is correct');
 131 is($cd8->get_column('artist'), $cd1->get_column('artist'), 'artist is correct');
 132 is($cd8->title, $cd1->title, 'title is correct');
 133 is($cd8->year, $cd1->year, 'year is correct');
 134
 135 # Add an extra row to potentially confuse the query
 136 $schema->resultset('CD')->create ({
 137   artist => 2,
 138   title => $title,
 139   year => 2022,
 140 });
 141 my $cd9 = $artist->cds->update_or_create(
 142   {
 143     cdid   => $cd1->cdid,
 144     title  => $title,
 145     year   => 2021,
 146   },
 147   { key => 'cd_artist_title' }
 148 );
 149
 150 ok(! $cd9->is_changed, 'update_or_create by specific key: row is clean');
 151 is($cd9->cdid, $cd1->cdid, 'cdid is correct');
 152 is($cd9->get_column('artist'), $cd1->get_column('artist'), 'artist is correct');
 153 is($cd9->title, $cd1->title, 'title is correct');
 154 is($cd9->year, 2021, 'year is correct');
 155
 156 # Table with two unique constraints, and we're satisying one of them
 157 my $track = $schema->resultset('Track')->find(
 158   {
 159     cd       => 1,
 160     position => 3,
 161   },
 162   { order_by => 'position' }
 163 );
 164
 165 is($track->get_column('cd'), 1, 'track cd is correct');
 166 is($track->get_column('position'), 3, 'track position is correct');
 167
 168 # Test a table with a unique constraint but no primary key
 169 my $row = $schema->resultset('NoPrimaryKey')->update_or_create(
 170   {
 171     foo => 1,
 172     bar => 2,
 173     baz => 3,
 174   },
 175   { key => 'foo_bar' }
 176 );
 177
 178 ok(! $row->is_changed, 'update_or_create on table without primary key: row is clean');
 179 is($row->foo, 1, 'foo is correct');
 180 is($row->bar, 2, 'bar is correct');
 181 is($row->baz, 3, 'baz is correct');
 182
 183 # Test a unique condition with extra information in the where attr
 184 {
 185   my $artist = $schema->resultset('Artist')->find({ artistid => 1 });
 186   my $cd = $artist->cds->find_or_new(
 187     {
 188       cdid  => 1,
 189       title => 'Not The Real Title',
 190       year  => 3000,
 191     },
 192     { key => 'primary' }
 193   );
 194
 195   ok($cd->in_storage, 'find correctly grepped the key across a relationship');
 196   is($cd->cdid, 1, 'cdid is correct');
 197 }
 198
 199 # Test update_or_new
 200 {
 201     my $cd1 = $schema->resultset('CD')->update_or_new(
 202       {
 203         artist => $artistid,
 204         title  => "SuperHits $$",
 205         year   => 2007,
 206       },
 207       { key => 'cd_artist_title' }
 208     );
 209
 210     is($cd1->in_storage, 0, 'CD is not in storage yet after update_or_new');
 211     $cd1->insert;
 212     ok($cd1->in_storage, 'CD got added to strage after update_or_new && insert');
 213
 214     my $cd2 = $schema->resultset('CD')->update_or_new(
 215       {
 216         artist => $artistid,
 217         title  => "SuperHits $$",
 218         year   => 2008,
 219       },
 220       { key => 'cd_artist_title' }
 221     );
 222     ok($cd2->in_storage, 'Updating year using update_or_new was successful');
 223     is($cd2->id, $cd1->id, 'Got the same CD using update_or_new');
 224 }
 225
 226 # make sure the ident condition is assembled sanely
 227 {
 228   my $artist = $schema->resultset('Artist')->next;
 229
 230   my ($sql, @bind);
 231   $schema->storage->debugobj(DBIC::DebugObj->new(\$sql, \@bind)),
 232   $schema->storage->debug(1);
 233
 234   $artist->discard_changes;
 235
 236   is_same_sql_bind (
 237     $sql,
 238     \@bind,
 239     'SELECT me.artistid, me.name, me.rank, me.charfield FROM artist me WHERE me.artistid = ?',
 240     [qw/'1'/],
 241   );
 242
 243   $schema->storage->debug(0);
 244   $schema->storage->debugobj(undef);
 245 }
 246
 247 {
 248   throws_ok {
 249     eval <<'MOD' or die $@;
 250       package # hide from PAUSE
 251         DBICTest::Schema::UniqueConstraintWarningTest;
 252
 253       use base qw/DBIx::Class::Core/;
 254
 255       __PACKAGE__->table('dummy');
 256
 257       __PACKAGE__->add_column(qw/ foo bar /);
 258
 259       __PACKAGE__->add_unique_constraint(
 260         constraint1 => [qw/ foo /],
 261         constraint2 => [qw/ bar /],
 262       );
 263
 264       1;
 265 MOD
 266   } qr/\Qadd_unique_constraint() does not accept multiple constraints, use add_unique_constraints() instead\E/,
 267     'add_unique_constraint throws when more than one constraint specified';
 268 }
 269
 270
 271 done_testing;
 272