t/72pg.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use Sub::Name;
   7 use DBIx::Class::Optional::Dependencies ();
   8 use lib qw(t/lib);
   9 use DBICTest;
  10
  11 plan skip_all => 'Test needs ' . DBIx::Class::Optional::Dependencies->req_missing_for ('test_rdbms_pg')
  12   unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_rdbms_pg');
  13
  14 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
  15
  16 plan skip_all => <<'EOM' unless $dsn && $user;
  17 Set $ENV{DBICTEST_PG_DSN}, _USER and _PASS to run this test
  18 ( NOTE: This test drops and creates tables called 'artist', 'cd',
  19 'timestamp_primary_key_test', 'track', 'casecheck', 'array_test' and
  20 'sequence_test' as well as following sequences: 'pkid1_seq', 'pkid2_seq' and
  21 'nonpkid_seq'. as well as following schemas: 'dbic_t_schema',
  22 'dbic_t_schema_2', 'dbic_t_schema_3', 'dbic_t_schema_4', and 'dbic_t_schema_5')
  23 EOM
  24
  25 ### load any test classes that are defined further down in the file via BEGIN blocks
  26
  27 our @test_classes; #< array that will be pushed into by test classes defined in this file
  28 DBICTest::Schema->load_classes( map {s/.+:://;$_} @test_classes ) if @test_classes;
  29
  30 ###  pre-connect tests (keep each test separate as to make sure rebless() runs)
  31   {
  32     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  33
  34     ok (!$s->storage->_dbh, 'definitely not connected');
  35
  36     # Check that datetime_parser returns correctly before we explicitly connect.
  37     SKIP: {
  38         skip (
  39           "Pg parser detection test needs " . DBIx::Class::Optional::Dependencies->req_missing_for ('test_dt_pg'),
  40           2
  41         ) unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_dt_pg');
  42
  43         my $store = ref $s->storage;
  44         is($store, 'DBIx::Class::Storage::DBI', 'Started with generic storage');
  45
  46         my $parser = $s->storage->datetime_parser;
  47         is( $parser, 'DateTime::Format::Pg', 'datetime_parser is as expected');
  48     }
  49
  50     ok (!$s->storage->_dbh, 'still not connected');
  51   }
  52
  53   {
  54     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  55     # make sure sqlt_type overrides work (::Storage::DBI::Pg does this)
  56     ok (!$s->storage->_dbh, 'definitely not connected');
  57     is ($s->storage->sqlt_type, 'PostgreSQL', 'sqlt_type correct pre-connection');
  58     ok (!$s->storage->_dbh, 'still not connected');
  59   }
  60
  61 # test LIMIT support
  62 {
  63   my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
  64   drop_test_schema($schema);
  65   create_test_schema($schema);
  66   for (1..6) {
  67     $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
  68   }
  69   my $it = $schema->resultset('Artist')->search( {},
  70     { rows => 3,
  71       offset => 2,
  72       order_by => 'artistid' }
  73   );
  74   is( $it->count, 3, "LIMIT count ok" );  # ask for 3 rows out of 6 artists
  75   is( $it->next->name, "Artist 3", "iterator->next ok" );
  76   $it->next;
  77   $it->next;
  78   $it->next;
  79   is( $it->next, undef, "next past end of resultset ok" );
  80
  81   # Limit with select-lock
  82   lives_ok {
  83     $schema->txn_do (sub {
  84       isa_ok (
  85         $schema->resultset('Artist')->find({artistid => 1}, {for => 'update', rows => 1}),
  86         'DBICTest::Schema::Artist',
  87       );
  88     });
  89   } 'Limited FOR UPDATE select works';
  90 }
  91
  92 # check if we indeed do support stuff
  93 my $test_server_supports_insert_returning = do {
  94   my $v = DBICTest::Schema->connect($dsn, $user, $pass)
  95                    ->storage
  96                     ->_get_dbh
  97                      ->get_info(18);
  98   $v =~ /^(\d+)\.(\d+)/
  99     or die "Unparseable Pg server version: $v\n";
 100
 101   ( sprintf ('%d.%d', $1, $2) >= 8.2 ) ? 1 : 0;
 102 };
 103 is (
 104   DBICTest::Schema->connect($dsn, $user, $pass)->storage->_use_insert_returning,
 105   $test_server_supports_insert_returning,
 106   'insert returning capability guessed correctly'
 107 );
 108
 109 my $schema;
 110 for my $use_insert_returning ($test_server_supports_insert_returning
 111   ? (0,1)
 112   : (0)
 113 ) {
 114
 115   no warnings qw/once/;
 116   local *DBICTest::Schema::connection = subname 'DBICTest::Schema::connection' => sub {
 117     my $s = shift->next::method (@_);
 118     $s->storage->_use_insert_returning ($use_insert_returning);
 119     $s;
 120   };
 121
 122 ### test capability override
 123   {
 124     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
 125
 126     ok (!$s->storage->_dbh, 'definitely not connected');
 127
 128     ok (
 129       ! ($s->storage->_use_insert_returning xor $use_insert_returning),
 130       'insert returning capability set correctly',
 131     );
 132     ok (!$s->storage->_dbh, 'still not connected (capability override works)');
 133   }
 134
 135 ### connect, create postgres-specific test schema
 136
 137   $schema = DBICTest::Schema->connect($dsn, $user, $pass);
 138   $schema->storage->ensure_connected;
 139
 140   drop_test_schema($schema);
 141   create_test_schema($schema);
 142
 143 ### begin main tests
 144
 145 # run a BIG bunch of tests for last-insert-id / Auto-PK / sequence
 146 # discovery
 147   run_apk_tests($schema); #< older set of auto-pk tests
 148   run_extended_apk_tests($schema); #< new extended set of auto-pk tests
 149
 150 ### type_info tests
 151
 152   my $test_type_info = {
 153       'artistid' => {
 154           'data_type' => 'integer',
 155           'is_nullable' => 0,
 156           'size' => 4,
 157       },
 158       'name' => {
 159           'data_type' => 'character varying',
 160           'is_nullable' => 1,
 161           'size' => 100,
 162           'default_value' => undef,
 163       },
 164       'rank' => {
 165           'data_type' => 'integer',
 166           'is_nullable' => 0,
 167           'size' => 4,
 168           'default_value' => 13,
 169
 170       },
 171       'charfield' => {
 172           'data_type' => 'character',
 173           'is_nullable' => 1,
 174           'size' => 10,
 175           'default_value' => undef,
 176       },
 177       'arrayfield' => {
 178           'data_type' => 'integer[]',
 179           'is_nullable' => 1,
 180           'size' => undef,
 181           'default_value' => undef,
 182       },
 183   };
 184
 185   my $type_info = $schema->storage->columns_info_for('dbic_t_schema.artist');
 186   my $artistid_defval = delete $type_info->{artistid}->{default_value};
 187   like($artistid_defval,
 188        qr/^nextval\('([^\.]*\.){0,1}artist_artistid_seq'::(?:text|regclass)\)/,
 189        'columns_info_for - sequence matches Pg get_autoinc_seq expectations');
 190   is_deeply($type_info, $test_type_info,
 191             'columns_info_for - column data types');
 192
 193
 194
 195
 196 ####### Array tests
 197
 198   BEGIN {
 199     package DBICTest::Schema::ArrayTest;
 200     push @main::test_classes, __PACKAGE__;
 201
 202     use strict;
 203     use warnings;
 204     use base 'DBICTest::BaseResult';
 205
 206     __PACKAGE__->table('dbic_t_schema.array_test');
 207     __PACKAGE__->add_columns(qw/id arrayfield/);
 208     __PACKAGE__->column_info_from_storage(1);
 209     __PACKAGE__->set_primary_key('id');
 210
 211   }
 212   SKIP: {
 213     skip "Need DBD::Pg 2.9.2 or newer for array tests", 4 if $DBD::Pg::VERSION < 2.009002;
 214
 215     my $arr_rs = $schema->resultset('ArrayTest');
 216
 217     lives_ok {
 218       $arr_rs->create({
 219         arrayfield => [1, 2],
 220       });
 221     } 'inserting arrayref as pg array data';
 222
 223     lives_ok {
 224       $arr_rs->update({
 225         arrayfield => [3, 4],
 226       });
 227     } 'updating arrayref as pg array data';
 228
 229     $arr_rs->create({
 230       arrayfield => [5, 6],
 231     });
 232
 233     lives_ok {
 234       $schema->populate('ArrayTest', [
 235         [ qw/arrayfield/ ],
 236         [ [0,0]          ],
 237       ]);
 238     } 'inserting arrayref using void ctx populate';
 239
 240     # Search using arrays
 241     lives_ok {
 242       is_deeply (
 243         $arr_rs->search({ arrayfield => { -value => [3,4] } })->first->arrayfield,
 244         [3,4],
 245         'Array value matches'
 246       );
 247     } 'searching by arrayref';
 248
 249     lives_ok {
 250       is_deeply (
 251         $arr_rs->search({ arrayfield => { '=' => { -value => [3,4] }} })->first->arrayfield,
 252         [3,4],,
 253         'Array value matches explicit equal'
 254       );
 255     } 'searching by arrayref (explicit equal sign)';
 256
 257     lives_ok {
 258       is_deeply (
 259         $arr_rs->search({ arrayfield => { '>' => { -value => [3,1] }} })->first->arrayfield,
 260         [3,4],
 261         'Array value matches greater than'
 262       );
 263     } 'searching by arrayref (greater than)';
 264
 265     lives_ok {
 266       is (
 267         $arr_rs->search({ arrayfield => { '>' => { -value => [3,7] }} })->count,
 268         1,
 269         'Greater than search found [5,6]',
 270       );
 271     } 'searching by arrayref (greater than)';
 272
 273     # Find using arrays
 274     lives_ok {
 275       is_deeply (
 276         $arr_rs->find({ arrayfield => { -value => [3,4] } })->arrayfield,
 277         [3,4],
 278         'Array value matches implicit equal'
 279       );
 280     } 'find by arrayref';
 281
 282     lives_ok {
 283       is_deeply (
 284         $arr_rs->find({ arrayfield => { '=' => { -value => [3,4] }} })->arrayfield,
 285         [3,4],
 286         'Array value matches explicit equal'
 287       );
 288     } 'find by arrayref (equal)';
 289
 290     # test inferred condition for creation
 291     TODO: for my $cond (
 292       { -value => [3,4] },
 293       \[ '= ?' => [arrayfield => [3, 4]] ],
 294     ) {
 295       local $TODO = 'No introspection of complex conditions :(';
 296       my $arr_rs_cond = $arr_rs->search({ arrayfield => $cond });
 297
 298       my $row = $arr_rs_cond->create({});
 299       is_deeply ($row->arrayfield, [3,4], 'Array value taken from $rs condition');
 300       $row->discard_changes;
 301       is_deeply ($row->arrayfield, [3,4], 'Array value made it to storage');
 302     }
 303   }
 304
 305 ########## Case check
 306
 307   BEGIN {
 308     package DBICTest::Schema::Casecheck;
 309     push @main::test_classes, __PACKAGE__;
 310
 311     use strict;
 312     use warnings;
 313     use base 'DBIx::Class::Core';
 314
 315     __PACKAGE__->table('dbic_t_schema.casecheck');
 316     __PACKAGE__->add_columns(qw/id name NAME uc_name/);
 317     __PACKAGE__->column_info_from_storage(1);
 318     __PACKAGE__->set_primary_key('id');
 319   }
 320
 321   my $name_info = $schema->source('Casecheck')->column_info( 'name' );
 322   is( $name_info->{size}, 1, "Case sensitive matching info for 'name'" );
 323
 324   my $NAME_info = $schema->source('Casecheck')->column_info( 'NAME' );
 325   is( $NAME_info->{size}, 2, "Case sensitive matching info for 'NAME'" );
 326
 327   my $uc_name_info = $schema->source('Casecheck')->column_info( 'uc_name' );
 328   is( $uc_name_info->{size}, 3, "Case insensitive matching info for 'uc_name'" );
 329
 330
 331 ## Test ResultSet->update
 332 my $artist = $schema->resultset('Artist')->first;
 333 my $cds = $artist->cds_unordered->search({
 334     year => { '!=' => 2010 }
 335 }, { prefetch => 'liner_notes' });
 336 lives_ok { $cds->update({ year => '2010' }) } 'Update on prefetched rs';
 337
 338 ## Test SELECT ... FOR UPDATE
 339
 340   SKIP: {
 341       if(eval { require Sys::SigAction }) {
 342           Sys::SigAction->import( 'set_sig_handler' );
 343       }
 344       else {
 345         skip "Sys::SigAction is not available", 6;
 346       }
 347
 348       my ($timed_out, $artist2);
 349
 350       for my $t (
 351         {
 352           # Make sure that an error was raised, and that the update failed
 353           update_lock => 1,
 354           test_sub => sub {
 355             ok($timed_out, "update from second schema times out");
 356             ok($artist2->is_column_changed('name'), "'name' column is still dirty from second schema");
 357           },
 358         },
 359         {
 360           # Make sure that an error was NOT raised, and that the update succeeded
 361           update_lock => 0,
 362           test_sub => sub {
 363             ok(! $timed_out, "update from second schema DOES NOT timeout");
 364             ok(! $artist2->is_column_changed('name'), "'name' column is NOT dirty from second schema");
 365           },
 366         },
 367       ) {
 368         # create a new schema
 369         my $schema2 = DBICTest::Schema->connect($dsn, $user, $pass);
 370         $schema2->source("Artist")->name("dbic_t_schema.artist");
 371
 372         $schema->txn_do( sub {
 373           my $rs = $schema->resultset('Artist')->search(
 374               {
 375                   artistid => 1
 376               },
 377               $t->{update_lock} ? { for => 'update' } : {}
 378           );
 379           ok ($rs->count, 'Count works');
 380
 381           my $artist = $rs->next;
 382           is($artist->artistid, 1, "select returns artistid = 1");
 383
 384           $timed_out = 0;
 385           eval {
 386               my $h = set_sig_handler( 'ALRM', sub { die "DBICTestTimeout" } );
 387               alarm(2);
 388               $artist2 = $schema2->resultset('Artist')->find(1);
 389               $artist2->name('fooey');
 390               $artist2->update;
 391               alarm(0);
 392           };
 393           $timed_out = $@ =~ /DBICTestTimeout/;
 394         });
 395
 396         $t->{test_sub}->();
 397       }
 398   }
 399
 400
 401 ######## other older Auto-pk tests
 402
 403   $schema->source("SequenceTest")->name("dbic_t_schema.sequence_test");
 404   for (1..5) {
 405       my $st = $schema->resultset('SequenceTest')->create({ name => 'foo' });
 406       is($st->pkid1, $_, "Auto-PK for sequence without default: First primary key");
 407       is($st->pkid2, $_ + 9, "Auto-PK for sequence without default: Second primary key");
 408       is($st->nonpkid, $_ + 19, "Auto-PK for sequence without default: Non-primary key");
 409   }
 410   my $st = $schema->resultset('SequenceTest')->create({ name => 'foo', pkid1 => 55 });
 411   is($st->pkid1, 55, "Auto-PK for sequence without default: First primary key set manually");
 412
 413
 414 ######## test non-serial auto-pk
 415
 416   if ($schema->storage->_use_insert_returning) {
 417     $schema->source('TimestampPrimaryKey')->name('dbic_t_schema.timestamp_primary_key_test');
 418     my $row = $schema->resultset('TimestampPrimaryKey')->create({});
 419     ok $row->id;
 420   }
 421
 422 ######## test with_deferred_fk_checks
 423
 424   $schema->source('CD')->name('dbic_t_schema.cd');
 425   $schema->source('Track')->name('dbic_t_schema.track');
 426   lives_ok {
 427     $schema->storage->with_deferred_fk_checks(sub {
 428       $schema->resultset('Track')->create({
 429         trackid => 999, cd => 999, position => 1, title => 'deferred FK track'
 430       });
 431       $schema->resultset('CD')->create({
 432         artist => 1, cdid => 999, year => '2003', title => 'deferred FK cd'
 433       });
 434     });
 435   } 'with_deferred_fk_checks code survived';
 436
 437   is eval { $schema->resultset('Track')->find(999)->title }, 'deferred FK track',
 438      'code in with_deferred_fk_checks worked';
 439
 440   throws_ok {
 441     $schema->resultset('Track')->create({
 442       trackid => 1, cd => 9999, position => 1, title => 'Track1'
 443     });
 444   } qr/constraint/i, 'with_deferred_fk_checks is off';
 445 }
 446
 447 done_testing;
 448
 449 END {
 450     return unless $schema;
 451     drop_test_schema($schema);
 452     eapk_drop_all($schema);
 453     undef $schema;
 454 };
 455
 456
 457 ######### SUBROUTINES
 458
 459 sub create_test_schema {
 460     my $schema = shift;
 461     $schema->storage->dbh_do(sub {
 462       my (undef,$dbh) = @_;
 463
 464       local $dbh->{Warn} = 0;
 465
 466       my $std_artist_table = <<EOS;
 467 (
 468   artistid serial PRIMARY KEY
 469   , name VARCHAR(100)
 470   , rank INTEGER NOT NULL DEFAULT '13'
 471   , charfield CHAR(10)
 472   , arrayfield INTEGER[]
 473 )
 474 EOS
 475
 476       $dbh->do("CREATE SCHEMA dbic_t_schema");
 477       $dbh->do("CREATE TABLE dbic_t_schema.artist $std_artist_table");
 478
 479       $dbh->do(<<EOS);
 480 CREATE TABLE dbic_t_schema.timestamp_primary_key_test (
 481   id timestamp default current_timestamp
 482 )
 483 EOS
 484       $dbh->do(<<EOS);
 485 CREATE TABLE dbic_t_schema.cd (
 486   cdid int PRIMARY KEY,
 487   artist int,
 488   title varchar(255),
 489   year varchar(4),
 490   genreid int,
 491   single_track int
 492 )
 493 EOS
 494       $dbh->do(<<EOS);
 495 CREATE TABLE dbic_t_schema.track (
 496   trackid int,
 497   cd int REFERENCES dbic_t_schema.cd(cdid) DEFERRABLE,
 498   position int,
 499   title varchar(255),
 500   last_updated_on date,
 501   last_updated_at date
 502 )
 503 EOS
 504
 505       $dbh->do(<<EOS);
 506 CREATE TABLE dbic_t_schema.sequence_test (
 507     pkid1 integer
 508     , pkid2 integer
 509     , nonpkid integer
 510     , name VARCHAR(100)
 511     , CONSTRAINT pk PRIMARY KEY(pkid1, pkid2)
 512 )
 513 EOS
 514       $dbh->do("CREATE SEQUENCE pkid1_seq START 1 MAXVALUE 999999 MINVALUE 0");
 515       $dbh->do("CREATE SEQUENCE pkid2_seq START 10 MAXVALUE 999999 MINVALUE 0");
 516       $dbh->do("CREATE SEQUENCE nonpkid_seq START 20 MAXVALUE 999999 MINVALUE 0");
 517       $dbh->do(<<EOS);
 518 CREATE TABLE dbic_t_schema.casecheck (
 519     id serial PRIMARY KEY
 520     , "name" VARCHAR(1)
 521     , "NAME" VARCHAR(2)
 522     , "UC_NAME" VARCHAR(3)
 523 )
 524 EOS
 525       $dbh->do(<<EOS);
 526 CREATE TABLE dbic_t_schema.array_test (
 527     id serial PRIMARY KEY
 528     , arrayfield INTEGER[]
 529 )
 530 EOS
 531       $dbh->do("CREATE SCHEMA dbic_t_schema_2");
 532       $dbh->do("CREATE TABLE dbic_t_schema_2.artist $std_artist_table");
 533       $dbh->do("CREATE SCHEMA dbic_t_schema_3");
 534       $dbh->do("CREATE TABLE dbic_t_schema_3.artist $std_artist_table");
 535       $dbh->do('set search_path=dbic_t_schema,public');
 536       $dbh->do("CREATE SCHEMA dbic_t_schema_4");
 537       $dbh->do("CREATE SCHEMA dbic_t_schema_5");
 538       $dbh->do(<<EOS);
 539  CREATE TABLE dbic_t_schema_4.artist
 540  (
 541    artistid integer not null default nextval('artist_artistid_seq'::regclass) PRIMARY KEY
 542    , name VARCHAR(100)
 543    , rank INTEGER NOT NULL DEFAULT '13'
 544    , charfield CHAR(10)
 545    , arrayfield INTEGER[]
 546  );
 547 EOS
 548       $dbh->do('set search_path=public,dbic_t_schema,dbic_t_schema_3');
 549       $dbh->do('create sequence public.artist_artistid_seq'); #< in the public schema
 550       $dbh->do(<<EOS);
 551  CREATE TABLE dbic_t_schema_5.artist
 552  (
 553    artistid integer not null default nextval('public.artist_artistid_seq'::regclass) PRIMARY KEY
 554    , name VARCHAR(100)
 555    , rank INTEGER NOT NULL DEFAULT '13'
 556    , charfield CHAR(10)
 557    , arrayfield INTEGER[]
 558  );
 559 EOS
 560       $dbh->do('set search_path=dbic_t_schema,public');
 561   });
 562 }
 563
 564
 565
 566 sub drop_test_schema {
 567     my ( $schema, $warn_exceptions ) = @_;
 568
 569     $schema->storage->dbh_do(sub {
 570         my (undef,$dbh) = @_;
 571
 572         local $dbh->{Warn} = 0;
 573
 574         for my $stat (
 575                       'DROP SCHEMA dbic_t_schema_5 CASCADE',
 576                       'DROP SEQUENCE public.artist_artistid_seq CASCADE',
 577                       'DROP SCHEMA dbic_t_schema_4 CASCADE',
 578                       'DROP SCHEMA dbic_t_schema CASCADE',
 579                       'DROP SEQUENCE pkid1_seq CASCADE',
 580                       'DROP SEQUENCE pkid2_seq CASCADE',
 581                       'DROP SEQUENCE nonpkid_seq CASCADE',
 582                       'DROP SCHEMA dbic_t_schema_2 CASCADE',
 583                       'DROP SCHEMA dbic_t_schema_3 CASCADE',
 584                      ) {
 585             eval { $dbh->do ($stat) };
 586             diag $@ if $@ && $warn_exceptions;
 587         }
 588     });
 589 }
 590
 591
 592 ###  auto-pk / last_insert_id / sequence discovery
 593 sub run_apk_tests {
 594     my $schema = shift;
 595
 596     # This is in Core now, but it's here just to test that it doesn't break
 597     $schema->class('Artist')->load_components('PK::Auto');
 598     cmp_ok( $schema->resultset('Artist')->count, '==', 0, 'this should start with an empty artist table');
 599
 600     # test that auto-pk also works with the defined search path by
 601     # un-schema-qualifying the table name
 602     apk_t_set($schema,'artist');
 603
 604     my $unq_new;
 605     lives_ok {
 606         $unq_new = $schema->resultset('Artist')->create({ name => 'baz' });
 607     } 'insert into unqualified, shadowed table succeeds';
 608
 609     is($unq_new && $unq_new->artistid, 1, "and got correct artistid");
 610
 611     my @test_schemas = ( [qw| dbic_t_schema_2    1  |],
 612                          [qw| dbic_t_schema_3    1  |],
 613                          [qw| dbic_t_schema_4    2  |],
 614                          [qw| dbic_t_schema_5    1  |],
 615                        );
 616     foreach my $t ( @test_schemas ) {
 617         my ($sch_name, $start_num) = @$t;
 618         #test with dbic_t_schema_2
 619         apk_t_set($schema,"$sch_name.artist");
 620         my $another_new;
 621         lives_ok {
 622             $another_new = $schema->resultset('Artist')->create({ name => 'Tollbooth Willy'});
 623             is( $another_new->artistid,$start_num, "got correct artistid for $sch_name")
 624                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 625         } "$sch_name liid 1 did not die"
 626             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 627         lives_ok {
 628             $another_new = $schema->resultset('Artist')->create({ name => 'Adam Sandler'});
 629             is( $another_new->artistid,$start_num+1, "got correct artistid for $sch_name")
 630                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 631         } "$sch_name liid 2 did not die"
 632             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 633
 634     }
 635
 636     lives_ok {
 637         apk_t_set($schema,'dbic_t_schema.artist');
 638         my $new = $schema->resultset('Artist')->create({ name => 'foo' });
 639         is($new->artistid, 4, "Auto-PK worked");
 640         $new = $schema->resultset('Artist')->create({ name => 'bar' });
 641         is($new->artistid, 5, "Auto-PK worked");
 642     } 'old auto-pk tests did not die either';
 643 }
 644
 645 # sets the artist table name and clears sequence name cache
 646 sub apk_t_set {
 647     my ( $s, $n ) = @_;
 648     $s->source("Artist")->name($n);
 649     $s->source('Artist')->column_info('artistid')->{sequence} = undef; #< clear sequence name cache
 650 }
 651
 652
 653 ######## EXTENDED AUTO-PK TESTS
 654
 655 my @eapk_id_columns;
 656 BEGIN {
 657   package DBICTest::Schema::ExtAPK;
 658   push @main::test_classes, __PACKAGE__;
 659
 660   use strict;
 661   use warnings;
 662   use base 'DBIx::Class::Core';
 663
 664   __PACKAGE__->table('apk');
 665
 666   @eapk_id_columns = qw( id1 id2 id3 id4 );
 667   __PACKAGE__->add_columns(
 668     map { $_ => { data_type => 'integer', is_auto_increment => 1 } }
 669        @eapk_id_columns
 670   );
 671
 672   __PACKAGE__->set_primary_key('id2'); #< note the SECOND column is
 673                                        #the primary key
 674 }
 675
 676 my @eapk_schemas;
 677 BEGIN{ @eapk_schemas = map "dbic_apk_$_", 0..5 }
 678 my %seqs; #< hash of schema.table.col => currval of its (DBIC) primary key sequence
 679
 680 sub run_extended_apk_tests {
 681   my $schema = shift;
 682
 683   #save the search path and reset it at the end
 684   my $search_path_save = eapk_get_search_path($schema);
 685
 686   eapk_drop_all($schema);
 687   %seqs = ();
 688
 689   # make the test schemas and sequences
 690   $schema->storage->dbh_do(sub {
 691     my ( undef, $dbh ) = @_;
 692
 693     $dbh->do("CREATE SCHEMA $_")
 694         for @eapk_schemas;
 695
 696     $dbh->do("CREATE SEQUENCE $eapk_schemas[5].fooseq");
 697     $dbh->do("SELECT setval('$eapk_schemas[5].fooseq',400)");
 698     $seqs{"$eapk_schemas[1].apk.id2"} = 400;
 699
 700     $dbh->do("CREATE SEQUENCE $eapk_schemas[4].fooseq");
 701     $dbh->do("SELECT setval('$eapk_schemas[4].fooseq',300)");
 702     $seqs{"$eapk_schemas[3].apk.id2"} = 300;
 703
 704     $dbh->do("CREATE SEQUENCE $eapk_schemas[3].fooseq");
 705     $dbh->do("SELECT setval('$eapk_schemas[3].fooseq',200)");
 706     $seqs{"$eapk_schemas[4].apk.id2"} = 200;
 707
 708     $dbh->do("SET search_path = ".join ',', reverse @eapk_schemas );
 709   });
 710
 711   # clear our search_path cache
 712   $schema->storage->{_pg_search_path} = undef;
 713
 714   eapk_create( $schema,
 715                with_search_path => [0,1],
 716              );
 717   eapk_create( $schema,
 718                with_search_path => [1,0,'public'],
 719                nextval => "$eapk_schemas[5].fooseq",
 720              );
 721   eapk_create( $schema,
 722                with_search_path => ['public',0,1],
 723                qualify_table => 2,
 724              );
 725   eapk_create( $schema,
 726                with_search_path => [3,1,0,'public'],
 727                nextval => "$eapk_schemas[4].fooseq",
 728              );
 729   eapk_create( $schema,
 730                with_search_path => [3,1,0,'public'],
 731                nextval => "$eapk_schemas[3].fooseq",
 732                qualify_table => 4,
 733              );
 734
 735   eapk_poke( $schema );
 736   eapk_poke( $schema, 0 );
 737   eapk_poke( $schema, 2 );
 738   eapk_poke( $schema, 4 );
 739   eapk_poke( $schema, 1 );
 740   eapk_poke( $schema, 0 );
 741   eapk_poke( $schema, 1 );
 742   eapk_poke( $schema );
 743   eapk_poke( $schema, 4 );
 744   eapk_poke( $schema, 3 );
 745   eapk_poke( $schema, 1 );
 746   eapk_poke( $schema, 2 );
 747   eapk_poke( $schema, 0 );
 748
 749   # set our search path back
 750   eapk_set_search_path( $schema, @$search_path_save );
 751 }
 752
 753 # do a DBIC create on the apk table in the given schema number (which is an
 754 # index of @eapk_schemas)
 755
 756 sub eapk_poke {
 757   my ($s, $schema_num) = @_;
 758
 759   my $schema_name = defined $schema_num
 760       ? $eapk_schemas[$schema_num]
 761       : '';
 762
 763   my $schema_name_actual = $schema_name || eapk_find_visible_schema($s);
 764
 765   $s->source('ExtAPK')->name($schema_name ? $schema_name.'.apk' : 'apk');
 766   #< clear sequence name cache
 767   $s->source('ExtAPK')->column_info($_)->{sequence} = undef
 768       for @eapk_id_columns;
 769
 770   no warnings 'uninitialized';
 771   lives_ok {
 772     my $new;
 773     for my $inc (1,2,3) {
 774       $new = $schema->resultset('ExtAPK')->create({ id1 => 1});
 775       my $proper_seqval = ++$seqs{"$schema_name_actual.apk.id2"};
 776       is( $new->id2, $proper_seqval, "$schema_name_actual.apk.id2 correct inc $inc" )
 777           or eapk_seq_diag($s,$schema_name);
 778       $new->discard_changes;
 779       is( $new->id1, 1 );
 780       for my $id ('id3','id4') {
 781         my $proper_seqval = ++$seqs{"$schema_name_actual.apk.$id"};
 782         is( $new->$id, $proper_seqval, "$schema_name_actual.apk.$id correct inc $inc" )
 783             or eapk_seq_diag($s,$schema_name);
 784       }
 785     }
 786   } "create in schema '$schema_name' lives"
 787       or eapk_seq_diag($s,$schema_name);
 788 }
 789
 790 # print diagnostic info on which sequences were found in the ExtAPK
 791 # class
 792 sub eapk_seq_diag {
 793     my $s = shift;
 794     my $schema = shift || eapk_find_visible_schema($s);
 795
 796     diag "$schema.apk sequences: ",
 797         join(', ',
 798              map "$_:".($s->source('ExtAPK')->column_info($_)->{sequence} || '<none>'),
 799              @eapk_id_columns
 800             );
 801 }
 802
 803 # get the postgres search path as an arrayref
 804 sub eapk_get_search_path {
 805     my ( $s ) = @_;
 806     # cache the search path as ['schema','schema',...] in the storage
 807     # obj
 808
 809     return $s->storage->dbh_do(sub {
 810         my (undef, $dbh) = @_;
 811         my @search_path;
 812         my ($sp_string) = $dbh->selectrow_array('SHOW search_path');
 813         while ( $sp_string =~ s/("[^"]+"|[^,]+),?// ) {
 814             unless( defined $1 and length $1 ) {
 815                 die "search path sanity check failed: '$1'";
 816             }
 817             push @search_path, $1;
 818         }
 819         \@search_path
 820     });
 821 }
 822 sub eapk_set_search_path {
 823     my ($s,@sp) = @_;
 824     my $sp = join ',',@sp;
 825     $s->storage->dbh_do( sub { $_[1]->do("SET search_path = $sp") } );
 826 }
 827
 828 # create the apk table in the given schema, can set whether the table name is qualified, what the nextval is for the second ID
 829 sub eapk_create {
 830     my ($schema, %a) = @_;
 831
 832     $schema->storage->dbh_do(sub {
 833         my (undef,$dbh) = @_;
 834
 835         my $searchpath_save;
 836         if ( $a{with_search_path} ) {
 837             ($searchpath_save) = $dbh->selectrow_array('SHOW search_path');
 838
 839             my $search_path = join ',',map {/\D/ ? $_ : $eapk_schemas[$_]} @{$a{with_search_path}};
 840
 841             $dbh->do("SET search_path = $search_path");
 842         }
 843
 844         my $table_name = $a{qualify_table}
 845             ? ($eapk_schemas[$a{qualify_table}] || die). ".apk"
 846             : 'apk';
 847         local $_[1]->{Warn} = 0;
 848
 849         my $id_def = $a{nextval}
 850             ? "integer not null default nextval('$a{nextval}'::regclass)"
 851             : 'serial';
 852         $dbh->do(<<EOS);
 853 CREATE TABLE $table_name (
 854   id1 serial
 855   , id2 $id_def
 856   , id3 serial primary key
 857   , id4 serial
 858 )
 859 EOS
 860
 861         if( $searchpath_save ) {
 862             $dbh->do("SET search_path = $searchpath_save");
 863         }
 864     });
 865 }
 866
 867 sub eapk_drop_all {
 868     my ( $schema, $warn_exceptions ) = @_;
 869
 870     $schema->storage->dbh_do(sub {
 871         my (undef,$dbh) = @_;
 872
 873         local $dbh->{Warn} = 0;
 874
 875         # drop the test schemas
 876         for (@eapk_schemas ) {
 877             eval{ $dbh->do("DROP SCHEMA $_ CASCADE") };
 878             diag $@ if $@ && $warn_exceptions;
 879         }
 880
 881
 882     });
 883 }
 884
 885 sub eapk_find_visible_schema {
 886     my ($s) = @_;
 887
 888     my ($schema) =
 889         $s->storage->dbh_do(sub {
 890             $_[1]->selectrow_array(<<EOS);
 891 SELECT n.nspname
 892 FROM pg_catalog.pg_namespace n
 893 JOIN pg_catalog.pg_class c ON c.relnamespace = n.oid
 894 WHERE c.relname = 'apk'
 895   AND pg_catalog.pg_table_is_visible(c.oid)
 896 EOS
 897         });
 898     return $schema;
 899 }