t/746sybase.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use lib qw(t/lib);
   6 use DBICTest;
   7 use DBIx::Class::Storage::DBI::Sybase::DateTime;
   8
   9 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_SYBASE_${_}" } qw/DSN USER PASS/};
  10
  11 plan skip_all => 'Set $ENV{DBICTEST_SYBASE_DSN}, _USER and _PASS to run this test'
  12   unless ($dsn && $user);
  13
  14 plan tests => (17 + 4*2)*2;
  15
  16 my @storage_types = (
  17   'DBI::Sybase',
  18   'DBI::Sybase::NoBindVars',
  19 );
  20 my $schema;
  21
  22 for my $storage_type (@storage_types) {
  23   $schema = DBICTest::Schema->clone;
  24
  25   unless ($storage_type eq 'DBI::Sybase') { # autodetect
  26     $schema->storage_type("::$storage_type");
  27   }
  28   $schema->connection($dsn, $user, $pass, {AutoCommit => 1});
  29
  30   $schema->storage->ensure_connected;
  31
  32   isa_ok( $schema->storage, "DBIx::Class::Storage::$storage_type" );
  33
  34   $schema->storage->dbh_do (sub {
  35       my ($storage, $dbh) = @_;
  36       eval { $dbh->do("DROP TABLE artist") };
  37       $dbh->do(<<'SQL');
  38 CREATE TABLE artist (
  39    artistid INT IDENTITY PRIMARY KEY,
  40    name VARCHAR(100),
  41    rank INT DEFAULT 13 NOT NULL,
  42    charfield CHAR(10) NULL
  43 )
  44 SQL
  45   });
  46
  47   my %seen_id;
  48
  49 # so we start unconnected
  50   $schema->storage->disconnect;
  51
  52 # test primary key handling
  53   my $new = $schema->resultset('Artist')->create({ name => 'foo' });
  54   ok($new->artistid > 0, "Auto-PK worked");
  55
  56   $seen_id{$new->artistid}++;
  57
  58   for (1..6) {
  59     $new = $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
  60     is ( $seen_id{$new->artistid}, undef, "id for Artist $_ is unique" );
  61     $seen_id{$new->artistid}++;
  62   }
  63
  64 # test simple count
  65   is ($schema->resultset('Artist')->count, 7, 'count(*) of whole table ok');
  66
  67 # test LIMIT support
  68
  69 ## avoid quoting bug with NoBindVars for now
  70 #  my $it = $schema->resultset('Artist')->search({artistid => { '>' => 0 }}, {
  71
  72   my $it = $schema->resultset('Artist')->search({}, {
  73     rows => 3,
  74     order_by => 'artistid',
  75   });
  76
  77   is( $it->count, 3, "LIMIT count ok" );
  78
  79   is( $it->next->name, "foo", "iterator->next ok" );
  80   $it->next;
  81   is( $it->next->name, "Artist 2", "iterator->next ok" );
  82   is( $it->next, undef, "next past end of resultset ok" );
  83
  84 # now try with offset
  85   $it = $schema->resultset('Artist')->search({}, {
  86     rows => 3,
  87     offset => 3,
  88     order_by => 'artistid',
  89   });
  90
  91   is( $it->count, 3, "LIMIT with offset count ok" );
  92
  93   is( $it->next->name, "Artist 3", "iterator->next ok" );
  94   $it->next;
  95   is( $it->next->name, "Artist 5", "iterator->next ok" );
  96   is( $it->next, undef, "next past end of resultset ok" );
  97
  98   SKIP: {
  99     skip 'quoting bug with NoBindVars', 4*2
 100         if $storage_type eq 'DBI::Sybase::NoBindVars';
 101
 102 # Test DateTime inflation with DATETIME
 103     my @dt_types = (
 104       ['DATETIME', '2004-08-21T14:36:48.080Z'],
 105       ['SMALLDATETIME', '2004-08-21T14:36:00.000Z'], # minute precision
 106     );
 107
 108     for my $dt_type (@dt_types) {
 109       my ($type, $sample_dt) = @$dt_type;
 110
 111       eval { $schema->storage->dbh->do("DROP TABLE track") };
 112       $schema->storage->dbh->do(<<"SQL");
 113 CREATE TABLE track (
 114    trackid INT IDENTITY PRIMARY KEY,
 115    cd INT,
 116    position INT,
 117    last_updated_on $type,
 118 )
 119 SQL
 120       ok(my $dt = DBIx::Class::Storage::DBI::Sybase::DateTime
 121         ->parse_datetime($sample_dt));
 122
 123       my $row;
 124       ok( $row = $schema->resultset('Track')->create({
 125         last_updated_on => $dt,
 126         cd => 1,
 127       }));
 128       ok( $row = $schema->resultset('Track')
 129         ->search({ trackid => $row->trackid }, { select => ['last_updated_on'] })
 130         ->first
 131       );
 132       is( $row->updated_date, $dt, 'DateTime inflation works' );
 133     }
 134   }
 135 }
 136
 137 # clean up our mess
 138 END {
 139   if (my $dbh = eval { $schema->storage->_dbh }) {
 140     $dbh->do('DROP TABLE artist');
 141     $dbh->do('DROP TABLE track');
 142   }
 143 }