t/72pg.t

   1 use DBIx::Class::Optional::Dependencies -skip_all_without => 'test_rdbms_pg';
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More;
   7 use Test::Exception;
   8 use Sub::Name;
   9 use Config;
  10 use DBIx::Class::Optional::Dependencies ();
  11 use lib qw(t/lib);
  12 use DBICTest;
  13 use SQL::Abstract 'is_literal_value';
  14 use DBIx::Class::_Util 'is_exception';
  15
  16 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
  17
  18 ### load any test classes that are defined further down in the file via BEGIN blocks
  19 our @test_classes; #< array that will be pushed into by test classes defined in this file
  20 DBICTest::Schema->load_classes( map {s/.+:://;$_} @test_classes ) if @test_classes;
  21
  22 ###  pre-connect tests (keep each test separate as to make sure rebless() runs)
  23   {
  24     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  25     # make sure sqlt_type overrides work (::Storage::DBI::Pg does this)
  26     ok (!$s->storage->_dbh, 'definitely not connected');
  27     is ($s->storage->sqlt_type, 'PostgreSQL', 'sqlt_type correct pre-connection');
  28     ok (!$s->storage->_dbh, 'still not connected');
  29   }
  30
  31 # test LIMIT support
  32 {
  33   my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
  34   drop_test_schema($schema);
  35   create_test_schema($schema);
  36   for (1..6) {
  37     $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
  38   }
  39   my $it = $schema->resultset('Artist')->search( {},
  40     { rows => 3,
  41       offset => 2,
  42       order_by => 'artistid' }
  43   );
  44   is( $it->count, 3, "LIMIT count ok" );  # ask for 3 rows out of 6 artists
  45   is( $it->next->name, "Artist 3", "iterator->next ok" );
  46   $it->next;
  47   $it->next;
  48   $it->next;
  49   is( $it->next, undef, "next past end of resultset ok" );
  50
  51   # Limit with select-lock
  52   lives_ok {
  53     $schema->txn_do (sub {
  54       isa_ok (
  55         $schema->resultset('Artist')->find({artistid => 1}, {for => 'update', rows => 1}),
  56         'DBICTest::Schema::Artist',
  57       );
  58     });
  59   } 'Limited FOR UPDATE select works';
  60 }
  61
  62 # check if we indeed do support stuff
  63 my $test_server_supports_insert_returning = do {
  64
  65   my $si = DBICTest::Schema->connect($dsn, $user, $pass)->storage->_server_info;
  66   die "Unparseable Pg server version: $si->{dbms_version}\n"
  67     unless $si->{normalized_dbms_version};
  68
  69   $si->{normalized_dbms_version} < 8.002 ? 0 : 1;
  70 };
  71 is (
  72   DBICTest::Schema->connect($dsn, $user, $pass)->storage->_use_insert_returning,
  73   $test_server_supports_insert_returning,
  74   'insert returning capability guessed correctly'
  75 );
  76
  77 my $schema;
  78 for my $use_insert_returning ($test_server_supports_insert_returning
  79   ? (0,1)
  80   : (0)
  81 ) {
  82
  83   no warnings qw/once redefine/;
  84   my $old_connection = DBICTest::Schema->can('connection');
  85   local *DBICTest::Schema::connection = subname 'DBICTest::Schema::connection' => sub {
  86     my $s = shift->$old_connection(@_);
  87     $s->storage->_use_insert_returning ($use_insert_returning);
  88     $s;
  89   };
  90
  91 ### test capability override
  92   {
  93     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  94
  95     ok (!$s->storage->_dbh, 'definitely not connected');
  96
  97     ok (
  98       ! ($s->storage->_use_insert_returning xor $use_insert_returning),
  99       'insert returning capability set correctly',
 100     );
 101     ok (!$s->storage->_dbh, 'still not connected (capability override works)');
 102   }
 103
 104 ### connect, create postgres-specific test schema
 105
 106   $schema = DBICTest::Schema->connect($dsn, $user, $pass);
 107   $schema->storage->ensure_connected;
 108
 109   drop_test_schema($schema);
 110   create_test_schema($schema);
 111
 112 ### begin main tests
 113
 114 # run a BIG bunch of tests for last-insert-id / Auto-PK / sequence
 115 # discovery
 116   run_apk_tests($schema); #< older set of auto-pk tests
 117   run_extended_apk_tests($schema); #< new extended set of auto-pk tests
 118
 119
 120 ######## test the pg-specific syntax from https://rt.cpan.org/Ticket/Display.html?id=99503
 121   lives_ok {
 122     is(
 123       $schema->resultset('Artist')->search({ artistid => { -in => \ '(select 4) union (select 5)' } })->count,
 124       2,
 125       'Two expected artists found on subselect union within IN',
 126     );
 127   };
 128
 129 ### type_info tests
 130
 131   my $test_type_info = {
 132       'artistid' => {
 133           'data_type' => 'integer',
 134           'is_nullable' => 0,
 135           'size' => 4,
 136       },
 137       'name' => {
 138           'data_type' => 'character varying',
 139           'is_nullable' => 1,
 140           'size' => 100,
 141           'default_value' => undef,
 142       },
 143       'rank' => {
 144           'data_type' => 'integer',
 145           'is_nullable' => 0,
 146           'size' => 4,
 147           'default_value' => 13,
 148
 149       },
 150       'charfield' => {
 151           'data_type' => 'character',
 152           'is_nullable' => 1,
 153           'size' => 10,
 154           'default_value' => undef,
 155       },
 156       'arrayfield' => {
 157           'data_type' => 'integer[]',
 158           'is_nullable' => 1,
 159           'size' => undef,
 160           'default_value' => undef,
 161       },
 162   };
 163
 164   my $type_info = $schema->storage->columns_info_for('dbic_t_schema.artist');
 165   my $artistid_defval = delete $type_info->{artistid}->{default_value};
 166
 167   # The curor info is too radically different from what is in the column_info
 168   # call - just punt it (DBD::SQLite tests the codepath plenty enough)
 169   unless (DBIx::Class::_ENV_::STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE) {
 170     like(
 171       $artistid_defval,
 172       qr/^nextval\('([^\.]*\.){0,1}artist_artistid_seq'::(?:text|regclass)\)/,
 173       'columns_info_for - sequence matches Pg get_autoinc_seq expectations'
 174     );
 175
 176     is_deeply($type_info, $test_type_info,
 177             'columns_info_for - column data types');
 178   }
 179
 180 ####### Array tests
 181
 182   BEGIN {
 183     package DBICTest::Schema::ArrayTest;
 184     push @main::test_classes, __PACKAGE__;
 185
 186     use strict;
 187     use warnings;
 188     use base 'DBICTest::BaseResult';
 189
 190     __PACKAGE__->table('dbic_t_schema.array_test');
 191     __PACKAGE__->add_columns(qw/id arrayfield/);
 192     __PACKAGE__->column_info_from_storage(1);
 193     __PACKAGE__->set_primary_key('id');
 194
 195   }
 196   SKIP: {
 197     skip "Need DBD::Pg 2.9.2 or newer for array tests", 4 if $DBD::Pg::VERSION < 2.009002;
 198
 199     my $arr_rs = $schema->resultset('ArrayTest');
 200
 201     lives_ok {
 202       $arr_rs->create({
 203         arrayfield => [1, 2],
 204       });
 205     } 'inserting arrayref as pg array data';
 206
 207     lives_ok {
 208       $arr_rs->update({
 209         arrayfield => [3, 4],
 210       });
 211     } 'updating arrayref as pg array data';
 212
 213     $arr_rs->create({
 214       arrayfield => [5, 6],
 215     });
 216
 217     lives_ok {
 218       $schema->populate('ArrayTest', [
 219         [ qw/arrayfield/ ],
 220         [ [0,0]          ],
 221       ]);
 222     } 'inserting arrayref using void ctx populate';
 223
 224     # Search using arrays
 225     lives_ok {
 226       is_deeply (
 227         $arr_rs->search({ arrayfield => { -value => [3,4] } })->first->arrayfield,
 228         [3,4],
 229         'Array value matches'
 230       );
 231     } 'searching by arrayref';
 232
 233     lives_ok {
 234       is_deeply (
 235         $arr_rs->search({ arrayfield => { '=' => { -value => [3,4] }} })->first->arrayfield,
 236         [3,4],
 237         'Array value matches explicit equal'
 238       );
 239     } 'searching by arrayref (explicit equal sign)';
 240
 241     lives_ok {
 242       is_deeply (
 243         $arr_rs->search({ arrayfield => { '>' => { -value => [3,1] }} })->first->arrayfield,
 244         [3,4],
 245         'Array value matches greater than'
 246       );
 247     } 'searching by arrayref (greater than)';
 248
 249     lives_ok {
 250       is (
 251         $arr_rs->search({ arrayfield => { '>' => { -value => [3,7] }} })->count,
 252         1,
 253         'Greater than search found [5,6]',
 254       );
 255     } 'searching by arrayref (greater than)';
 256
 257     # Find using arrays
 258     lives_ok {
 259       is_deeply (
 260         $arr_rs->find({ arrayfield => { -value => [3,4] } })->arrayfield,
 261         [3,4],
 262         'Array value matches implicit equal'
 263       );
 264     } 'find by arrayref';
 265
 266     lives_ok {
 267       is_deeply (
 268         $arr_rs->find({ arrayfield => { '=' => { -value => [3,4] }} })->arrayfield,
 269         [3,4],
 270         'Array value matches explicit equal'
 271       );
 272     } 'find by arrayref (equal)';
 273
 274     # test inferred condition for creation
 275     for my $cond (
 276       { -value => [3,4] },
 277       \[ '= ?' => [3, 4] ],
 278     ) {
 279       local $TODO = 'No introspection of complex literal conditions :('
 280         if is_literal_value $cond;
 281
 282
 283       my $arr_rs_cond = $arr_rs->search({ arrayfield => $cond });
 284
 285       my $row = $arr_rs_cond->create({});
 286       is_deeply ($row->arrayfield, [3,4], 'Array value taken from $rs condition');
 287       $row->discard_changes;
 288       is_deeply ($row->arrayfield, [3,4], 'Array value made it to storage');
 289     }
 290
 291     my $arr = [ 1..10 ];
 292     # exercise the creation-logic even more (akin to t/100populate.t)
 293     for my $insert_value (
 294       $arr,
 295       { -value => $arr },
 296       \[ '?', $arr ],
 297     ) {
 298       $arr_rs->delete;
 299
 300       my @objs = (
 301         $arr_rs->create({ arrayfield => $insert_value }),
 302         $arr_rs->populate([ { arrayfield => $insert_value } ]),
 303         $arr_rs->populate([ ['arrayfield'], [ $insert_value ] ]),
 304       );
 305
 306       my $loose_obj = $arr_rs->new({ arrayfield => $insert_value });
 307
 308       unless (is_literal_value $insert_value) {
 309         is_deeply( $_->arrayfield, $arr, 'array value preserved during set_columns' )
 310           for ($loose_obj, @objs)
 311       }
 312
 313       push @objs, $loose_obj->insert;
 314
 315       $_->discard_changes for @objs;
 316       is_deeply( $_->arrayfield, $arr, 'array value correct after discard_changes' )
 317         for (@objs);
 318
 319       # insert couple more in void ctx
 320       $arr_rs->populate([ { arrayfield => $insert_value } ]);
 321       $arr_rs->populate([ ['arrayfield'], [ $insert_value ] ]);
 322
 323       # should have a total of 6 now, all pristine
 324       my @retrieved_objs = $arr_rs->search({
 325         arrayfield => ref $insert_value eq 'ARRAY'
 326           ? { -value => $insert_value }
 327           : { '=' => $insert_value }
 328       })->all;
 329       is scalar @retrieved_objs, 6, 'Correct count of inserted rows';
 330       is_deeply( $_->arrayfield, $arr, 'array value correct after storage retrieval' )
 331         for (@retrieved_objs);
 332     }
 333   }
 334
 335 ########## Case check
 336
 337   BEGIN {
 338     package DBICTest::Schema::Casecheck;
 339     push @main::test_classes, __PACKAGE__;
 340
 341     use strict;
 342     use warnings;
 343     use base 'DBIx::Class::Core';
 344
 345     __PACKAGE__->table('dbic_t_schema.casecheck');
 346     __PACKAGE__->add_columns(qw/id name NAME uc_name/);
 347     __PACKAGE__->column_info_from_storage(1);
 348     __PACKAGE__->set_primary_key('id');
 349   }
 350
 351   my $name_info = $schema->source('Casecheck')->column_info( 'name' );
 352   is( $name_info->{size}, 1, "Case sensitive matching info for 'name'" );
 353
 354   my $NAME_info = $schema->source('Casecheck')->column_info( 'NAME' );
 355   is( $NAME_info->{size}, 2, "Case sensitive matching info for 'NAME'" );
 356
 357   my $uc_name_info = $schema->source('Casecheck')->column_info( 'uc_name' );
 358   is( $uc_name_info->{size}, 3, "Case insensitive matching info for 'uc_name'" );
 359
 360
 361 ## Test ResultSet->update
 362 my $artist = $schema->resultset('Artist')->first;
 363 my $cds = $artist->cds_unordered->search({
 364     year => { '!=' => 2010 }
 365 }, { prefetch => 'liner_notes' });
 366 lives_ok { $cds->update({ year => '2010' }) } 'Update on prefetched rs';
 367
 368 ## Test SELECT ... FOR UPDATE
 369   SKIP: {
 370       skip "Your system does not support unsafe signals (d_sigaction) - unable to run deadlock test", 1
 371         unless eval { $Config{d_sigaction} and require POSIX };
 372
 373       my ($timed_out, $artist2);
 374
 375       for my $t (
 376         {
 377           # Make sure that an error was raised, and that the update failed
 378           update_lock => 1,
 379           test_sub => sub {
 380             ok($timed_out, "update from second schema times out");
 381             ok($artist2->is_column_changed('name'), "'name' column is still dirty from second schema");
 382           },
 383         },
 384         {
 385           # Make sure that an error was NOT raised, and that the update succeeded
 386           update_lock => 0,
 387           test_sub => sub {
 388             ok(! $timed_out, "update from second schema DOES NOT timeout");
 389             ok(! $artist2->is_column_changed('name'), "'name' column is NOT dirty from second schema");
 390           },
 391         },
 392       ) {
 393         # create a new schema
 394         my $schema2 = DBICTest::Schema->connect($dsn, $user, $pass);
 395         $schema2->source("Artist")->name("dbic_t_schema.artist");
 396
 397         $schema->txn_do( sub {
 398           my $rs = $schema->resultset('Artist')->search(
 399               {
 400                   artistid => 1
 401               },
 402               $t->{update_lock} ? { for => 'update' } : {}
 403           );
 404           ok ($rs->count, 'Count works');
 405
 406           my $artist = $rs->next;
 407           is($artist->artistid, 1, "select returns artistid = 1");
 408
 409           $timed_out = 0;
 410
 411           eval {
 412               # can not use %SIG assignment directly - we need sigaction below
 413               # localization to a block still works however
 414               local $SIG{ALRM};
 415
 416               POSIX::sigaction( POSIX::SIGALRM() => POSIX::SigAction->new(
 417                 sub { die "DBICTestTimeout" },
 418               ));
 419
 420               $artist2 = $schema2->resultset('Artist')->find(1);
 421               $artist2->name('fooey');
 422
 423               # FIXME - this needs to go away in lieu of a non-retrying runner
 424               # ( i.e. after solving RT#47005 )
 425               local *DBIx::Class::Storage::DBI::_ping = sub { 1 }, DBIx::Class::_ENV_::OLD_MRO && Class::C3->reinitialize()
 426                 if DBIx::Class::_Util::modver_gt_or_eq( 'DBD::Pg' => '3.5.0' );
 427
 428               alarm(1);
 429               $artist2->update;
 430           };
 431
 432           alarm(0);
 433
 434           if (is_exception($@)) {
 435             $timed_out = $@ =~ /DBICTestTimeout/
 436               or die $@;
 437           }
 438         });
 439
 440         $t->{test_sub}->();
 441       }
 442   }
 443
 444
 445 ######## other older Auto-pk tests
 446
 447   $schema->source("SequenceTest")->name("dbic_t_schema.sequence_test");
 448   for (1..5) {
 449       my $st = $schema->resultset('SequenceTest')->create({ name => 'foo' });
 450       is($st->pkid1, $_, "Auto-PK for sequence without default: First primary key");
 451       is($st->pkid2, $_ + 9, "Auto-PK for sequence without default: Second primary key");
 452       is($st->nonpkid, $_ + 19, "Auto-PK for sequence without default: Non-primary key");
 453   }
 454   my $st = $schema->resultset('SequenceTest')->create({ name => 'foo', pkid1 => 55 });
 455   is($st->pkid1, 55, "Auto-PK for sequence without default: First primary key set manually");
 456
 457
 458 ######## test non-serial auto-pk
 459
 460   if ($schema->storage->_use_insert_returning) {
 461     $schema->source('TimestampPrimaryKey')->name('dbic_t_schema.timestamp_primary_key_test');
 462     my $row = $schema->resultset('TimestampPrimaryKey')->create({});
 463     ok $row->id;
 464   }
 465
 466 ######## test with_deferred_fk_checks
 467
 468   $schema->source('CD')->name('dbic_t_schema.cd');
 469   $schema->source('Track')->name('dbic_t_schema.track');
 470   lives_ok {
 471     $schema->storage->with_deferred_fk_checks(sub {
 472       $schema->resultset('Track')->create({
 473         trackid => 999, cd => 999, position => 1, title => 'deferred FK track'
 474       });
 475       $schema->resultset('CD')->create({
 476         artist => 1, cdid => 999, year => '2003', title => 'deferred FK cd'
 477       });
 478     });
 479   } 'with_deferred_fk_checks code survived';
 480
 481   is eval { $schema->resultset('Track')->find(999)->title }, 'deferred FK track',
 482      'code in with_deferred_fk_checks worked';
 483
 484   throws_ok {
 485     $schema->resultset('Track')->create({
 486       trackid => 1, cd => 9999, position => 1, title => 'Track1'
 487     });
 488   } qr/constraint/i, 'with_deferred_fk_checks is off';
 489 }
 490
 491 done_testing;
 492
 493 END {
 494     return unless $schema;
 495     drop_test_schema($schema);
 496     eapk_drop_all($schema);
 497     undef $schema;
 498 };
 499
 500
 501 ######### SUBROUTINES
 502
 503 sub create_test_schema {
 504     my $schema = shift;
 505     $schema->storage->dbh_do(sub {
 506       my (undef,$dbh) = @_;
 507
 508       local $dbh->{Warn} = 0;
 509
 510       my $std_artist_table = <<EOS;
 511 (
 512   artistid serial PRIMARY KEY
 513   , name VARCHAR(100)
 514   , rank INTEGER NOT NULL DEFAULT '13'
 515   , charfield CHAR(10)
 516   , arrayfield INTEGER[]
 517 )
 518 EOS
 519
 520       $dbh->do("CREATE SCHEMA dbic_t_schema");
 521       $dbh->do("CREATE TABLE dbic_t_schema.artist $std_artist_table");
 522
 523       $dbh->do(<<EOS);
 524 CREATE TABLE dbic_t_schema.timestamp_primary_key_test (
 525   id timestamp default current_timestamp
 526 )
 527 EOS
 528       $dbh->do(<<EOS);
 529 CREATE TABLE dbic_t_schema.cd (
 530   cdid int PRIMARY KEY,
 531   artist int,
 532   title varchar(255),
 533   year varchar(4),
 534   genreid int,
 535   single_track int
 536 )
 537 EOS
 538       $dbh->do(<<EOS);
 539 CREATE TABLE dbic_t_schema.track (
 540   trackid int,
 541   cd int REFERENCES dbic_t_schema.cd(cdid) DEFERRABLE,
 542   position int,
 543   title varchar(255),
 544   last_updated_on date,
 545   last_updated_at date
 546 )
 547 EOS
 548
 549       $dbh->do(<<EOS);
 550 CREATE TABLE dbic_t_schema.sequence_test (
 551     pkid1 integer
 552     , pkid2 integer
 553     , nonpkid integer
 554     , name VARCHAR(100)
 555     , CONSTRAINT pk PRIMARY KEY(pkid1, pkid2)
 556 )
 557 EOS
 558       $dbh->do("CREATE SEQUENCE pkid1_seq START 1 MAXVALUE 999999 MINVALUE 0");
 559       $dbh->do("CREATE SEQUENCE pkid2_seq START 10 MAXVALUE 999999 MINVALUE 0");
 560       $dbh->do("CREATE SEQUENCE nonpkid_seq START 20 MAXVALUE 999999 MINVALUE 0");
 561       $dbh->do(<<EOS);
 562 CREATE TABLE dbic_t_schema.casecheck (
 563     id serial PRIMARY KEY
 564     , "name" VARCHAR(1)
 565     , "NAME" VARCHAR(2)
 566     , "UC_NAME" VARCHAR(3)
 567 )
 568 EOS
 569       $dbh->do(<<EOS);
 570 CREATE TABLE dbic_t_schema.array_test (
 571     id serial PRIMARY KEY
 572     , arrayfield INTEGER[]
 573 )
 574 EOS
 575       $dbh->do("CREATE SCHEMA dbic_t_schema_2");
 576       $dbh->do("CREATE TABLE dbic_t_schema_2.artist $std_artist_table");
 577       $dbh->do("CREATE SCHEMA dbic_t_schema_3");
 578       $dbh->do("CREATE TABLE dbic_t_schema_3.artist $std_artist_table");
 579       $dbh->do('set search_path=dbic_t_schema,public');
 580       $dbh->do("CREATE SCHEMA dbic_t_schema_4");
 581       $dbh->do("CREATE SCHEMA dbic_t_schema_5");
 582       $dbh->do(<<EOS);
 583  CREATE TABLE dbic_t_schema_4.artist
 584  (
 585    artistid integer not null default nextval('artist_artistid_seq'::regclass) PRIMARY KEY
 586    , name VARCHAR(100)
 587    , rank INTEGER NOT NULL DEFAULT '13'
 588    , charfield CHAR(10)
 589    , arrayfield INTEGER[]
 590  );
 591 EOS
 592       $dbh->do('set search_path=public,dbic_t_schema,dbic_t_schema_3');
 593       $dbh->do('create sequence public.artist_artistid_seq'); #< in the public schema
 594       $dbh->do(<<EOS);
 595  CREATE TABLE dbic_t_schema_5.artist
 596  (
 597    artistid integer not null default nextval('public.artist_artistid_seq'::regclass) PRIMARY KEY
 598    , name VARCHAR(100)
 599    , rank INTEGER NOT NULL DEFAULT '13'
 600    , charfield CHAR(10)
 601    , arrayfield INTEGER[]
 602  );
 603 EOS
 604       $dbh->do('set search_path=dbic_t_schema,public');
 605   });
 606 }
 607
 608
 609
 610 sub drop_test_schema {
 611     my ( $schema, $warn_exceptions ) = @_;
 612
 613     $schema->storage->dbh_do(sub {
 614         my (undef,$dbh) = @_;
 615
 616         local $dbh->{Warn} = 0;
 617
 618         for my $stat (
 619                       'DROP SCHEMA dbic_t_schema_5 CASCADE',
 620                       'DROP SEQUENCE public.artist_artistid_seq CASCADE',
 621                       'DROP SCHEMA dbic_t_schema_4 CASCADE',
 622                       'DROP SCHEMA dbic_t_schema CASCADE',
 623                       'DROP SEQUENCE pkid1_seq CASCADE',
 624                       'DROP SEQUENCE pkid2_seq CASCADE',
 625                       'DROP SEQUENCE nonpkid_seq CASCADE',
 626                       'DROP SCHEMA dbic_t_schema_2 CASCADE',
 627                       'DROP SCHEMA dbic_t_schema_3 CASCADE',
 628                      ) {
 629             eval { $dbh->do ($stat) };
 630             diag $@ if $@ && $warn_exceptions;
 631         }
 632     });
 633 }
 634
 635
 636 ###  auto-pk / last_insert_id / sequence discovery
 637 sub run_apk_tests {
 638     my $schema = shift;
 639
 640     # This is in Core now, but it's here just to test that it doesn't break
 641     $schema->class('Artist')->load_components('PK::Auto');
 642     cmp_ok( $schema->resultset('Artist')->count, '==', 0, 'this should start with an empty artist table');
 643
 644     # test that auto-pk also works with the defined search path by
 645     # un-schema-qualifying the table name
 646     apk_t_set($schema,'artist');
 647
 648     my $unq_new;
 649     lives_ok {
 650         $unq_new = $schema->resultset('Artist')->create({ name => 'baz' });
 651     } 'insert into unqualified, shadowed table succeeds';
 652
 653     is($unq_new && $unq_new->artistid, 1, "and got correct artistid");
 654
 655     my @test_schemas = ( [qw| dbic_t_schema_2    1  |],
 656                          [qw| dbic_t_schema_3    1  |],
 657                          [qw| dbic_t_schema_4    2  |],
 658                          [qw| dbic_t_schema_5    1  |],
 659                        );
 660     foreach my $t ( @test_schemas ) {
 661         my ($sch_name, $start_num) = @$t;
 662         #test with dbic_t_schema_2
 663         apk_t_set($schema,"$sch_name.artist");
 664         my $another_new;
 665         lives_ok {
 666             $another_new = $schema->resultset('Artist')->create({ name => 'Tollbooth Willy'});
 667             is( $another_new->artistid,$start_num, "got correct artistid for $sch_name")
 668                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 669         } "$sch_name liid 1 did not die"
 670             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 671         lives_ok {
 672             $another_new = $schema->resultset('Artist')->create({ name => 'Adam Sandler'});
 673             is( $another_new->artistid,$start_num+1, "got correct artistid for $sch_name")
 674                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 675         } "$sch_name liid 2 did not die"
 676             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 677
 678     }
 679
 680     lives_ok {
 681         apk_t_set($schema,'dbic_t_schema.artist');
 682         my $new = $schema->resultset('Artist')->create({ name => 'foo' });
 683         is($new->artistid, 4, "Auto-PK worked");
 684         $new = $schema->resultset('Artist')->create({ name => 'bar' });
 685         is($new->artistid, 5, "Auto-PK worked");
 686     } 'old auto-pk tests did not die either';
 687 }
 688
 689 # sets the artist table name and clears sequence name cache
 690 sub apk_t_set {
 691     my ( $s, $n ) = @_;
 692     $s->source("Artist")->name($n);
 693     $s->source('Artist')->column_info('artistid')->{sequence} = undef; #< clear sequence name cache
 694 }
 695
 696
 697 ######## EXTENDED AUTO-PK TESTS
 698
 699 my @eapk_id_columns;
 700 BEGIN {
 701   package DBICTest::Schema::ExtAPK;
 702   push @main::test_classes, __PACKAGE__;
 703
 704   use strict;
 705   use warnings;
 706   use base 'DBIx::Class::Core';
 707
 708   __PACKAGE__->table('apk');
 709
 710   @eapk_id_columns = qw( id1 id2 id3 id4 );
 711   __PACKAGE__->add_columns(
 712     map { $_ => { data_type => 'integer', is_auto_increment => 1 } }
 713        @eapk_id_columns
 714   );
 715
 716   __PACKAGE__->set_primary_key('id2'); #< note the SECOND column is
 717                                        #the primary key
 718 }
 719
 720 my @eapk_schemas;
 721 BEGIN{ @eapk_schemas = map "dbic_apk_$_", 0..5 }
 722 my %seqs; #< hash of schema.table.col => currval of its (DBIC) primary key sequence
 723
 724 sub run_extended_apk_tests {
 725   my $schema = shift;
 726
 727   #save the search path and reset it at the end
 728   my $search_path_save = eapk_get_search_path($schema);
 729
 730   eapk_drop_all($schema);
 731   %seqs = ();
 732
 733   # make the test schemas and sequences
 734   $schema->storage->dbh_do(sub {
 735     my ( undef, $dbh ) = @_;
 736
 737     $dbh->do("CREATE SCHEMA $_")
 738         for @eapk_schemas;
 739
 740     $dbh->do("CREATE SEQUENCE $eapk_schemas[5].fooseq");
 741     $dbh->do("SELECT setval('$eapk_schemas[5].fooseq',400)");
 742     $seqs{"$eapk_schemas[1].apk.id2"} = 400;
 743
 744     $dbh->do("CREATE SEQUENCE $eapk_schemas[4].fooseq");
 745     $dbh->do("SELECT setval('$eapk_schemas[4].fooseq',300)");
 746     $seqs{"$eapk_schemas[3].apk.id2"} = 300;
 747
 748     $dbh->do("CREATE SEQUENCE $eapk_schemas[3].fooseq");
 749     $dbh->do("SELECT setval('$eapk_schemas[3].fooseq',200)");
 750     $seqs{"$eapk_schemas[4].apk.id2"} = 200;
 751
 752     $dbh->do("SET search_path = ".join ',', reverse @eapk_schemas );
 753   });
 754
 755   # clear our search_path cache
 756   $schema->storage->{_pg_search_path} = undef;
 757
 758   eapk_create( $schema,
 759                with_search_path => [0,1],
 760              );
 761   eapk_create( $schema,
 762                with_search_path => [1,0,'public'],
 763                nextval => "$eapk_schemas[5].fooseq",
 764              );
 765   eapk_create( $schema,
 766                with_search_path => ['public',0,1],
 767                qualify_table => 2,
 768              );
 769   eapk_create( $schema,
 770                with_search_path => [3,1,0,'public'],
 771                nextval => "$eapk_schemas[4].fooseq",
 772              );
 773   eapk_create( $schema,
 774                with_search_path => [3,1,0,'public'],
 775                nextval => "$eapk_schemas[3].fooseq",
 776                qualify_table => 4,
 777              );
 778
 779   eapk_poke( $schema );
 780   eapk_poke( $schema, 0 );
 781   eapk_poke( $schema, 2 );
 782   eapk_poke( $schema, 4 );
 783   eapk_poke( $schema, 1 );
 784   eapk_poke( $schema, 0 );
 785   eapk_poke( $schema, 1 );
 786   eapk_poke( $schema );
 787   eapk_poke( $schema, 4 );
 788   eapk_poke( $schema, 3 );
 789   eapk_poke( $schema, 1 );
 790   eapk_poke( $schema, 2 );
 791   eapk_poke( $schema, 0 );
 792
 793   # set our search path back
 794   eapk_set_search_path( $schema, @$search_path_save );
 795 }
 796
 797 # do a DBIC create on the apk table in the given schema number (which is an
 798 # index of @eapk_schemas)
 799
 800 sub eapk_poke {
 801   my ($s, $schema_num) = @_;
 802
 803   my $schema_name = defined $schema_num
 804       ? $eapk_schemas[$schema_num]
 805       : '';
 806
 807   my $schema_name_actual = $schema_name || eapk_find_visible_schema($s);
 808
 809   $s->source('ExtAPK')->name($schema_name ? $schema_name.'.apk' : 'apk');
 810   #< clear sequence name cache
 811   $s->source('ExtAPK')->column_info($_)->{sequence} = undef
 812       for @eapk_id_columns;
 813
 814   no warnings 'uninitialized';
 815   lives_ok {
 816     my $new;
 817     for my $inc (1,2,3) {
 818       $new = $schema->resultset('ExtAPK')->create({ id1 => 1});
 819       my $proper_seqval = ++$seqs{"$schema_name_actual.apk.id2"};
 820       is( $new->id2, $proper_seqval, "$schema_name_actual.apk.id2 correct inc $inc" )
 821           or eapk_seq_diag($s,$schema_name);
 822       $new->discard_changes;
 823       is( $new->id1, 1 );
 824       for my $id ('id3','id4') {
 825         my $proper_seqval = ++$seqs{"$schema_name_actual.apk.$id"};
 826         is( $new->$id, $proper_seqval, "$schema_name_actual.apk.$id correct inc $inc" )
 827             or eapk_seq_diag($s,$schema_name);
 828       }
 829     }
 830   } "create in schema '$schema_name' lives"
 831       or eapk_seq_diag($s,$schema_name);
 832 }
 833
 834 # print diagnostic info on which sequences were found in the ExtAPK
 835 # class
 836 sub eapk_seq_diag {
 837     my $s = shift;
 838     my $schema = shift || eapk_find_visible_schema($s);
 839
 840     diag "$schema.apk sequences: ",
 841         join(', ',
 842              map "$_:".($s->source('ExtAPK')->column_info($_)->{sequence} || '<none>'),
 843              @eapk_id_columns
 844             );
 845 }
 846
 847 # get the postgres search path as an arrayref
 848 sub eapk_get_search_path {
 849     my ( $s ) = @_;
 850     # cache the search path as ['schema','schema',...] in the storage
 851     # obj
 852
 853     return $s->storage->dbh_do(sub {
 854         my (undef, $dbh) = @_;
 855         my @search_path;
 856         my ($sp_string) = $dbh->selectrow_array('SHOW search_path');
 857         while ( $sp_string =~ s/("[^"]+"|[^,]+),?// ) {
 858             unless( defined $1 and length $1 ) {
 859                 die "search path sanity check failed: '$1'";
 860             }
 861             push @search_path, $1;
 862         }
 863         \@search_path
 864     });
 865 }
 866 sub eapk_set_search_path {
 867     my ($s,@sp) = @_;
 868     my $sp = join ',',@sp;
 869     $s->storage->dbh_do( sub { $_[1]->do("SET search_path = $sp") } );
 870 }
 871
 872 # create the apk table in the given schema, can set whether the table name is qualified, what the nextval is for the second ID
 873 sub eapk_create {
 874     my ($schema, %a) = @_;
 875
 876     $schema->storage->dbh_do(sub {
 877         my (undef,$dbh) = @_;
 878
 879         my $searchpath_save;
 880         if ( $a{with_search_path} ) {
 881             ($searchpath_save) = $dbh->selectrow_array('SHOW search_path');
 882
 883             my $search_path = join ',',map {/\D/ ? $_ : $eapk_schemas[$_]} @{$a{with_search_path}};
 884
 885             $dbh->do("SET search_path = $search_path");
 886         }
 887
 888         my $table_name = $a{qualify_table}
 889             ? ($eapk_schemas[$a{qualify_table}] || die). ".apk"
 890             : 'apk';
 891         local $_[1]->{Warn} = 0;
 892
 893         my $id_def = $a{nextval}
 894             ? "integer not null default nextval('$a{nextval}'::regclass)"
 895             : 'serial';
 896         $dbh->do(<<EOS);
 897 CREATE TABLE $table_name (
 898   id1 serial
 899   , id2 $id_def
 900   , id3 serial primary key
 901   , id4 serial
 902 )
 903 EOS
 904
 905         if( $searchpath_save ) {
 906             $dbh->do("SET search_path = $searchpath_save");
 907         }
 908     });
 909 }
 910
 911 sub eapk_drop_all {
 912     my ( $schema, $warn_exceptions ) = @_;
 913
 914     $schema->storage->dbh_do(sub {
 915         my (undef,$dbh) = @_;
 916
 917         local $dbh->{Warn} = 0;
 918
 919         # drop the test schemas
 920         for (@eapk_schemas ) {
 921             eval{ $dbh->do("DROP SCHEMA $_ CASCADE") };
 922             diag $@ if $@ && $warn_exceptions;
 923         }
 924
 925
 926     });
 927 }
 928
 929 sub eapk_find_visible_schema {
 930     my ($s) = @_;
 931
 932     my ($schema) =
 933         $s->storage->dbh_do(sub {
 934             $_[1]->selectrow_array(<<EOS);
 935 SELECT n.nspname
 936 FROM pg_catalog.pg_namespace n
 937 JOIN pg_catalog.pg_class c ON c.relnamespace = n.oid
 938 WHERE c.relname = 'apk'
 939   AND pg_catalog.pg_table_is_visible(c.oid)
 940 EOS
 941         });
 942     return $schema;
 943 }