t/746sybase.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use lib qw(t/lib);
   6 use DBICTest;
   7 use DBIx::Class::Storage::DBI::Sybase::DateTime;
   8
   9 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_SYBASE_${_}" } qw/DSN USER PASS/};
  10
  11 plan skip_all => 'Set $ENV{DBICTEST_SYBASE_DSN}, _USER and _PASS to run this test'
  12   unless ($dsn && $user);
  13
  14 plan tests => 16*2;
  15
  16 my @storage_types = (
  17   'DBI::Sybase',
  18   'DBI::Sybase::NoBindVars',
  19 );
  20 my $schema;
  21
  22 for my $storage_type (@storage_types) {
  23   $schema = DBICTest::Schema->clone;
  24
  25   unless ($storage_type eq 'DBI::Sybase') { # autodetect
  26     $schema->storage_type("::$storage_type");
  27   }
  28   $schema->connection($dsn, $user, $pass, {AutoCommit => 1});
  29
  30   $schema->storage->ensure_connected;
  31
  32   isa_ok( $schema->storage, "DBIx::Class::Storage::$storage_type" );
  33
  34   $schema->storage->dbh_do (sub {
  35       my ($storage, $dbh) = @_;
  36       eval { $dbh->do("DROP TABLE artist") };
  37       eval { $dbh->do("DROP TABLE track") };
  38       $dbh->do(<<'SQL');
  39 CREATE TABLE artist (
  40    artistid INT IDENTITY PRIMARY KEY,
  41    name VARCHAR(100),
  42    rank INT DEFAULT 13 NOT NULL,
  43    charfield CHAR(10) NULL
  44 )
  45 SQL
  46
  47 # we only need the DT
  48       $dbh->do(<<'SQL');
  49 CREATE TABLE track (
  50    trackid INT IDENTITY PRIMARY KEY,
  51    cd INT,
  52    position INT,
  53    last_updated_on DATETIME,
  54 )
  55 SQL
  56   });
  57
  58   my %seen_id;
  59
  60 # so we start unconnected
  61   $schema->storage->disconnect;
  62
  63 # test primary key handling
  64   my $new = $schema->resultset('Artist')->create({ name => 'foo' });
  65   ok($new->artistid > 0, "Auto-PK worked");
  66
  67   $seen_id{$new->artistid}++;
  68
  69 # test LIMIT support
  70   for (1..6) {
  71     $new = $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
  72     is ( $seen_id{$new->artistid}, undef, "id for Artist $_ is unique" );
  73     $seen_id{$new->artistid}++;
  74   }
  75
  76   my $it = $schema->resultset('Artist')->search( {}, {
  77     rows => 3,
  78     order_by => 'artistid',
  79   });
  80
  81   TODO: {
  82     local $TODO = 'Sybase is very very fucked in the limit department';
  83
  84     is( $it->count, 3, "LIMIT count ok" );
  85   }
  86
  87   is( $it->next->name, "foo", "iterator->next ok" );
  88   $it->next;
  89   is( $it->next->name, "Artist 2", "iterator->next ok" );
  90   is( $it->next, undef, "next past end of resultset ok" );
  91
  92   SKIP: {
  93     skip 'quoting bug with NoBindVars', 4
  94         if $storage_type eq 'DBI::Sybase::NoBindVars';
  95
  96 # Test DateTime inflation
  97     ok(my $dt = DBIx::Class::Storage::DBI::Sybase::DateTime
  98       ->parse_datetime('2004-08-21T14:36:48.080Z'));
  99
 100     my $row;
 101     ok( $row = $schema->resultset('Track')->create({
 102       last_updated_on => $dt,
 103       cd => 1,
 104     }));
 105     ok( $row = $schema->resultset('Track')
 106       ->search({ trackid => $row->trackid }, { select => ['last_updated_on'] })
 107       ->first
 108     );
 109     is( $row->updated_date, $dt, 'DateTime inflation works' );
 110   }
 111 }
 112
 113 # clean up our mess
 114 END {
 115   if (my $dbh = eval { $schema->storage->_dbh }) {
 116     $dbh->do('DROP TABLE artist');
 117     $dbh->do('DROP TABLE track');
 118   }
 119 }