t/750firebird.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use lib qw(t/lib);
   7 use DBICTest;
   8 use Scope::Guard ();
   9
  10 # tests stolen from 749sybase_asa.t
  11
  12 my ($dsn, $user, $pass)    = @ENV{map { "DBICTEST_FIREBIRD_${_}" }      qw/DSN USER PASS/};
  13 my ($dsn2, $user2, $pass2) = @ENV{map { "DBICTEST_FIREBIRD_ODBC_${_}" } qw/DSN USER PASS/};
  14
  15 plan skip_all => <<'EOF' unless $dsn || $dsn2;
  16 Set $ENV{DBICTEST_FIREBIRD_DSN} and/or $ENV{DBICTEST_FIREBIRD_ODBC_DSN},
  17 _USER and _PASS to run these tests
  18 EOF
  19
  20 my @info = (
  21   [ $dsn,  $user,  $pass  ],
  22   [ $dsn2, $user2, $pass2 ],
  23 );
  24
  25 my $schema;
  26
  27 foreach my $conn_idx (0..$#info) {
  28   my ($dsn, $user, $pass) = @{ $info[$conn_idx] || [] };
  29
  30   next unless $dsn;
  31
  32   $schema = DBICTest::Schema->connect($dsn, $user, $pass, {
  33     auto_savepoint  => 1,
  34     quote_char      => q["],
  35     name_sep        => q[.],
  36     on_connect_call => 'use_softcommit',
  37   });
  38   my $dbh = $schema->storage->dbh;
  39
  40   my $sg = Scope::Guard->new(\&cleanup);
  41
  42   eval { $dbh->do(q[DROP TABLE "artist"]) };
  43   $dbh->do(<<EOF);
  44   CREATE TABLE "artist" (
  45     "artistid" INT PRIMARY KEY,
  46     "name" VARCHAR(255),
  47     "charfield" CHAR(10),
  48     "rank" INT DEFAULT 13
  49   )
  50 EOF
  51   eval { $dbh->do(q[DROP GENERATOR "gen_artist_artistid"]) };
  52   $dbh->do('CREATE GENERATOR "gen_artist_artistid"');
  53   eval { $dbh->do('DROP TRIGGER "artist_bi"') };
  54   $dbh->do(<<EOF);
  55   CREATE TRIGGER "artist_bi" FOR "artist"
  56   ACTIVE BEFORE INSERT POSITION 0
  57   AS
  58   BEGIN
  59    IF (NEW."artistid" IS NULL) THEN
  60     NEW."artistid" = GEN_ID("gen_artist_artistid",1);
  61   END
  62 EOF
  63   eval { $dbh->do('DROP TABLE "sequence_test"') };
  64   $dbh->do(<<EOF);
  65   CREATE TABLE "sequence_test" (
  66     "pkid1" INT NOT NULL,
  67     "pkid2" INT NOT NULL,
  68     "nonpkid" INT,
  69     "name" VARCHAR(255)
  70   )
  71 EOF
  72   $dbh->do('ALTER TABLE "sequence_test" ADD CONSTRAINT "sequence_test_constraint" PRIMARY KEY ("pkid1", "pkid2")');
  73   eval { $dbh->do('DROP GENERATOR "pkid1_seq"') };
  74   eval { $dbh->do('DROP GENERATOR "pkid2_seq"') };
  75   eval { $dbh->do('DROP GENERATOR "nonpkid_seq"') };
  76   $dbh->do('CREATE GENERATOR "pkid1_seq"');
  77   $dbh->do('CREATE GENERATOR "pkid2_seq"');
  78   $dbh->do('SET GENERATOR "pkid2_seq" TO 9');
  79   $dbh->do('CREATE GENERATOR "nonpkid_seq"');
  80   $dbh->do('SET GENERATOR "nonpkid_seq" TO 19');
  81
  82   my $ars = $schema->resultset('Artist');
  83   is ( $ars->count, 0, 'No rows at first' );
  84
  85 # test primary key handling
  86   my $new = $ars->create({ name => 'foo' });
  87   ok($new->artistid, "Auto-PK worked");
  88
  89 # test auto increment using generators WITHOUT triggers
  90   for (1..5) {
  91       my $st = $schema->resultset('SequenceTest')->create({ name => 'foo' });
  92       is($st->pkid1, $_, "Firebird Auto-PK without trigger: First primary key");
  93       is($st->pkid2, $_ + 9, "Firebird Auto-PK without trigger: Second primary key");
  94       is($st->nonpkid, $_ + 19, "Firebird Auto-PK without trigger: Non-primary key");
  95   }
  96   my $st = $schema->resultset('SequenceTest')->create({ name => 'foo', pkid1 => 55 });
  97   is($st->pkid1, 55, "Firebird Auto-PK without trigger: First primary key set manually");
  98
  99 # test savepoints
 100   eval {
 101     $schema->txn_do(sub {
 102       eval {
 103         $schema->txn_do(sub {
 104           $ars->create({ name => 'in_savepoint' });
 105           die "rolling back savepoint";
 106         });
 107       };
 108       ok ((not $ars->search({ name => 'in_savepoint' })->first),
 109         'savepoint rolled back');
 110       $ars->create({ name => 'in_outer_txn' });
 111       die "rolling back outer txn";
 112     });
 113   };
 114
 115   like $@, qr/rolling back outer txn/,
 116     'correct exception for rollback';
 117
 118   ok ((not $ars->search({ name => 'in_outer_txn' })->first),
 119     'outer txn rolled back');
 120
 121 # test explicit key spec
 122   $new = $ars->create ({ name => 'bar', artistid => 66 });
 123   is($new->artistid, 66, 'Explicit PK worked');
 124   $new->discard_changes;
 125   is($new->artistid, 66, 'Explicit PK assigned');
 126
 127 # row update
 128   lives_ok {
 129     $new->update({ name => 'baz' })
 130   } 'update survived';
 131   $new->discard_changes;
 132   is $new->name, 'baz', 'row updated';
 133
 134 # test populate
 135   lives_ok (sub {
 136     my @pop;
 137     for (1..2) {
 138       push @pop, { name => "Artist_$_" };
 139     }
 140     $ars->populate (\@pop);
 141   });
 142
 143 # test populate with explicit key
 144   lives_ok (sub {
 145     my @pop;
 146     for (1..2) {
 147       push @pop, { name => "Artist_expkey_$_", artistid => 100 + $_ };
 148     }
 149     $ars->populate (\@pop);
 150   });
 151
 152 # count what we did so far
 153   is ($ars->count, 6, 'Simple count works');
 154
 155 # test ResultSet UPDATE
 156   lives_and {
 157     $ars->search({ name => 'foo' })->update({ rank => 4 });
 158
 159     is eval { $ars->search({ name => 'foo' })->first->rank }, 4;
 160   } 'Can update a column';
 161
 162   my ($updated) = $schema->resultset('Artist')->search({name => 'foo'});
 163   is eval { $updated->rank }, 4, 'and the update made it to the database';
 164
 165
 166 # test LIMIT support
 167   my $lim = $ars->search( {},
 168     {
 169       rows => 3,
 170       offset => 4,
 171       order_by => 'artistid'
 172     }
 173   );
 174   is( $lim->count, 2, 'ROWS+OFFSET count ok' );
 175   is( $lim->all, 2, 'Number of ->all objects matches count' );
 176
 177 # test iterator
 178   $lim->reset;
 179   is( eval { $lim->next->artistid }, 101, "iterator->next ok" );
 180   is( eval { $lim->next->artistid }, 102, "iterator->next ok" );
 181   is( $lim->next, undef, "next past end of resultset ok" );
 182
 183 # test multiple executing cursors
 184   {
 185     my $rs1 = $ars->search({}, { order_by => { -asc  => 'artistid' }});
 186     my $rs2 = $ars->search({}, { order_by => { -desc => 'artistid' }});
 187
 188     is $rs1->next->artistid, 1,   'multiple cursors';
 189     is $rs2->next->artistid, 102, 'multiple cursors';
 190   }
 191
 192 # test empty insert
 193   {
 194     local $ars->result_source->column_info('artistid')->{is_auto_increment} = 0;
 195
 196     lives_ok { $ars->create({}) }
 197       'empty insert works';
 198   }
 199
 200 # test blobs (stolen from 73oracle.t)
 201   eval { $dbh->do('DROP TABLE "bindtype_test"') };
 202   $dbh->do(q[
 203   CREATE TABLE "bindtype_test"
 204   (
 205     "id"     INT PRIMARY KEY,
 206     "bytea"  INT,
 207     "blob"   BLOB,
 208     "clob"   BLOB SUB_TYPE TEXT
 209   )
 210   ]);
 211
 212   my %binstr = ( 'small' => join('', map { chr($_) } ( 1 .. 127 )) );
 213   $binstr{'large'} = $binstr{'small'} x 1024;
 214
 215   my $maxloblen = length $binstr{'large'};
 216   local $dbh->{'LongReadLen'} = $maxloblen;
 217
 218   my $rs = $schema->resultset('BindType');
 219   my $id = 0;
 220
 221   foreach my $type (qw( blob clob )) {
 222     foreach my $size (qw( small large )) {
 223       $id++;
 224
 225 # turn off horrendous binary DBIC_TRACE output
 226       local $schema->storage->{debug} = 0;
 227
 228       lives_ok { $rs->create( { 'id' => $id, $type => $binstr{$size} } ) }
 229       "inserted $size $type without dying";
 230
 231       ok($rs->find($id)->$type eq $binstr{$size}, "verified inserted $size $type" );
 232     }
 233   }
 234 }
 235
 236 done_testing;
 237
 238 # clean up our mess
 239
 240 sub cleanup {
 241   my $dbh;
 242   eval {
 243     $schema->storage->disconnect; # to avoid object FOO is in use errors
 244     $dbh = $schema->storage->dbh;
 245   };
 246   return unless $dbh;
 247
 248   eval { $dbh->do('DROP TRIGGER "artist_bi"') };
 249   diag $@ if $@;
 250
 251   foreach my $generator (qw/gen_artist_artistid pkid1_seq pkid2_seq
 252                             nonpkid_seq/) {
 253     eval { $dbh->do(qq{DROP GENERATOR "$generator"}) };
 254     diag $@ if $@;
 255   }
 256
 257   foreach my $table (qw/artist bindtype_test sequence_test/) {
 258     eval { $dbh->do(qq[DROP TABLE "$table"]) };
 259     diag $@ if $@;
 260   }
 261 }