t/746sybase.t

   1 use strict;
   2 use warnings;
   3 no warnings 'uninitialized';
   4
   5 use Test::More;
   6 use Test::Exception;
   7 use lib qw(t/lib);
   8 use DBICTest;
   9 use DBIx::Class::Storage::DBI::Sybase;
  10 use DBIx::Class::Storage::DBI::Sybase::NoBindVars;
  11
  12 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_SYBASE_${_}" } qw/DSN USER PASS/};
  13
  14 my $TESTS = 52 + 2;
  15
  16 if (not ($dsn && $user)) {
  17   plan skip_all =>
  18     'Set $ENV{DBICTEST_SYBASE_DSN}, _USER and _PASS to run this test' .
  19     "\nWarning: This test drops and creates the tables " .
  20     "'artist', 'money_test' and 'bindtype_test'";
  21 } else {
  22   plan tests => $TESTS*2 + 1;
  23 }
  24
  25 my @storage_types = (
  26   'DBI::Sybase',
  27   'DBI::Sybase::NoBindVars',
  28 );
  29 my $schema;
  30 my $storage_idx = -1;
  31
  32 sub get_schema {
  33   DBICTest::Schema->connect($dsn, $user, $pass, {
  34     on_connect_call => [
  35       [ blob_setup => log_on_update => 1 ], # this is a safer option
  36     ],
  37   });
  38 }
  39
  40 my $ping_count = 0;
  41 {
  42   my $ping = DBIx::Class::Storage::DBI::Sybase->can('_ping');
  43   *DBIx::Class::Storage::DBI::Sybase::_ping = sub {
  44     $ping_count++;
  45     goto $ping;
  46   };
  47 }
  48
  49 for my $storage_type (@storage_types) {
  50   $storage_idx++;
  51
  52   unless ($storage_type eq 'DBI::Sybase') { # autodetect
  53     DBICTest::Schema->storage_type("::$storage_type");
  54   }
  55
  56   $schema = get_schema();
  57
  58   $schema->storage->ensure_connected;
  59
  60   if ($storage_idx == 0 &&
  61       $schema->storage->isa('DBIx::Class::Storage::DBI::Sybase::NoBindVars')) {
  62 # no placeholders in this version of Sybase or DBD::Sybase (or using FreeTDS)
  63       my $tb = Test::More->builder;
  64       $tb->skip('no placeholders') for 1..$TESTS;
  65       next;
  66   }
  67
  68   isa_ok( $schema->storage, "DBIx::Class::Storage::$storage_type" );
  69
  70   $schema->storage->_dbh->disconnect;
  71   lives_ok (sub { $schema->storage->dbh }, 'reconnect works');
  72
  73   $schema->storage->dbh_do (sub {
  74       my ($storage, $dbh) = @_;
  75       eval { $dbh->do("DROP TABLE artist") };
  76       $dbh->do(<<'SQL');
  77 CREATE TABLE artist (
  78    artistid INT IDENTITY PRIMARY KEY,
  79    name VARCHAR(100),
  80    rank INT DEFAULT 13 NOT NULL,
  81    charfield CHAR(10) NULL
  82 )
  83 SQL
  84   });
  85
  86   my %seen_id;
  87
  88 # so we start unconnected
  89   $schema->storage->disconnect;
  90
  91 # test primary key handling
  92   my $new = $schema->resultset('Artist')->create({ name => 'foo' });
  93   ok($new->artistid > 0, "Auto-PK worked");
  94
  95   $seen_id{$new->artistid}++;
  96
  97 # check redispatch to storage-specific insert when auto-detected storage
  98   if ($storage_type eq 'DBI::Sybase') {
  99     DBICTest::Schema->storage_type('::DBI');
 100     $schema = get_schema();
 101   }
 102
 103   $new = $schema->resultset('Artist')->create({ name => 'Artist 1' });
 104   is ( $seen_id{$new->artistid}, undef, 'id for Artist 1 is unique' );
 105   $seen_id{$new->artistid}++;
 106
 107 # inserts happen in a txn, so we make sure it still works inside a txn too
 108   $schema->txn_begin;
 109
 110   for (2..6) {
 111     $new = $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
 112     is ( $seen_id{$new->artistid}, undef, "id for Artist $_ is unique" );
 113     $seen_id{$new->artistid}++;
 114   }
 115
 116   $schema->txn_commit;
 117
 118 # test simple count
 119   is ($schema->resultset('Artist')->count, 7, 'count(*) of whole table ok');
 120
 121 # test LIMIT support
 122   my $it = $schema->resultset('Artist')->search({
 123     artistid => { '>' => 0 }
 124   }, {
 125     rows => 3,
 126     order_by => 'artistid',
 127   });
 128
 129   is( $it->count, 3, "LIMIT count ok" );
 130
 131   is( $it->next->name, "foo", "iterator->next ok" );
 132   $it->next;
 133   is( $it->next->name, "Artist 2", "iterator->next ok" );
 134   is( $it->next, undef, "next past end of resultset ok" );
 135
 136 # now try with offset
 137   $it = $schema->resultset('Artist')->search({}, {
 138     rows => 3,
 139     offset => 3,
 140     order_by => 'artistid',
 141   });
 142
 143   is( $it->count, 3, "LIMIT with offset count ok" );
 144
 145   is( $it->next->name, "Artist 3", "iterator->next ok" );
 146   $it->next;
 147   is( $it->next->name, "Artist 5", "iterator->next ok" );
 148   is( $it->next, undef, "next past end of resultset ok" );
 149
 150 # now try a grouped count
 151   $schema->resultset('Artist')->create({ name => 'Artist 6' })
 152     for (1..6);
 153
 154   $it = $schema->resultset('Artist')->search({}, {
 155     group_by => 'name'
 156   });
 157
 158   is( $it->count, 7, 'COUNT of GROUP_BY ok' );
 159
 160 # do an identity insert (which should happen with no txn when using
 161 # placeholders.)
 162   {
 163     no warnings 'redefine';
 164
 165     my @debug_out;
 166     local $schema->storage->{debug} = 1;
 167     local $schema->storage->debugobj->{callback} = sub {
 168       push @debug_out, $_[1];
 169     };
 170
 171     my $txn_used = 0;
 172     my $txn_commit = \&DBIx::Class::Storage::DBI::txn_commit;
 173     local *DBIx::Class::Storage::DBI::txn_commit = sub {
 174       $txn_used = 1;
 175       goto &$txn_commit;
 176     };
 177
 178     $schema->resultset('Artist')
 179       ->create({ artistid => 999, name => 'mtfnpy' });
 180
 181     ok((grep /IDENTITY_INSERT/i, @debug_out), 'IDENTITY_INSERT');
 182
 183     SKIP: {
 184       skip 'not testing lack of txn on IDENTITY_INSERT with NoBindVars', 1
 185         if $storage_type =~ /NoBindVars/i;
 186
 187       is $txn_used, 0, 'no txn on insert with IDENTITY_INSERT';
 188     }
 189   }
 190
 191 # test insert_bulk using populate.
 192   lives_ok {
 193     $schema->resultset('Artist')->populate([
 194       {
 195         name => 'bulk artist 1',
 196         charfield => 'foo',
 197       },
 198       {
 199         name => 'bulk artist 2',
 200         charfield => 'foo',
 201       },
 202       {
 203         name => 'bulk artist 3',
 204         charfield => 'foo',
 205       },
 206     ]);
 207   } 'insert_bulk via populate';
 208
 209   my $bulk_rs = $schema->resultset('Artist')->search({
 210     name => { -like => 'bulk artist %' }
 211   });
 212
 213   is $bulk_rs->count, 3, 'correct number inserted via insert_bulk';
 214
 215   is ((grep $_->charfield eq 'foo', $bulk_rs->all), 3,
 216     'column set correctly via insert_bulk');
 217
 218   my %bulk_ids;
 219   @bulk_ids{map $_->artistid, $bulk_rs->all} = ();
 220
 221   is ((scalar keys %bulk_ids), 3,
 222     'identities generated correctly in insert_bulk');
 223
 224   $bulk_rs->delete;
 225
 226 # make sure insert_bulk works a second time on the same connection
 227   lives_ok {
 228     $schema->resultset('Artist')->populate([
 229       {
 230         name => 'bulk artist 1',
 231         charfield => 'bar',
 232       },
 233       {
 234         name => 'bulk artist 2',
 235         charfield => 'bar',
 236       },
 237       {
 238         name => 'bulk artist 3',
 239         charfield => 'bar',
 240       },
 241     ]);
 242   } 'insert_bulk via populate called a second time';
 243
 244   is $bulk_rs->count, 3,
 245     'correct number inserted via insert_bulk';
 246
 247   is ((grep $_->charfield eq 'bar', $bulk_rs->all), 3,
 248     'column set correctly via insert_bulk');
 249
 250   $bulk_rs->delete;
 251
 252 # test invalid insert_bulk (missing required column)
 253 #
 254 # There should be a rollback, reconnect and the next valid insert_bulk should
 255 # succeed.
 256   throws_ok {
 257     $schema->resultset('Artist')->populate([
 258       {
 259         charfield => 'foo',
 260       }
 261     ]);
 262   } qr/no value or default|does not allow null/i,
 263 # The second pattern is the error from fallback to regular array insert on
 264 # incompatible charset.
 265   'insert_bulk with missing required column throws error';
 266
 267 # now test insert_bulk with IDENTITY_INSERT
 268   lives_ok {
 269     $schema->resultset('Artist')->populate([
 270       {
 271         artistid => 2001,
 272         name => 'bulk artist 1',
 273         charfield => 'foo',
 274       },
 275       {
 276         artistid => 2002,
 277         name => 'bulk artist 2',
 278         charfield => 'foo',
 279       },
 280       {
 281         artistid => 2003,
 282         name => 'bulk artist 3',
 283         charfield => 'foo',
 284       },
 285     ]);
 286   } 'insert_bulk with IDENTITY_INSERT via populate';
 287
 288   is $bulk_rs->count, 3,
 289     'correct number inserted via insert_bulk with IDENTITY_INSERT';
 290
 291   is ((grep $_->charfield eq 'foo', $bulk_rs->all), 3,
 292     'column set correctly via insert_bulk with IDENTITY_INSERT');
 293
 294   $bulk_rs->delete;
 295
 296 # test correlated subquery
 297   my $subq = $schema->resultset('Artist')->search({ artistid => { '>' => 3 } })
 298     ->get_column('artistid')
 299     ->as_query;
 300   my $subq_rs = $schema->resultset('Artist')->search({
 301     artistid => { -in => $subq }
 302   });
 303   is $subq_rs->count, 11, 'correlated subquery';
 304
 305 # mostly stolen from the blob stuff Nniuq wrote for t/73oracle.t
 306   SKIP: {
 307     skip 'TEXT/IMAGE support does not work with FreeTDS', 13
 308       if $schema->storage->using_freetds;
 309
 310     my $dbh = $schema->storage->_dbh;
 311     {
 312       local $SIG{__WARN__} = sub {};
 313       eval { $dbh->do('DROP TABLE bindtype_test') };
 314
 315       $dbh->do(qq[
 316         CREATE TABLE bindtype_test
 317         (
 318           id    INT   IDENTITY PRIMARY KEY,
 319           bytea INT   NULL,
 320           blob  IMAGE NULL,
 321           clob  TEXT  NULL
 322         )
 323       ],{ RaiseError => 1, PrintError => 0 });
 324     }
 325
 326     my %binstr = ( 'small' => join('', map { chr($_) } ( 1 .. 127 )) );
 327     $binstr{'large'} = $binstr{'small'} x 1024;
 328
 329     my $maxloblen = length $binstr{'large'};
 330
 331     if (not $schema->storage->using_freetds) {
 332       $dbh->{'LongReadLen'} = $maxloblen * 2;
 333     } else {
 334       $dbh->do("set textsize ".($maxloblen * 2));
 335     }
 336
 337     my $rs = $schema->resultset('BindType');
 338     my $last_id;
 339
 340     foreach my $type (qw(blob clob)) {
 341       foreach my $size (qw(small large)) {
 342         no warnings 'uninitialized';
 343
 344         my $created = eval { $rs->create( { $type => $binstr{$size} } ) };
 345         ok(!$@, "inserted $size $type without dying");
 346         diag $@ if $@;
 347
 348         $last_id = $created->id if $created;
 349
 350         my $got = eval {
 351           $rs->find($last_id)->$type
 352         };
 353         diag $@ if $@;
 354         ok($got eq $binstr{$size}, "verified inserted $size $type");
 355       }
 356     }
 357
 358     # blob insert with explicit PK
 359     # also a good opportunity to test IDENTITY_INSERT
 360     {
 361       local $SIG{__WARN__} = sub {};
 362       eval { $dbh->do('DROP TABLE bindtype_test') };
 363
 364       $dbh->do(qq[
 365         CREATE TABLE bindtype_test
 366         (
 367           id    INT   IDENTITY PRIMARY KEY,
 368           bytea INT   NULL,
 369           blob  IMAGE NULL,
 370           clob  TEXT  NULL
 371         )
 372       ],{ RaiseError => 1, PrintError => 0 });
 373     }
 374     my $created = eval { $rs->create( { id => 1, blob => $binstr{large} } ) };
 375     ok(!$@, "inserted large blob without dying with manual PK");
 376     diag $@ if $@;
 377
 378     my $got = eval {
 379       $rs->find(1)->blob
 380     };
 381     diag $@ if $@;
 382     ok($got eq $binstr{large}, "verified inserted large blob with manual PK");
 383
 384     # try a blob update
 385     my $new_str = $binstr{large} . 'mtfnpy';
 386
 387     # check redispatch to storage-specific update when auto-detected storage
 388     if ($storage_type eq 'DBI::Sybase') {
 389       DBICTest::Schema->storage_type('::DBI');
 390       $schema = get_schema();
 391     }
 392
 393     eval { $rs->search({ id => 1 })->update({ blob => $new_str }) };
 394     ok !$@, 'updated blob successfully';
 395     diag $@ if $@;
 396     $got = eval {
 397       $rs->find(1)->blob
 398     };
 399     diag $@ if $@;
 400     ok($got eq $new_str, "verified updated blob");
 401
 402     ## try multi-row blob update
 403     # first insert some blobs
 404     $rs->find(1)->delete;
 405     $rs->create({ blob => $binstr{large} }) for (1..3);
 406     $new_str = $binstr{large} . 'foo';
 407     $rs->update({ blob => $new_str });
 408     is((grep $_->blob eq $new_str, $rs->all), 3, 'multi-row blob update');
 409   }
 410
 411 # test MONEY column support
 412   $schema->storage->dbh_do (sub {
 413       my ($storage, $dbh) = @_;
 414       eval { $dbh->do("DROP TABLE money_test") };
 415       $dbh->do(<<'SQL');
 416 CREATE TABLE money_test (
 417    id INT IDENTITY PRIMARY KEY,
 418    amount MONEY NULL
 419 )
 420 SQL
 421   });
 422
 423 # test insert transaction when there's an active cursor
 424   SKIP: {
 425     skip 'not testing insert with active cursor if using ::NoBindVars', 1
 426       if $storage_type =~ /NoBindVars/i;
 427
 428     my $artist_rs = $schema->resultset('Artist');
 429     $artist_rs->first;
 430     lives_ok {
 431       my $row = $schema->resultset('Money')->create({ amount => 100 });
 432       $row->delete;
 433     } 'inserted a row with an active cursor';
 434     $ping_count-- if $@; # dbh_do calls ->connected
 435   }
 436
 437 # test insert in an outer transaction when there's an active cursor
 438   TODO: {
 439     local $TODO = 'this should work once we have eager cursors';
 440
 441 # clear state, or we get a deadlock on $row->delete
 442 # XXX figure out why this happens
 443     $schema->storage->disconnect;
 444
 445     lives_ok {
 446       $schema->txn_do(sub {
 447         my $artist_rs = $schema->resultset('Artist');
 448         $artist_rs->first;
 449         my $row = $schema->resultset('Money')->create({ amount => 100 });
 450         $row->delete;
 451       });
 452     } 'inserted a row with an active cursor in outer txn';
 453     $ping_count-- if $@; # dbh_do calls ->connected
 454   }
 455
 456 # Now test money values.
 457   my $rs = $schema->resultset('Money');
 458
 459   my $row;
 460   lives_ok {
 461     $row = $rs->create({ amount => 100 });
 462   } 'inserted a money value';
 463
 464   is eval { $rs->find($row->id)->amount }, 100, 'money value round-trip';
 465
 466   lives_ok {
 467     $row->update({ amount => 200 });
 468   } 'updated a money value';
 469
 470   is eval { $rs->find($row->id)->amount },
 471     200, 'updated money value round-trip';
 472
 473   lives_ok {
 474     $row->update({ amount => undef });
 475   } 'updated a money value to NULL';
 476
 477   my $null_amount = eval { $rs->find($row->id)->amount };
 478   ok(
 479     (($null_amount == undef) && (not $@)),
 480     'updated money value to NULL round-trip'
 481   );
 482   diag $@ if $@;
 483 }
 484
 485 is $ping_count, 0, 'no pings';
 486
 487 # clean up our mess
 488 END {
 489   if (my $dbh = eval { $schema->storage->_dbh }) {
 490     eval { $dbh->do("DROP TABLE $_") }
 491       for qw/artist bindtype_test money_test/;
 492   }
 493 }