t/752sqlite.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use Test::Warn;
   7 use Time::HiRes 'time';
   8 use Math::BigInt;
   9
  10 use lib qw(t/lib);
  11 use DBICTest;
  12 use DBIx::Class::_Util qw( sigwarn_silencer modver_gt_or_eq modver_gt_or_eq_and_lt );
  13
  14 # check that we work somewhat OK with braindead SQLite transaction handling
  15 #
  16 # As per https://metacpan.org/source/ADAMK/DBD-SQLite-1.37/lib/DBD/SQLite.pm#L921
  17 # SQLite does *not* try to synchronize
  18 #
  19 # However DBD::SQLite 1.38_02 seems to fix this, with an accompanying test:
  20 # https://metacpan.org/source/ADAMK/DBD-SQLite-1.38_02/t/54_literal_txn.t
  21
  22 require DBD::SQLite;
  23 my $lit_txn_todo = modver_gt_or_eq('DBD::SQLite', '1.38_02')
  24   ? undef
  25   : "DBD::SQLite before 1.38_02 is retarded wrt detecting literal BEGIN/COMMIT statements"
  26 ;
  27
  28 for my $prefix_comment (qw/Begin_only Commit_only Begin_and_Commit/) {
  29   note "Testing with comment prefixes on $prefix_comment";
  30
  31   # FIXME warning won't help us for the time being
  32   # perhaps when (if ever) DBD::SQLite gets fixed,
  33   # we can do something extra here
  34   local $SIG{__WARN__} = sigwarn_silencer( qr/Internal transaction state .+? does not seem to match/ )
  35     if ( $lit_txn_todo && !$ENV{TEST_VERBOSE} );
  36
  37   my ($c_begin, $c_commit) = map { $prefix_comment =~ $_ ? 1 : 0 } (qr/Begin/, qr/Commit/);
  38
  39   my $schema = DBICTest->init_schema( no_deploy => 1 );
  40   my $ars = $schema->resultset('Artist');
  41
  42   ok (! $schema->storage->connected, 'No connection yet');
  43
  44   $schema->storage->dbh->do(<<'DDL');
  45 CREATE TABLE artist (
  46   artistid INTEGER PRIMARY KEY NOT NULL,
  47   name varchar(100),
  48   rank integer DEFAULT 13,
  49   charfield char(10) NULL
  50 );
  51 DDL
  52
  53   my $artist = $ars->create({ name => 'Artist_' . time() });
  54   is ($ars->count, 1, 'Inserted artist ' . $artist->name);
  55
  56   ok ($schema->storage->connected, 'Connected');
  57   ok ($schema->storage->_dbh->{AutoCommit}, 'DBD not in txn yet');
  58
  59   $schema->storage->dbh->do(join "\n",
  60     $c_begin ? '-- comment' : (),
  61     'BEGIN TRANSACTION'
  62   );
  63   ok ($schema->storage->connected, 'Still connected');
  64   {
  65     local $TODO = $lit_txn_todo if $c_begin;
  66     ok (! $schema->storage->_dbh->{AutoCommit}, "DBD aware of txn begin with comments on $prefix_comment");
  67   }
  68
  69   $schema->storage->dbh->do(join "\n",
  70     $c_commit ? '-- comment' : (),
  71     'COMMIT'
  72   );
  73   ok ($schema->storage->connected, 'Still connected');
  74   {
  75     local $TODO = $lit_txn_todo if $c_commit and ! $c_begin;
  76     ok ($schema->storage->_dbh->{AutoCommit}, "DBD aware txn ended with comments on $prefix_comment");
  77   }
  78
  79   is ($ars->count, 1, 'Inserted artists still there');
  80
  81   {
  82     # this never worked in the 1st place
  83     local $TODO = $lit_txn_todo if ! $c_begin and $c_commit;
  84
  85     # odd argument passing, because such nested crefs leak on 5.8
  86     lives_ok {
  87       $schema->storage->txn_do (sub {
  88         ok ($_[0]->find({ name => $_[1] }), "Artist still where we left it after cycle with comments on $prefix_comment");
  89       }, $ars, $artist->name );
  90     } "Succesfull transaction with comments on $prefix_comment";
  91   }
  92 }
  93
  94 # test blank begin/svp/commit/begin cycle
  95 warnings_are {
  96   my $schema = DBICTest->init_schema( no_populate => 1 );
  97   my $rs = $schema->resultset('Artist');
  98   is ($rs->count, 0, 'Start with empty table');
  99
 100   for my $do_commit (1, 0) {
 101     $schema->txn_begin;
 102     $schema->svp_begin;
 103     $schema->svp_rollback;
 104
 105     $schema->svp_begin;
 106     $schema->svp_rollback;
 107
 108     $schema->svp_release;
 109
 110     $schema->svp_begin;
 111
 112     $schema->txn_rollback;
 113
 114     $schema->txn_begin;
 115     $schema->svp_begin;
 116     $schema->svp_rollback;
 117
 118     $schema->svp_begin;
 119     $schema->svp_rollback;
 120
 121     $schema->svp_release;
 122
 123     $schema->svp_begin;
 124
 125     $do_commit ? $schema->txn_commit : $schema->txn_rollback;
 126
 127     is_deeply $schema->storage->savepoints, [], 'Savepoint names cleared away'
 128   }
 129
 130   $schema->txn_do(sub {
 131     ok (1, 'all seems fine');
 132   });
 133 } [], 'No warnings emitted';
 134
 135 my $schema = DBICTest->init_schema();
 136
 137 # make sure the side-effects of RT#67581 do not result in data loss
 138 my $row;
 139 warnings_exist { $row = $schema->resultset('Artist')->create ({ name => 'alpha rank', rank => 'abc' }) }
 140   [qr/Non-integer value supplied for column 'rank' despite the integer datatype/],
 141   'proper warning on string insertion into an numeric column'
 142 ;
 143 $row->discard_changes;
 144 is ($row->rank, 'abc', 'proper rank inserted into database');
 145
 146 # and make sure we do not lose actual bigints
 147 SKIP: {
 148
 149 skip "Not testing bigint handling on known broken DBD::SQLite trial versions", 1
 150   if modver_gt_or_eq_and_lt( 'DBD::SQLite', '1.45', '1.45_03' );
 151
 152 {
 153   package DBICTest::BigIntArtist;
 154   use base 'DBICTest::Schema::Artist';
 155   __PACKAGE__->table('artist');
 156   __PACKAGE__->add_column(bigint => { data_type => 'bigint' });
 157 }
 158 $schema->register_class(BigIntArtist => 'DBICTest::BigIntArtist');
 159 $schema->storage->dbh_do(sub {
 160   $_[1]->do('ALTER TABLE artist ADD COLUMN bigint BIGINT');
 161 });
 162
 163 my $sqlite_broken_bigint = modver_gt_or_eq_and_lt( 'DBD::SQLite', '1.34', '1.37' );
 164
 165 # 63 bit integer
 166 my $many_bits = (Math::BigInt->new(2) ** 62);
 167
 168 # test upper/lower boundaries for sqlite and some values inbetween
 169 # range is -(2**63) .. 2**63 - 1
 170 #
 171 # Not testing -0 - it seems to overflow to ~0 on some combinations,
 172 # thus not triggering the >32 bit guards
 173 # interesting read: https://en.wikipedia.org/wiki/Signed_zero#Representations
 174 for my $bi ( qw(
 175   -2
 176   -1
 177   0
 178   +0
 179   1
 180   2
 181
 182   -9223372036854775807
 183   -8694837494948124658
 184   -6848440844435891639
 185   -5664812265578554454
 186   -5380388020020483213
 187   -2564279463598428141
 188   2442753333597784273
 189   4790993557925631491
 190   6773854980030157393
 191   7627910776496326154
 192   8297530189347439311
 193   9223372036854775806
 194   9223372036854775807
 195
 196   4294967295
 197   4294967296
 198
 199   -4294967296
 200   -4294967295
 201   -4294967294
 202
 203   -2147483649
 204   -2147483648
 205   -2147483647
 206   -2147483646
 207
 208   2147483646
 209   2147483647
 210 ),
 211   # these values cause exceptions even with all workarounds in place on these
 212   # fucked DBD::SQLite versions *regardless* of ivsize >.<
 213   $sqlite_broken_bigint
 214     ? ()
 215     : ( '2147483648', '2147483649' )
 216   ,
 217
 218   # with newer compilers ( gcc 4.9+ ) older DBD::SQLite does not
 219   # play well with the "Most Negative Number"
 220   modver_gt_or_eq( 'DBD::SQLite', '1.33' )
 221     ? ( '-9223372036854775808' )
 222     : ()
 223   ,
 224
 225 ) {
 226   # unsigned 32 bit ints have a range of −2,147,483,648 to 2,147,483,647
 227   # alternatively expressed as the hexadecimal numbers below
 228   # the comparison math will come out right regardless of ivsize, since
 229   # we are operating within 31 bits
 230   # P.S. 31 because one bit is lost for the sign
 231   my $v_bits = ($bi > 0x7fff_ffff || $bi < -0x8000_0000) ? 64 : 32;
 232
 233   my $v_desc = sprintf '%s (%d bit signed int)', $bi, $v_bits;
 234
 235   my @w;
 236   local $SIG{__WARN__} = sub {
 237     if ($_[0] =~ /datatype mismatch/) {
 238       push @w, @_;
 239     }
 240     elsif ($_[0] =~ /An integer value occupying more than 32 bits was supplied .+ can not bind properly so DBIC will treat it as a string instead/ ) {
 241       # do nothing, this warning will pop up here and there depending on
 242       # DBD/bitness combination
 243       # we don't want to test for it explicitly, we are just interested
 244       # in the results matching at the end
 245     }
 246     else {
 247       warn @_;
 248     }
 249   };
 250
 251   # some combinations of SQLite 1.35 and older 5.8 faimly is wonky
 252   # instead of a warning we get a full exception. Sod it
 253   eval {
 254     $row = $schema->resultset('BigIntArtist')->create({ bigint => $bi });
 255   } or do {
 256     fail("Exception on inserting $v_desc: $@") unless $sqlite_broken_bigint;
 257     next;
 258   };
 259
 260   # explicitly using eq, to make sure we did not nummify the argument
 261   # which can be an issue on 32 bit ivsize
 262   cmp_ok ($row->bigint, 'eq', $bi, "value in object correct ($v_desc)");
 263
 264   $row->discard_changes;
 265
 266   cmp_ok (
 267     $row->bigint,
 268
 269     # the test will not pass an == if we are running under 32 bit ivsize
 270     # use 'eq' on the numified (and possibly "scientificied") returned value
 271     (DBIx::Class::_ENV_::IV_SIZE < 8 and $v_bits > 32) ? 'eq' : '==',
 272
 273     # in 1.37 DBD::SQLite switched to proper losless representation of bigints
 274     # regardless of ivize
 275     # before this use 'eq' (from above) on the numified (and possibly
 276     # "scientificied") returned value
 277     (DBIx::Class::_ENV_::IV_SIZE < 8 and ! modver_gt_or_eq('DBD::SQLite', '1.37')) ? $bi+0 : $bi,
 278
 279     "value in database correct ($v_desc)"
 280   );
 281
 282   # check if math works
 283   # start by adding/subtracting a 50 bit integer, and then divide by 2 for good measure
 284   my ($sqlop, $expect) = $bi < 0
 285     ? ( '(bigint + ? )', ($bi + $many_bits) )
 286     : ( '(bigint - ? )', ($bi - $many_bits) )
 287   ;
 288
 289   $expect = ($expect + ($expect % 2)) / 2;
 290
 291   # read https://en.wikipedia.org/wiki/Modulo_operation#Common_pitfalls
 292   # and check the tables on the right side of the article for an
 293   # enlightening journey on why a mere bigint % 2 won't work
 294   $sqlop = "( $sqlop + ( ((bigint % 2)+2)%2 ) ) / 2";
 295
 296   for my $dtype (undef, \'int', \'bigint') {
 297
 298     # FIXME - the double-load should not be needed
 299     # will fix in the future
 300     $row->update({ bigint => $bi });
 301     $row->discard_changes;
 302     $row->update({ bigint => \[ $sqlop, [ $dtype => $many_bits ] ] });
 303     $row->discard_changes;
 304
 305     # can't use cmp_ok - will not engage the M::BI overload of $many_bits
 306     ok (
 307       $row->bigint
 308
 309       ==
 310
 311       (DBIx::Class::_ENV_::IV_SIZE < 8 and ! modver_gt_or_eq('DBD::SQLite', '1.37')) ? $expect->bstr + 0 : $expect
 312     , "simple integer math with@{[ $dtype ? '' : 'out' ]} bindtype in database correct (base $v_desc)")
 313       or diag sprintf '%s != %s', $row->bigint, $expect;
 314   }
 315
 316   is_deeply (\@w, [], "No mismatch warnings on bigint operations ($v_desc)" );
 317
 318 }}
 319
 320 done_testing;
 321
 322 # vim:sts=2 sw=2: