t/73oracle.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::Exception;
   5 use Test::More;
   6 use Sub::Name;
   7 use Try::Tiny;
   8
   9 use lib qw(t/lib);
  10 use DBICTest;
  11 use DBIC::SqlMakerTest;
  12
  13 plan skip_all => 'Test needs ' . DBIx::Class::Optional::Dependencies->req_missing_for ('test_rdbms_oracle')
  14   unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_rdbms_oracle');
  15
  16 $ENV{NLS_SORT} = "BINARY";
  17 $ENV{NLS_COMP} = "BINARY";
  18 $ENV{NLS_LANG} = "AMERICAN";
  19
  20 my ($dsn,  $user,  $pass)  = @ENV{map { "DBICTEST_ORA_${_}" }  qw/DSN USER PASS/};
  21
  22 # optional:
  23 my ($dsn2, $user2, $pass2) = @ENV{map { "DBICTEST_ORA_EXTRAUSER_${_}" } qw/DSN USER PASS/};
  24
  25 plan skip_all => 'Set $ENV{DBICTEST_ORA_DSN}, _USER and _PASS to run this test.'
  26   unless ($dsn && $user && $pass);
  27
  28 {
  29   package    # hide from PAUSE
  30     DBICTest::Schema::ArtistFQN;
  31
  32   use base 'DBIx::Class::Core';
  33
  34   __PACKAGE__->table(
  35     $ENV{DBICTEST_ORA_USER}
  36       ? (uc $ENV{DBICTEST_ORA_USER}) . '.artist'
  37       : '??_no_user_??'
  38   );
  39   __PACKAGE__->add_columns(
  40     'artistid' => {
  41       data_type         => 'integer',
  42       is_auto_increment => 1,
  43     },
  44     'name' => {
  45       data_type   => 'varchar',
  46       size        => 100,
  47       is_nullable => 1,
  48     },
  49     'autoinc_col' => {
  50       data_type         => 'integer',
  51       is_auto_increment => 1,
  52     },
  53     'default_value_col' => {
  54       data_type           => 'varchar',
  55       size                => 100,
  56       is_nullable         => 0,
  57       retrieve_on_insert  => 1,
  58     }
  59   );
  60   __PACKAGE__->set_primary_key(qw/ artistid autoinc_col /);
  61
  62   1;
  63 }
  64
  65 DBICTest::Schema->load_classes('ArtistFQN');
  66
  67 # This is in Core now, but it's here just to test that it doesn't break
  68 DBICTest::Schema::Artist->load_components('PK::Auto');
  69 # These are compat shims for PK::Auto...
  70 DBICTest::Schema::CD->load_components('PK::Auto::Oracle');
  71 DBICTest::Schema::Track->load_components('PK::Auto::Oracle');
  72
  73
  74 # check if we indeed do support stuff
  75 my $v = do {
  76   my $v = DBICTest::Schema->connect($dsn, $user, $pass)->storage->_dbh_get_info(18);
  77   $v =~ /^(\d+)\.(\d+)/
  78     or die "Unparseable Oracle server version: $v\n";
  79
  80   sprintf('%d.%03d', $1, $2);
  81 };
  82
  83 my $test_server_supports_only_orajoins = $v < 9;
  84
  85 # TODO find out which version supports the RETURNING syntax
  86 # 8i (8.1) has it and earlier docs are a 404 on oracle.com
  87 my $test_server_supports_insert_returning = $v >= 8.001;
  88
  89 is (
  90   DBICTest::Schema->connect($dsn, $user, $pass)->storage->_use_insert_returning,
  91   $test_server_supports_insert_returning,
  92   'insert returning capability guessed correctly'
  93 );
  94
  95 ##########
  96 # the recyclebin (new for 10g) sometimes comes in the way
  97 my $on_connect_sql = $v >= 10 ? ["ALTER SESSION SET recyclebin = OFF"] : [];
  98
  99 # iterate all tests on following options
 100 my @tryopt = (
 101   { on_connect_do => $on_connect_sql },
 102   { quote_char => '"', on_connect_do => $on_connect_sql },
 103 );
 104
 105 # keep a database handle open for cleanup
 106 my ($dbh, $dbh2);
 107
 108 my $schema;
 109 for my $use_insert_returning ($test_server_supports_insert_returning ? (1,0) : (0) ) {
 110   for my $force_ora_joins ($test_server_supports_only_orajoins ? (0) : (0,1) ) {
 111
 112     no warnings qw/once/;
 113     local *DBICTest::Schema::connection = subname 'DBICTest::Schema::connection' => sub {
 114       my $s = shift->next::method (@_);
 115       $s->storage->_use_insert_returning ($use_insert_returning);
 116       $s->storage->sql_maker_class('DBIx::Class::SQLMaker::OracleJoins') if $force_ora_joins;
 117       $s;
 118     };
 119
 120     for my $opt (@tryopt) {
 121       # clean all cached sequences from previous run
 122       for (map { values %{DBICTest::Schema->source($_)->columns_info} } (qw/Artist CD Track/) ) {
 123         delete $_->{sequence};
 124       }
 125
 126       my $schema = DBICTest::Schema->connect($dsn, $user, $pass, $opt);
 127
 128       $dbh = $schema->storage->dbh;
 129       my $q = $schema->storage->sql_maker->quote_char || '';
 130
 131       do_creates($dbh, $q);
 132
 133       _run_tests($schema, $opt);
 134     }
 135   }
 136 }
 137
 138 sub _run_tests {
 139   my ($schema, $opt) = @_;
 140
 141   my $q = $schema->storage->sql_maker->quote_char || '';
 142
 143 # test primary key handling with multiple triggers
 144   my ($new, $seq);
 145
 146   my $new_artist = $schema->resultset('Artist')->create({ name => 'foo' });
 147   my $new_cd     = $schema->resultset('CD')->create({ artist => 1, title => 'EP C', year => '2003' });
 148
 149   SKIP: {
 150     skip 'not detecting sequences when using INSERT ... RETURNING', 4
 151       if $schema->storage->_use_insert_returning;
 152
 153     is($new_artist->artistid, 1, "Oracle Auto-PK worked for standard sqlt-like trigger");
 154     $seq = $new_artist->result_source->column_info('artistid')->{sequence};
 155     $seq = $$seq if ref $seq;
 156     like ($seq, qr/\.${q}artist_pk_seq${q}$/, 'Correct PK sequence selected for sqlt-like trigger');
 157
 158     is($new_cd->cdid, 1, 'Oracle Auto-PK worked - using scalar ref as table name/custom weird trigger');
 159     $seq = $new_cd->result_source->column_info('cdid')->{sequence};
 160     $seq = $$seq if ref $seq;
 161     like ($seq, qr/\.${q}cd_seq${q}$/, 'Correct PK sequence selected for custom trigger');
 162   }
 163
 164 # test PKs again with fully-qualified table name
 165   my $artistfqn_rs = $schema->resultset('ArtistFQN');
 166   my $artist_rsrc = $artistfqn_rs->result_source;
 167
 168   delete $artist_rsrc->column_info('artistid')->{sequence};
 169   $new = $artistfqn_rs->create( { name => 'bar' } );
 170
 171   is_deeply( {map { $_ => $new->$_ } $artist_rsrc->primary_columns},
 172     { artistid => 2, autoinc_col => 2},
 173     "Oracle Multi-Auto-PK worked with fully-qualified tablename" );
 174
 175
 176   delete $artist_rsrc->column_info('artistid')->{sequence};
 177   $new = $artistfqn_rs->create( { name => 'bar', autoinc_col => 1000 } );
 178
 179   is( $new->artistid, 3, "Oracle Auto-PK worked with fully-qualified tablename" );
 180   is( $new->autoinc_col, 1000, "Oracle Auto-Inc overruled with fully-qualified tablename");
 181
 182
 183   is( $new->default_value_col, 'default_value', $schema->storage->_use_insert_returning
 184     ? 'Check retrieve_on_insert on default_value_col with INSERT ... RETURNING'
 185     : 'Check retrieve_on_insert on default_value_col without INSERT ... RETURNING'
 186   );
 187
 188   SKIP: {
 189     skip 'not detecting sequences when using INSERT ... RETURNING', 1
 190       if $schema->storage->_use_insert_returning;
 191
 192     $seq = $new->result_source->column_info('artistid')->{sequence};
 193     $seq = $$seq if ref $seq;
 194     like ($seq, qr/\.${q}artist_pk_seq${q}$/, 'Correct PK sequence selected for sqlt-like trigger');
 195   }
 196
 197
 198 # test LIMIT support
 199   for (1..6) {
 200     $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
 201   }
 202   my $it = $schema->resultset('Artist')->search( { name => { -like => 'Artist %' } }, {
 203     rows => 3,
 204     offset => 4,
 205     order_by => 'artistid'
 206   });
 207
 208   is( $it->count, 2, "LIMIT count past end of RS ok" );
 209   is( $it->next->name, "Artist 5", "iterator->next ok" );
 210   is( $it->next->name, "Artist 6", "iterator->next ok" );
 211   is( $it->next, undef, "next past end of resultset ok" );
 212
 213 # test identifiers over the 30 char limit
 214   lives_ok {
 215     my @results = $schema->resultset('CD')->search(undef, {
 216       prefetch => 'very_long_artist_relationship',
 217       rows => 3,
 218       offset => 0,
 219     })->all;
 220     ok( scalar @results > 0, 'limit with long identifiers returned something');
 221   } 'limit with long identifiers executed successfully';
 222
 223
 224 # test rel names over the 30 char limit
 225   my $query = $schema->resultset('Artist')->search({
 226     artistid => 1
 227   }, {
 228     prefetch => 'cds_very_very_very_long_relationship_name'
 229   });
 230
 231   lives_and {
 232     is $query->first->cds_very_very_very_long_relationship_name->first->cdid, 1
 233   } 'query with rel name over 30 chars survived and worked';
 234
 235 # test rel names over the 30 char limit using group_by and join
 236   {
 237     my @group_cols = ( 'me.name' );
 238     my $query = $schema->resultset('Artist')->search({
 239       artistid => 1
 240     }, {
 241       select => \@group_cols,
 242       as => [map { /^\w+\.(\w+)$/ } @group_cols],
 243       join => [qw( cds_very_very_very_long_relationship_name )],
 244       group_by => \@group_cols,
 245     });
 246
 247     lives_and {
 248       my @got = $query->get_column('name')->all();
 249       is_deeply \@got, [$new_artist->name];
 250     } 'query with rel name over 30 chars worked on join, group_by for me col';
 251
 252     lives_and {
 253       is $query->count(), 1
 254     } 'query with rel name over 30 chars worked on join, group_by, count for me col';
 255   }
 256   {
 257     my @group_cols = ( 'cds_very_very_very_long_relationship_name.title' );
 258     my $query = $schema->resultset('Artist')->search({
 259       artistid => 1
 260     }, {
 261       select => \@group_cols,
 262       as => [map { /^\w+\.(\w+)$/ } @group_cols],
 263       join => [qw( cds_very_very_very_long_relationship_name )],
 264       group_by => \@group_cols,
 265     });
 266
 267     lives_and {
 268       my @got = $query->get_column('title')->all();
 269       is_deeply \@got, [$new_cd->title];
 270     } 'query with rel name over 30 chars worked on join, group_by for long rel col';
 271
 272     lives_and {
 273       is $query->count(), 1
 274     } 'query with rel name over 30 chars worked on join, group_by, count for long rel col';
 275   }
 276
 277   # rel name over 30 char limit with user condition
 278   # This requires walking the SQLA data structure.
 279   {
 280     $query = $schema->resultset('Artist')->search({
 281       'cds_very_very_very_long_relationship_name.title' => 'EP C'
 282     }, {
 283       prefetch => 'cds_very_very_very_long_relationship_name'
 284     });
 285
 286     lives_and {
 287       is $query->first->cds_very_very_very_long_relationship_name->first->cdid, 1
 288     } 'query with rel name over 30 chars and user condition survived and worked';
 289   }
 290
 291
 292 # test join with row count ambiguity
 293   my $cd = $schema->resultset('CD')->next;
 294   my $track = $cd->create_related('tracks', { position => 1, title => 'Track1'} );
 295   my $tjoin = $schema->resultset('Track')->search({ 'me.title' => 'Track1'}, {
 296     join => 'cd', rows => 2
 297   });
 298
 299   ok(my $row = $tjoin->next);
 300
 301   is($row->title, 'Track1', "ambiguous column ok");
 302
 303
 304
 305 # check count distinct with multiple columns
 306   my $other_track = $schema->resultset('Track')->create({ cd => $cd->cdid, position => 1, title => 'Track2' });
 307
 308   my $tcount = $schema->resultset('Track')->search(
 309     {},
 310     {
 311       select => [ qw/position title/ ],
 312       distinct => 1,
 313     }
 314   );
 315   is($tcount->count, 2, 'multiple column COUNT DISTINCT ok');
 316
 317   $tcount = $schema->resultset('Track')->search(
 318     {},
 319     {
 320       columns => [ qw/position title/ ],
 321       distinct => 1,
 322     }
 323   );
 324   is($tcount->count, 2, 'multiple column COUNT DISTINCT ok');
 325
 326   $tcount = $schema->resultset('Track')->search(
 327     {},
 328     {
 329       group_by => [ qw/position title/ ]
 330     }
 331   );
 332   is($tcount->count, 2, 'multiple column COUNT DISTINCT using column syntax ok');
 333
 334
 335 # check group_by
 336   my $g_rs = $schema->resultset('Track')->search( undef, { columns=>[qw/trackid position/], group_by=> [ qw/trackid position/ ] , rows => 2, offset => 1 });
 337   is( scalar $g_rs->all, 1, "Group by with limit OK" );
 338
 339
 340 # test with_deferred_fk_checks
 341   lives_ok {
 342     $schema->storage->with_deferred_fk_checks(sub {
 343       $schema->resultset('Track')->create({
 344         trackid => 999, cd => 999, position => 1, title => 'deferred FK track'
 345       });
 346       $schema->resultset('CD')->create({
 347         artist => 1, cdid => 999, year => '2003', title => 'deferred FK cd'
 348       });
 349     });
 350   } 'with_deferred_fk_checks code survived';
 351
 352   is eval { $schema->resultset('Track')->find(999)->title }, 'deferred FK track',
 353     'code in with_deferred_fk_checks worked';
 354
 355   throws_ok {
 356     $schema->resultset('Track')->create({
 357       trackid => 1, cd => 9999, position => 1, title => 'Track1'
 358     });
 359   } qr/constraint/i, 'with_deferred_fk_checks is off';
 360
 361
 362 # test auto increment using sequences WITHOUT triggers
 363   for (1..5) {
 364     my $st = $schema->resultset('SequenceTest')->create({ name => 'foo' });
 365     is($st->pkid1, $_, "Oracle Auto-PK without trigger: First primary key");
 366     is($st->pkid2, $_ + 9, "Oracle Auto-PK without trigger: Second primary key");
 367     is($st->nonpkid, $_ + 19, "Oracle Auto-PK without trigger: Non-primary key");
 368   }
 369   my $st = $schema->resultset('SequenceTest')->create({ name => 'foo', pkid1 => 55 });
 370   is($st->pkid1, 55, "Oracle Auto-PK without trigger: First primary key set manually");
 371
 372
 373 # test BLOBs
 374   SKIP: {
 375   TODO: {
 376     my %binstr = ( 'small' => join('', map { chr($_) } ( 1 .. 127 )) );
 377     $binstr{'large'} = $binstr{'small'} x 1024;
 378
 379     my $maxloblen = (length $binstr{'large'}) + 5;
 380     note "Localizing LongReadLen to $maxloblen to avoid truncation of test data";
 381     local $dbh->{'LongReadLen'} = $maxloblen;
 382
 383     my $rs = $schema->resultset('BindType');
 384
 385     if ($DBD::Oracle::VERSION eq '1.23') {
 386       throws_ok { $rs->create({ id => 1, blob => $binstr{large} }) }
 387         qr/broken/,
 388         'throws on blob insert with DBD::Oracle == 1.23';
 389
 390       skip 'buggy BLOB support in DBD::Oracle 1.23', 1;
 391     }
 392
 393     # disable BLOB mega-output
 394     my $orig_debug = $schema->storage->debug;
 395     $schema->storage->debug (0);
 396
 397     local $TODO = 'Something is confusing column bindtype assignment when quotes are active'
 398                 . ': https://rt.cpan.org/Ticket/Display.html?id=64206'
 399       if $q;
 400
 401     my $id;
 402     foreach my $size (qw( small large )) {
 403       $id++;
 404
 405       my $str = $binstr{$size};
 406       lives_ok {
 407         $rs->create( { 'id' => $id, blob => "blob:$str", clob => "clob:$str" } )
 408       } "inserted $size without dying";
 409
 410       my %kids = %{$schema->storage->_dbh->{CachedKids}};
 411       my @objs = $rs->search({ blob => "blob:$str", clob => "clob:$str" })->all;
 412       is_deeply (
 413         $schema->storage->_dbh->{CachedKids},
 414         \%kids,
 415         'multi-part LOB equality query was not cached',
 416       ) if $size eq 'large';
 417       is @objs, 1, 'One row found matching on both LOBs';
 418       ok (try { $objs[0]->blob }||'' eq "blob:$str", 'blob inserted/retrieved correctly');
 419       ok (try { $objs[0]->clob }||'' eq "clob:$str", 'clob inserted/retrieved correctly');
 420
 421       @objs = $rs->search({ clob => { -like => 'clob:%' } })->all;
 422       ok (@objs, 'rows found matching CLOB with a LIKE query');
 423
 424       ok(my $subq = $rs->search(
 425         { blob => "blob:$str", clob => "clob:$str" },
 426         {
 427           from => \ "(SELECT * FROM ${q}bindtype_test${q} WHERE ${q}id${q} != ?) ${q}me${q}",
 428           bind => [ [ undef => 12345678 ] ],
 429         }
 430       )->get_column('id')->as_query);
 431
 432       @objs = $rs->search({ id => { -in => $subq } })->all;
 433       is (@objs, 1, 'One row found matching on both LOBs as a subquery');
 434
 435       lives_ok {
 436         $rs->search({ blob => "blob:$str", clob => "clob:$str" })
 437           ->update({ blob => 'updated blob', clob => 'updated clob' });
 438       } 'blob UPDATE with WHERE clause survived';
 439
 440       @objs = $rs->search({ blob => "updated blob", clob => 'updated clob' })->all;
 441       is @objs, 1, 'found updated row';
 442       ok (try { $objs[0]->blob }||'' eq "updated blob", 'blob updated/retrieved correctly');
 443       ok (try { $objs[0]->clob }||'' eq "updated clob", 'clob updated/retrieved correctly');
 444
 445       lives_ok {
 446         $rs->search({ blob => "updated blob", clob => "updated clob" })
 447           ->delete;
 448       } 'blob DELETE with WHERE clause survived';
 449       @objs = $rs->search({ blob => "updated blob", clob => 'updated clob' })->all;
 450       is @objs, 0, 'row deleted successfully';
 451     }
 452
 453     $schema->storage->debug ($orig_debug);
 454   }}
 455
 456 # test populate (identity, success and error handling)
 457   my $art_rs = $schema->resultset('Artist');
 458
 459   my $seq_pos = $art_rs->get_column('artistid')->max;
 460   ok($seq_pos, 'Starting with something in the artist table');
 461
 462
 463   my $pop_rs = $schema->resultset('Artist')->search(
 464     { name => { -like => 'pop_art_%' } },
 465     { order_by => 'artistid' }
 466   );
 467
 468   $art_rs->delete;
 469   lives_ok {
 470     $pop_rs->populate([
 471       map { +{ name => "pop_art_$_" } }
 472       (1,2,3)
 473     ]);
 474
 475     is_deeply (
 476       [ $pop_rs->get_column('artistid')->all ],
 477       [ map { $seq_pos + $_ } (1,2,3) ],
 478       'Sequence works after empty-table insertion'
 479     );
 480   } 'Populate without identity does not throw';
 481
 482   lives_ok {
 483     $pop_rs->populate([
 484       map { +{ artistid => $_, name => "pop_art_$_" } }
 485       (1,2,3)
 486     ]);
 487
 488     is_deeply (
 489       [ $pop_rs->get_column('artistid')->all ],
 490       [ 1,2,3, map { $seq_pos + $_ } (1,2,3) ],
 491       'Explicit id population works'
 492     );
 493   } 'Populate with identity does not throw';
 494
 495   throws_ok {
 496     $pop_rs->populate([
 497       map { +{ artistid => $_, name => "pop_art_$_" } }
 498       (200, 1, 300)
 499     ]);
 500   } qr/unique constraint.+populate slice.+name => "pop_art_1"/s, 'Partially failed populate throws';
 501
 502   is_deeply (
 503     [ $pop_rs->get_column('artistid')->all ],
 504     [ 1,2,3, map { $seq_pos + $_ } (1,2,3) ],
 505     'Partially failed populate did not alter table contents'
 506   );
 507
 508 # test complex join (exercise orajoins)
 509   lives_ok {
 510     my @hri = $schema->resultset('CD')->search(
 511       { 'artist.name' => 'pop_art_1', 'me.cdid' => { '!=', 999} },
 512       { join => 'artist', prefetch => 'tracks', rows => 4, order_by => 'tracks.trackid' }
 513     )->hri_dump->all;
 514
 515     my $expect = [{
 516       artist => 1,
 517       cdid => 1,
 518       genreid => undef,
 519       single_track => undef,
 520       title => "EP C",
 521       tracks => [
 522         {
 523           cd => 1,
 524           last_updated_at => undef,
 525           last_updated_on => undef,
 526           position => 1,
 527           title => "Track1",
 528           trackid => 1
 529         },
 530         {
 531           cd => 1,
 532           last_updated_at => undef,
 533           last_updated_on => undef,
 534           position => 1,
 535           title => "Track2",
 536           trackid => 2
 537         },
 538       ],
 539       year => 2003
 540     }];
 541
 542     is_deeply (
 543       \@hri,
 544       $expect,
 545       'Correct set of data prefetched',
 546     );
 547
 548   } 'complex prefetch ok';
 549
 550 # test sequence detection from a different schema
 551   SKIP: {
 552   TODO: {
 553     skip ((join '',
 554       'Set DBICTEST_ORA_EXTRAUSER_DSN, _USER and _PASS to a *DIFFERENT* Oracle user',
 555       ' to run the cross-schema sequence detection test.'),
 556     1) unless $dsn2 && $user2 && $user2 ne $user;
 557
 558     skip 'not detecting cross-schema sequence name when using INSERT ... RETURNING', 1
 559       if $schema->storage->_use_insert_returning;
 560
 561     # Oracle8i Reference Release 2 (8.1.6)
 562     #   http://download.oracle.com/docs/cd/A87860_01/doc/server.817/a76961/ch294.htm#993
 563     # Oracle Database Reference 10g Release 2 (10.2)
 564     #   http://download.oracle.com/docs/cd/B19306_01/server.102/b14237/statviews_2107.htm#sthref1297
 565     local $TODO = "On Oracle8i all_triggers view is empty, i don't yet know why..."
 566       if $schema->storage->_server_info->{normalized_dbms_version} < 9;
 567
 568     my $schema2 = $schema->connect($dsn2, $user2, $pass2, $opt);
 569     my $dbh2 = $schema2->storage->dbh;
 570
 571     # create identically named tables/sequences in the other schema
 572     do_creates($dbh2, $q);
 573
 574     # grand select privileges to the 2nd user
 575     $dbh->do("GRANT INSERT ON ${q}artist${q} TO " . uc $user2);
 576     $dbh->do("GRANT SELECT ON ${q}artist${q} TO " . uc $user2);
 577     $dbh->do("GRANT SELECT ON ${q}artist_pk_seq${q} TO " . uc $user2);
 578     $dbh->do("GRANT SELECT ON ${q}artist_autoinc_seq${q} TO " . uc $user2);
 579
 580     # test with a fully qualified table (user1/schema prepended)
 581     my $rs2 = $schema2->resultset('ArtistFQN');
 582     delete $rs2->result_source->column_info('artistid')->{sequence};
 583
 584     lives_and {
 585       my $row = $rs2->create({ name => 'From Different Schema' });
 586       ok $row->artistid;
 587     } 'used autoinc sequence across schemas';
 588
 589     # now quote the sequence name (do_creates always uses an lc name)
 590     my $q_seq = $q
 591       ? '"artist_pk_seq"'
 592       : '"ARTIST_PK_SEQ"'
 593     ;
 594     delete $rs2->result_source->column_info('artistid')->{sequence};
 595     $dbh->do(qq{
 596       CREATE OR REPLACE TRIGGER ${q}artist_insert_trg_pk${q}
 597       BEFORE INSERT ON ${q}artist${q}
 598       FOR EACH ROW
 599       BEGIN
 600         IF :new.${q}artistid${q} IS NULL THEN
 601           SELECT $q_seq.nextval
 602           INTO :new.${q}artistid${q}
 603           FROM DUAL;
 604         END IF;
 605       END;
 606     });
 607
 608
 609     lives_and {
 610       my $row = $rs2->create({ name => 'From Different Schema With Quoted Sequence' });
 611       ok $row->artistid;
 612     } 'used quoted autoinc sequence across schemas';
 613
 614     is_deeply $rs2->result_source->column_info('artistid')->{sequence},
 615       \( (uc $user) . ".$q_seq"),
 616       'quoted sequence name correctly extracted';
 617
 618     # try an insert operation on the default user2 artist
 619     my $art1 = $schema->resultset('Artist');
 620     my $art2 = $schema2->resultset('Artist');
 621     my $art1_count = $art1->count || 0;
 622     my $art2_count = $art2->count;
 623
 624     is( $art2_count, 0, 'No artists created yet in second schema' );
 625
 626     delete $art2->result_source->column_info('artistid')->{sequence};
 627     my $new_art = $art2->create({ name => '2nd best' });
 628
 629     is ($art1->count, $art1_count, 'No new rows in main schema');
 630     is ($art2->count, 1, 'One artist create in 2nd schema');
 631
 632     is( $new_art->artistid, 1, 'Expected first PK' );
 633
 634     do_clean ($dbh2);
 635   }}
 636
 637   do_clean ($dbh);
 638 }
 639
 640 done_testing;
 641
 642 sub do_creates {
 643   my ($dbh, $q) = @_;
 644
 645   do_clean($dbh);
 646
 647   $dbh->do("CREATE SEQUENCE ${q}artist_autoinc_seq${q} START WITH 1 MAXVALUE 999999 MINVALUE 0");
 648   $dbh->do("CREATE SEQUENCE ${q}artist_pk_seq${q} START WITH 1 MAXVALUE 999999 MINVALUE 0");
 649   $dbh->do("CREATE SEQUENCE ${q}cd_seq${q} START WITH 1 MAXVALUE 999999 MINVALUE 0");
 650   $dbh->do("CREATE SEQUENCE ${q}track_seq${q} START WITH 1 MAXVALUE 999999 MINVALUE 0");
 651
 652   $dbh->do("CREATE SEQUENCE ${q}nonpkid_seq${q} START WITH 20 MAXVALUE 999999 MINVALUE 0");
 653   # this one is always quoted as per manually specified sequence =>
 654   $dbh->do('CREATE SEQUENCE "pkid1_seq" START WITH 1 MAXVALUE 999999 MINVALUE 0');
 655   # this one is always unquoted as per manually specified sequence =>
 656   $dbh->do("CREATE SEQUENCE pkid2_seq START WITH 10 MAXVALUE 999999 MINVALUE 0");
 657
 658   $dbh->do("CREATE TABLE ${q}artist${q} (${q}artistid${q} NUMBER(12), ${q}name${q} VARCHAR(255),${q}default_value_col${q} VARCHAR(255) DEFAULT 'default_value', ${q}autoinc_col${q} NUMBER(12), ${q}rank${q} NUMBER(38), ${q}charfield${q} VARCHAR2(10))");
 659   $dbh->do("ALTER TABLE ${q}artist${q} ADD (CONSTRAINT ${q}artist_pk${q} PRIMARY KEY (${q}artistid${q}))");
 660
 661   $dbh->do("CREATE TABLE ${q}sequence_test${q} (${q}pkid1${q} NUMBER(12), ${q}pkid2${q} NUMBER(12), ${q}nonpkid${q} NUMBER(12), ${q}name${q} VARCHAR(255))");
 662   $dbh->do("ALTER TABLE ${q}sequence_test${q} ADD (CONSTRAINT ${q}sequence_test_constraint${q} PRIMARY KEY (${q}pkid1${q}, ${q}pkid2${q}))");
 663
 664   # table cd will be unquoted => Oracle will see it as uppercase
 665   $dbh->do("CREATE TABLE cd (${q}cdid${q} NUMBER(12), ${q}artist${q} NUMBER(12), ${q}title${q} VARCHAR(255), ${q}year${q} VARCHAR(4), ${q}genreid${q} NUMBER(12), ${q}single_track${q} NUMBER(12))");
 666   $dbh->do("ALTER TABLE cd ADD (CONSTRAINT ${q}cd_pk${q} PRIMARY KEY (${q}cdid${q}))");
 667
 668   $dbh->do("CREATE TABLE ${q}track${q} (${q}trackid${q} NUMBER(12), ${q}cd${q} NUMBER(12) REFERENCES CD(${q}cdid${q}) DEFERRABLE, ${q}position${q} NUMBER(12), ${q}title${q} VARCHAR(255), ${q}last_updated_on${q} DATE, ${q}last_updated_at${q} DATE)");
 669   $dbh->do("ALTER TABLE ${q}track${q} ADD (CONSTRAINT ${q}track_pk${q} PRIMARY KEY (${q}trackid${q}))");
 670
 671   $dbh->do("CREATE TABLE ${q}bindtype_test${q} (${q}id${q} integer NOT NULL PRIMARY KEY, ${q}bytea${q} integer NULL, ${q}blob${q} blob NULL, ${q}clob${q} clob NULL, ${q}a_memo${q} integer NULL)");
 672
 673   $dbh->do(qq{
 674     CREATE OR REPLACE TRIGGER ${q}artist_insert_trg_auto${q}
 675     BEFORE INSERT ON ${q}artist${q}
 676     FOR EACH ROW
 677     BEGIN
 678       IF :new.${q}autoinc_col${q} IS NULL THEN
 679         SELECT ${q}artist_autoinc_seq${q}.nextval
 680         INTO :new.${q}autoinc_col${q}
 681         FROM DUAL;
 682       END IF;
 683     END;
 684   });
 685
 686   $dbh->do(qq{
 687     CREATE OR REPLACE TRIGGER ${q}artist_insert_trg_pk${q}
 688     BEFORE INSERT ON ${q}artist${q}
 689     FOR EACH ROW
 690     BEGIN
 691       IF :new.${q}artistid${q} IS NULL THEN
 692         SELECT ${q}artist_pk_seq${q}.nextval
 693         INTO :new.${q}artistid${q}
 694         FROM DUAL;
 695       END IF;
 696     END;
 697   });
 698
 699   $dbh->do(qq{
 700     CREATE OR REPLACE TRIGGER ${q}cd_insert_trg${q}
 701     BEFORE INSERT OR UPDATE ON cd
 702     FOR EACH ROW
 703
 704     DECLARE
 705     tmpVar NUMBER;
 706
 707     BEGIN
 708       tmpVar := 0;
 709
 710       IF :new.${q}cdid${q} IS NULL THEN
 711         SELECT ${q}cd_seq${q}.nextval
 712         INTO tmpVar
 713         FROM dual;
 714
 715         :new.${q}cdid${q} := tmpVar;
 716       END IF;
 717     END;
 718   });
 719
 720   $dbh->do(qq{
 721     CREATE OR REPLACE TRIGGER ${q}track_insert_trg${q}
 722     BEFORE INSERT ON ${q}track${q}
 723     FOR EACH ROW
 724     BEGIN
 725       IF :new.${q}trackid${q} IS NULL THEN
 726         SELECT ${q}track_seq${q}.nextval
 727         INTO :new.${q}trackid${q}
 728         FROM DUAL;
 729       END IF;
 730     END;
 731   });
 732 }
 733
 734 # clean up our mess
 735 sub do_clean {
 736
 737   my $dbh = shift || return;
 738
 739   for my $q ('', '"') {
 740     my @clean = (
 741       "DROP TRIGGER ${q}track_insert_trg${q}",
 742       "DROP TRIGGER ${q}cd_insert_trg${q}",
 743       "DROP TRIGGER ${q}artist_insert_trg_auto${q}",
 744       "DROP TRIGGER ${q}artist_insert_trg_pk${q}",
 745       "DROP SEQUENCE ${q}nonpkid_seq${q}",
 746       "DROP SEQUENCE ${q}pkid2_seq${q}",
 747       "DROP SEQUENCE ${q}pkid1_seq${q}",
 748       "DROP SEQUENCE ${q}track_seq${q}",
 749       "DROP SEQUENCE ${q}cd_seq${q}",
 750       "DROP SEQUENCE ${q}artist_autoinc_seq${q}",
 751       "DROP SEQUENCE ${q}artist_pk_seq${q}",
 752       "DROP TABLE ${q}bindtype_test${q}",
 753       "DROP TABLE ${q}sequence_test${q}",
 754       "DROP TABLE ${q}track${q}",
 755       "DROP TABLE ${q}cd${q}",
 756       "DROP TABLE ${q}artist${q}",
 757     );
 758     eval { $dbh -> do ($_) } for @clean;
 759   }
 760 }
 761
 762 END {
 763   for ($dbh, $dbh2) {
 764     next unless $_;
 765     local $SIG{__WARN__} = sub {};
 766     do_clean($_);
 767     $_->disconnect;
 768   }
 769 }