t/746sybase.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use lib qw(t/lib);
   6 use DBICTest;
   7 use DBIx::Class::Storage::DBI::Sybase::DateTime;
   8
   9 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_SYBASE_${_}" } qw/DSN USER PASS/};
  10
  11 plan skip_all => 'Set $ENV{DBICTEST_SYBASE_DSN}, _USER and _PASS to run this test'
  12   unless ($dsn && $user);
  13
  14 plan tests => 20*2;
  15
  16 my @storage_types = (
  17   'DBI::Sybase',
  18   'DBI::Sybase::NoBindVars',
  19 );
  20 my $schema;
  21
  22 for my $storage_type (@storage_types) {
  23   $schema = DBICTest::Schema->clone;
  24
  25   unless ($storage_type eq 'DBI::Sybase') { # autodetect
  26     $schema->storage_type("::$storage_type");
  27   }
  28   $schema->connection($dsn, $user, $pass, {AutoCommit => 1});
  29
  30   $schema->storage->ensure_connected;
  31
  32   isa_ok( $schema->storage, "DBIx::Class::Storage::$storage_type" );
  33
  34   $schema->storage->dbh_do (sub {
  35       my ($storage, $dbh) = @_;
  36       eval { $dbh->do("DROP TABLE artist") };
  37       $dbh->do(<<'SQL');
  38 CREATE TABLE artist (
  39    artistid INT IDENTITY PRIMARY KEY,
  40    name VARCHAR(100),
  41    rank INT DEFAULT 13 NOT NULL,
  42    charfield CHAR(10) NULL
  43 )
  44 SQL
  45   });
  46
  47   my %seen_id;
  48
  49 # so we start unconnected
  50   $schema->storage->disconnect;
  51
  52 # test primary key handling
  53   my $new = $schema->resultset('Artist')->create({ name => 'foo' });
  54   ok($new->artistid > 0, "Auto-PK worked");
  55
  56   $seen_id{$new->artistid}++;
  57
  58 # test LIMIT support
  59   for (1..6) {
  60     $new = $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
  61     is ( $seen_id{$new->artistid}, undef, "id for Artist $_ is unique" );
  62     $seen_id{$new->artistid}++;
  63   }
  64
  65   my $it = $schema->resultset('Artist')->search( {}, {
  66     rows => 3,
  67     order_by => 'artistid',
  68   });
  69
  70   TODO: {
  71     local $TODO = 'Sybase is very very fucked in the limit department';
  72
  73     is( $it->count, 3, "LIMIT count ok" );
  74   }
  75
  76   is( $it->next->name, "foo", "iterator->next ok" );
  77   $it->next;
  78   is( $it->next->name, "Artist 2", "iterator->next ok" );
  79   is( $it->next, undef, "next past end of resultset ok" );
  80
  81   SKIP: {
  82     skip 'quoting bug with NoBindVars', 8
  83         if $storage_type eq 'DBI::Sybase::NoBindVars';
  84
  85 # Test DateTime inflation with DATETIME
  86     my @dt_types = (
  87       ['DATETIME', '2004-08-21T14:36:48.080Z'],
  88       ['SMALLDATETIME', '2004-08-21T14:36:00.000Z'], # minute precision
  89     );
  90
  91     for my $dt_type (@dt_types) {
  92       my ($type, $sample_dt) = @$dt_type;
  93
  94       eval { $schema->storage->dbh->do("DROP TABLE track") };
  95       $schema->storage->dbh->do(<<"SQL");
  96 CREATE TABLE track (
  97    trackid INT IDENTITY PRIMARY KEY,
  98    cd INT,
  99    position INT,
 100    last_updated_on $type,
 101 )
 102 SQL
 103       ok(my $dt = DBIx::Class::Storage::DBI::Sybase::DateTime
 104         ->parse_datetime($sample_dt));
 105
 106       my $row;
 107       ok( $row = $schema->resultset('Track')->create({
 108         last_updated_on => $dt,
 109         cd => 1,
 110       }));
 111       ok( $row = $schema->resultset('Track')
 112         ->search({ trackid => $row->trackid }, { select => ['last_updated_on'] })
 113         ->first
 114       );
 115       is( $row->updated_date, $dt, 'DateTime inflation works' );
 116     }
 117   }
 118 }
 119
 120 # clean up our mess
 121 END {
 122   if (my $dbh = eval { $schema->storage->_dbh }) {
 123     $dbh->do('DROP TABLE artist');
 124     $dbh->do('DROP TABLE track');
 125   }
 126 }