t/72pg.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use Sub::Name;
   7 use Config;
   8 use DBIx::Class::Optional::Dependencies ();
   9 use lib qw(t/lib);
  10 use DBICTest;
  11 use SQL::Abstract 'is_literal_value';
  12 use DBIx::Class::_Util 'is_exception';
  13
  14 plan skip_all => 'Test needs ' . DBIx::Class::Optional::Dependencies->req_missing_for ('test_rdbms_pg')
  15   unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_rdbms_pg');
  16
  17 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
  18
  19 plan skip_all => <<'EOM' unless $dsn && $user;
  20 Set $ENV{DBICTEST_PG_DSN}, _USER and _PASS to run this test
  21 ( NOTE: This test drops and creates tables called 'artist', 'cd',
  22 'timestamp_primary_key_test', 'track', 'casecheck', 'array_test' and
  23 'sequence_test' as well as following sequences: 'pkid1_seq', 'pkid2_seq' and
  24 'nonpkid_seq'. as well as following schemas: 'dbic_t_schema',
  25 'dbic_t_schema_2', 'dbic_t_schema_3', 'dbic_t_schema_4', and 'dbic_t_schema_5')
  26 EOM
  27
  28 ### load any test classes that are defined further down in the file via BEGIN blocks
  29
  30 our @test_classes; #< array that will be pushed into by test classes defined in this file
  31 DBICTest::Schema->load_classes( map {s/.+:://;$_} @test_classes ) if @test_classes;
  32
  33 ###  pre-connect tests (keep each test separate as to make sure rebless() runs)
  34   {
  35     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  36
  37     ok (!$s->storage->_dbh, 'definitely not connected');
  38
  39     # Check that datetime_parser returns correctly before we explicitly connect.
  40     SKIP: {
  41         skip (
  42           "Pg parser detection test needs " . DBIx::Class::Optional::Dependencies->req_missing_for ('test_dt_pg'),
  43           2
  44         ) unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_dt_pg');
  45
  46         my $store = ref $s->storage;
  47         is($store, 'DBIx::Class::Storage::DBI', 'Started with generic storage');
  48
  49         my $parser = $s->storage->datetime_parser;
  50         is( $parser, 'DateTime::Format::Pg', 'datetime_parser is as expected');
  51     }
  52
  53     ok (!$s->storage->_dbh, 'still not connected');
  54   }
  55
  56   {
  57     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  58     # make sure sqlt_type overrides work (::Storage::DBI::Pg does this)
  59     ok (!$s->storage->_dbh, 'definitely not connected');
  60     is ($s->storage->sqlt_type, 'PostgreSQL', 'sqlt_type correct pre-connection');
  61     ok (!$s->storage->_dbh, 'still not connected');
  62   }
  63
  64 # test LIMIT support
  65 {
  66   my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
  67   drop_test_schema($schema);
  68   create_test_schema($schema);
  69   for (1..6) {
  70     $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
  71   }
  72   my $it = $schema->resultset('Artist')->search( {},
  73     { rows => 3,
  74       offset => 2,
  75       order_by => 'artistid' }
  76   );
  77   is( $it->count, 3, "LIMIT count ok" );  # ask for 3 rows out of 6 artists
  78   is( $it->next->name, "Artist 3", "iterator->next ok" );
  79   $it->next;
  80   $it->next;
  81   $it->next;
  82   is( $it->next, undef, "next past end of resultset ok" );
  83
  84   # Limit with select-lock
  85   lives_ok {
  86     $schema->txn_do (sub {
  87       isa_ok (
  88         $schema->resultset('Artist')->find({artistid => 1}, {for => 'update', rows => 1}),
  89         'DBICTest::Schema::Artist',
  90       );
  91     });
  92   } 'Limited FOR UPDATE select works';
  93 }
  94
  95 # check if we indeed do support stuff
  96 my $test_server_supports_insert_returning = do {
  97
  98   my $si = DBICTest::Schema->connect($dsn, $user, $pass)->storage->_server_info;
  99   die "Unparseable Pg server version: $si->{dbms_version}\n"
 100     unless $si->{normalized_dbms_version};
 101
 102   $si->{normalized_dbms_version} < 8.002 ? 0 : 1;
 103 };
 104 is (
 105   DBICTest::Schema->connect($dsn, $user, $pass)->storage->_use_insert_returning,
 106   $test_server_supports_insert_returning,
 107   'insert returning capability guessed correctly'
 108 );
 109
 110 my $schema;
 111 for my $use_insert_returning ($test_server_supports_insert_returning
 112   ? (0,1)
 113   : (0)
 114 ) {
 115
 116   no warnings qw/once redefine/;
 117   my $old_connection = DBICTest::Schema->can('connection');
 118   local *DBICTest::Schema::connection = subname 'DBICTest::Schema::connection' => sub {
 119     my $s = shift->$old_connection(@_);
 120     $s->storage->_use_insert_returning ($use_insert_returning);
 121     $s;
 122   };
 123
 124 ### test capability override
 125   {
 126     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
 127
 128     ok (!$s->storage->_dbh, 'definitely not connected');
 129
 130     ok (
 131       ! ($s->storage->_use_insert_returning xor $use_insert_returning),
 132       'insert returning capability set correctly',
 133     );
 134     ok (!$s->storage->_dbh, 'still not connected (capability override works)');
 135   }
 136
 137 ### connect, create postgres-specific test schema
 138
 139   $schema = DBICTest::Schema->connect($dsn, $user, $pass);
 140   $schema->storage->ensure_connected;
 141
 142   drop_test_schema($schema);
 143   create_test_schema($schema);
 144
 145 ### begin main tests
 146
 147 # run a BIG bunch of tests for last-insert-id / Auto-PK / sequence
 148 # discovery
 149   run_apk_tests($schema); #< older set of auto-pk tests
 150   run_extended_apk_tests($schema); #< new extended set of auto-pk tests
 151
 152
 153 ######## test the pg-specific syntax from https://rt.cpan.org/Ticket/Display.html?id=99503
 154   lives_ok {
 155     is(
 156       $schema->resultset('Artist')->search({ artistid => { -in => \ '(select 4) union (select 5)' } })->count,
 157       2,
 158       'Two expected artists found on subselect union within IN',
 159     );
 160   };
 161
 162 ### type_info tests
 163
 164   my $test_type_info = {
 165       'artistid' => {
 166           'data_type' => 'integer',
 167           'is_nullable' => 0,
 168           'size' => 4,
 169       },
 170       'name' => {
 171           'data_type' => 'character varying',
 172           'is_nullable' => 1,
 173           'size' => 100,
 174           'default_value' => undef,
 175       },
 176       'rank' => {
 177           'data_type' => 'integer',
 178           'is_nullable' => 0,
 179           'size' => 4,
 180           'default_value' => 13,
 181
 182       },
 183       'charfield' => {
 184           'data_type' => 'character',
 185           'is_nullable' => 1,
 186           'size' => 10,
 187           'default_value' => undef,
 188       },
 189       'arrayfield' => {
 190           'data_type' => 'integer[]',
 191           'is_nullable' => 1,
 192           'size' => undef,
 193           'default_value' => undef,
 194       },
 195   };
 196
 197   my $type_info = $schema->storage->columns_info_for('dbic_t_schema.artist');
 198   my $artistid_defval = delete $type_info->{artistid}->{default_value};
 199
 200   # The curor info is too radically different from what is in the column_info
 201   # call - just punt it (DBD::SQLite tests the codepath plenty enough)
 202   unless (DBIx::Class::_ENV_::STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE) {
 203     like(
 204       $artistid_defval,
 205       qr/^nextval\('([^\.]*\.){0,1}artist_artistid_seq'::(?:text|regclass)\)/,
 206       'columns_info_for - sequence matches Pg get_autoinc_seq expectations'
 207     );
 208
 209     is_deeply($type_info, $test_type_info,
 210             'columns_info_for - column data types');
 211   }
 212
 213 ####### Array tests
 214
 215   BEGIN {
 216     package DBICTest::Schema::ArrayTest;
 217     push @main::test_classes, __PACKAGE__;
 218
 219     use strict;
 220     use warnings;
 221     use base 'DBICTest::BaseResult';
 222
 223     __PACKAGE__->table('dbic_t_schema.array_test');
 224     __PACKAGE__->add_columns(qw/id arrayfield/);
 225     __PACKAGE__->column_info_from_storage(1);
 226     __PACKAGE__->set_primary_key('id');
 227
 228   }
 229   SKIP: {
 230     skip "Need DBD::Pg 2.9.2 or newer for array tests", 4 if $DBD::Pg::VERSION < 2.009002;
 231
 232     my $arr_rs = $schema->resultset('ArrayTest');
 233
 234     lives_ok {
 235       $arr_rs->create({
 236         arrayfield => [1, 2],
 237       });
 238     } 'inserting arrayref as pg array data';
 239
 240     lives_ok {
 241       $arr_rs->update({
 242         arrayfield => [3, 4],
 243       });
 244     } 'updating arrayref as pg array data';
 245
 246     $arr_rs->create({
 247       arrayfield => [5, 6],
 248     });
 249
 250     lives_ok {
 251       $schema->populate('ArrayTest', [
 252         [ qw/arrayfield/ ],
 253         [ [0,0]          ],
 254       ]);
 255     } 'inserting arrayref using void ctx populate';
 256
 257     # Search using arrays
 258     lives_ok {
 259       is_deeply (
 260         $arr_rs->search({ arrayfield => { -value => [3,4] } })->first->arrayfield,
 261         [3,4],
 262         'Array value matches'
 263       );
 264     } 'searching by arrayref';
 265
 266     lives_ok {
 267       is_deeply (
 268         $arr_rs->search({ arrayfield => { '=' => { -value => [3,4] }} })->first->arrayfield,
 269         [3,4],
 270         'Array value matches explicit equal'
 271       );
 272     } 'searching by arrayref (explicit equal sign)';
 273
 274     lives_ok {
 275       is_deeply (
 276         $arr_rs->search({ arrayfield => { '>' => { -value => [3,1] }} })->first->arrayfield,
 277         [3,4],
 278         'Array value matches greater than'
 279       );
 280     } 'searching by arrayref (greater than)';
 281
 282     lives_ok {
 283       is (
 284         $arr_rs->search({ arrayfield => { '>' => { -value => [3,7] }} })->count,
 285         1,
 286         'Greater than search found [5,6]',
 287       );
 288     } 'searching by arrayref (greater than)';
 289
 290     # Find using arrays
 291     lives_ok {
 292       is_deeply (
 293         $arr_rs->find({ arrayfield => { -value => [3,4] } })->arrayfield,
 294         [3,4],
 295         'Array value matches implicit equal'
 296       );
 297     } 'find by arrayref';
 298
 299     lives_ok {
 300       is_deeply (
 301         $arr_rs->find({ arrayfield => { '=' => { -value => [3,4] }} })->arrayfield,
 302         [3,4],
 303         'Array value matches explicit equal'
 304       );
 305     } 'find by arrayref (equal)';
 306
 307     # test inferred condition for creation
 308     for my $cond (
 309       { -value => [3,4] },
 310       \[ '= ?' => [arrayfield => [3, 4]] ],
 311     ) {
 312       local $TODO = 'No introspection of complex literal conditions :('
 313         if is_literal_value $cond;
 314
 315
 316       my $arr_rs_cond = $arr_rs->search({ arrayfield => $cond });
 317
 318       my $row = $arr_rs_cond->create({});
 319       is_deeply ($row->arrayfield, [3,4], 'Array value taken from $rs condition');
 320       $row->discard_changes;
 321       is_deeply ($row->arrayfield, [3,4], 'Array value made it to storage');
 322     }
 323   }
 324
 325 ########## Case check
 326
 327   BEGIN {
 328     package DBICTest::Schema::Casecheck;
 329     push @main::test_classes, __PACKAGE__;
 330
 331     use strict;
 332     use warnings;
 333     use base 'DBIx::Class::Core';
 334
 335     __PACKAGE__->table('dbic_t_schema.casecheck');
 336     __PACKAGE__->add_columns(qw/id name NAME uc_name/);
 337     __PACKAGE__->column_info_from_storage(1);
 338     __PACKAGE__->set_primary_key('id');
 339   }
 340
 341   my $name_info = $schema->source('Casecheck')->column_info( 'name' );
 342   is( $name_info->{size}, 1, "Case sensitive matching info for 'name'" );
 343
 344   my $NAME_info = $schema->source('Casecheck')->column_info( 'NAME' );
 345   is( $NAME_info->{size}, 2, "Case sensitive matching info for 'NAME'" );
 346
 347   my $uc_name_info = $schema->source('Casecheck')->column_info( 'uc_name' );
 348   is( $uc_name_info->{size}, 3, "Case insensitive matching info for 'uc_name'" );
 349
 350
 351 ## Test ResultSet->update
 352 my $artist = $schema->resultset('Artist')->first;
 353 my $cds = $artist->cds_unordered->search({
 354     year => { '!=' => 2010 }
 355 }, { prefetch => 'liner_notes' });
 356 lives_ok { $cds->update({ year => '2010' }) } 'Update on prefetched rs';
 357
 358 ## Test SELECT ... FOR UPDATE
 359   SKIP: {
 360       skip "Your system does not support unsafe signals (d_sigaction) - unable to run deadlock test", 1
 361         unless eval { $Config{d_sigaction} and require POSIX };
 362
 363       my ($timed_out, $artist2);
 364
 365       for my $t (
 366         {
 367           # Make sure that an error was raised, and that the update failed
 368           update_lock => 1,
 369           test_sub => sub {
 370             ok($timed_out, "update from second schema times out");
 371             ok($artist2->is_column_changed('name'), "'name' column is still dirty from second schema");
 372           },
 373         },
 374         {
 375           # Make sure that an error was NOT raised, and that the update succeeded
 376           update_lock => 0,
 377           test_sub => sub {
 378             ok(! $timed_out, "update from second schema DOES NOT timeout");
 379             ok(! $artist2->is_column_changed('name'), "'name' column is NOT dirty from second schema");
 380           },
 381         },
 382       ) {
 383         # create a new schema
 384         my $schema2 = DBICTest::Schema->connect($dsn, $user, $pass);
 385         $schema2->source("Artist")->name("dbic_t_schema.artist");
 386
 387         $schema->txn_do( sub {
 388           my $rs = $schema->resultset('Artist')->search(
 389               {
 390                   artistid => 1
 391               },
 392               $t->{update_lock} ? { for => 'update' } : {}
 393           );
 394           ok ($rs->count, 'Count works');
 395
 396           my $artist = $rs->next;
 397           is($artist->artistid, 1, "select returns artistid = 1");
 398
 399           $timed_out = 0;
 400
 401           eval {
 402               # can not use %SIG assignment directly - we need sigaction below
 403               # localization to a block still works however
 404               local $SIG{ALRM};
 405
 406               POSIX::sigaction( POSIX::SIGALRM() => POSIX::SigAction->new(
 407                 sub { die "DBICTestTimeout" },
 408               ));
 409
 410               alarm(2);
 411               $artist2 = $schema2->resultset('Artist')->find(1);
 412               $artist2->name('fooey');
 413               $artist2->update;
 414           };
 415
 416           alarm(0);
 417
 418           if (is_exception($@)) {
 419             $timed_out = $@ =~ /DBICTestTimeout/
 420               or die $@;
 421           }
 422         });
 423
 424         $t->{test_sub}->();
 425       }
 426   }
 427
 428
 429 ######## other older Auto-pk tests
 430
 431   $schema->source("SequenceTest")->name("dbic_t_schema.sequence_test");
 432   for (1..5) {
 433       my $st = $schema->resultset('SequenceTest')->create({ name => 'foo' });
 434       is($st->pkid1, $_, "Auto-PK for sequence without default: First primary key");
 435       is($st->pkid2, $_ + 9, "Auto-PK for sequence without default: Second primary key");
 436       is($st->nonpkid, $_ + 19, "Auto-PK for sequence without default: Non-primary key");
 437   }
 438   my $st = $schema->resultset('SequenceTest')->create({ name => 'foo', pkid1 => 55 });
 439   is($st->pkid1, 55, "Auto-PK for sequence without default: First primary key set manually");
 440
 441
 442 ######## test non-serial auto-pk
 443
 444   if ($schema->storage->_use_insert_returning) {
 445     $schema->source('TimestampPrimaryKey')->name('dbic_t_schema.timestamp_primary_key_test');
 446     my $row = $schema->resultset('TimestampPrimaryKey')->create({});
 447     ok $row->id;
 448   }
 449
 450 ######## test with_deferred_fk_checks
 451
 452   $schema->source('CD')->name('dbic_t_schema.cd');
 453   $schema->source('Track')->name('dbic_t_schema.track');
 454   lives_ok {
 455     $schema->storage->with_deferred_fk_checks(sub {
 456       $schema->resultset('Track')->create({
 457         trackid => 999, cd => 999, position => 1, title => 'deferred FK track'
 458       });
 459       $schema->resultset('CD')->create({
 460         artist => 1, cdid => 999, year => '2003', title => 'deferred FK cd'
 461       });
 462     });
 463   } 'with_deferred_fk_checks code survived';
 464
 465   is eval { $schema->resultset('Track')->find(999)->title }, 'deferred FK track',
 466      'code in with_deferred_fk_checks worked';
 467
 468   throws_ok {
 469     $schema->resultset('Track')->create({
 470       trackid => 1, cd => 9999, position => 1, title => 'Track1'
 471     });
 472   } qr/constraint/i, 'with_deferred_fk_checks is off';
 473 }
 474
 475 done_testing;
 476
 477 END {
 478     return unless $schema;
 479     drop_test_schema($schema);
 480     eapk_drop_all($schema);
 481     undef $schema;
 482 };
 483
 484
 485 ######### SUBROUTINES
 486
 487 sub create_test_schema {
 488     my $schema = shift;
 489     $schema->storage->dbh_do(sub {
 490       my (undef,$dbh) = @_;
 491
 492       local $dbh->{Warn} = 0;
 493
 494       my $std_artist_table = <<EOS;
 495 (
 496   artistid serial PRIMARY KEY
 497   , name VARCHAR(100)
 498   , rank INTEGER NOT NULL DEFAULT '13'
 499   , charfield CHAR(10)
 500   , arrayfield INTEGER[]
 501 )
 502 EOS
 503
 504       $dbh->do("CREATE SCHEMA dbic_t_schema");
 505       $dbh->do("CREATE TABLE dbic_t_schema.artist $std_artist_table");
 506
 507       $dbh->do(<<EOS);
 508 CREATE TABLE dbic_t_schema.timestamp_primary_key_test (
 509   id timestamp default current_timestamp
 510 )
 511 EOS
 512       $dbh->do(<<EOS);
 513 CREATE TABLE dbic_t_schema.cd (
 514   cdid int PRIMARY KEY,
 515   artist int,
 516   title varchar(255),
 517   year varchar(4),
 518   genreid int,
 519   single_track int
 520 )
 521 EOS
 522       $dbh->do(<<EOS);
 523 CREATE TABLE dbic_t_schema.track (
 524   trackid int,
 525   cd int REFERENCES dbic_t_schema.cd(cdid) DEFERRABLE,
 526   position int,
 527   title varchar(255),
 528   last_updated_on date,
 529   last_updated_at date
 530 )
 531 EOS
 532
 533       $dbh->do(<<EOS);
 534 CREATE TABLE dbic_t_schema.sequence_test (
 535     pkid1 integer
 536     , pkid2 integer
 537     , nonpkid integer
 538     , name VARCHAR(100)
 539     , CONSTRAINT pk PRIMARY KEY(pkid1, pkid2)
 540 )
 541 EOS
 542       $dbh->do("CREATE SEQUENCE pkid1_seq START 1 MAXVALUE 999999 MINVALUE 0");
 543       $dbh->do("CREATE SEQUENCE pkid2_seq START 10 MAXVALUE 999999 MINVALUE 0");
 544       $dbh->do("CREATE SEQUENCE nonpkid_seq START 20 MAXVALUE 999999 MINVALUE 0");
 545       $dbh->do(<<EOS);
 546 CREATE TABLE dbic_t_schema.casecheck (
 547     id serial PRIMARY KEY
 548     , "name" VARCHAR(1)
 549     , "NAME" VARCHAR(2)
 550     , "UC_NAME" VARCHAR(3)
 551 )
 552 EOS
 553       $dbh->do(<<EOS);
 554 CREATE TABLE dbic_t_schema.array_test (
 555     id serial PRIMARY KEY
 556     , arrayfield INTEGER[]
 557 )
 558 EOS
 559       $dbh->do("CREATE SCHEMA dbic_t_schema_2");
 560       $dbh->do("CREATE TABLE dbic_t_schema_2.artist $std_artist_table");
 561       $dbh->do("CREATE SCHEMA dbic_t_schema_3");
 562       $dbh->do("CREATE TABLE dbic_t_schema_3.artist $std_artist_table");
 563       $dbh->do('set search_path=dbic_t_schema,public');
 564       $dbh->do("CREATE SCHEMA dbic_t_schema_4");
 565       $dbh->do("CREATE SCHEMA dbic_t_schema_5");
 566       $dbh->do(<<EOS);
 567  CREATE TABLE dbic_t_schema_4.artist
 568  (
 569    artistid integer not null default nextval('artist_artistid_seq'::regclass) PRIMARY KEY
 570    , name VARCHAR(100)
 571    , rank INTEGER NOT NULL DEFAULT '13'
 572    , charfield CHAR(10)
 573    , arrayfield INTEGER[]
 574  );
 575 EOS
 576       $dbh->do('set search_path=public,dbic_t_schema,dbic_t_schema_3');
 577       $dbh->do('create sequence public.artist_artistid_seq'); #< in the public schema
 578       $dbh->do(<<EOS);
 579  CREATE TABLE dbic_t_schema_5.artist
 580  (
 581    artistid integer not null default nextval('public.artist_artistid_seq'::regclass) PRIMARY KEY
 582    , name VARCHAR(100)
 583    , rank INTEGER NOT NULL DEFAULT '13'
 584    , charfield CHAR(10)
 585    , arrayfield INTEGER[]
 586  );
 587 EOS
 588       $dbh->do('set search_path=dbic_t_schema,public');
 589   });
 590 }
 591
 592
 593
 594 sub drop_test_schema {
 595     my ( $schema, $warn_exceptions ) = @_;
 596
 597     $schema->storage->dbh_do(sub {
 598         my (undef,$dbh) = @_;
 599
 600         local $dbh->{Warn} = 0;
 601
 602         for my $stat (
 603                       'DROP SCHEMA dbic_t_schema_5 CASCADE',
 604                       'DROP SEQUENCE public.artist_artistid_seq CASCADE',
 605                       'DROP SCHEMA dbic_t_schema_4 CASCADE',
 606                       'DROP SCHEMA dbic_t_schema CASCADE',
 607                       'DROP SEQUENCE pkid1_seq CASCADE',
 608                       'DROP SEQUENCE pkid2_seq CASCADE',
 609                       'DROP SEQUENCE nonpkid_seq CASCADE',
 610                       'DROP SCHEMA dbic_t_schema_2 CASCADE',
 611                       'DROP SCHEMA dbic_t_schema_3 CASCADE',
 612                      ) {
 613             eval { $dbh->do ($stat) };
 614             diag $@ if $@ && $warn_exceptions;
 615         }
 616     });
 617 }
 618
 619
 620 ###  auto-pk / last_insert_id / sequence discovery
 621 sub run_apk_tests {
 622     my $schema = shift;
 623
 624     # This is in Core now, but it's here just to test that it doesn't break
 625     $schema->class('Artist')->load_components('PK::Auto');
 626     cmp_ok( $schema->resultset('Artist')->count, '==', 0, 'this should start with an empty artist table');
 627
 628     # test that auto-pk also works with the defined search path by
 629     # un-schema-qualifying the table name
 630     apk_t_set($schema,'artist');
 631
 632     my $unq_new;
 633     lives_ok {
 634         $unq_new = $schema->resultset('Artist')->create({ name => 'baz' });
 635     } 'insert into unqualified, shadowed table succeeds';
 636
 637     is($unq_new && $unq_new->artistid, 1, "and got correct artistid");
 638
 639     my @test_schemas = ( [qw| dbic_t_schema_2    1  |],
 640                          [qw| dbic_t_schema_3    1  |],
 641                          [qw| dbic_t_schema_4    2  |],
 642                          [qw| dbic_t_schema_5    1  |],
 643                        );
 644     foreach my $t ( @test_schemas ) {
 645         my ($sch_name, $start_num) = @$t;
 646         #test with dbic_t_schema_2
 647         apk_t_set($schema,"$sch_name.artist");
 648         my $another_new;
 649         lives_ok {
 650             $another_new = $schema->resultset('Artist')->create({ name => 'Tollbooth Willy'});
 651             is( $another_new->artistid,$start_num, "got correct artistid for $sch_name")
 652                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 653         } "$sch_name liid 1 did not die"
 654             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 655         lives_ok {
 656             $another_new = $schema->resultset('Artist')->create({ name => 'Adam Sandler'});
 657             is( $another_new->artistid,$start_num+1, "got correct artistid for $sch_name")
 658                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 659         } "$sch_name liid 2 did not die"
 660             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 661
 662     }
 663
 664     lives_ok {
 665         apk_t_set($schema,'dbic_t_schema.artist');
 666         my $new = $schema->resultset('Artist')->create({ name => 'foo' });
 667         is($new->artistid, 4, "Auto-PK worked");
 668         $new = $schema->resultset('Artist')->create({ name => 'bar' });
 669         is($new->artistid, 5, "Auto-PK worked");
 670     } 'old auto-pk tests did not die either';
 671 }
 672
 673 # sets the artist table name and clears sequence name cache
 674 sub apk_t_set {
 675     my ( $s, $n ) = @_;
 676     $s->source("Artist")->name($n);
 677     $s->source('Artist')->column_info('artistid')->{sequence} = undef; #< clear sequence name cache
 678 }
 679
 680
 681 ######## EXTENDED AUTO-PK TESTS
 682
 683 my @eapk_id_columns;
 684 BEGIN {
 685   package DBICTest::Schema::ExtAPK;
 686   push @main::test_classes, __PACKAGE__;
 687
 688   use strict;
 689   use warnings;
 690   use base 'DBIx::Class::Core';
 691
 692   __PACKAGE__->table('apk');
 693
 694   @eapk_id_columns = qw( id1 id2 id3 id4 );
 695   __PACKAGE__->add_columns(
 696     map { $_ => { data_type => 'integer', is_auto_increment => 1 } }
 697        @eapk_id_columns
 698   );
 699
 700   __PACKAGE__->set_primary_key('id2'); #< note the SECOND column is
 701                                        #the primary key
 702 }
 703
 704 my @eapk_schemas;
 705 BEGIN{ @eapk_schemas = map "dbic_apk_$_", 0..5 }
 706 my %seqs; #< hash of schema.table.col => currval of its (DBIC) primary key sequence
 707
 708 sub run_extended_apk_tests {
 709   my $schema = shift;
 710
 711   #save the search path and reset it at the end
 712   my $search_path_save = eapk_get_search_path($schema);
 713
 714   eapk_drop_all($schema);
 715   %seqs = ();
 716
 717   # make the test schemas and sequences
 718   $schema->storage->dbh_do(sub {
 719     my ( undef, $dbh ) = @_;
 720
 721     $dbh->do("CREATE SCHEMA $_")
 722         for @eapk_schemas;
 723
 724     $dbh->do("CREATE SEQUENCE $eapk_schemas[5].fooseq");
 725     $dbh->do("SELECT setval('$eapk_schemas[5].fooseq',400)");
 726     $seqs{"$eapk_schemas[1].apk.id2"} = 400;
 727
 728     $dbh->do("CREATE SEQUENCE $eapk_schemas[4].fooseq");
 729     $dbh->do("SELECT setval('$eapk_schemas[4].fooseq',300)");
 730     $seqs{"$eapk_schemas[3].apk.id2"} = 300;
 731
 732     $dbh->do("CREATE SEQUENCE $eapk_schemas[3].fooseq");
 733     $dbh->do("SELECT setval('$eapk_schemas[3].fooseq',200)");
 734     $seqs{"$eapk_schemas[4].apk.id2"} = 200;
 735
 736     $dbh->do("SET search_path = ".join ',', reverse @eapk_schemas );
 737   });
 738
 739   # clear our search_path cache
 740   $schema->storage->{_pg_search_path} = undef;
 741
 742   eapk_create( $schema,
 743                with_search_path => [0,1],
 744              );
 745   eapk_create( $schema,
 746                with_search_path => [1,0,'public'],
 747                nextval => "$eapk_schemas[5].fooseq",
 748              );
 749   eapk_create( $schema,
 750                with_search_path => ['public',0,1],
 751                qualify_table => 2,
 752              );
 753   eapk_create( $schema,
 754                with_search_path => [3,1,0,'public'],
 755                nextval => "$eapk_schemas[4].fooseq",
 756              );
 757   eapk_create( $schema,
 758                with_search_path => [3,1,0,'public'],
 759                nextval => "$eapk_schemas[3].fooseq",
 760                qualify_table => 4,
 761              );
 762
 763   eapk_poke( $schema );
 764   eapk_poke( $schema, 0 );
 765   eapk_poke( $schema, 2 );
 766   eapk_poke( $schema, 4 );
 767   eapk_poke( $schema, 1 );
 768   eapk_poke( $schema, 0 );
 769   eapk_poke( $schema, 1 );
 770   eapk_poke( $schema );
 771   eapk_poke( $schema, 4 );
 772   eapk_poke( $schema, 3 );
 773   eapk_poke( $schema, 1 );
 774   eapk_poke( $schema, 2 );
 775   eapk_poke( $schema, 0 );
 776
 777   # set our search path back
 778   eapk_set_search_path( $schema, @$search_path_save );
 779 }
 780
 781 # do a DBIC create on the apk table in the given schema number (which is an
 782 # index of @eapk_schemas)
 783
 784 sub eapk_poke {
 785   my ($s, $schema_num) = @_;
 786
 787   my $schema_name = defined $schema_num
 788       ? $eapk_schemas[$schema_num]
 789       : '';
 790
 791   my $schema_name_actual = $schema_name || eapk_find_visible_schema($s);
 792
 793   $s->source('ExtAPK')->name($schema_name ? $schema_name.'.apk' : 'apk');
 794   #< clear sequence name cache
 795   $s->source('ExtAPK')->column_info($_)->{sequence} = undef
 796       for @eapk_id_columns;
 797
 798   no warnings 'uninitialized';
 799   lives_ok {
 800     my $new;
 801     for my $inc (1,2,3) {
 802       $new = $schema->resultset('ExtAPK')->create({ id1 => 1});
 803       my $proper_seqval = ++$seqs{"$schema_name_actual.apk.id2"};
 804       is( $new->id2, $proper_seqval, "$schema_name_actual.apk.id2 correct inc $inc" )
 805           or eapk_seq_diag($s,$schema_name);
 806       $new->discard_changes;
 807       is( $new->id1, 1 );
 808       for my $id ('id3','id4') {
 809         my $proper_seqval = ++$seqs{"$schema_name_actual.apk.$id"};
 810         is( $new->$id, $proper_seqval, "$schema_name_actual.apk.$id correct inc $inc" )
 811             or eapk_seq_diag($s,$schema_name);
 812       }
 813     }
 814   } "create in schema '$schema_name' lives"
 815       or eapk_seq_diag($s,$schema_name);
 816 }
 817
 818 # print diagnostic info on which sequences were found in the ExtAPK
 819 # class
 820 sub eapk_seq_diag {
 821     my $s = shift;
 822     my $schema = shift || eapk_find_visible_schema($s);
 823
 824     diag "$schema.apk sequences: ",
 825         join(', ',
 826              map "$_:".($s->source('ExtAPK')->column_info($_)->{sequence} || '<none>'),
 827              @eapk_id_columns
 828             );
 829 }
 830
 831 # get the postgres search path as an arrayref
 832 sub eapk_get_search_path {
 833     my ( $s ) = @_;
 834     # cache the search path as ['schema','schema',...] in the storage
 835     # obj
 836
 837     return $s->storage->dbh_do(sub {
 838         my (undef, $dbh) = @_;
 839         my @search_path;
 840         my ($sp_string) = $dbh->selectrow_array('SHOW search_path');
 841         while ( $sp_string =~ s/("[^"]+"|[^,]+),?// ) {
 842             unless( defined $1 and length $1 ) {
 843                 die "search path sanity check failed: '$1'";
 844             }
 845             push @search_path, $1;
 846         }
 847         \@search_path
 848     });
 849 }
 850 sub eapk_set_search_path {
 851     my ($s,@sp) = @_;
 852     my $sp = join ',',@sp;
 853     $s->storage->dbh_do( sub { $_[1]->do("SET search_path = $sp") } );
 854 }
 855
 856 # create the apk table in the given schema, can set whether the table name is qualified, what the nextval is for the second ID
 857 sub eapk_create {
 858     my ($schema, %a) = @_;
 859
 860     $schema->storage->dbh_do(sub {
 861         my (undef,$dbh) = @_;
 862
 863         my $searchpath_save;
 864         if ( $a{with_search_path} ) {
 865             ($searchpath_save) = $dbh->selectrow_array('SHOW search_path');
 866
 867             my $search_path = join ',',map {/\D/ ? $_ : $eapk_schemas[$_]} @{$a{with_search_path}};
 868
 869             $dbh->do("SET search_path = $search_path");
 870         }
 871
 872         my $table_name = $a{qualify_table}
 873             ? ($eapk_schemas[$a{qualify_table}] || die). ".apk"
 874             : 'apk';
 875         local $_[1]->{Warn} = 0;
 876
 877         my $id_def = $a{nextval}
 878             ? "integer not null default nextval('$a{nextval}'::regclass)"
 879             : 'serial';
 880         $dbh->do(<<EOS);
 881 CREATE TABLE $table_name (
 882   id1 serial
 883   , id2 $id_def
 884   , id3 serial primary key
 885   , id4 serial
 886 )
 887 EOS
 888
 889         if( $searchpath_save ) {
 890             $dbh->do("SET search_path = $searchpath_save");
 891         }
 892     });
 893 }
 894
 895 sub eapk_drop_all {
 896     my ( $schema, $warn_exceptions ) = @_;
 897
 898     $schema->storage->dbh_do(sub {
 899         my (undef,$dbh) = @_;
 900
 901         local $dbh->{Warn} = 0;
 902
 903         # drop the test schemas
 904         for (@eapk_schemas ) {
 905             eval{ $dbh->do("DROP SCHEMA $_ CASCADE") };
 906             diag $@ if $@ && $warn_exceptions;
 907         }
 908
 909
 910     });
 911 }
 912
 913 sub eapk_find_visible_schema {
 914     my ($s) = @_;
 915
 916     my ($schema) =
 917         $s->storage->dbh_do(sub {
 918             $_[1]->selectrow_array(<<EOS);
 919 SELECT n.nspname
 920 FROM pg_catalog.pg_namespace n
 921 JOIN pg_catalog.pg_class c ON c.relnamespace = n.oid
 922 WHERE c.relname = 'apk'
 923   AND pg_catalog.pg_table_is_visible(c.oid)
 924 EOS
 925         });
 926     return $schema;
 927 }