t/746sybase.t

   1 use strict;
   2 use warnings;
   3 no warnings 'uninitialized';
   4
   5 use Test::More;
   6 use Test::Exception;
   7 use lib qw(t/lib);
   8 use DBICTest;
   9 use DBIx::Class::Storage::DBI::Sybase;
  10 use DBIx::Class::Storage::DBI::Sybase::NoBindVars;
  11
  12 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_SYBASE_${_}" } qw/DSN USER PASS/};
  13
  14 my $TESTS = 41 + 2;
  15
  16 if (not ($dsn && $user)) {
  17   plan skip_all =>
  18     'Set $ENV{DBICTEST_SYBASE_DSN}, _USER and _PASS to run this test' .
  19     "\nWarning: This test drops and creates the tables " .
  20     "'artist' and 'bindtype_test'";
  21 } else {
  22   plan tests => $TESTS*2 + 1;
  23 }
  24
  25 my @storage_types = (
  26   'DBI::Sybase',
  27   'DBI::Sybase::NoBindVars',
  28 );
  29 my $schema;
  30 my $storage_idx = -1;
  31
  32 sub get_schema {
  33   DBICTest::Schema->connect($dsn, $user, $pass, {
  34     on_connect_call => [
  35       [ blob_setup => log_on_update => 1 ], # this is a safer option
  36     ],
  37   });
  38 }
  39
  40 my $ping_count = 0;
  41 {
  42   my $ping = DBIx::Class::Storage::DBI::Sybase->can('_ping');
  43   *DBIx::Class::Storage::DBI::Sybase::_ping = sub {
  44     $ping_count++;
  45     goto $ping;
  46   };
  47 }
  48
  49 for my $storage_type (@storage_types) {
  50   $storage_idx++;
  51
  52   unless ($storage_type eq 'DBI::Sybase') { # autodetect
  53     DBICTest::Schema->storage_type("::$storage_type");
  54   }
  55
  56   $schema = get_schema();
  57
  58   $schema->storage->ensure_connected;
  59
  60   if ($storage_idx == 0 &&
  61       $schema->storage->isa('DBIx::Class::Storage::DBI::Sybase::NoBindVars')) {
  62 # no placeholders in this version of Sybase or DBD::Sybase (or using FreeTDS)
  63       my $tb = Test::More->builder;
  64       $tb->skip('no placeholders') for 1..$TESTS;
  65       next;
  66   }
  67
  68   isa_ok( $schema->storage, "DBIx::Class::Storage::$storage_type" );
  69
  70   $schema->storage->_dbh->disconnect;
  71   lives_ok (sub { $schema->storage->dbh }, 'reconnect works');
  72
  73   $schema->storage->dbh_do (sub {
  74       my ($storage, $dbh) = @_;
  75       eval { $dbh->do("DROP TABLE artist") };
  76       $dbh->do(<<'SQL');
  77 CREATE TABLE artist (
  78    artistid INT IDENTITY PRIMARY KEY,
  79    name VARCHAR(100),
  80    rank INT DEFAULT 13 NOT NULL,
  81    charfield CHAR(10) NULL
  82 )
  83 SQL
  84   });
  85
  86   my %seen_id;
  87
  88 # so we start unconnected
  89   $schema->storage->disconnect;
  90
  91 # test primary key handling
  92   my $new = $schema->resultset('Artist')->create({ name => 'foo' });
  93   ok($new->artistid > 0, "Auto-PK worked");
  94
  95   $seen_id{$new->artistid}++;
  96
  97 # check redispatch to storage-specific insert when auto-detected storage
  98   if ($storage_type eq 'DBI::Sybase') {
  99     DBICTest::Schema->storage_type('::DBI');
 100     $schema = get_schema();
 101   }
 102
 103   $new = $schema->resultset('Artist')->create({ name => 'Artist 1' });
 104   is ( $seen_id{$new->artistid}, undef, 'id for Artist 1 is unique' );
 105   $seen_id{$new->artistid}++;
 106
 107 # inserts happen in a txn, so we make sure it still works inside a txn too
 108   $schema->txn_begin;
 109
 110   for (2..6) {
 111     $new = $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
 112     is ( $seen_id{$new->artistid}, undef, "id for Artist $_ is unique" );
 113     $seen_id{$new->artistid}++;
 114   }
 115
 116   $schema->txn_commit;
 117
 118 # test simple count
 119   is ($schema->resultset('Artist')->count, 7, 'count(*) of whole table ok');
 120
 121 # test LIMIT support
 122   my $it = $schema->resultset('Artist')->search({
 123     artistid => { '>' => 0 }
 124   }, {
 125     rows => 3,
 126     order_by => 'artistid',
 127   });
 128
 129   is( $it->count, 3, "LIMIT count ok" );
 130
 131   is( $it->next->name, "foo", "iterator->next ok" );
 132   $it->next;
 133   is( $it->next->name, "Artist 2", "iterator->next ok" );
 134   is( $it->next, undef, "next past end of resultset ok" );
 135
 136 # now try with offset
 137   $it = $schema->resultset('Artist')->search({}, {
 138     rows => 3,
 139     offset => 3,
 140     order_by => 'artistid',
 141   });
 142
 143   is( $it->count, 3, "LIMIT with offset count ok" );
 144
 145   is( $it->next->name, "Artist 3", "iterator->next ok" );
 146   $it->next;
 147   is( $it->next->name, "Artist 5", "iterator->next ok" );
 148   is( $it->next, undef, "next past end of resultset ok" );
 149
 150 # now try a grouped count
 151   $schema->resultset('Artist')->create({ name => 'Artist 6' })
 152     for (1..6);
 153
 154   $it = $schema->resultset('Artist')->search({}, {
 155     group_by => 'name'
 156   });
 157
 158   is( $it->count, 7, 'COUNT of GROUP_BY ok' );
 159
 160 # do an identity insert (which should happen with no txn when using
 161 # placeholders.)
 162   {
 163     no warnings 'redefine';
 164
 165     my @debug_out;
 166     local $schema->storage->{debug} = 1;
 167     local $schema->storage->debugobj->{callback} = sub {
 168       push @debug_out, $_[1];
 169     };
 170
 171     my $txn_used = 0;
 172     my $txn_commit = \&DBIx::Class::Storage::DBI::txn_commit;
 173     local *DBIx::Class::Storage::DBI::txn_commit = sub {
 174       $txn_used = 1;
 175       goto &$txn_commit;
 176     };
 177
 178     $schema->resultset('Artist')
 179       ->create({ artistid => 999, name => 'mtfnpy' });
 180
 181     ok((grep /IDENTITY_INSERT/i, @debug_out), 'IDENTITY_INSERT');
 182
 183     SKIP: {
 184       skip 'not testing lack of txn on IDENTITY_INSERT with NoBindVars', 1
 185         if $storage_type =~ /NoBindVars/i;
 186
 187       is $txn_used, 0, 'no txn on insert with IDENTITY_INSERT';
 188     }
 189   }
 190
 191 # test correlated subquery
 192   my $subq = $schema->resultset('Artist')->search({ artistid => { '>' => 3 } })
 193     ->get_column('artistid')
 194     ->as_query;
 195   my $subq_rs = $schema->resultset('Artist')->search({
 196     artistid => { -in => $subq }
 197   });
 198   is $subq_rs->count, 11, 'correlated subquery';
 199
 200 # mostly stolen from the blob stuff Nniuq wrote for t/73oracle.t
 201   SKIP: {
 202     skip 'TEXT/IMAGE support does not work with FreeTDS', 13
 203       if $schema->storage->using_freetds;
 204
 205     my $dbh = $schema->storage->_dbh;
 206     {
 207       local $SIG{__WARN__} = sub {};
 208       eval { $dbh->do('DROP TABLE bindtype_test') };
 209
 210       $dbh->do(qq[
 211         CREATE TABLE bindtype_test
 212         (
 213           id    INT   IDENTITY PRIMARY KEY,
 214           bytea INT   NULL,
 215           blob  IMAGE NULL,
 216           clob  TEXT  NULL
 217         )
 218       ],{ RaiseError => 1, PrintError => 0 });
 219     }
 220
 221     my %binstr = ( 'small' => join('', map { chr($_) } ( 1 .. 127 )) );
 222     $binstr{'large'} = $binstr{'small'} x 1024;
 223
 224     my $maxloblen = length $binstr{'large'};
 225
 226     if (not $schema->storage->using_freetds) {
 227       $dbh->{'LongReadLen'} = $maxloblen * 2;
 228     } else {
 229       $dbh->do("set textsize ".($maxloblen * 2));
 230     }
 231
 232     my $rs = $schema->resultset('BindType');
 233     my $last_id;
 234
 235     foreach my $type (qw(blob clob)) {
 236       foreach my $size (qw(small large)) {
 237         no warnings 'uninitialized';
 238
 239         my $created = eval { $rs->create( { $type => $binstr{$size} } ) };
 240         ok(!$@, "inserted $size $type without dying");
 241         diag $@ if $@;
 242
 243         $last_id = $created->id if $created;
 244
 245         my $got = eval {
 246           $rs->find($last_id)->$type
 247         };
 248         diag $@ if $@;
 249         ok($got eq $binstr{$size}, "verified inserted $size $type");
 250       }
 251     }
 252
 253     # blob insert with explicit PK
 254     # also a good opportunity to test IDENTITY_INSERT
 255     {
 256       local $SIG{__WARN__} = sub {};
 257       eval { $dbh->do('DROP TABLE bindtype_test') };
 258
 259       $dbh->do(qq[
 260         CREATE TABLE bindtype_test
 261         (
 262           id    INT   IDENTITY PRIMARY KEY,
 263           bytea INT   NULL,
 264           blob  IMAGE NULL,
 265           clob  TEXT  NULL
 266         )
 267       ],{ RaiseError => 1, PrintError => 0 });
 268     }
 269     my $created = eval { $rs->create( { id => 1, blob => $binstr{large} } ) };
 270     ok(!$@, "inserted large blob without dying with manual PK");
 271     diag $@ if $@;
 272
 273     my $got = eval {
 274       $rs->find(1)->blob
 275     };
 276     diag $@ if $@;
 277     ok($got eq $binstr{large}, "verified inserted large blob with manual PK");
 278
 279     # try a blob update
 280     my $new_str = $binstr{large} . 'mtfnpy';
 281
 282     # check redispatch to storage-specific update when auto-detected storage
 283     if ($storage_type eq 'DBI::Sybase') {
 284       DBICTest::Schema->storage_type('::DBI');
 285       $schema = get_schema();
 286     }
 287
 288     eval { $rs->search({ id => 1 })->update({ blob => $new_str }) };
 289     ok !$@, 'updated blob successfully';
 290     diag $@ if $@;
 291     $got = eval {
 292       $rs->find(1)->blob
 293     };
 294     diag $@ if $@;
 295     ok($got eq $new_str, "verified updated blob");
 296
 297     ## try multi-row blob update
 298     # first insert some blobs
 299     $rs->find(1)->delete;
 300     $rs->create({ blob => $binstr{large} }) for (1..3);
 301     $new_str = $binstr{large} . 'foo';
 302     $rs->update({ blob => $new_str });
 303     is((grep $_->blob eq $new_str, $rs->all), 3, 'multi-row blob update');
 304   }
 305
 306 # test MONEY column support
 307   $schema->storage->dbh_do (sub {
 308       my ($storage, $dbh) = @_;
 309       eval { $dbh->do("DROP TABLE money_test") };
 310       $dbh->do(<<'SQL');
 311 CREATE TABLE money_test (
 312    id INT IDENTITY PRIMARY KEY,
 313    amount MONEY NULL
 314 )
 315 SQL
 316   });
 317
 318 # test insert transaction when there's an active cursor
 319   SKIP: {
 320     skip 'not testing insert with active cursor if using ::NoBindVars', 1
 321       if $storage_type =~ /NoBindVars/i;
 322
 323     my $artist_rs = $schema->resultset('Artist');
 324     $artist_rs->first;
 325     lives_ok {
 326       my $row = $schema->resultset('Money')->create({ amount => 100 });
 327       $row->delete;
 328     } 'inserted a row with an active cursor';
 329     $ping_count-- if $@; # dbh_do calls ->connected
 330   }
 331
 332 # test insert in an outer transaction when there's an active cursor
 333   TODO: {
 334     local $TODO = 'this should work once we have eager cursors';
 335
 336 # clear state, or we get a deadlock on $row->delete
 337 # XXX figure out why this happens
 338     $schema->storage->disconnect;
 339
 340     lives_ok {
 341       $schema->txn_do(sub {
 342         my $artist_rs = $schema->resultset('Artist');
 343         $artist_rs->first;
 344         my $row = $schema->resultset('Money')->create({ amount => 100 });
 345         $row->delete;
 346       });
 347     } 'inserted a row with an active cursor in outer txn';
 348     $ping_count-- if $@; # dbh_do calls ->connected
 349   }
 350
 351 # Now test money values.
 352   my $rs = $schema->resultset('Money');
 353
 354   my $row;
 355   lives_ok {
 356     $row = $rs->create({ amount => 100 });
 357   } 'inserted a money value';
 358
 359   is eval { $rs->find($row->id)->amount }, 100, 'money value round-trip';
 360
 361   lives_ok {
 362     $row->update({ amount => 200 });
 363   } 'updated a money value';
 364
 365   is eval { $rs->find($row->id)->amount },
 366     200, 'updated money value round-trip';
 367
 368   lives_ok {
 369     $row->update({ amount => undef });
 370   } 'updated a money value to NULL';
 371
 372   my $null_amount = eval { $rs->find($row->id)->amount };
 373   ok(
 374     (($null_amount == undef) && (not $@)),
 375     'updated money value to NULL round-trip'
 376   );
 377   diag $@ if $@;
 378 }
 379
 380 is $ping_count, 0, 'no pings';
 381
 382 # clean up our mess
 383 END {
 384   if (my $dbh = eval { $schema->storage->_dbh }) {
 385     eval { $dbh->do("DROP TABLE $_") }
 386       for qw/artist bindtype_test money_test/;
 387   }
 388 }