t/746sybase.t

   1 use strict;
   2 use warnings;
   3 no warnings 'uninitialized';
   4
   5 use Test::More;
   6 use Test::Exception;
   7 use lib qw(t/lib);
   8 use DBICTest;
   9
  10 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_SYBASE_${_}" } qw/DSN USER PASS/};
  11
  12 my $TESTS = 29 + 2;
  13
  14 if (not ($dsn && $user)) {
  15   plan skip_all =>
  16     'Set $ENV{DBICTEST_SYBASE_DSN}, _USER and _PASS to run this test' .
  17     "\nWarning: This test drops and creates the tables " .
  18     "'artist' and 'bindtype_test'";
  19 } else {
  20   plan tests => $TESTS*2;
  21 }
  22
  23 my @storage_types = (
  24   'DBI::Sybase',
  25   'DBI::Sybase::NoBindVars',
  26 );
  27 my $schema;
  28 my $storage_idx = -1;
  29
  30 for my $storage_type (@storage_types) {
  31   $storage_idx++;
  32 # this is so we can set ->storage_type before connecting
  33   my $schema = DBICTest::Schema->clone;
  34
  35   unless ($storage_type eq 'DBI::Sybase') { # autodetect
  36     $schema->storage_type("::$storage_type");
  37   }
  38
  39   $schema->connection($dsn, $user, $pass, {
  40     AutoCommit => 1,
  41     on_connect_call => [
  42       [ blob_setup => log_on_update => 1 ], # this is a safer option
  43     ],
  44   });
  45
  46   $schema->storage->ensure_connected;
  47
  48   if ($storage_idx == 0 &&
  49       $schema->storage->isa('DBIx::Class::Storage::DBI::Sybase::NoBindVars')) {
  50 # no placeholders in this version of Sybase or DBD::Sybase (or using FreeTDS)
  51       my $tb = Test::More->builder;
  52       $tb->skip('no placeholders') for 1..$TESTS;
  53       next;
  54   }
  55
  56   isa_ok( $schema->storage, "DBIx::Class::Storage::$storage_type" );
  57
  58   $schema->storage->_dbh->disconnect;
  59   lives_ok (sub { $schema->storage->dbh }, 'reconnect works');
  60
  61   $schema->storage->dbh_do (sub {
  62       my ($storage, $dbh) = @_;
  63       eval { $dbh->do("DROP TABLE artist") };
  64       $dbh->do(<<'SQL');
  65 CREATE TABLE artist (
  66    artistid INT IDENTITY PRIMARY KEY,
  67    name VARCHAR(100),
  68    rank INT DEFAULT 13 NOT NULL,
  69    charfield CHAR(10) NULL
  70 )
  71 SQL
  72   });
  73
  74   my %seen_id;
  75
  76 # so we start unconnected
  77   $schema->storage->disconnect;
  78
  79 # test primary key handling
  80   my $new = $schema->resultset('Artist')->create({ name => 'foo' });
  81   ok($new->artistid > 0, "Auto-PK worked");
  82
  83   $seen_id{$new->artistid}++;
  84
  85   for (1..6) {
  86     $new = $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
  87     is ( $seen_id{$new->artistid}, undef, "id for Artist $_ is unique" );
  88     $seen_id{$new->artistid}++;
  89   }
  90
  91 # test simple count
  92   is ($schema->resultset('Artist')->count, 7, 'count(*) of whole table ok');
  93
  94 # test LIMIT support
  95   my $it = $schema->resultset('Artist')->search({
  96     artistid => { '>' => 0 }
  97   }, {
  98     rows => 3,
  99     order_by => 'artistid',
 100   });
 101
 102   is( $it->count, 3, "LIMIT count ok" );
 103
 104   is( $it->next->name, "foo", "iterator->next ok" );
 105   $it->next;
 106   is( $it->next->name, "Artist 2", "iterator->next ok" );
 107   is( $it->next, undef, "next past end of resultset ok" );
 108
 109 # now try with offset
 110   $it = $schema->resultset('Artist')->search({}, {
 111     rows => 3,
 112     offset => 3,
 113     order_by => 'artistid',
 114   });
 115
 116   is( $it->count, 3, "LIMIT with offset count ok" );
 117
 118   is( $it->next->name, "Artist 3", "iterator->next ok" );
 119   $it->next;
 120   is( $it->next->name, "Artist 5", "iterator->next ok" );
 121   is( $it->next, undef, "next past end of resultset ok" );
 122
 123 # now try a grouped count
 124   $schema->resultset('Artist')->create({ name => 'Artist 6' })
 125     for (1..6);
 126
 127   $it = $schema->resultset('Artist')->search({}, {
 128     group_by => 'name'
 129   });
 130
 131   is( $it->count, 7, 'COUNT of GROUP_BY ok' );
 132
 133 # mostly stolen from the blob stuff Nniuq wrote for t/73oracle.t
 134   SKIP: {
 135     skip 'TEXT/IMAGE support does not work with FreeTDS', 12
 136       if $schema->storage->_using_freetds;
 137
 138     my $dbh = $schema->storage->dbh;
 139     {
 140       local $SIG{__WARN__} = sub {};
 141       eval { $dbh->do('DROP TABLE bindtype_test') };
 142
 143       $dbh->do(qq[
 144         CREATE TABLE bindtype_test
 145         (
 146           id    INT   IDENTITY PRIMARY KEY,
 147           bytea INT   NULL,
 148           blob  IMAGE NULL,
 149           clob  TEXT  NULL
 150         )
 151       ],{ RaiseError => 1, PrintError => 0 });
 152     }
 153
 154     my %binstr = ( 'small' => join('', map { chr($_) } ( 1 .. 127 )) );
 155     $binstr{'large'} = $binstr{'small'} x 1024;
 156
 157     my $maxloblen = length $binstr{'large'};
 158     note
 159       "Localizing LongReadLen to $maxloblen to avoid truncation of test data";
 160     local $dbh->{'LongReadLen'} = $maxloblen * 2;
 161
 162     my $rs = $schema->resultset('BindType');
 163     my $last_id;
 164
 165     foreach my $type (qw(blob clob)) {
 166       foreach my $size (qw(small large)) {
 167         no warnings 'uninitialized';
 168
 169         my $created = eval { $rs->create( { $type => $binstr{$size} } ) };
 170         ok(!$@, "inserted $size $type without dying");
 171         diag $@ if $@;
 172
 173         $last_id = $created->id if $created;
 174
 175         my $got = eval {
 176           $rs->find($last_id)->$type
 177         };
 178         diag $@ if $@;
 179         ok($got eq $binstr{$size}, "verified inserted $size $type");
 180       }
 181     }
 182
 183     # blob insert with explicit PK
 184     # also a good opportunity to test IDENTITY_INSERT
 185     {
 186       local $SIG{__WARN__} = sub {};
 187       eval { $dbh->do('DROP TABLE bindtype_test') };
 188
 189       $dbh->do(qq[
 190         CREATE TABLE bindtype_test
 191         (
 192           id    INT   IDENTITY PRIMARY KEY,
 193           bytea INT   NULL,
 194           blob  IMAGE NULL,
 195           clob  TEXT  NULL
 196         )
 197       ],{ RaiseError => 1, PrintError => 0 });
 198     }
 199     my $created = eval { $rs->create( { id => 1, blob => $binstr{large} } ) };
 200     ok(!$@, "inserted large blob without dying with manual PK");
 201     diag $@ if $@;
 202
 203     my $got = eval {
 204       $rs->find(1)->blob
 205     };
 206     diag $@ if $@;
 207     ok($got eq $binstr{large}, "verified inserted large blob with manual PK");
 208
 209     # try a blob update
 210     my $new_str = $binstr{large} . 'mtfnpy';
 211     eval { $rs->search({ id => 1 })->update({ blob => $new_str }) };
 212     ok !$@, 'updated blob successfully';
 213     diag $@ if $@;
 214     $got = eval {
 215       $rs->find(1)->blob
 216     };
 217     diag $@ if $@;
 218     ok($got eq $new_str, "verified updated blob");
 219   }
 220 }
 221
 222 # clean up our mess
 223 END {
 224   if (my $dbh = eval { $schema->storage->_dbh }) {
 225     $dbh->do('DROP TABLE artist');
 226     eval { $dbh->do('DROP TABLE bindtype_test')    };
 227   }
 228 }