t/72pg.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use Sub::Name;
   7 use lib qw(t/lib);
   8 use DBICTest;
   9
  10
  11 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
  12
  13 plan skip_all => <<'EOM' unless $dsn && $user;
  14 Set $ENV{DBICTEST_PG_DSN}, _USER and _PASS to run this test
  15 ( NOTE: This test drops and creates tables called 'artist', 'cd',
  16 'timestamp_primary_key_test', 'track', 'casecheck', 'array_test' and
  17 'sequence_test' as well as following sequences: 'pkid1_seq', 'pkid2_seq' and
  18 'nonpkid_seq'. as well as following schemas: 'dbic_t_schema',
  19 'dbic_t_schema_2', 'dbic_t_schema_3', 'dbic_t_schema_4', and 'dbic_t_schema_5')
  20 EOM
  21
  22 ### load any test classes that are defined further down in the file via BEGIN blocks
  23
  24 our @test_classes; #< array that will be pushed into by test classes defined in this file
  25 DBICTest::Schema->load_classes( map {s/.+:://;$_} @test_classes ) if @test_classes;
  26
  27 ###  pre-connect tests (keep each test separate as to make sure rebless() runs)
  28   {
  29     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  30
  31     ok (!$s->storage->_dbh, 'definitely not connected');
  32
  33     # Check that datetime_parser returns correctly before we explicitly connect.
  34     SKIP: {
  35         skip (
  36           "Pg parser detection test needs " . DBIx::Class::Optional::Dependencies->req_missing_for ('test_dt_pg'),
  37           2
  38         ) unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_dt_pg');
  39
  40         my $store = ref $s->storage;
  41         is($store, 'DBIx::Class::Storage::DBI', 'Started with generic storage');
  42
  43         my $parser = $s->storage->datetime_parser;
  44         is( $parser, 'DateTime::Format::Pg', 'datetime_parser is as expected');
  45     }
  46
  47     ok (!$s->storage->_dbh, 'still not connected');
  48   }
  49
  50   {
  51     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  52     # make sure sqlt_type overrides work (::Storage::DBI::Pg does this)
  53     ok (!$s->storage->_dbh, 'definitely not connected');
  54     is ($s->storage->sqlt_type, 'PostgreSQL', 'sqlt_type correct pre-connection');
  55     ok (!$s->storage->_dbh, 'still not connected');
  56   }
  57
  58 # test LIMIT support
  59 {
  60   my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
  61   drop_test_schema($schema);
  62   create_test_schema($schema);
  63   for (1..6) {
  64     $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
  65   }
  66   my $it = $schema->resultset('Artist')->search( {},
  67     { rows => 3,
  68       offset => 2,
  69       order_by => 'artistid' }
  70   );
  71   is( $it->count, 3, "LIMIT count ok" );  # ask for 3 rows out of 6 artists
  72   is( $it->next->name, "Artist 3", "iterator->next ok" );
  73   $it->next;
  74   $it->next;
  75   $it->next;
  76   is( $it->next, undef, "next past end of resultset ok" );
  77
  78   # Limit with select-lock
  79   lives_ok {
  80     $schema->txn_do (sub {
  81       isa_ok (
  82         $schema->resultset('Artist')->find({artistid => 1}, {for => 'update', rows => 1}),
  83         'DBICTest::Schema::Artist',
  84       );
  85     });
  86   } 'Limited FOR UPDATE select works';
  87 }
  88
  89 # check if we indeed do support stuff
  90 my $test_server_supports_insert_returning = do {
  91   my $v = DBICTest::Schema->connect($dsn, $user, $pass)
  92                    ->storage
  93                     ->_get_dbh
  94                      ->get_info(18);
  95   $v =~ /^(\d+)\.(\d+)/
  96     or die "Unparseable Pg server version: $v\n";
  97
  98   ( sprintf ('%d.%d', $1, $2) >= 8.2 ) ? 1 : 0;
  99 };
 100 is (
 101   DBICTest::Schema->connect($dsn, $user, $pass)->storage->_use_insert_returning,
 102   $test_server_supports_insert_returning,
 103   'insert returning capability guessed correctly'
 104 );
 105
 106 my $schema;
 107 for my $use_insert_returning ($test_server_supports_insert_returning
 108   ? (0,1)
 109   : (0)
 110 ) {
 111
 112   no warnings qw/once/;
 113   local *DBICTest::Schema::connection = subname 'DBICTest::Schema::connection' => sub {
 114     my $s = shift->next::method (@_);
 115     $s->storage->_use_insert_returning ($use_insert_returning);
 116     $s;
 117   };
 118
 119 ### test capability override
 120   {
 121     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
 122
 123     ok (!$s->storage->_dbh, 'definitely not connected');
 124
 125     ok (
 126       ! ($s->storage->_use_insert_returning xor $use_insert_returning),
 127       'insert returning capability set correctly',
 128     );
 129     ok (!$s->storage->_dbh, 'still not connected (capability override works)');
 130   }
 131
 132 ### connect, create postgres-specific test schema
 133
 134   $schema = DBICTest::Schema->connect($dsn, $user, $pass);
 135   $schema->storage->ensure_connected;
 136
 137   drop_test_schema($schema);
 138   create_test_schema($schema);
 139
 140 ### begin main tests
 141
 142 # run a BIG bunch of tests for last-insert-id / Auto-PK / sequence
 143 # discovery
 144   run_apk_tests($schema); #< older set of auto-pk tests
 145   run_extended_apk_tests($schema); #< new extended set of auto-pk tests
 146
 147 ### type_info tests
 148
 149   my $test_type_info = {
 150       'artistid' => {
 151           'data_type' => 'integer',
 152           'is_nullable' => 0,
 153           'size' => 4,
 154       },
 155       'name' => {
 156           'data_type' => 'character varying',
 157           'is_nullable' => 1,
 158           'size' => 100,
 159           'default_value' => undef,
 160       },
 161       'rank' => {
 162           'data_type' => 'integer',
 163           'is_nullable' => 0,
 164           'size' => 4,
 165           'default_value' => 13,
 166
 167       },
 168       'charfield' => {
 169           'data_type' => 'character',
 170           'is_nullable' => 1,
 171           'size' => 10,
 172           'default_value' => undef,
 173       },
 174       'arrayfield' => {
 175           'data_type' => 'integer[]',
 176           'is_nullable' => 1,
 177           'size' => undef,
 178           'default_value' => undef,
 179       },
 180   };
 181
 182   my $type_info = $schema->storage->columns_info_for('dbic_t_schema.artist');
 183   my $artistid_defval = delete $type_info->{artistid}->{default_value};
 184   like($artistid_defval,
 185        qr/^nextval\('([^\.]*\.){0,1}artist_artistid_seq'::(?:text|regclass)\)/,
 186        'columns_info_for - sequence matches Pg get_autoinc_seq expectations');
 187   is_deeply($type_info, $test_type_info,
 188             'columns_info_for - column data types');
 189
 190
 191
 192
 193 ####### Array tests
 194
 195   BEGIN {
 196     package DBICTest::Schema::ArrayTest;
 197     push @main::test_classes, __PACKAGE__;
 198
 199     use strict;
 200     use warnings;
 201     use base 'DBICTest::BaseResult';
 202
 203     __PACKAGE__->table('dbic_t_schema.array_test');
 204     __PACKAGE__->add_columns(qw/id arrayfield/);
 205     __PACKAGE__->column_info_from_storage(1);
 206     __PACKAGE__->set_primary_key('id');
 207
 208   }
 209   SKIP: {
 210     skip "Need DBD::Pg 2.9.2 or newer for array tests", 4 if $DBD::Pg::VERSION < 2.009002;
 211
 212     my $arr_rs = $schema->resultset('ArrayTest');
 213
 214     lives_ok {
 215       $arr_rs->create({
 216         arrayfield => [1, 2],
 217       });
 218     } 'inserting arrayref as pg array data';
 219
 220     lives_ok {
 221       $arr_rs->update({
 222         arrayfield => [3, 4],
 223       });
 224     } 'updating arrayref as pg array data';
 225
 226     $arr_rs->create({
 227       arrayfield => [5, 6],
 228     });
 229
 230     # Search using arrays
 231     lives_ok {
 232       is_deeply (
 233         $arr_rs->search({ arrayfield => { -value => [3,4] } })->first->arrayfield,
 234         [3,4],
 235         'Array value matches'
 236       );
 237     } 'searching by arrayref';
 238
 239     lives_ok {
 240       is_deeply (
 241         $arr_rs->search({ arrayfield => { '=' => { -value => [3,4] }} })->first->arrayfield,
 242         [3,4],,
 243         'Array value matches explicit equal'
 244       );
 245     } 'searching by arrayref (explicit equal sign)';
 246
 247     lives_ok {
 248       is_deeply (
 249         $arr_rs->search({ arrayfield => { '>' => { -value => [3,1] }} })->first->arrayfield,
 250         [3,4],
 251         'Array value matches greater than'
 252       );
 253     } 'searching by arrayref (greater than)';
 254
 255     lives_ok {
 256       is (
 257         $arr_rs->search({ arrayfield => { '>' => { -value => [3,7] }} })->count,
 258         1,
 259         'Greater than search found [5,6]',
 260       );
 261     } 'searching by arrayref (greater than)';
 262
 263     # Find using arrays
 264     lives_ok {
 265       is_deeply (
 266         $arr_rs->find({ arrayfield => { -value => [3,4] } })->arrayfield,
 267         [3,4],
 268         'Array value matches implicit equal'
 269       );
 270     } 'find by arrayref';
 271
 272     lives_ok {
 273       is_deeply (
 274         $arr_rs->find({ arrayfield => { '=' => { -value => [3,4] }} })->arrayfield,
 275         [3,4],
 276         'Array value matches explicit equal'
 277       );
 278     } 'find by arrayref (equal)';
 279
 280     # test inferred condition for creation
 281     TODO: for my $cond (
 282       { -value => [3,4] },
 283       \[ '= ?' => [arrayfield => [3, 4]] ],
 284     ) {
 285       local $TODO = 'No introspection of complex conditions :(';
 286       my $arr_rs_cond = $arr_rs->search({ arrayfield => $cond });
 287
 288       my $row = $arr_rs_cond->create({});
 289       is_deeply ($row->arrayfield, [3,4], 'Array value taken from $rs condition');
 290       $row->discard_changes;
 291       is_deeply ($row->arrayfield, [3,4], 'Array value made it to storage');
 292     }
 293   }
 294
 295 ########## Case check
 296
 297   BEGIN {
 298     package DBICTest::Schema::Casecheck;
 299     push @main::test_classes, __PACKAGE__;
 300
 301     use strict;
 302     use warnings;
 303     use base 'DBIx::Class::Core';
 304
 305     __PACKAGE__->table('dbic_t_schema.casecheck');
 306     __PACKAGE__->add_columns(qw/id name NAME uc_name/);
 307     __PACKAGE__->column_info_from_storage(1);
 308     __PACKAGE__->set_primary_key('id');
 309   }
 310
 311   my $name_info = $schema->source('Casecheck')->column_info( 'name' );
 312   is( $name_info->{size}, 1, "Case sensitive matching info for 'name'" );
 313
 314   my $NAME_info = $schema->source('Casecheck')->column_info( 'NAME' );
 315   is( $NAME_info->{size}, 2, "Case sensitive matching info for 'NAME'" );
 316
 317   my $uc_name_info = $schema->source('Casecheck')->column_info( 'uc_name' );
 318   is( $uc_name_info->{size}, 3, "Case insensitive matching info for 'uc_name'" );
 319
 320
 321 ## Test ResultSet->update
 322 my $artist = $schema->resultset('Artist')->first;
 323 my $cds = $artist->cds_unordered->search({
 324     year => { '!=' => 2010 }
 325 }, { prefetch => 'liner_notes' });
 326 lives_ok { $cds->update({ year => '2010' }) } 'Update on prefetched rs';
 327
 328 ## Test SELECT ... FOR UPDATE
 329
 330   SKIP: {
 331       if(eval { require Sys::SigAction }) {
 332           Sys::SigAction->import( 'set_sig_handler' );
 333       }
 334       else {
 335         skip "Sys::SigAction is not available", 6;
 336       }
 337
 338       my ($timed_out, $artist2);
 339
 340       for my $t (
 341         {
 342           # Make sure that an error was raised, and that the update failed
 343           update_lock => 1,
 344           test_sub => sub {
 345             ok($timed_out, "update from second schema times out");
 346             ok($artist2->is_column_changed('name'), "'name' column is still dirty from second schema");
 347           },
 348         },
 349         {
 350           # Make sure that an error was NOT raised, and that the update succeeded
 351           update_lock => 0,
 352           test_sub => sub {
 353             ok(! $timed_out, "update from second schema DOES NOT timeout");
 354             ok(! $artist2->is_column_changed('name'), "'name' column is NOT dirty from second schema");
 355           },
 356         },
 357       ) {
 358         # create a new schema
 359         my $schema2 = DBICTest::Schema->connect($dsn, $user, $pass);
 360         $schema2->source("Artist")->name("dbic_t_schema.artist");
 361
 362         $schema->txn_do( sub {
 363           my $rs = $schema->resultset('Artist')->search(
 364               {
 365                   artistid => 1
 366               },
 367               $t->{update_lock} ? { for => 'update' } : {}
 368           );
 369           ok ($rs->count, 'Count works');
 370
 371           my $artist = $rs->next;
 372           is($artist->artistid, 1, "select returns artistid = 1");
 373
 374           $timed_out = 0;
 375           eval {
 376               my $h = set_sig_handler( 'ALRM', sub { die "DBICTestTimeout" } );
 377               alarm(2);
 378               $artist2 = $schema2->resultset('Artist')->find(1);
 379               $artist2->name('fooey');
 380               $artist2->update;
 381               alarm(0);
 382           };
 383           $timed_out = $@ =~ /DBICTestTimeout/;
 384         });
 385
 386         $t->{test_sub}->();
 387       }
 388   }
 389
 390
 391 ######## other older Auto-pk tests
 392
 393   $schema->source("SequenceTest")->name("dbic_t_schema.sequence_test");
 394   for (1..5) {
 395       my $st = $schema->resultset('SequenceTest')->create({ name => 'foo' });
 396       is($st->pkid1, $_, "Auto-PK for sequence without default: First primary key");
 397       is($st->pkid2, $_ + 9, "Auto-PK for sequence without default: Second primary key");
 398       is($st->nonpkid, $_ + 19, "Auto-PK for sequence without default: Non-primary key");
 399   }
 400   my $st = $schema->resultset('SequenceTest')->create({ name => 'foo', pkid1 => 55 });
 401   is($st->pkid1, 55, "Auto-PK for sequence without default: First primary key set manually");
 402
 403
 404 ######## test non-serial auto-pk
 405
 406   if ($schema->storage->_use_insert_returning) {
 407     $schema->source('TimestampPrimaryKey')->name('dbic_t_schema.timestamp_primary_key_test');
 408     my $row = $schema->resultset('TimestampPrimaryKey')->create({});
 409     ok $row->id;
 410   }
 411
 412 ######## test with_deferred_fk_checks
 413
 414   $schema->source('CD')->name('dbic_t_schema.cd');
 415   $schema->source('Track')->name('dbic_t_schema.track');
 416   lives_ok {
 417     $schema->storage->with_deferred_fk_checks(sub {
 418       $schema->resultset('Track')->create({
 419         trackid => 999, cd => 999, position => 1, title => 'deferred FK track'
 420       });
 421       $schema->resultset('CD')->create({
 422         artist => 1, cdid => 999, year => '2003', title => 'deferred FK cd'
 423       });
 424     });
 425   } 'with_deferred_fk_checks code survived';
 426
 427   is eval { $schema->resultset('Track')->find(999)->title }, 'deferred FK track',
 428      'code in with_deferred_fk_checks worked';
 429
 430   throws_ok {
 431     $schema->resultset('Track')->create({
 432       trackid => 1, cd => 9999, position => 1, title => 'Track1'
 433     });
 434   } qr/constraint/i, 'with_deferred_fk_checks is off';
 435 }
 436
 437 done_testing;
 438
 439 END {
 440     return unless $schema;
 441     drop_test_schema($schema);
 442     eapk_drop_all( $schema)
 443 };
 444
 445
 446 ######### SUBROUTINES
 447
 448 sub create_test_schema {
 449     my $schema = shift;
 450     $schema->storage->dbh_do(sub {
 451       my (undef,$dbh) = @_;
 452
 453       local $dbh->{Warn} = 0;
 454
 455       my $std_artist_table = <<EOS;
 456 (
 457   artistid serial PRIMARY KEY
 458   , name VARCHAR(100)
 459   , rank INTEGER NOT NULL DEFAULT '13'
 460   , charfield CHAR(10)
 461   , arrayfield INTEGER[]
 462 )
 463 EOS
 464
 465       $dbh->do("CREATE SCHEMA dbic_t_schema");
 466       $dbh->do("CREATE TABLE dbic_t_schema.artist $std_artist_table");
 467
 468       $dbh->do(<<EOS);
 469 CREATE TABLE dbic_t_schema.timestamp_primary_key_test (
 470   id timestamp default current_timestamp
 471 )
 472 EOS
 473       $dbh->do(<<EOS);
 474 CREATE TABLE dbic_t_schema.cd (
 475   cdid int PRIMARY KEY,
 476   artist int,
 477   title varchar(255),
 478   year varchar(4),
 479   genreid int,
 480   single_track int
 481 )
 482 EOS
 483       $dbh->do(<<EOS);
 484 CREATE TABLE dbic_t_schema.track (
 485   trackid int,
 486   cd int REFERENCES dbic_t_schema.cd(cdid) DEFERRABLE,
 487   position int,
 488   title varchar(255),
 489   last_updated_on date,
 490   last_updated_at date
 491 )
 492 EOS
 493
 494       $dbh->do(<<EOS);
 495 CREATE TABLE dbic_t_schema.sequence_test (
 496     pkid1 integer
 497     , pkid2 integer
 498     , nonpkid integer
 499     , name VARCHAR(100)
 500     , CONSTRAINT pk PRIMARY KEY(pkid1, pkid2)
 501 )
 502 EOS
 503       $dbh->do("CREATE SEQUENCE pkid1_seq START 1 MAXVALUE 999999 MINVALUE 0");
 504       $dbh->do("CREATE SEQUENCE pkid2_seq START 10 MAXVALUE 999999 MINVALUE 0");
 505       $dbh->do("CREATE SEQUENCE nonpkid_seq START 20 MAXVALUE 999999 MINVALUE 0");
 506       $dbh->do(<<EOS);
 507 CREATE TABLE dbic_t_schema.casecheck (
 508     id serial PRIMARY KEY
 509     , "name" VARCHAR(1)
 510     , "NAME" VARCHAR(2)
 511     , "UC_NAME" VARCHAR(3)
 512 )
 513 EOS
 514       $dbh->do(<<EOS);
 515 CREATE TABLE dbic_t_schema.array_test (
 516     id serial PRIMARY KEY
 517     , arrayfield INTEGER[]
 518 )
 519 EOS
 520       $dbh->do("CREATE SCHEMA dbic_t_schema_2");
 521       $dbh->do("CREATE TABLE dbic_t_schema_2.artist $std_artist_table");
 522       $dbh->do("CREATE SCHEMA dbic_t_schema_3");
 523       $dbh->do("CREATE TABLE dbic_t_schema_3.artist $std_artist_table");
 524       $dbh->do('set search_path=dbic_t_schema,public');
 525       $dbh->do("CREATE SCHEMA dbic_t_schema_4");
 526       $dbh->do("CREATE SCHEMA dbic_t_schema_5");
 527       $dbh->do(<<EOS);
 528  CREATE TABLE dbic_t_schema_4.artist
 529  (
 530    artistid integer not null default nextval('artist_artistid_seq'::regclass) PRIMARY KEY
 531    , name VARCHAR(100)
 532    , rank INTEGER NOT NULL DEFAULT '13'
 533    , charfield CHAR(10)
 534    , arrayfield INTEGER[]
 535  );
 536 EOS
 537       $dbh->do('set search_path=public,dbic_t_schema,dbic_t_schema_3');
 538       $dbh->do('create sequence public.artist_artistid_seq'); #< in the public schema
 539       $dbh->do(<<EOS);
 540  CREATE TABLE dbic_t_schema_5.artist
 541  (
 542    artistid integer not null default nextval('public.artist_artistid_seq'::regclass) PRIMARY KEY
 543    , name VARCHAR(100)
 544    , rank INTEGER NOT NULL DEFAULT '13'
 545    , charfield CHAR(10)
 546    , arrayfield INTEGER[]
 547  );
 548 EOS
 549       $dbh->do('set search_path=dbic_t_schema,public');
 550   });
 551 }
 552
 553
 554
 555 sub drop_test_schema {
 556     my ( $schema, $warn_exceptions ) = @_;
 557
 558     $schema->storage->dbh_do(sub {
 559         my (undef,$dbh) = @_;
 560
 561         local $dbh->{Warn} = 0;
 562
 563         for my $stat (
 564                       'DROP SCHEMA dbic_t_schema_5 CASCADE',
 565                       'DROP SEQUENCE public.artist_artistid_seq CASCADE',
 566                       'DROP SCHEMA dbic_t_schema_4 CASCADE',
 567                       'DROP SCHEMA dbic_t_schema CASCADE',
 568                       'DROP SEQUENCE pkid1_seq CASCADE',
 569                       'DROP SEQUENCE pkid2_seq CASCADE',
 570                       'DROP SEQUENCE nonpkid_seq CASCADE',
 571                       'DROP SCHEMA dbic_t_schema_2 CASCADE',
 572                       'DROP SCHEMA dbic_t_schema_3 CASCADE',
 573                      ) {
 574             eval { $dbh->do ($stat) };
 575             diag $@ if $@ && $warn_exceptions;
 576         }
 577     });
 578 }
 579
 580
 581 ###  auto-pk / last_insert_id / sequence discovery
 582 sub run_apk_tests {
 583     my $schema = shift;
 584
 585     # This is in Core now, but it's here just to test that it doesn't break
 586     $schema->class('Artist')->load_components('PK::Auto');
 587     cmp_ok( $schema->resultset('Artist')->count, '==', 0, 'this should start with an empty artist table');
 588
 589     # test that auto-pk also works with the defined search path by
 590     # un-schema-qualifying the table name
 591     apk_t_set($schema,'artist');
 592
 593     my $unq_new;
 594     lives_ok {
 595         $unq_new = $schema->resultset('Artist')->create({ name => 'baz' });
 596     } 'insert into unqualified, shadowed table succeeds';
 597
 598     is($unq_new && $unq_new->artistid, 1, "and got correct artistid");
 599
 600     my @test_schemas = ( [qw| dbic_t_schema_2    1  |],
 601                          [qw| dbic_t_schema_3    1  |],
 602                          [qw| dbic_t_schema_4    2  |],
 603                          [qw| dbic_t_schema_5    1  |],
 604                        );
 605     foreach my $t ( @test_schemas ) {
 606         my ($sch_name, $start_num) = @$t;
 607         #test with dbic_t_schema_2
 608         apk_t_set($schema,"$sch_name.artist");
 609         my $another_new;
 610         lives_ok {
 611             $another_new = $schema->resultset('Artist')->create({ name => 'Tollbooth Willy'});
 612             is( $another_new->artistid,$start_num, "got correct artistid for $sch_name")
 613                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 614         } "$sch_name liid 1 did not die"
 615             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 616         lives_ok {
 617             $another_new = $schema->resultset('Artist')->create({ name => 'Adam Sandler'});
 618             is( $another_new->artistid,$start_num+1, "got correct artistid for $sch_name")
 619                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 620         } "$sch_name liid 2 did not die"
 621             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 622
 623     }
 624
 625     lives_ok {
 626         apk_t_set($schema,'dbic_t_schema.artist');
 627         my $new = $schema->resultset('Artist')->create({ name => 'foo' });
 628         is($new->artistid, 4, "Auto-PK worked");
 629         $new = $schema->resultset('Artist')->create({ name => 'bar' });
 630         is($new->artistid, 5, "Auto-PK worked");
 631     } 'old auto-pk tests did not die either';
 632 }
 633
 634 # sets the artist table name and clears sequence name cache
 635 sub apk_t_set {
 636     my ( $s, $n ) = @_;
 637     $s->source("Artist")->name($n);
 638     $s->source('Artist')->column_info('artistid')->{sequence} = undef; #< clear sequence name cache
 639 }
 640
 641
 642 ######## EXTENDED AUTO-PK TESTS
 643
 644 my @eapk_id_columns;
 645 BEGIN {
 646   package DBICTest::Schema::ExtAPK;
 647   push @main::test_classes, __PACKAGE__;
 648
 649   use strict;
 650   use warnings;
 651   use base 'DBIx::Class::Core';
 652
 653   __PACKAGE__->table('apk');
 654
 655   @eapk_id_columns = qw( id1 id2 id3 id4 );
 656   __PACKAGE__->add_columns(
 657     map { $_ => { data_type => 'integer', is_auto_increment => 1 } }
 658        @eapk_id_columns
 659   );
 660
 661   __PACKAGE__->set_primary_key('id2'); #< note the SECOND column is
 662                                        #the primary key
 663 }
 664
 665 my @eapk_schemas;
 666 BEGIN{ @eapk_schemas = map "dbic_apk_$_", 0..5 }
 667 my %seqs; #< hash of schema.table.col => currval of its (DBIC) primary key sequence
 668
 669 sub run_extended_apk_tests {
 670   my $schema = shift;
 671
 672   #save the search path and reset it at the end
 673   my $search_path_save = eapk_get_search_path($schema);
 674
 675   eapk_drop_all($schema);
 676   %seqs = ();
 677
 678   # make the test schemas and sequences
 679   $schema->storage->dbh_do(sub {
 680     my ( undef, $dbh ) = @_;
 681
 682     $dbh->do("CREATE SCHEMA $_")
 683         for @eapk_schemas;
 684
 685     $dbh->do("CREATE SEQUENCE $eapk_schemas[5].fooseq");
 686     $dbh->do("SELECT setval('$eapk_schemas[5].fooseq',400)");
 687     $seqs{"$eapk_schemas[1].apk.id2"} = 400;
 688
 689     $dbh->do("CREATE SEQUENCE $eapk_schemas[4].fooseq");
 690     $dbh->do("SELECT setval('$eapk_schemas[4].fooseq',300)");
 691     $seqs{"$eapk_schemas[3].apk.id2"} = 300;
 692
 693     $dbh->do("CREATE SEQUENCE $eapk_schemas[3].fooseq");
 694     $dbh->do("SELECT setval('$eapk_schemas[3].fooseq',200)");
 695     $seqs{"$eapk_schemas[4].apk.id2"} = 200;
 696
 697     $dbh->do("SET search_path = ".join ',', reverse @eapk_schemas );
 698   });
 699
 700   # clear our search_path cache
 701   $schema->storage->{_pg_search_path} = undef;
 702
 703   eapk_create( $schema,
 704                with_search_path => [0,1],
 705              );
 706   eapk_create( $schema,
 707                with_search_path => [1,0,'public'],
 708                nextval => "$eapk_schemas[5].fooseq",
 709              );
 710   eapk_create( $schema,
 711                with_search_path => ['public',0,1],
 712                qualify_table => 2,
 713              );
 714   eapk_create( $schema,
 715                with_search_path => [3,1,0,'public'],
 716                nextval => "$eapk_schemas[4].fooseq",
 717              );
 718   eapk_create( $schema,
 719                with_search_path => [3,1,0,'public'],
 720                nextval => "$eapk_schemas[3].fooseq",
 721                qualify_table => 4,
 722              );
 723
 724   eapk_poke( $schema );
 725   eapk_poke( $schema, 0 );
 726   eapk_poke( $schema, 2 );
 727   eapk_poke( $schema, 4 );
 728   eapk_poke( $schema, 1 );
 729   eapk_poke( $schema, 0 );
 730   eapk_poke( $schema, 1 );
 731   eapk_poke( $schema );
 732   eapk_poke( $schema, 4 );
 733   eapk_poke( $schema, 3 );
 734   eapk_poke( $schema, 1 );
 735   eapk_poke( $schema, 2 );
 736   eapk_poke( $schema, 0 );
 737
 738   # set our search path back
 739   eapk_set_search_path( $schema, @$search_path_save );
 740 }
 741
 742 # do a DBIC create on the apk table in the given schema number (which is an
 743 # index of @eapk_schemas)
 744
 745 sub eapk_poke {
 746   my ($s, $schema_num) = @_;
 747
 748   my $schema_name = defined $schema_num
 749       ? $eapk_schemas[$schema_num]
 750       : '';
 751
 752   my $schema_name_actual = $schema_name || eapk_find_visible_schema($s);
 753
 754   $s->source('ExtAPK')->name($schema_name ? $schema_name.'.apk' : 'apk');
 755   #< clear sequence name cache
 756   $s->source('ExtAPK')->column_info($_)->{sequence} = undef
 757       for @eapk_id_columns;
 758
 759   no warnings 'uninitialized';
 760   lives_ok {
 761     my $new;
 762     for my $inc (1,2,3) {
 763       $new = $schema->resultset('ExtAPK')->create({ id1 => 1});
 764       my $proper_seqval = ++$seqs{"$schema_name_actual.apk.id2"};
 765       is( $new->id2, $proper_seqval, "$schema_name_actual.apk.id2 correct inc $inc" )
 766           or eapk_seq_diag($s,$schema_name);
 767       $new->discard_changes;
 768       is( $new->id1, 1 );
 769       for my $id ('id3','id4') {
 770         my $proper_seqval = ++$seqs{"$schema_name_actual.apk.$id"};
 771         is( $new->$id, $proper_seqval, "$schema_name_actual.apk.$id correct inc $inc" )
 772             or eapk_seq_diag($s,$schema_name);
 773       }
 774     }
 775   } "create in schema '$schema_name' lives"
 776       or eapk_seq_diag($s,$schema_name);
 777 }
 778
 779 # print diagnostic info on which sequences were found in the ExtAPK
 780 # class
 781 sub eapk_seq_diag {
 782     my $s = shift;
 783     my $schema = shift || eapk_find_visible_schema($s);
 784
 785     diag "$schema.apk sequences: ",
 786         join(', ',
 787              map "$_:".($s->source('ExtAPK')->column_info($_)->{sequence} || '<none>'),
 788              @eapk_id_columns
 789             );
 790 }
 791
 792 # get the postgres search path as an arrayref
 793 sub eapk_get_search_path {
 794     my ( $s ) = @_;
 795     # cache the search path as ['schema','schema',...] in the storage
 796     # obj
 797
 798     return $s->storage->dbh_do(sub {
 799         my (undef, $dbh) = @_;
 800         my @search_path;
 801         my ($sp_string) = $dbh->selectrow_array('SHOW search_path');
 802         while ( $sp_string =~ s/("[^"]+"|[^,]+),?// ) {
 803             unless( defined $1 and length $1 ) {
 804                 die "search path sanity check failed: '$1'";
 805             }
 806             push @search_path, $1;
 807         }
 808         \@search_path
 809     });
 810 }
 811 sub eapk_set_search_path {
 812     my ($s,@sp) = @_;
 813     my $sp = join ',',@sp;
 814     $s->storage->dbh_do( sub { $_[1]->do("SET search_path = $sp") } );
 815 }
 816
 817 # create the apk table in the given schema, can set whether the table name is qualified, what the nextval is for the second ID
 818 sub eapk_create {
 819     my ($schema, %a) = @_;
 820
 821     $schema->storage->dbh_do(sub {
 822         my (undef,$dbh) = @_;
 823
 824         my $searchpath_save;
 825         if ( $a{with_search_path} ) {
 826             ($searchpath_save) = $dbh->selectrow_array('SHOW search_path');
 827
 828             my $search_path = join ',',map {/\D/ ? $_ : $eapk_schemas[$_]} @{$a{with_search_path}};
 829
 830             $dbh->do("SET search_path = $search_path");
 831         }
 832
 833         my $table_name = $a{qualify_table}
 834             ? ($eapk_schemas[$a{qualify_table}] || die). ".apk"
 835             : 'apk';
 836         local $_[1]->{Warn} = 0;
 837
 838         my $id_def = $a{nextval}
 839             ? "integer not null default nextval('$a{nextval}'::regclass)"
 840             : 'serial';
 841         $dbh->do(<<EOS);
 842 CREATE TABLE $table_name (
 843   id1 serial
 844   , id2 $id_def
 845   , id3 serial primary key
 846   , id4 serial
 847 )
 848 EOS
 849
 850         if( $searchpath_save ) {
 851             $dbh->do("SET search_path = $searchpath_save");
 852         }
 853     });
 854 }
 855
 856 sub eapk_drop_all {
 857     my ( $schema, $warn_exceptions ) = @_;
 858
 859     $schema->storage->dbh_do(sub {
 860         my (undef,$dbh) = @_;
 861
 862         local $dbh->{Warn} = 0;
 863
 864         # drop the test schemas
 865         for (@eapk_schemas ) {
 866             eval{ $dbh->do("DROP SCHEMA $_ CASCADE") };
 867             diag $@ if $@ && $warn_exceptions;
 868         }
 869
 870
 871     });
 872 }
 873
 874 sub eapk_find_visible_schema {
 875     my ($s) = @_;
 876
 877     my ($schema) =
 878         $s->storage->dbh_do(sub {
 879             $_[1]->selectrow_array(<<EOS);
 880 SELECT n.nspname
 881 FROM pg_catalog.pg_namespace n
 882 JOIN pg_catalog.pg_class c ON c.relnamespace = n.oid
 883 WHERE c.relname = 'apk'
 884   AND pg_catalog.pg_table_is_visible(c.oid)
 885 EOS
 886         });
 887     return $schema;
 888 }