t/73oracle.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use lib qw(t/lib);
   6 use DBICTest;
   7
   8 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_ORA_${_}" } qw/DSN USER PASS/};
   9
  10 plan skip_all => 'Set $ENV{DBICTEST_ORA_DSN}, _USER and _PASS to run this test. ' .
  11   'Warning: This test drops and creates tables called \'artist\', \'cd\' and \'track\''
  12   unless ($dsn && $user && $pass);
  13
  14 plan tests => 6;
  15
  16 my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
  17
  18 my $dbh = $schema->storage->dbh;
  19
  20 eval {
  21   $dbh->do("DROP SEQUENCE artist_seq");
  22   $dbh->do("DROP TABLE artist");
  23   $dbh->do("DROP TABLE cd");
  24   $dbh->do("DROP TABLE track");
  25 };
  26 $dbh->do("CREATE SEQUENCE artist_seq START WITH 1 MAXVALUE 999999 MINVALUE 0");
  27 $dbh->do("CREATE TABLE artist (artistid NUMBER(12), name VARCHAR(255))");
  28 $dbh->do("CREATE TABLE cd (cdid NUMBER(12), artist NUMBER(12), title VARCHAR(255), year VARCHAR(4))");
  29 $dbh->do("CREATE TABLE track (trackid NUMBER(12), cd NUMBER(12), position NUMBER(12), title VARCHAR(255))");
  30
  31 $dbh->do("ALTER TABLE artist ADD (CONSTRAINT artist_pk PRIMARY KEY (artistid))");
  32 $dbh->do(qq{
  33   CREATE OR REPLACE TRIGGER artist_insert_trg
  34   BEFORE INSERT ON artist
  35   FOR EACH ROW
  36   BEGIN
  37     IF :new.artistid IS NULL THEN
  38       SELECT artist_seq.nextval
  39       INTO :new.artistid
  40       FROM DUAL;
  41     END IF;
  42   END;
  43 });
  44
  45 # This is in Core now, but it's here just to test that it doesn't break
  46 $schema->class('Artist')->load_components('PK::Auto');
  47 # These are compat shims for PK::Auto...
  48 $schema->class('CD')->load_components('PK::Auto::Oracle');
  49 $schema->class('Track')->load_components('PK::Auto::Oracle');
  50
  51 # test primary key handling
  52 my $new = $schema->resultset('Artist')->create({ name => 'foo' });
  53 is($new->artistid, 1, "Oracle Auto-PK worked");
  54
  55 # test join with row count ambiguity
  56 my $cd = $schema->resultset('CD')->create({ cdid => 1, artist => 1, title => 'EP C', year => '2003' });
  57 my $track = $schema->resultset('Track')->create({ trackid => 1, cd => 1, position => 1, title => 'Track1' });
  58 my $tjoin = $schema->resultset('Track')->search({ 'me.title' => 'Track1'},
  59         { join => 'cd',
  60           rows => 2 }
  61 );
  62
  63 is($tjoin->next->title, 'Track1', "ambiguous column ok");
  64
  65 # check count distinct with multiple columns
  66 my $other_track = $schema->resultset('Track')->create({ trackid => 2, cd => 1, position => 1, title => 'Track2' });
  67 my $tcount = $schema->resultset('Track')->search(
  68     {},
  69     {
  70         select => [{count => {distinct => ['position', 'title']}}],
  71         as => ['count']
  72     }
  73   );
  74
  75 is($tcount->next->get_column('count'), 2, "multiple column select distinct ok");
  76
  77 # test LIMIT support
  78 for (1..6) {
  79     $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
  80 }
  81 my $it = $schema->resultset('Artist')->search( {},
  82     { rows => 3,
  83       offset => 2,
  84       order_by => 'artistid' }
  85 );
  86 is( $it->count, 3, "LIMIT count ok" );
  87 is( $it->next->name, "Artist 2", "iterator->next ok" );
  88 $it->next;
  89 $it->next;
  90 is( $it->next, undef, "next past end of resultset ok" );
  91
  92 # clean up our mess
  93 END {
  94     if($dbh) {
  95         $dbh->do("DROP SEQUENCE artist_seq");
  96         $dbh->do("DROP TABLE artist");
  97         $dbh->do("DROP TABLE cd");
  98         $dbh->do("DROP TABLE track");
  99     }
 100 }
 101