t/746sybase.t

   1 use strict;
   2 use warnings;
   3 no warnings 'uninitialized';
   4
   5 use Test::More;
   6 use Test::Exception;
   7 use DBIx::Class::Optional::Dependencies ();
   8 use lib qw(t/lib);
   9 use DBICTest;
  10
  11 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_SYBASE_${_}" } qw/DSN USER PASS/};
  12 if (not ($dsn && $user)) {
  13   plan skip_all => join ' ',
  14     'Set $ENV{DBICTEST_SYBASE_DSN}, _USER and _PASS to run this test.',
  15     'Warning: This test drops and creates the tables:',
  16     "'artist', 'money_test' and 'bindtype_test'",
  17   ;
  18 };
  19
  20 plan skip_all => 'Test needs ' . DBIx::Class::Optional::Dependencies->req_missing_for ('test_rdbms_ase')
  21   unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_rdbms_ase');
  22
  23 my @storage_types = (
  24   'DBI::Sybase::ASE',
  25   'DBI::Sybase::ASE::NoBindVars',
  26 );
  27 eval "require DBIx::Class::Storage::$_;" for @storage_types;
  28
  29 my $schema;
  30 my $storage_idx = -1;
  31
  32 sub get_schema {
  33   DBICTest::Schema->connect($dsn, $user, $pass, {
  34     on_connect_call => [
  35       [ blob_setup => log_on_update => 1 ], # this is a safer option
  36     ],
  37   });
  38 }
  39
  40 my $ping_count = 0;
  41 {
  42   my $ping = DBIx::Class::Storage::DBI::Sybase::ASE->can('_ping');
  43   *DBIx::Class::Storage::DBI::Sybase::ASE::_ping = sub {
  44     $ping_count++;
  45     goto $ping;
  46   };
  47 }
  48
  49 for my $storage_type (@storage_types) {
  50   $storage_idx++;
  51
  52   unless ($storage_type eq 'DBI::Sybase::ASE') { # autodetect
  53     DBICTest::Schema->storage_type("::$storage_type");
  54   }
  55
  56   $schema = get_schema();
  57
  58   $schema->storage->ensure_connected;
  59
  60   if ($storage_idx == 0 &&
  61       $schema->storage->isa('DBIx::Class::Storage::DBI::Sybase::ASE::NoBindVars')) {
  62       # no placeholders in this version of Sybase or DBD::Sybase (or using FreeTDS)
  63       skip "Skipping entire test for $storage_type - no placeholder support", 1;
  64       next;
  65   }
  66
  67   isa_ok( $schema->storage, "DBIx::Class::Storage::$storage_type" );
  68
  69   $schema->storage->_dbh->disconnect;
  70   lives_ok (sub { $schema->storage->dbh }, 'reconnect works');
  71
  72   $schema->storage->dbh_do (sub {
  73       my ($storage, $dbh) = @_;
  74       eval { $dbh->do("DROP TABLE artist") };
  75       $dbh->do(<<'SQL');
  76 CREATE TABLE artist (
  77    artistid INT IDENTITY PRIMARY KEY,
  78    name VARCHAR(100),
  79    rank INT DEFAULT 13 NOT NULL,
  80    charfield CHAR(10) NULL
  81 )
  82 SQL
  83   });
  84
  85   my %seen_id;
  86
  87 # so we start unconnected
  88   $schema->storage->disconnect;
  89
  90 # test primary key handling
  91   my $new = $schema->resultset('Artist')->create({ name => 'foo' });
  92   like $new->artistid, qr/^\d+\z/, 'Auto-PK returned a number';
  93   ok($new->artistid > 0, "Auto-PK worked");
  94
  95   $seen_id{$new->artistid}++;
  96
  97 # check redispatch to storage-specific insert when auto-detected storage
  98   if ($storage_type eq 'DBI::Sybase::ASE') {
  99     DBICTest::Schema->storage_type('::DBI');
 100     $schema = get_schema();
 101   }
 102
 103   $new = $schema->resultset('Artist')->create({ name => 'Artist 1' });
 104   is ( $seen_id{$new->artistid}, undef, 'id for Artist 1 is unique' );
 105   $seen_id{$new->artistid}++;
 106
 107 # inserts happen in a txn, so we make sure it still works inside a txn too
 108   $schema->txn_begin;
 109
 110   for (2..6) {
 111     $new = $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
 112     is ( $seen_id{$new->artistid}, undef, "id for Artist $_ is unique" );
 113     $seen_id{$new->artistid}++;
 114   }
 115
 116   $schema->txn_commit;
 117
 118 # test simple count
 119   is ($schema->resultset('Artist')->count, 7, 'count(*) of whole table ok');
 120
 121 # test LIMIT support
 122   my $it = $schema->resultset('Artist')->search({
 123     artistid => { '>' => 0 }
 124   }, {
 125     rows => 3,
 126     order_by => 'artistid',
 127   });
 128
 129   is( $it->count, 3, "LIMIT count ok" );
 130
 131   is( $it->next->name, "foo", "iterator->next ok" );
 132   $it->next;
 133   is( $it->next->name, "Artist 2", "iterator->next ok" );
 134   is( $it->next, undef, "next past end of resultset ok" );
 135
 136 # now try with offset
 137   $it = $schema->resultset('Artist')->search({}, {
 138     rows => 3,
 139     offset => 3,
 140     order_by => 'artistid',
 141   });
 142
 143   is( $it->count, 3, "LIMIT with offset count ok" );
 144
 145   is( $it->next->name, "Artist 3", "iterator->next ok" );
 146   $it->next;
 147   is( $it->next->name, "Artist 5", "iterator->next ok" );
 148   is( $it->next, undef, "next past end of resultset ok" );
 149
 150 # now try a grouped count
 151   $schema->resultset('Artist')->create({ name => 'Artist 6' })
 152     for (1..6);
 153
 154   $it = $schema->resultset('Artist')->search({}, {
 155     group_by => 'name'
 156   });
 157
 158   is( $it->count, 7, 'COUNT of GROUP_BY ok' );
 159
 160 # do an IDENTITY_INSERT
 161   {
 162     no warnings 'redefine';
 163
 164     my @debug_out;
 165     local $schema->storage->{debug} = 1;
 166     local $schema->storage->debugobj->{callback} = sub {
 167       push @debug_out, $_[1];
 168     };
 169
 170     my $txn_used = 0;
 171     my $txn_commit = \&DBIx::Class::Storage::DBI::txn_commit;
 172     local *DBIx::Class::Storage::DBI::txn_commit = sub {
 173       $txn_used = 1;
 174       goto &$txn_commit;
 175     };
 176
 177     $schema->resultset('Artist')
 178       ->create({ artistid => 999, name => 'mtfnpy' });
 179
 180     ok((grep /IDENTITY_INSERT/i, @debug_out), 'IDENTITY_INSERT used');
 181
 182     SKIP: {
 183       skip 'not testing lack of txn on IDENTITY_INSERT with NoBindVars', 1
 184         if $storage_type =~ /NoBindVars/i;
 185
 186       is $txn_used, 0, 'no txn on insert with IDENTITY_INSERT';
 187     }
 188   }
 189
 190 # do an IDENTITY_UPDATE
 191   {
 192     my @debug_out;
 193     local $schema->storage->{debug} = 1;
 194     local $schema->storage->debugobj->{callback} = sub {
 195       push @debug_out, $_[1];
 196     };
 197
 198     lives_and {
 199       $schema->resultset('Artist')
 200         ->find(999)->update({ artistid => 555 });
 201       ok((grep /IDENTITY_UPDATE/i, @debug_out));
 202     } 'IDENTITY_UPDATE used';
 203     $ping_count-- if $@;
 204   }
 205
 206   my $bulk_rs = $schema->resultset('Artist')->search({
 207     name => { -like => 'bulk artist %' }
 208   });
 209
 210 # test _insert_bulk using populate.
 211   SKIP: {
 212     skip '_insert_bulk not supported', 4
 213       unless $storage_type !~ /NoBindVars/i;
 214
 215     lives_ok {
 216       $schema->resultset('Artist')->populate([
 217         {
 218           name => 'bulk artist 1',
 219           charfield => 'foo',
 220         },
 221         {
 222           name => 'bulk artist 2',
 223           charfield => 'foo',
 224         },
 225         {
 226           name => 'bulk artist 3',
 227           charfield => 'foo',
 228         },
 229       ]);
 230     } '_insert_bulk via populate';
 231
 232     is $bulk_rs->count, 3, 'correct number inserted via _insert_bulk';
 233
 234     is ((grep $_->charfield eq 'foo', $bulk_rs->all), 3,
 235       'column set correctly via _insert_bulk');
 236
 237     my %bulk_ids;
 238     @bulk_ids{map $_->artistid, $bulk_rs->all} = ();
 239
 240     is ((scalar keys %bulk_ids), 3,
 241       'identities generated correctly in _insert_bulk');
 242
 243     $bulk_rs->delete;
 244   }
 245
 246 # make sure _insert_bulk works a second time on the same connection
 247   SKIP: {
 248     skip '_insert_bulk not supported', 3
 249       unless $storage_type !~ /NoBindVars/i;
 250
 251     lives_ok {
 252       $schema->resultset('Artist')->populate([
 253         {
 254           name => 'bulk artist 1',
 255           charfield => 'bar',
 256         },
 257         {
 258           name => 'bulk artist 2',
 259           charfield => 'bar',
 260         },
 261         {
 262           name => 'bulk artist 3',
 263           charfield => 'bar',
 264         },
 265       ]);
 266     } '_insert_bulk via populate called a second time';
 267
 268     is $bulk_rs->count, 3,
 269       'correct number inserted via _insert_bulk';
 270
 271     is ((grep $_->charfield eq 'bar', $bulk_rs->all), 3,
 272       'column set correctly via _insert_bulk');
 273
 274     $bulk_rs->delete;
 275   }
 276
 277 # test invalid _insert_bulk (missing required column)
 278 #
 279   throws_ok {
 280     $schema->resultset('Artist')->populate([
 281       {
 282         charfield => 'foo',
 283       }
 284     ]);
 285   }
 286 # The second pattern is the error from fallback to regular array insert on
 287 # incompatible charset.
 288 # The third is for ::NoBindVars with no syb_has_blk.
 289   qr/
 290     \Qno value or default\E
 291       |
 292     \Qdoes not allow null\E
 293       |
 294     \QUnable to invoke fast-path insert without storage placeholder support\E
 295   /xi,
 296   '_insert_bulk with missing required column throws error';
 297
 298 # now test _insert_bulk with IDENTITY_INSERT
 299   SKIP: {
 300     skip '_insert_bulk not supported', 3
 301       unless $storage_type !~ /NoBindVars/i;
 302
 303     lives_ok {
 304       $schema->resultset('Artist')->populate([
 305         {
 306           artistid => 2001,
 307           name => 'bulk artist 1',
 308           charfield => 'foo',
 309         },
 310         {
 311           artistid => 2002,
 312           name => 'bulk artist 2',
 313           charfield => 'foo',
 314         },
 315         {
 316           artistid => 2003,
 317           name => 'bulk artist 3',
 318           charfield => 'foo',
 319         },
 320       ]);
 321     } '_insert_bulk with IDENTITY_INSERT via populate';
 322
 323     is $bulk_rs->count, 3,
 324       'correct number inserted via _insert_bulk with IDENTITY_INSERT';
 325
 326     is ((grep $_->charfield eq 'foo', $bulk_rs->all), 3,
 327       'column set correctly via _insert_bulk with IDENTITY_INSERT');
 328
 329     $bulk_rs->delete;
 330   }
 331
 332 # test correlated subquery
 333   my $subq = $schema->resultset('Artist')->search({ artistid => { '>' => 3 } })
 334     ->get_column('artistid')
 335     ->as_query;
 336   my $subq_rs = $schema->resultset('Artist')->search({
 337     artistid => { -in => $subq }
 338   });
 339   is $subq_rs->count, 11, 'correlated subquery';
 340
 341 # mostly stolen from the blob stuff Nniuq wrote for t/73oracle.t
 342   SKIP: {
 343     skip 'TEXT/IMAGE support does not work with FreeTDS', 22
 344       if $schema->storage->_using_freetds;
 345
 346     my $dbh = $schema->storage->_dbh;
 347     {
 348       local $SIG{__WARN__} = sub {};
 349       eval { $dbh->do('DROP TABLE bindtype_test') };
 350
 351       $dbh->do(qq[
 352         CREATE TABLE bindtype_test
 353         (
 354           id     INT   IDENTITY PRIMARY KEY,
 355           bytea  IMAGE NULL,
 356           blob   IMAGE NULL,
 357           clob   TEXT  NULL,
 358           a_memo IMAGE NULL
 359         )
 360       ],{ RaiseError => 1, PrintError => 0 });
 361     }
 362
 363     my %binstr = ( 'small' => join('', map { chr($_) } ( 1 .. 127 )) );
 364     $binstr{'large'} = $binstr{'small'} x 1024;
 365
 366     my $maxloblen = length $binstr{'large'};
 367
 368     if (not $schema->storage->_using_freetds) {
 369       $dbh->{'LongReadLen'} = $maxloblen * 2;
 370     } else {
 371       $dbh->do("set textsize ".($maxloblen * 2));
 372     }
 373
 374     my $rs = $schema->resultset('BindType');
 375     my $last_id;
 376
 377     foreach my $type (qw(blob clob)) {
 378       foreach my $size (qw(small large)) {
 379         no warnings 'uninitialized';
 380
 381         my $created;
 382         lives_ok {
 383           $created = $rs->create( { $type => $binstr{$size} } )
 384         } "inserted $size $type without dying";
 385
 386         $last_id = $created->id if $created;
 387
 388         lives_and {
 389           ok($rs->find($last_id)->$type eq $binstr{$size})
 390         } "verified inserted $size $type";
 391       }
 392     }
 393
 394     $rs->delete;
 395
 396     # blob insert with explicit PK
 397     # also a good opportunity to test IDENTITY_INSERT
 398     lives_ok {
 399       $rs->create( { id => 1, blob => $binstr{large} } )
 400     } 'inserted large blob without dying with manual PK';
 401
 402     lives_and {
 403       ok($rs->find(1)->blob eq $binstr{large})
 404     } 'verified inserted large blob with manual PK';
 405
 406     # try a blob update
 407     my $new_str = $binstr{large} . 'mtfnpy';
 408
 409     # check redispatch to storage-specific update when auto-detected storage
 410     if ($storage_type eq 'DBI::Sybase::ASE') {
 411       DBICTest::Schema->storage_type('::DBI');
 412       $schema = get_schema();
 413     }
 414
 415     lives_ok {
 416       $rs->search({ id => 1 })->update({ blob => $new_str })
 417     } 'updated blob successfully';
 418
 419     lives_and {
 420       ok($rs->find(1)->blob eq $new_str)
 421     } 'verified updated blob';
 422
 423     # try a blob update with IDENTITY_UPDATE
 424     lives_and {
 425       $new_str = $binstr{large} . 'hlagh';
 426       $rs->find(1)->update({ id => 999, blob => $new_str });
 427       ok($rs->find(999)->blob eq $new_str);
 428     } 'verified updated blob with IDENTITY_UPDATE';
 429
 430     ## try multi-row blob update
 431     # first insert some blobs
 432     $new_str = $binstr{large} . 'foo';
 433     lives_and {
 434       $rs->delete;
 435       $rs->create({ blob => $binstr{large} }) for (1..2);
 436       $rs->update({ blob => $new_str });
 437       is((grep $_->blob eq $new_str, $rs->all), 2);
 438     } 'multi-row blob update';
 439
 440     $rs->delete;
 441
 442     # now try _insert_bulk with blobs and only blobs
 443     $new_str = $binstr{large} . 'bar';
 444     lives_ok {
 445       $rs->populate([
 446         {
 447           blob => $binstr{large},
 448           clob => $new_str,
 449         },
 450         {
 451           blob => $binstr{large},
 452           clob => $new_str,
 453         },
 454       ]);
 455     } '_insert_bulk with blobs does not die';
 456
 457     is((grep $_->blob eq $binstr{large}, $rs->all), 2,
 458       'IMAGE column set correctly via _insert_bulk');
 459
 460     is((grep $_->clob eq $new_str, $rs->all), 2,
 461       'TEXT column set correctly via _insert_bulk');
 462
 463     # now try _insert_bulk with blobs and a non-blob which also happens to be an
 464     # identity column
 465     SKIP: {
 466       skip 'no _insert_bulk without placeholders', 4
 467         if $storage_type =~ /NoBindVars/i;
 468
 469       $rs->delete;
 470       $new_str = $binstr{large} . 'bar';
 471       lives_ok {
 472         $rs->populate([
 473           {
 474             id => 1,
 475             bytea => 1,
 476             blob => $binstr{large},
 477             clob => $new_str,
 478             a_memo => 2,
 479           },
 480           {
 481             id => 2,
 482             bytea => 1,
 483             blob => $binstr{large},
 484             clob => $new_str,
 485             a_memo => 2,
 486           },
 487         ]);
 488       } '_insert_bulk with blobs and explicit identity does NOT die';
 489
 490       is((grep $_->blob eq $binstr{large}, $rs->all), 2,
 491         'IMAGE column set correctly via _insert_bulk with identity');
 492
 493       is((grep $_->clob eq $new_str, $rs->all), 2,
 494         'TEXT column set correctly via _insert_bulk with identity');
 495
 496       is_deeply [ map $_->id, $rs->all ], [ 1,2 ],
 497         'explicit identities set correctly via _insert_bulk with blobs';
 498     }
 499
 500     lives_and {
 501       $rs->delete;
 502       $rs->create({ blob => $binstr{large} }) for (1..2);
 503       $rs->update({ blob => undef });
 504       is((grep !defined($_->blob), $rs->all), 2);
 505     } 'blob update to NULL';
 506   }
 507
 508 # test MONEY column support (and some other misc. stuff)
 509   $schema->storage->dbh_do (sub {
 510       my ($storage, $dbh) = @_;
 511       eval { $dbh->do("DROP TABLE money_test") };
 512       $dbh->do(<<'SQL');
 513 CREATE TABLE money_test (
 514    id INT IDENTITY PRIMARY KEY,
 515    amount MONEY DEFAULT $999.99 NULL
 516 )
 517 SQL
 518   });
 519
 520   my $rs = $schema->resultset('Money');
 521
 522 # test insert with defaults
 523   lives_and {
 524     $rs->create({});
 525     is((grep $_->amount == 999.99, $rs->all), 1);
 526   } 'insert with all defaults works';
 527   $rs->delete;
 528
 529 # test insert transaction when there's an active cursor
 530   {
 531     my $artist_rs = $schema->resultset('Artist');
 532     $artist_rs->first;
 533     lives_ok {
 534       my $row = $schema->resultset('Money')->create({ amount => 100 });
 535       $row->delete;
 536     } 'inserted a row with an active cursor';
 537     $ping_count-- if $@; # dbh_do calls ->connected
 538   }
 539
 540 # test insert in an outer transaction when there's an active cursor
 541   {
 542     local $TODO = 'this should work once we have eager cursors';
 543
 544 # clear state, or we get a deadlock on $row->delete
 545 # XXX figure out why this happens
 546     $schema->storage->disconnect;
 547
 548     lives_ok {
 549       $schema->txn_do(sub {
 550         my $artist_rs = $schema->resultset('Artist');
 551         $artist_rs->first;
 552         my $row = $schema->resultset('Money')->create({ amount => 100 });
 553         $row->delete;
 554       });
 555     } 'inserted a row with an active cursor in outer txn';
 556     $ping_count-- if $@; # dbh_do calls ->connected
 557   }
 558
 559 # Now test money values.
 560   my $row;
 561   lives_ok {
 562     $row = $rs->create({ amount => 100 });
 563   } 'inserted a money value';
 564
 565   cmp_ok eval { $rs->find($row->id)->amount }, '==', 100,
 566     'money value round-trip';
 567
 568   lives_ok {
 569     $row->update({ amount => 200 });
 570   } 'updated a money value';
 571
 572   cmp_ok eval { $rs->find($row->id)->amount }, '==', 200,
 573     'updated money value round-trip';
 574
 575   lives_ok {
 576     $row->update({ amount => undef });
 577   } 'updated a money value to NULL';
 578
 579   lives_and {
 580     my $null_amount = $rs->find($row->id)->amount;
 581     is $null_amount, undef;
 582   } 'updated money value to NULL round-trip';
 583
 584 # Test computed columns and timestamps
 585   $schema->storage->dbh_do (sub {
 586       my ($storage, $dbh) = @_;
 587       eval { $dbh->do("DROP TABLE computed_column_test") };
 588       $dbh->do(<<'SQL');
 589 CREATE TABLE computed_column_test (
 590    id INT IDENTITY PRIMARY KEY,
 591    a_computed_column AS getdate(),
 592    a_timestamp timestamp,
 593    charfield VARCHAR(20) DEFAULT 'foo'
 594 )
 595 SQL
 596   });
 597
 598   require DBICTest::Schema::ComputedColumn;
 599   $schema->register_class(
 600     ComputedColumn => 'DBICTest::Schema::ComputedColumn'
 601   );
 602
 603   ok (($rs = $schema->resultset('ComputedColumn')),
 604     'got rs for ComputedColumn');
 605
 606   lives_ok { $row = $rs->create({}) }
 607     'empty insert for a table with computed columns survived';
 608
 609   lives_ok {
 610     $row->update({ charfield => 'bar' })
 611   } 'update of a table with computed columns survived';
 612 }
 613
 614 is $ping_count, 0, 'no pings';
 615
 616 # if tests passed and did so under a non-C lang - let's rerun the test
 617 if (Test::Builder->new->is_passing and $ENV{LANG} and $ENV{LANG} ne 'C') {
 618   my $oldlang = $ENV{LANG};
 619   local $ENV{LANG} = 'C';
 620
 621   pass ("Your lang is set to $oldlang - retesting with C");
 622
 623   local $ENV{PATH};
 624   my @cmd = map { $_ =~ /(.+)/ } ($^X, __FILE__);
 625
 626   # this is cheating, and may even hang here and there (testing on windows passed fine)
 627   # will be replaced with Test::SubExec::Noninteractive in due course
 628   require IPC::Open2;
 629   IPC::Open2::open2(my $out, undef, @cmd);
 630   while (my $ln = <$out>) {
 631     print "   $ln";
 632   }
 633
 634   wait;
 635   ok (! $?, "Wstat $? from: @cmd");
 636 }
 637
 638 done_testing;
 639
 640 # clean up our mess
 641 END {
 642   if (my $dbh = eval { $schema->storage->_dbh }) {
 643     eval { $dbh->do("DROP TABLE $_") }
 644       for qw/artist bindtype_test money_test computed_column_test/;
 645   }
 646
 647   undef $schema;
 648 }