t/746mssql.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use Test::Warn;
   7 use Try::Tiny;
   8
   9 use DBIx::Class::Optional::Dependencies ();
  10 plan skip_all => 'Test needs ' . DBIx::Class::Optional::Dependencies->req_missing_for ('test_rdbms_mssql_odbc')
  11   unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_rdbms_mssql_odbc');
  12
  13 use lib qw(t/lib);
  14 use DBICTest;
  15
  16 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_MSSQL_ODBC_${_}" } qw/DSN USER PASS/};
  17
  18 plan skip_all => 'Set $ENV{DBICTEST_MSSQL_ODBC_DSN}, _USER and _PASS to run this test'
  19   unless ($dsn && $user);
  20
  21 {
  22   my $srv_ver = DBICTest::Schema->connect($dsn, $user, $pass)->storage->_server_info->{dbms_version};
  23   ok ($srv_ver, 'Got a test server version on fresh schema: ' . ($srv_ver||'???') );
  24 }
  25
  26 DBICTest::Schema->load_classes('ArtistGUID');
  27 my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
  28
  29 {
  30   no warnings 'redefine';
  31   my $connect_count = 0;
  32   my $orig_connect = \&DBI::connect;
  33   local *DBI::connect = sub { $connect_count++; goto &$orig_connect };
  34
  35   $schema->storage->ensure_connected;
  36
  37   is( $connect_count, 1, 'only one connection made');
  38 }
  39
  40 isa_ok( $schema->storage, 'DBIx::Class::Storage::DBI::ODBC::Microsoft_SQL_Server' );
  41
  42 {
  43   my $schema2 = $schema->connect (@{$schema->storage->connect_info});
  44   ok (! $schema2->storage->connected, 'a re-connected cloned schema starts unconnected');
  45 }
  46 $schema->storage->_dbh->disconnect;
  47
  48 lives_ok {
  49   $schema->storage->dbh_do(sub { $_[1]->do('select 1') })
  50 } '_ping works';
  51
  52 my %opts = (
  53   use_mars =>
  54     { opts => { on_connect_call => 'use_mars' } },
  55   use_dynamic_cursors =>
  56     { opts => { on_connect_call => 'use_dynamic_cursors' },
  57       required => $schema->storage->_using_freetds ? 0 : 1,
  58     },
  59   use_server_cursors =>
  60     { opts => { on_connect_call => 'use_server_cursors' } },
  61   plain =>
  62     { opts => {}, required => 1 },
  63 );
  64
  65 for my $opts_name (keys %opts) {
  66   SKIP: {
  67     my $opts = $opts{$opts_name}{opts};
  68     $schema = DBICTest::Schema->connect($dsn, $user, $pass, $opts);
  69
  70     try {
  71       $schema->storage->ensure_connected
  72     }
  73     catch {
  74       if ($opts{$opts_name}{required}) {
  75         die "on_connect_call option '$opts_name' is not functional: $_";
  76       }
  77       else {
  78         skip
  79           "on_connect_call option '$opts_name' not functional in this configuration: $_",
  80           1
  81         ;
  82       }
  83     };
  84
  85     $schema->storage->dbh_do (sub {
  86         my ($storage, $dbh) = @_;
  87         eval { $dbh->do("DROP TABLE artist") };
  88         $dbh->do(<<'SQL');
  89 CREATE TABLE artist (
  90    artistid INT IDENTITY NOT NULL,
  91    name VARCHAR(100),
  92    rank INT NOT NULL DEFAULT '13',
  93    charfield CHAR(10) NULL,
  94    primary key(artistid)
  95 )
  96 SQL
  97     });
  98
  99 # test Auto-PK
 100     $schema->resultset('Artist')->search({ name => 'foo' })->delete;
 101
 102     my $new = $schema->resultset('Artist')->create({ name => 'foo' });
 103
 104     ok(($new->artistid||0) > 0, "Auto-PK worked for $opts_name");
 105
 106 # Test graceful error handling if not supporting multiple active statements
 107     if( $opts_name eq 'plain' ) {
 108
 109       # keep the first cursor alive (as long as $rs is alive)
 110       my $rs = $schema->resultset("Artist");
 111
 112       my $a1 = $rs->next;
 113
 114       my $a2;
 115
 116       warnings_are {
 117         # second cursor, invalidates $rs, but it doesn't
 118         # matter as long as we do not try to use it
 119         $a2 = $schema->resultset("Artist")->next;
 120       } [], 'No warning on retry due to previous cursor invalidation';
 121
 122       is_deeply(
 123         { $a1->get_columns },
 124         { $a2->get_columns },
 125         'Same data',
 126       );
 127
 128       dies_ok {
 129         $rs->next;
 130       } 'Invalid cursor did not silently return garbage';
 131     }
 132
 133 # Test multiple active statements
 134     else {
 135       $schema->storage->ensure_connected;
 136
 137       lives_ok {
 138
 139         no warnings 'redefine';
 140         local *DBI::connect = sub { die "NO RECONNECTS!!!" };
 141
 142         my $artist_rs = $schema->resultset('Artist');
 143
 144         $artist_rs->delete;
 145
 146         $artist_rs->create({ name => "Artist$_" }) for (1..3);
 147
 148         my $forward  = $artist_rs->search({},
 149           { order_by => { -asc  => 'artistid' } });
 150         my $backward = $artist_rs->search({},
 151           { order_by => { -desc => 'artistid' } });
 152
 153         my @map = (
 154           [qw/Artist1 Artist3/], [qw/Artist2 Artist2/], [qw/Artist3 Artist1/]
 155         );
 156         my @result;
 157
 158         while (my $forward_row = $forward->next) {
 159           my $backward_row = $backward->next;
 160           push @result, [$forward_row->name, $backward_row->name];
 161         }
 162
 163         is_deeply \@result, \@map, "multiple active statements in $opts_name";
 164
 165         $artist_rs->delete;
 166
 167         is($artist_rs->count, 0, '$dbh still viable');
 168       } "Multiple active statements survive $opts_name";
 169     }
 170
 171 # Test populate
 172
 173     {
 174       $schema->storage->dbh_do (sub {
 175         my ($storage, $dbh) = @_;
 176         eval { $dbh->do("DROP TABLE owners") };
 177         eval { $dbh->do("DROP TABLE books") };
 178         $dbh->do(<<'SQL');
 179 CREATE TABLE books (
 180    id INT IDENTITY (1, 1) NOT NULL,
 181    source VARCHAR(100),
 182    owner INT,
 183    title VARCHAR(10),
 184    price INT NULL
 185 )
 186
 187 CREATE TABLE owners (
 188    id INT IDENTITY (1, 1) NOT NULL,
 189    name VARCHAR(100),
 190 )
 191 SQL
 192       });
 193
 194       lives_ok ( sub {
 195         # start a new connection, make sure rebless works
 196         my $schema = DBICTest::Schema->connect($dsn, $user, $pass, $opts);
 197         $schema->populate ('Owners', [
 198           [qw/id  name  /],
 199           [qw/1   wiggle/],
 200           [qw/2   woggle/],
 201           [qw/3   boggle/],
 202           [qw/4   fRIOUX/],
 203           [qw/5   fRUE/],
 204           [qw/6   fREW/],
 205           [qw/7   fROOH/],
 206           [qw/8   fISMBoC/],
 207           [qw/9   station/],
 208           [qw/10   mirror/],
 209           [qw/11   dimly/],
 210           [qw/12   face_to_face/],
 211           [qw/13   icarus/],
 212           [qw/14   dream/],
 213           [qw/15   dyrstyggyr/],
 214         ]);
 215       }, 'populate with PKs supplied ok' );
 216
 217
 218       lives_ok (sub {
 219         # start a new connection, make sure rebless works
 220         # test an insert with a supplied identity, followed by one without
 221         my $schema = DBICTest::Schema->connect($dsn, $user, $pass, $opts);
 222         for (2, 1) {
 223           my $id = $_ * 20 ;
 224           $schema->resultset ('Owners')->create ({ id => $id, name => "troglodoogle $id" });
 225           $schema->resultset ('Owners')->create ({ name => "troglodoogle " . ($id + 1) });
 226         }
 227       }, 'create with/without PKs ok' );
 228
 229       is ($schema->resultset ('Owners')->count, 19, 'owner rows really in db' );
 230
 231       lives_ok ( sub {
 232         # start a new connection, make sure rebless works
 233         my $schema = DBICTest::Schema->connect($dsn, $user, $pass, $opts);
 234         $schema->populate ('BooksInLibrary', [
 235           [qw/source  owner title   /],
 236           [qw/Library 1     secrets0/],
 237           [qw/Library 1     secrets1/],
 238           [qw/Eatery  1     secrets2/],
 239           [qw/Library 2     secrets3/],
 240           [qw/Library 3     secrets4/],
 241           [qw/Eatery  3     secrets5/],
 242           [qw/Library 4     secrets6/],
 243           [qw/Library 5     secrets7/],
 244           [qw/Eatery  5     secrets8/],
 245           [qw/Library 6     secrets9/],
 246           [qw/Library 7     secrets10/],
 247           [qw/Eatery  7     secrets11/],
 248           [qw/Library 8     secrets12/],
 249         ]);
 250       }, 'populate without PKs supplied ok' );
 251     }
 252
 253 # test simple, complex LIMIT and limited prefetch support, with both dialects and quote combinations (if possible)
 254     for my $dialect (
 255       'Top',
 256       ($schema->storage->_server_info->{normalized_dbms_version} || 0 ) >= 9
 257         ? ('RowNumberOver')
 258         : ()
 259       ,
 260     ) {
 261       for my $quoted (0, 1) {
 262
 263         $schema = DBICTest::Schema->connect($dsn, $user, $pass, {
 264             limit_dialect => $dialect,
 265             %$opts,
 266             $quoted
 267               ? ( quote_char => [ qw/ [ ] / ], name_sep => '.' )
 268               : ()
 269             ,
 270           });
 271
 272         my $test_type = "Dialect:$dialect Quoted:$quoted";
 273
 274         # basic limit support
 275         {
 276           my $art_rs = $schema->resultset ('Artist');
 277           $art_rs->delete;
 278           $art_rs->create({ name => 'Artist ' . $_ }) for (1..6);
 279
 280           my $it = $schema->resultset('Artist')->search( {}, {
 281             rows => 4,
 282             offset => 3,
 283             order_by => 'artistid',
 284           });
 285
 286           is( $it->count, 3, "$test_type: LIMIT count ok" );
 287
 288           local $TODO = "Top-limit does not work when your limit ends up past the resultset"
 289             if $dialect eq 'Top';
 290
 291           is( $it->next->name, 'Artist 4', "$test_type: iterator->next ok" );
 292           $it->next;
 293           is( $it->next->name, 'Artist 6', "$test_type: iterator->next ok" );
 294           is( $it->next, undef, "$test_type: next past end of resultset ok" );
 295         }
 296
 297         # plain ordered subqueries throw
 298         throws_ok (sub {
 299           $schema->resultset('Owners')->search ({}, { order_by => 'name' })->as_query
 300         }, qr/ordered subselect encountered/, "$test_type: Ordered Subselect detection throws ok");
 301
 302         # make sure ordered subselects *somewhat* work
 303         {
 304           my $owners = $schema->resultset ('Owners')->search ({}, { order_by => 'name', offset => 2, rows => 3, unsafe_subselect_ok => 1 });
 305           my $sealed_owners = $owners->as_subselect_rs;
 306
 307           is_deeply (
 308             [ sort map { $_->name } ($sealed_owners->all) ],
 309             [ sort map { $_->name } ($owners->all) ],
 310             "$test_type: Sort preserved from within a subquery",
 311           );
 312         }
 313
 314         # still even with lost order of IN, we should be getting correct
 315         # sets
 316         {
 317           my $owners = $schema->resultset ('Owners')->search ({}, { order_by => 'name', offset => 2, rows => 3, unsafe_subselect_ok => 1 });
 318           my $corelated_owners = $owners->result_source->resultset->search (
 319             {
 320               id => { -in => $owners->get_column('id')->as_query },
 321             },
 322             {
 323               order_by => 'name' #reorder because of what is shown above
 324             },
 325           );
 326
 327           is (
 328             join ("\x00", map { $_->name } ($corelated_owners->all) ),
 329             join ("\x00", map { $_->name } ($owners->all) ),
 330             "$test_type: With an outer order_by, everything still matches",
 331           );
 332         }
 333
 334         # make sure right-join-side single-prefetch ordering limit works
 335         {
 336           my $rs = $schema->resultset ('BooksInLibrary')->search (
 337             {
 338               'owner.name' => { '!=', 'woggle' },
 339             },
 340             {
 341               prefetch => 'owner',
 342               order_by => 'owner.name',
 343             }
 344           );
 345           # this is the order in which they should come from the above query
 346           my @owner_names = qw/boggle fISMBoC fREW fRIOUX fROOH fRUE wiggle wiggle/;
 347
 348           is ($rs->all, 8, "$test_type: Correct amount of objects from right-sorted joined resultset");
 349           is_deeply (
 350             [map { $_->owner->name } ($rs->all) ],
 351             \@owner_names,
 352             "$test_type: Prefetched rows were properly ordered"
 353           );
 354
 355           my $limited_rs = $rs->search ({}, {rows => 6, offset => 2, unsafe_subselect_ok => 1});
 356           is ($limited_rs->count, 6, "$test_type: Correct count of limited right-sorted joined resultset");
 357           is ($limited_rs->count_rs->next, 6, "$test_type: Correct count_rs of limited right-sorted joined resultset");
 358
 359           $schema->is_executed_querycount( sub {
 360             is_deeply (
 361               [map { $_->owner->name } ($limited_rs->all) ],
 362               [@owner_names[2 .. 7]],
 363               "$test_type: Prefetch-limited rows were properly ordered"
 364             );
 365           }, 1, "$test_type: Only one query with prefetch" );
 366
 367           is_deeply (
 368             [map { $_->name } ($limited_rs->search_related ('owner')->all) ],
 369             [@owner_names[2 .. 7]],
 370             "$test_type: Rows are still properly ordered after search_related",
 371           );
 372         }
 373
 374         # try a ->has_many direction with duplicates
 375         my $owners = $schema->resultset ('Owners')->search (
 376           {
 377             'books.id' => { '!=', undef },
 378             'me.name' => { '!=', 'somebogusstring' },
 379           },
 380           {
 381             prefetch => 'books',
 382             order_by => [ { -asc => \['name + ?', [ test => 'xxx' ]] }, 'me.id' ], # test bindvar propagation
 383             group_by => [ map { "me.$_" } $schema->source('Owners')->columns ], # the literal order_by requires an explicit group_by
 384             rows     => 3,  # 8 results total
 385             unsafe_subselect_ok => 1,
 386           },
 387         );
 388
 389         is ($owners->page(1)->all, 3, "$test_type: has_many prefetch returns correct number of rows");
 390         is ($owners->page(1)->count, 3, "$test_type: has-many prefetch returns correct count");
 391
 392         is ($owners->page(3)->count, 2, "$test_type: has-many prefetch returns correct count");
 393         {
 394           local $TODO = "Top-limit does not work when your limit ends up past the resultset"
 395             if $dialect eq 'Top';
 396           is ($owners->page(3)->all, 2, "$test_type: has_many prefetch returns correct number of rows");
 397           is ($owners->page(3)->count_rs->next, 2, "$test_type: has-many prefetch returns correct count_rs");
 398         }
 399
 400
 401         # try a ->belongs_to direction (no select collapse, group_by should work)
 402         my $books = $schema->resultset ('BooksInLibrary')->search (
 403           {
 404             'owner.name' => [qw/wiggle woggle/],
 405           },
 406           {
 407             distinct => 1,
 408             having => \['1 = ?', [ test => 1 ] ], #test having propagation
 409             prefetch => 'owner',
 410             rows     => 2,  # 3 results total
 411             order_by => [{ -desc => 'me.owner' }, 'me.id'],
 412             unsafe_subselect_ok => 1,
 413           },
 414         );
 415
 416         is ($books->page(1)->all, 2, "$test_type: Prefetched grouped search returns correct number of rows");
 417         is ($books->page(1)->count, 2, "$test_type: Prefetched grouped search returns correct count");
 418
 419         is ($books->page(2)->count, 1, "$test_type: Prefetched grouped search returns correct count");
 420         {
 421           local $TODO = "Top-limit does not work when your limit ends up past the resultset"
 422             if $dialect eq 'Top';
 423           is ($books->page(2)->all, 1, "$test_type: Prefetched grouped search returns correct number of rows");
 424           is ($books->page(2)->count_rs->next, 1, "$test_type: Prefetched grouped search returns correct count_rs");
 425         }
 426       }
 427     }
 428
 429
 430 # test GUID columns
 431     {
 432       $schema->storage->dbh_do (sub {
 433         my ($storage, $dbh) = @_;
 434         eval { $dbh->do("DROP TABLE artist_guid") };
 435         $dbh->do(<<'SQL');
 436 CREATE TABLE artist_guid (
 437    artistid UNIQUEIDENTIFIER NOT NULL,
 438    name VARCHAR(100),
 439    rank INT NOT NULL DEFAULT '13',
 440    charfield CHAR(10) NULL,
 441    a_guid UNIQUEIDENTIFIER,
 442    primary key(artistid)
 443 )
 444 SQL
 445       });
 446
 447       # start disconnected to make sure insert works on an un-reblessed storage
 448       $schema = DBICTest::Schema->connect($dsn, $user, $pass, $opts);
 449
 450       my $row;
 451       lives_ok {
 452         $row = $schema->resultset('ArtistGUID')->create({ name => 'mtfnpy' })
 453       } 'created a row with a GUID';
 454
 455       ok(
 456         eval { $row->artistid },
 457         'row has GUID PK col populated',
 458       );
 459       diag $@ if $@;
 460
 461       ok(
 462         eval { $row->a_guid },
 463         'row has a GUID col with auto_nextval populated',
 464       );
 465       diag $@ if $@;
 466
 467       my $row_from_db = $schema->resultset('ArtistGUID')
 468         ->search({ name => 'mtfnpy' })->first;
 469
 470       is $row_from_db->artistid, $row->artistid,
 471         'PK GUID round trip';
 472
 473       is $row_from_db->a_guid, $row->a_guid,
 474         'NON-PK GUID round trip';
 475     }
 476
 477 # test MONEY type
 478     {
 479       $schema->storage->dbh_do (sub {
 480         my ($storage, $dbh) = @_;
 481         eval { $dbh->do("DROP TABLE money_test") };
 482         $dbh->do(<<'SQL');
 483 CREATE TABLE money_test (
 484    id INT IDENTITY PRIMARY KEY,
 485    amount MONEY NULL
 486 )
 487 SQL
 488       });
 489
 490       {
 491         my $freetds_and_dynamic_cursors = 1
 492           if $opts_name eq 'use_dynamic_cursors' &&
 493             $schema->storage->_using_freetds;
 494
 495         local $TODO =
 496 'these tests fail on freetds with dynamic cursors for some reason'
 497           if $freetds_and_dynamic_cursors;
 498         local $ENV{DBIC_NULLABLE_KEY_NOWARN} = 1
 499           if $freetds_and_dynamic_cursors;
 500
 501         my $rs = $schema->resultset('Money');
 502         my $row;
 503
 504         lives_ok {
 505           $row = $rs->create({ amount => 100 });
 506         } 'inserted a money value';
 507
 508         cmp_ok ((try { $rs->find($row->id)->amount })||0, '==', 100,
 509           'money value round-trip');
 510
 511         lives_ok {
 512           $row->update({ amount => 200 });
 513         } 'updated a money value';
 514
 515         cmp_ok ((try { $rs->find($row->id)->amount })||0, '==', 200,
 516           'updated money value round-trip');
 517
 518         lives_ok {
 519           $row->update({ amount => undef });
 520         } 'updated a money value to NULL';
 521
 522         is try { $rs->find($row->id)->amount }, undef,
 523           'updated money value to NULL round-trip';
 524       }
 525     }
 526   }
 527 }
 528
 529 done_testing;
 530
 531 # clean up our mess
 532 END {
 533   if (my $dbh = eval { $schema->storage->_dbh }) {
 534     eval { $dbh->do("DROP TABLE $_") }
 535       for qw/artist artist_guid money_test books owners/;
 536   }
 537   undef $schema;
 538 }
 539 # vim:sw=2 sts=2