t/750firebird.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use lib qw(t/lib);
   7 use DBICTest;
   8 use Scope::Guard ();
   9
  10 # tests stolen from 749sybase_asa.t
  11
  12 my ($dsn, $user, $pass)    = @ENV{map { "DBICTEST_FIREBIRD_${_}" }      qw/DSN USER PASS/};
  13 my ($dsn2, $user2, $pass2) = @ENV{map { "DBICTEST_FIREBIRD_ODBC_${_}" } qw/DSN USER PASS/};
  14
  15 plan skip_all => <<'EOF' unless $dsn || $dsn2;
  16 Set $ENV{DBICTEST_FIREBIRD_DSN} and/or $ENV{DBICTEST_FIREBIRD_ODBC_DSN},
  17 _USER and _PASS to run these tests.
  18
  19 WARNING: this test creates and drops the tables "artist", "bindtype_test" and
  20 "sequence_test"; the generators "gen_artist_artistid", "pkid1_seq", "pkid2_seq"
  21 and "nonpkid_seq" and the trigger "artist_bi".
  22 EOF
  23
  24 my @info = (
  25   [ $dsn,  $user,  $pass  ],
  26   [ $dsn2, $user2, $pass2 ],
  27 );
  28
  29 my $schema;
  30
  31 foreach my $conn_idx (0..$#info) {
  32   my ($dsn, $user, $pass) = @{ $info[$conn_idx] || [] };
  33
  34   next unless $dsn;
  35
  36   $schema = DBICTest::Schema->connect($dsn, $user, $pass, {
  37     auto_savepoint  => 1,
  38     quote_char      => q["],
  39     name_sep        => q[.],
  40     on_connect_call => 'use_softcommit',
  41   });
  42   my $dbh = $schema->storage->dbh;
  43
  44   my $sg = Scope::Guard->new(\&cleanup);
  45
  46   eval { $dbh->do(q[DROP TABLE "artist"]) };
  47   $dbh->do(<<EOF);
  48   CREATE TABLE "artist" (
  49     "artistid" INT PRIMARY KEY,
  50     "name" VARCHAR(255),
  51     "charfield" CHAR(10),
  52     "rank" INT DEFAULT 13
  53   )
  54 EOF
  55   eval { $dbh->do(q[DROP GENERATOR "gen_artist_artistid"]) };
  56   $dbh->do('CREATE GENERATOR "gen_artist_artistid"');
  57   eval { $dbh->do('DROP TRIGGER "artist_bi"') };
  58   $dbh->do(<<EOF);
  59   CREATE TRIGGER "artist_bi" FOR "artist"
  60   ACTIVE BEFORE INSERT POSITION 0
  61   AS
  62   BEGIN
  63    IF (NEW."artistid" IS NULL) THEN
  64     NEW."artistid" = GEN_ID("gen_artist_artistid",1);
  65   END
  66 EOF
  67   eval { $dbh->do('DROP TABLE "sequence_test"') };
  68   $dbh->do(<<EOF);
  69   CREATE TABLE "sequence_test" (
  70     "pkid1" INT NOT NULL,
  71     "pkid2" INT NOT NULL,
  72     "nonpkid" INT,
  73     "name" VARCHAR(255)
  74   )
  75 EOF
  76   $dbh->do('ALTER TABLE "sequence_test" ADD CONSTRAINT "sequence_test_constraint" PRIMARY KEY ("pkid1", "pkid2")');
  77   eval { $dbh->do('DROP GENERATOR "pkid1_seq"') };
  78   eval { $dbh->do('DROP GENERATOR "pkid2_seq"') };
  79   eval { $dbh->do('DROP GENERATOR "nonpkid_seq"') };
  80   $dbh->do('CREATE GENERATOR "pkid1_seq"');
  81   $dbh->do('CREATE GENERATOR "pkid2_seq"');
  82   $dbh->do('SET GENERATOR "pkid2_seq" TO 9');
  83   $dbh->do('CREATE GENERATOR "nonpkid_seq"');
  84   $dbh->do('SET GENERATOR "nonpkid_seq" TO 19');
  85
  86   my $ars = $schema->resultset('Artist');
  87   is ( $ars->count, 0, 'No rows at first' );
  88
  89 # test primary key handling
  90   my $new = $ars->create({ name => 'foo' });
  91   ok($new->artistid, "Auto-PK worked");
  92
  93 # test auto increment using generators WITHOUT triggers
  94   for (1..5) {
  95       my $st = $schema->resultset('SequenceTest')->create({ name => 'foo' });
  96       is($st->pkid1, $_, "Firebird Auto-PK without trigger: First primary key");
  97       is($st->pkid2, $_ + 9, "Firebird Auto-PK without trigger: Second primary key");
  98       is($st->nonpkid, $_ + 19, "Firebird Auto-PK without trigger: Non-primary key");
  99   }
 100   my $st = $schema->resultset('SequenceTest')->create({ name => 'foo', pkid1 => 55 });
 101   is($st->pkid1, 55, "Firebird Auto-PK without trigger: First primary key set manually");
 102
 103 # test savepoints
 104   eval {
 105     $schema->txn_do(sub {
 106       eval {
 107         $schema->txn_do(sub {
 108           $ars->create({ name => 'in_savepoint' });
 109           die "rolling back savepoint";
 110         });
 111       };
 112       ok ((not $ars->search({ name => 'in_savepoint' })->first),
 113         'savepoint rolled back');
 114       $ars->create({ name => 'in_outer_txn' });
 115       die "rolling back outer txn";
 116     });
 117   };
 118
 119   like $@, qr/rolling back outer txn/,
 120     'correct exception for rollback';
 121
 122   ok ((not $ars->search({ name => 'in_outer_txn' })->first),
 123     'outer txn rolled back');
 124
 125 # test explicit key spec
 126   $new = $ars->create ({ name => 'bar', artistid => 66 });
 127   is($new->artistid, 66, 'Explicit PK worked');
 128   $new->discard_changes;
 129   is($new->artistid, 66, 'Explicit PK assigned');
 130
 131 # row update
 132   lives_ok {
 133     $new->update({ name => 'baz' })
 134   } 'update survived';
 135   $new->discard_changes;
 136   is $new->name, 'baz', 'row updated';
 137
 138 # test populate
 139   lives_ok (sub {
 140     my @pop;
 141     for (1..2) {
 142       push @pop, { name => "Artist_$_" };
 143     }
 144     $ars->populate (\@pop);
 145   });
 146
 147 # test populate with explicit key
 148   lives_ok (sub {
 149     my @pop;
 150     for (1..2) {
 151       push @pop, { name => "Artist_expkey_$_", artistid => 100 + $_ };
 152     }
 153     $ars->populate (\@pop);
 154   });
 155
 156 # count what we did so far
 157   is ($ars->count, 6, 'Simple count works');
 158
 159 # test ResultSet UPDATE
 160   lives_and {
 161     $ars->search({ name => 'foo' })->update({ rank => 4 });
 162
 163     is eval { $ars->search({ name => 'foo' })->first->rank }, 4;
 164   } 'Can update a column';
 165
 166   my ($updated) = $schema->resultset('Artist')->search({name => 'foo'});
 167   is eval { $updated->rank }, 4, 'and the update made it to the database';
 168
 169
 170 # test LIMIT support
 171   my $lim = $ars->search( {},
 172     {
 173       rows => 3,
 174       offset => 4,
 175       order_by => 'artistid'
 176     }
 177   );
 178   is( $lim->count, 2, 'ROWS+OFFSET count ok' );
 179   is( $lim->all, 2, 'Number of ->all objects matches count' );
 180
 181 # test iterator
 182   $lim->reset;
 183   is( eval { $lim->next->artistid }, 101, "iterator->next ok" );
 184   is( eval { $lim->next->artistid }, 102, "iterator->next ok" );
 185   is( $lim->next, undef, "next past end of resultset ok" );
 186
 187 # test multiple executing cursors
 188   {
 189     my $rs1 = $ars->search({}, { order_by => { -asc  => 'artistid' }});
 190     my $rs2 = $ars->search({}, { order_by => { -desc => 'artistid' }});
 191
 192     is $rs1->next->artistid, 1,   'multiple cursors';
 193     is $rs2->next->artistid, 102, 'multiple cursors';
 194   }
 195
 196 # test empty insert
 197   lives_and {
 198     my $row = $ars->create({});
 199     ok $row->artistid;
 200   } 'empty insert works';
 201
 202 # test inferring the generator from the trigger source and using it with
 203 # auto_nextval
 204   {
 205     local $ars->result_source->column_info('artistid')->{auto_nextval} = 1;
 206
 207     lives_and {
 208       my $row = $ars->create({ name => 'introspecting generator' });
 209       ok $row->artistid;
 210     } 'inferring generator from trigger source works';
 211   }
 212
 213 # test blobs (stolen from 73oracle.t)
 214   eval { $dbh->do('DROP TABLE "bindtype_test"') };
 215   $dbh->do(q[
 216   CREATE TABLE "bindtype_test"
 217   (
 218     "id"     INT PRIMARY KEY,
 219     "bytea"  INT,
 220     "blob"   BLOB,
 221     "clob"   BLOB SUB_TYPE TEXT
 222   )
 223   ]);
 224
 225   my %binstr = ( 'small' => join('', map { chr($_) } ( 1 .. 127 )) );
 226   $binstr{'large'} = $binstr{'small'} x 1024;
 227
 228   my $maxloblen = length $binstr{'large'};
 229   local $dbh->{'LongReadLen'} = $maxloblen;
 230
 231   my $rs = $schema->resultset('BindType');
 232   my $id = 0;
 233
 234   foreach my $type (qw( blob clob )) {
 235     foreach my $size (qw( small large )) {
 236       $id++;
 237
 238 # turn off horrendous binary DBIC_TRACE output
 239       local $schema->storage->{debug} = 0;
 240
 241       lives_ok { $rs->create( { 'id' => $id, $type => $binstr{$size} } ) }
 242       "inserted $size $type without dying";
 243
 244       ok($rs->find($id)->$type eq $binstr{$size}, "verified inserted $size $type" );
 245     }
 246   }
 247 }
 248
 249 done_testing;
 250
 251 # clean up our mess
 252
 253 sub cleanup {
 254   my $dbh;
 255   eval {
 256     $schema->storage->disconnect; # to avoid object FOO is in use errors
 257     $dbh = $schema->storage->dbh;
 258   };
 259   return unless $dbh;
 260
 261   eval { $dbh->do('DROP TRIGGER "artist_bi"') };
 262   diag $@ if $@;
 263
 264   foreach my $generator (qw/gen_artist_artistid pkid1_seq pkid2_seq
 265                             nonpkid_seq/) {
 266     eval { $dbh->do(qq{DROP GENERATOR "$generator"}) };
 267     diag $@ if $@;
 268   }
 269
 270   foreach my $table (qw/artist bindtype_test sequence_test/) {
 271     eval { $dbh->do(qq[DROP TABLE "$table"]) };
 272     diag $@ if $@;
 273   }
 274 }