t/746sybase.t

   1 use strict;
   2 use warnings;
   3 no warnings 'uninitialized';
   4
   5 use Test::More;
   6 use Test::Exception;
   7 use lib qw(t/lib);
   8 use DBICTest;
   9
  10 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_SYBASE_${_}" } qw/DSN USER PASS/};
  11
  12 if (not ($dsn && $user)) {
  13   plan skip_all =>
  14     'Set $ENV{DBICTEST_SYBASE_DSN}, _USER and _PASS to run this test' .
  15     "\nWarning: This test drops and creates the tables " .
  16     "'artist' and 'bindtype_test'";
  17 } else {
  18   plan tests => (27 + 2)*2;
  19 }
  20
  21 my @storage_types = (
  22   'DBI::Sybase',
  23   'DBI::Sybase::NoBindVars',
  24 );
  25 my $schema;
  26
  27 for my $storage_type (@storage_types) {
  28   $schema = DBICTest::Schema->clone;
  29
  30   unless ($storage_type eq 'DBI::Sybase') { # autodetect
  31     $schema->storage_type("::$storage_type");
  32   }
  33   $schema->connection($dsn, $user, $pass, {
  34     AutoCommit => 1,
  35     on_connect_call => [
  36       [ blob_setup => log_on_update => 1 ], # this is a safer option
  37     ],
  38   });
  39
  40   $schema->storage->ensure_connected;
  41   $schema->storage->_dbh->disconnect;
  42
  43   isa_ok( $schema->storage, "DBIx::Class::Storage::$storage_type" );
  44
  45   lives_ok (sub { $schema->storage->dbh }, 'reconnect works');
  46
  47   $schema->storage->dbh_do (sub {
  48       my ($storage, $dbh) = @_;
  49       eval { $dbh->do("DROP TABLE artist") };
  50       $dbh->do(<<'SQL');
  51 CREATE TABLE artist (
  52    artistid INT IDENTITY PRIMARY KEY,
  53    name VARCHAR(100),
  54    rank INT DEFAULT 13 NOT NULL,
  55    charfield CHAR(10) NULL
  56 )
  57 SQL
  58   });
  59
  60   my %seen_id;
  61
  62 # so we start unconnected
  63   $schema->storage->disconnect;
  64
  65 # test primary key handling
  66   my $new = $schema->resultset('Artist')->create({ name => 'foo' });
  67   ok($new->artistid > 0, "Auto-PK worked");
  68
  69   $seen_id{$new->artistid}++;
  70
  71   for (1..6) {
  72     $new = $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
  73     is ( $seen_id{$new->artistid}, undef, "id for Artist $_ is unique" );
  74     $seen_id{$new->artistid}++;
  75   }
  76
  77 # test simple count
  78   is ($schema->resultset('Artist')->count, 7, 'count(*) of whole table ok');
  79
  80 # test LIMIT support
  81   my $it = $schema->resultset('Artist')->search({
  82     artistid => { '>' => 0 }
  83   }, {
  84     rows => 3,
  85     order_by => 'artistid',
  86   });
  87
  88   is( $it->count, 3, "LIMIT count ok" );
  89
  90   is( $it->next->name, "foo", "iterator->next ok" );
  91   $it->next;
  92   is( $it->next->name, "Artist 2", "iterator->next ok" );
  93   is( $it->next, undef, "next past end of resultset ok" );
  94
  95 # now try with offset
  96   $it = $schema->resultset('Artist')->search({}, {
  97     rows => 3,
  98     offset => 3,
  99     order_by => 'artistid',
 100   });
 101
 102   is( $it->count, 3, "LIMIT with offset count ok" );
 103
 104   is( $it->next->name, "Artist 3", "iterator->next ok" );
 105   $it->next;
 106   is( $it->next->name, "Artist 5", "iterator->next ok" );
 107   is( $it->next, undef, "next past end of resultset ok" );
 108
 109 # now try a grouped count
 110   $schema->resultset('Artist')->create({ name => 'Artist 6' })
 111     for (1..6);
 112
 113   $it = $schema->resultset('Artist')->search({}, {
 114     group_by => 'name'
 115   });
 116
 117   is( $it->count, 7, 'COUNT of GROUP_BY ok' );
 118
 119 # mostly stole the blob stuff Nniuq wrote for t/73oracle.t
 120   my $dbh = $schema->storage->dbh;
 121   {
 122     local $SIG{__WARN__} = sub {};
 123     eval { $dbh->do('DROP TABLE bindtype_test') };
 124
 125     $dbh->do(qq[
 126       CREATE TABLE bindtype_test
 127       (
 128         id    INT   PRIMARY KEY,
 129         bytea INT   NULL,
 130         blob  IMAGE NULL,
 131         clob  TEXT  NULL
 132       )
 133     ],{ RaiseError => 1, PrintError => 1 });
 134   }
 135
 136   my %binstr = ( 'small' => join('', map { chr($_) } ( 1 .. 127 )) );
 137   $binstr{'large'} = $binstr{'small'} x 1024;
 138
 139   my $maxloblen = length $binstr{'large'};
 140   note "Localizing LongReadLen to $maxloblen to avoid truncation of test data";
 141   local $dbh->{'LongReadLen'} = $maxloblen;
 142
 143   my $rs = $schema->resultset('BindType');
 144   my $id = 0;
 145
 146   foreach my $type (qw(blob clob)) {
 147     foreach my $size (qw(small large)) {
 148       no warnings 'uninitialized';
 149       $id++;
 150
 151       eval { $rs->create( { 'id' => $id, $type => $binstr{$size} } ) };
 152       ok(!$@, "inserted $size $type without dying");
 153       diag $@ if $@;
 154
 155       my $got = eval {
 156         $rs->search({ id=> $id }, { select => [$type] })->single->$type
 157       };
 158       diag $@ if $@;
 159       ok($got eq $binstr{$size}, "verified inserted $size $type");
 160     }
 161   }
 162
 163   # try a blob update
 164   TODO: {
 165     local $TODO = 'updating TEXT/IMAGE does not work yet';
 166
 167     my $new_str = $binstr{large} . 'foo';
 168     eval { $rs->search({ id => $id })->update({ blob => $new_str }) };
 169     ok !$@, 'updated blob successfully';
 170     diag $@ if $@;
 171     ok(eval {
 172       $rs->search({ id=> $id }, { select => ['blob'] })->single->blob
 173     } eq $new_str, "verified updated blob" );
 174     diag $@ if $@;
 175   }
 176 }
 177
 178 # clean up our mess
 179 END {
 180   if (my $dbh = eval { $schema->storage->_dbh }) {
 181     $dbh->do('DROP TABLE artist');
 182     $dbh->do('DROP TABLE bindtype_test');
 183   }
 184 }