t/746sybase.t

   1 use strict;
   2 use warnings;
   3 no warnings 'uninitialized';
   4
   5 use Test::More;
   6 use Test::Exception;
   7 use lib qw(t/lib);
   8 use DBICTest;
   9
  10 require DBIx::Class::Storage::DBI::Sybase;
  11 require DBIx::Class::Storage::DBI::Sybase::NoBindVars;
  12
  13 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_SYBASE_${_}" } qw/DSN USER PASS/};
  14
  15 my $TESTS = 51 + 2;
  16
  17 if (not ($dsn && $user)) {
  18   plan skip_all =>
  19     'Set $ENV{DBICTEST_SYBASE_DSN}, _USER and _PASS to run this test' .
  20     "\nWarning: This test drops and creates the tables " .
  21     "'artist', 'money_test' and 'bindtype_test'";
  22 } else {
  23   plan tests => $TESTS*2 + 1;
  24 }
  25
  26 my @storage_types = (
  27   'DBI::Sybase',
  28   'DBI::Sybase::NoBindVars',
  29 );
  30 my $schema;
  31 my $storage_idx = -1;
  32
  33 sub get_schema {
  34   DBICTest::Schema->connect($dsn, $user, $pass, {
  35     on_connect_call => [
  36       [ blob_setup => log_on_update => 1 ], # this is a safer option
  37     ],
  38   });
  39 }
  40
  41 my $ping_count = 0;
  42 {
  43   my $ping = DBIx::Class::Storage::DBI::Sybase->can('_ping');
  44   *DBIx::Class::Storage::DBI::Sybase::_ping = sub {
  45     $ping_count++;
  46     goto $ping;
  47   };
  48 }
  49
  50 for my $storage_type (@storage_types) {
  51   $storage_idx++;
  52
  53   unless ($storage_type eq 'DBI::Sybase') { # autodetect
  54     DBICTest::Schema->storage_type("::$storage_type");
  55   }
  56
  57   $schema = get_schema();
  58
  59   $schema->storage->ensure_connected;
  60
  61   if ($storage_idx == 0 &&
  62       $schema->storage->isa('DBIx::Class::Storage::DBI::Sybase::NoBindVars')) {
  63 # no placeholders in this version of Sybase or DBD::Sybase (or using FreeTDS)
  64       my $tb = Test::More->builder;
  65       $tb->skip('no placeholders') for 1..$TESTS;
  66       next;
  67   }
  68
  69   isa_ok( $schema->storage, "DBIx::Class::Storage::$storage_type" );
  70
  71   $schema->storage->_dbh->disconnect;
  72   lives_ok (sub { $schema->storage->dbh }, 'reconnect works');
  73
  74   $schema->storage->dbh_do (sub {
  75       my ($storage, $dbh) = @_;
  76       eval { $dbh->do("DROP TABLE artist") };
  77       $dbh->do(<<'SQL');
  78 CREATE TABLE artist (
  79    artistid INT IDENTITY PRIMARY KEY,
  80    name VARCHAR(100),
  81    rank INT DEFAULT 13 NOT NULL,
  82    charfield CHAR(10) NULL
  83 )
  84 SQL
  85   });
  86
  87   my %seen_id;
  88
  89 # so we start unconnected
  90   $schema->storage->disconnect;
  91
  92 # test primary key handling
  93   my $new = $schema->resultset('Artist')->create({ name => 'foo' });
  94   ok($new->artistid > 0, "Auto-PK worked");
  95
  96   $seen_id{$new->artistid}++;
  97
  98 # check redispatch to storage-specific insert when auto-detected storage
  99   if ($storage_type eq 'DBI::Sybase') {
 100     DBICTest::Schema->storage_type('::DBI');
 101     $schema = get_schema();
 102   }
 103
 104   $new = $schema->resultset('Artist')->create({ name => 'Artist 1' });
 105   is ( $seen_id{$new->artistid}, undef, 'id for Artist 1 is unique' );
 106   $seen_id{$new->artistid}++;
 107
 108 # inserts happen in a txn, so we make sure it still works inside a txn too
 109   $schema->txn_begin;
 110
 111   for (2..6) {
 112     $new = $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
 113     is ( $seen_id{$new->artistid}, undef, "id for Artist $_ is unique" );
 114     $seen_id{$new->artistid}++;
 115   }
 116
 117   $schema->txn_commit;
 118
 119 # test simple count
 120   is ($schema->resultset('Artist')->count, 7, 'count(*) of whole table ok');
 121
 122 # test LIMIT support
 123   my $it = $schema->resultset('Artist')->search({
 124     artistid => { '>' => 0 }
 125   }, {
 126     rows => 3,
 127     order_by => 'artistid',
 128   });
 129
 130   is( $it->count, 3, "LIMIT count ok" );
 131
 132   is( $it->next->name, "foo", "iterator->next ok" );
 133   $it->next;
 134   is( $it->next->name, "Artist 2", "iterator->next ok" );
 135   is( $it->next, undef, "next past end of resultset ok" );
 136
 137 # now try with offset
 138   $it = $schema->resultset('Artist')->search({}, {
 139     rows => 3,
 140     offset => 3,
 141     order_by => 'artistid',
 142   });
 143
 144   is( $it->count, 3, "LIMIT with offset count ok" );
 145
 146   is( $it->next->name, "Artist 3", "iterator->next ok" );
 147   $it->next;
 148   is( $it->next->name, "Artist 5", "iterator->next ok" );
 149   is( $it->next, undef, "next past end of resultset ok" );
 150
 151 # now try a grouped count
 152   $schema->resultset('Artist')->create({ name => 'Artist 6' })
 153     for (1..6);
 154
 155   $it = $schema->resultset('Artist')->search({}, {
 156     group_by => 'name'
 157   });
 158
 159   is( $it->count, 7, 'COUNT of GROUP_BY ok' );
 160
 161 # do an IDENTITY_INSERT
 162   {
 163     no warnings 'redefine';
 164
 165     my @debug_out;
 166     local $schema->storage->{debug} = 1;
 167     local $schema->storage->debugobj->{callback} = sub {
 168       push @debug_out, $_[1];
 169     };
 170
 171     my $txn_used = 0;
 172     my $txn_commit = \&DBIx::Class::Storage::DBI::txn_commit;
 173     local *DBIx::Class::Storage::DBI::txn_commit = sub {
 174       $txn_used = 1;
 175       goto &$txn_commit;
 176     };
 177
 178     $schema->resultset('Artist')
 179       ->create({ artistid => 999, name => 'mtfnpy' });
 180
 181     ok((grep /IDENTITY_INSERT/i, @debug_out), 'IDENTITY_INSERT used');
 182
 183     SKIP: {
 184       skip 'not testing lack of txn on IDENTITY_INSERT with NoBindVars', 1
 185         if $storage_type =~ /NoBindVars/i;
 186
 187       is $txn_used, 0, 'no txn on insert with IDENTITY_INSERT';
 188     }
 189   }
 190
 191 # do an IDENTITY_UPDATE
 192   {
 193     my @debug_out;
 194     local $schema->storage->{debug} = 1;
 195     local $schema->storage->debugobj->{callback} = sub {
 196       push @debug_out, $_[1];
 197     };
 198
 199     lives_and {
 200       $schema->resultset('Artist')
 201         ->find(999)->update({ artistid => 555 });
 202       ok((grep /IDENTITY_UPDATE/i, @debug_out));
 203     } 'IDENTITY_UPDATE used';
 204     $ping_count-- if $@;
 205   }
 206
 207   my $bulk_rs = $schema->resultset('Artist')->search({
 208     name => { -like => 'bulk artist %' }
 209   });
 210
 211 # test insert_bulk using populate, this should always pass whether or not it
 212 # does anything Sybase specific or not. Just here to aid debugging.
 213   SKIP: {
 214     skip 'insert_bulk not supported', 4
 215       unless $schema->storage->_can_insert_bulk;
 216
 217     lives_ok {
 218       $schema->resultset('Artist')->populate([
 219         {
 220           name => 'bulk artist 1',
 221           charfield => 'foo',
 222         },
 223         {
 224           name => 'bulk artist 2',
 225           charfield => 'foo',
 226         },
 227         {
 228           name => 'bulk artist 3',
 229           charfield => 'foo',
 230         },
 231       ]);
 232     } 'insert_bulk via populate';
 233
 234     is $bulk_rs->count, 3, 'correct number inserted via insert_bulk';
 235
 236     is ((grep $_->charfield eq 'foo', $bulk_rs->all), 3,
 237       'column set correctly via insert_bulk');
 238
 239     my %bulk_ids;
 240     @bulk_ids{map $_->artistid, $bulk_rs->all} = ();
 241
 242     is ((scalar keys %bulk_ids), 3,
 243       'identities generated correctly in insert_bulk');
 244
 245     $bulk_rs->delete;
 246   }
 247
 248 # now test insert_bulk with IDENTITY_INSERT
 249   SKIP: {
 250     skip 'insert_bulk not supported', 3
 251       unless $schema->storage->_can_insert_bulk;
 252
 253     lives_ok {
 254       $schema->resultset('Artist')->populate([
 255         {
 256           artistid => 2001,
 257           name => 'bulk artist 1',
 258           charfield => 'foo',
 259         },
 260         {
 261           artistid => 2002,
 262           name => 'bulk artist 2',
 263           charfield => 'foo',
 264         },
 265         {
 266           artistid => 2003,
 267           name => 'bulk artist 3',
 268           charfield => 'foo',
 269         },
 270       ]);
 271     } 'insert_bulk with IDENTITY_INSERT via populate';
 272
 273     is $bulk_rs->count, 3,
 274       'correct number inserted via insert_bulk with IDENTITY_INSERT';
 275
 276     is ((grep $_->charfield eq 'foo', $bulk_rs->all), 3,
 277       'column set correctly via insert_bulk with IDENTITY_INSERT');
 278
 279     $bulk_rs->delete;
 280   }
 281
 282 # test correlated subquery
 283   my $subq = $schema->resultset('Artist')->search({ artistid => { '>' => 3 } })
 284     ->get_column('artistid')
 285     ->as_query;
 286   my $subq_rs = $schema->resultset('Artist')->search({
 287     artistid => { -in => $subq }
 288   });
 289   is $subq_rs->count, 11, 'correlated subquery';
 290
 291 # mostly stolen from the blob stuff Nniuq wrote for t/73oracle.t
 292   SKIP: {
 293     skip 'TEXT/IMAGE support does not work with FreeTDS', 15
 294       if $schema->storage->using_freetds;
 295
 296     my $dbh = $schema->storage->_dbh;
 297     {
 298       local $SIG{__WARN__} = sub {};
 299       eval { $dbh->do('DROP TABLE bindtype_test') };
 300
 301       $dbh->do(qq[
 302         CREATE TABLE bindtype_test
 303         (
 304           id    INT   IDENTITY PRIMARY KEY,
 305           bytea INT   NULL,
 306           blob  IMAGE NULL,
 307           clob  TEXT  NULL
 308         )
 309       ],{ RaiseError => 1, PrintError => 0 });
 310     }
 311
 312     my %binstr = ( 'small' => join('', map { chr($_) } ( 1 .. 127 )) );
 313     $binstr{'large'} = $binstr{'small'} x 1024;
 314
 315     my $maxloblen = length $binstr{'large'};
 316
 317     if (not $schema->storage->using_freetds) {
 318       $dbh->{'LongReadLen'} = $maxloblen * 2;
 319     } else {
 320       $dbh->do("set textsize ".($maxloblen * 2));
 321     }
 322
 323     my $rs = $schema->resultset('BindType');
 324     my $last_id;
 325
 326     foreach my $type (qw(blob clob)) {
 327       foreach my $size (qw(small large)) {
 328         no warnings 'uninitialized';
 329
 330         my $created = eval { $rs->create( { $type => $binstr{$size} } ) };
 331         ok(!$@, "inserted $size $type without dying");
 332         diag $@ if $@;
 333
 334         $last_id = $created->id if $created;
 335
 336         my $got = eval {
 337           $rs->find($last_id)->$type
 338         };
 339         diag $@ if $@;
 340         ok($got eq $binstr{$size}, "verified inserted $size $type");
 341       }
 342     }
 343
 344     # blob insert with explicit PK
 345     # also a good opportunity to test IDENTITY_INSERT
 346
 347     $rs->delete;
 348
 349     my $created = eval { $rs->create( { id => 1, blob => $binstr{large} } ) };
 350     ok(!$@, "inserted large blob without dying with manual PK");
 351     diag $@ if $@;
 352
 353     my $got = eval {
 354       $rs->find(1)->blob
 355     };
 356     diag $@ if $@;
 357     ok($got eq $binstr{large}, "verified inserted large blob with manual PK");
 358
 359     # try a blob update
 360     my $new_str = $binstr{large} . 'mtfnpy';
 361
 362     # check redispatch to storage-specific update when auto-detected storage
 363     if ($storage_type eq 'DBI::Sybase') {
 364       DBICTest::Schema->storage_type('::DBI');
 365       $schema = get_schema();
 366     }
 367
 368     eval { $rs->search({ id => 1 })->update({ blob => $new_str }) };
 369     ok !$@, 'updated blob successfully';
 370     diag $@ if $@;
 371     $got = eval {
 372       $rs->find(1)->blob
 373     };
 374     diag $@ if $@;
 375     ok($got eq $new_str, "verified updated blob");
 376
 377     # try a blob update with IDENTITY_UPDATE
 378     lives_and {
 379       $new_str = $binstr{large} . 'hlagh';
 380       $rs->find(1)->update({ id => 999, blob => $new_str });
 381       ok($rs->find(999)->blob eq $new_str);
 382     } 'verified updated blob with IDENTITY_UPDATE';
 383
 384     ## try multi-row blob update
 385     # first insert some blobs
 386     $rs->delete;
 387     $rs->create({ blob => $binstr{large} }) for (1..3);
 388     $new_str = $binstr{large} . 'foo';
 389     $rs->update({ blob => $new_str });
 390     is((grep $_->blob eq $new_str, $rs->all), 3, 'multi-row blob update');
 391
 392     # make sure impossible blob update throws
 393     throws_ok {
 394       $rs->update({ clob => 'foo' });
 395       $rs->create({ clob => 'bar' });
 396       $rs->search({ clob => 'foo' })->update({ clob => 'bar' });
 397     } qr/impossible/, 'impossible blob update throws';
 398   }
 399
 400 # test MONEY column support
 401   $schema->storage->dbh_do (sub {
 402       my ($storage, $dbh) = @_;
 403       eval { $dbh->do("DROP TABLE money_test") };
 404       $dbh->do(<<'SQL');
 405 CREATE TABLE money_test (
 406    id INT IDENTITY PRIMARY KEY,
 407    amount MONEY NULL
 408 )
 409 SQL
 410   });
 411
 412 # test insert transaction when there's an active cursor
 413   {
 414     my $artist_rs = $schema->resultset('Artist');
 415     $artist_rs->first;
 416     lives_ok {
 417       my $row = $schema->resultset('Money')->create({ amount => 100 });
 418       $row->delete;
 419     } 'inserted a row with an active cursor';
 420     $ping_count-- if $@; # dbh_do calls ->connected
 421   }
 422
 423 # test insert in an outer transaction when there's an active cursor
 424   TODO: {
 425     local $TODO = 'this should work once we have eager cursors';
 426
 427 # clear state, or we get a deadlock on $row->delete
 428 # XXX figure out why this happens
 429     $schema->storage->disconnect;
 430
 431     lives_ok {
 432       $schema->txn_do(sub {
 433         my $artist_rs = $schema->resultset('Artist');
 434         $artist_rs->first;
 435         my $row = $schema->resultset('Money')->create({ amount => 100 });
 436         $row->delete;
 437       });
 438     } 'inserted a row with an active cursor in outer txn';
 439     $ping_count-- if $@; # dbh_do calls ->connected
 440   }
 441
 442 # Now test money values.
 443   my $rs = $schema->resultset('Money');
 444
 445   my $row;
 446   lives_ok {
 447     $row = $rs->create({ amount => 100 });
 448   } 'inserted a money value';
 449
 450   is eval { $rs->find($row->id)->amount }, 100, 'money value round-trip';
 451
 452   lives_ok {
 453     $row->update({ amount => 200 });
 454   } 'updated a money value';
 455
 456   is eval { $rs->find($row->id)->amount },
 457     200, 'updated money value round-trip';
 458
 459   lives_ok {
 460     $row->update({ amount => undef });
 461   } 'updated a money value to NULL';
 462
 463   my $null_amount = eval { $rs->find($row->id)->amount };
 464   ok(
 465     (($null_amount == undef) && (not $@)),
 466     'updated money value to NULL round-trip'
 467   );
 468   diag $@ if $@;
 469 }
 470
 471 is $ping_count, 0, 'no pings';
 472
 473 # clean up our mess
 474 END {
 475   if (my $dbh = eval { $schema->storage->_dbh }) {
 476     eval { $dbh->do("DROP TABLE $_") }
 477       for qw/artist bindtype_test money_test/;
 478   }
 479 }