t/72pg.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use Sub::Name;
   7 use lib qw(t/lib);
   8 use DBICTest;
   9
  10
  11 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
  12
  13 plan skip_all => <<'EOM' unless $dsn && $user;
  14 Set $ENV{DBICTEST_PG_DSN}, _USER and _PASS to run this test
  15 ( NOTE: This test drops and creates tables called 'artist', 'cd',
  16 'timestamp_primary_key_test', 'track', 'casecheck', 'array_test' and
  17 'sequence_test' as well as following sequences: 'pkid1_seq', 'pkid2_seq' and
  18 'nonpkid_seq'. as well as following schemas: 'dbic_t_schema',
  19 'dbic_t_schema_2', 'dbic_t_schema_3', 'dbic_t_schema_4', and 'dbic_t_schema_5')
  20 EOM
  21
  22 ### load any test classes that are defined further down in the file via BEGIN blocks
  23
  24 our @test_classes; #< array that will be pushed into by test classes defined in this file
  25 DBICTest::Schema->load_classes( map {s/.+:://;$_} @test_classes ) if @test_classes;
  26
  27 ###  pre-connect tests (keep each test separate as to make sure rebless() runs)
  28   {
  29     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  30
  31     ok (!$s->storage->_dbh, 'definitely not connected');
  32
  33     # Check that datetime_parser returns correctly before we explicitly connect.
  34     SKIP: {
  35         eval { require DateTime::Format::Pg };
  36         skip "DateTime::Format::Pg required", 2 if $@;
  37
  38         my $store = ref $s->storage;
  39         is($store, 'DBIx::Class::Storage::DBI', 'Started with generic storage');
  40
  41         my $parser = $s->storage->datetime_parser;
  42         is( $parser, 'DateTime::Format::Pg', 'datetime_parser is as expected');
  43     }
  44
  45     ok (!$s->storage->_dbh, 'still not connected');
  46   }
  47
  48   {
  49     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  50     # make sure sqlt_type overrides work (::Storage::DBI::Pg does this)
  51     ok (!$s->storage->_dbh, 'definitely not connected');
  52     is ($s->storage->sqlt_type, 'PostgreSQL', 'sqlt_type correct pre-connection');
  53     ok (!$s->storage->_dbh, 'still not connected');
  54   }
  55
  56 # test LIMIT support
  57 {
  58   my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
  59   drop_test_schema($schema);
  60   create_test_schema($schema);
  61   for (1..6) {
  62     $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
  63   }
  64   my $it = $schema->resultset('Artist')->search( {},
  65     { rows => 3,
  66       offset => 2,
  67       order_by => 'artistid' }
  68   );
  69   is( $it->count, 3, "LIMIT count ok" );  # ask for 3 rows out of 6 artists
  70   is( $it->next->name, "Artist 3", "iterator->next ok" );
  71   $it->next;
  72   $it->next;
  73   $it->next;
  74   is( $it->next, undef, "next past end of resultset ok" );
  75
  76   # Limit with select-lock
  77   lives_ok {
  78     $schema->txn_do (sub {
  79       isa_ok (
  80         $schema->resultset('Artist')->find({artistid => 1}, {for => 'update', rows => 1}),
  81         'DBICTest::Schema::Artist',
  82       );
  83     });
  84   } 'Limited FOR UPDATE select works';
  85 }
  86
  87 # check if we indeed do support stuff
  88 my $test_server_supports_insert_returning = do {
  89   my $v = DBICTest::Schema->connect($dsn, $user, $pass)
  90                    ->storage
  91                     ->_get_dbh
  92                      ->get_info(18);
  93   $v =~ /^(\d+)\.(\d+)/
  94     or die "Unparseable Pg server version: $v\n";
  95
  96   ( sprintf ('%d.%d', $1, $2) >= 8.2 ) ? 1 : 0;
  97 };
  98 is (
  99   DBICTest::Schema->connect($dsn, $user, $pass)->storage->_use_insert_returning,
 100   $test_server_supports_insert_returning,
 101   'insert returning capability guessed correctly'
 102 );
 103
 104 my $schema;
 105 for my $use_insert_returning ($test_server_supports_insert_returning
 106   ? (0,1)
 107   : (0)
 108 ) {
 109
 110   no warnings qw/once/;
 111   local *DBICTest::Schema::connection = subname 'DBICTest::Schema::connection' => sub {
 112     my $s = shift->next::method (@_);
 113     $s->storage->_use_insert_returning ($use_insert_returning);
 114     $s;
 115   };
 116
 117 ### test capability override
 118   {
 119     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
 120
 121     ok (!$s->storage->_dbh, 'definitely not connected');
 122
 123     ok (
 124       ! ($s->storage->_use_insert_returning xor $use_insert_returning),
 125       'insert returning capability set correctly',
 126     );
 127     ok (!$s->storage->_dbh, 'still not connected (capability override works)');
 128   }
 129
 130 ### connect, create postgres-specific test schema
 131
 132   $schema = DBICTest::Schema->connect($dsn, $user, $pass);
 133   $schema->storage->ensure_connected;
 134
 135   drop_test_schema($schema);
 136   create_test_schema($schema);
 137
 138 ### begin main tests
 139
 140 # run a BIG bunch of tests for last-insert-id / Auto-PK / sequence
 141 # discovery
 142   run_apk_tests($schema); #< older set of auto-pk tests
 143   run_extended_apk_tests($schema); #< new extended set of auto-pk tests
 144
 145 ### type_info tests
 146
 147   my $test_type_info = {
 148       'artistid' => {
 149           'data_type' => 'integer',
 150           'is_nullable' => 0,
 151           'size' => 4,
 152       },
 153       'name' => {
 154           'data_type' => 'character varying',
 155           'is_nullable' => 1,
 156           'size' => 100,
 157           'default_value' => undef,
 158       },
 159       'rank' => {
 160           'data_type' => 'integer',
 161           'is_nullable' => 0,
 162           'size' => 4,
 163           'default_value' => 13,
 164
 165       },
 166       'charfield' => {
 167           'data_type' => 'character',
 168           'is_nullable' => 1,
 169           'size' => 10,
 170           'default_value' => undef,
 171       },
 172       'arrayfield' => {
 173           'data_type' => 'integer[]',
 174           'is_nullable' => 1,
 175           'size' => undef,
 176           'default_value' => undef,
 177       },
 178   };
 179
 180   my $type_info = $schema->storage->columns_info_for('dbic_t_schema.artist');
 181   my $artistid_defval = delete $type_info->{artistid}->{default_value};
 182   like($artistid_defval,
 183        qr/^nextval\('([^\.]*\.){0,1}artist_artistid_seq'::(?:text|regclass)\)/,
 184        'columns_info_for - sequence matches Pg get_autoinc_seq expectations');
 185   is_deeply($type_info, $test_type_info,
 186             'columns_info_for - column data types');
 187
 188
 189
 190
 191 ####### Array tests
 192
 193   BEGIN {
 194     package DBICTest::Schema::ArrayTest;
 195     push @main::test_classes, __PACKAGE__;
 196
 197     use strict;
 198     use warnings;
 199     use base 'DBIx::Class::Core';
 200
 201     __PACKAGE__->table('dbic_t_schema.array_test');
 202     __PACKAGE__->add_columns(qw/id arrayfield/);
 203     __PACKAGE__->column_info_from_storage(1);
 204     __PACKAGE__->set_primary_key('id');
 205
 206   }
 207   SKIP: {
 208     skip "Need DBD::Pg 2.9.2 or newer for array tests", 4 if $DBD::Pg::VERSION < 2.009002;
 209
 210     lives_ok {
 211       $schema->resultset('ArrayTest')->create({
 212         arrayfield => [1, 2],
 213       });
 214     } 'inserting arrayref as pg array data';
 215
 216     lives_ok {
 217       $schema->resultset('ArrayTest')->update({
 218         arrayfield => [3, 4],
 219       });
 220     } 'updating arrayref as pg array data';
 221
 222     $schema->resultset('ArrayTest')->create({
 223       arrayfield => [5, 6],
 224     });
 225
 226     my $count;
 227     lives_ok {
 228       $count = $schema->resultset('ArrayTest')->search({
 229         arrayfield => \[ '= ?' => [arrayfield => [3, 4]] ],   #Todo anything less ugly than this?
 230       })->count;
 231     } 'comparing arrayref to pg array data does not blow up';
 232     is($count, 1, 'comparing arrayref to pg array data gives correct result');
 233   }
 234
 235
 236
 237 ########## Case check
 238
 239   BEGIN {
 240     package DBICTest::Schema::Casecheck;
 241     push @main::test_classes, __PACKAGE__;
 242
 243     use strict;
 244     use warnings;
 245     use base 'DBIx::Class::Core';
 246
 247     __PACKAGE__->table('dbic_t_schema.casecheck');
 248     __PACKAGE__->add_columns(qw/id name NAME uc_name/);
 249     __PACKAGE__->column_info_from_storage(1);
 250     __PACKAGE__->set_primary_key('id');
 251   }
 252
 253   my $name_info = $schema->source('Casecheck')->column_info( 'name' );
 254   is( $name_info->{size}, 1, "Case sensitive matching info for 'name'" );
 255
 256   my $NAME_info = $schema->source('Casecheck')->column_info( 'NAME' );
 257   is( $NAME_info->{size}, 2, "Case sensitive matching info for 'NAME'" );
 258
 259   my $uc_name_info = $schema->source('Casecheck')->column_info( 'uc_name' );
 260   is( $uc_name_info->{size}, 3, "Case insensitive matching info for 'uc_name'" );
 261
 262
 263 ## Test ResultSet->update
 264 my $artist = $schema->resultset('Artist')->first;
 265 my $cds = $artist->cds_unordered->search({
 266     year => { '!=' => 2010 }
 267 }, { prefetch => 'liner_notes' });
 268 lives_ok { $cds->update({ year => '2010' }) } 'Update on prefetched rs';
 269
 270 ## Test SELECT ... FOR UPDATE
 271
 272   SKIP: {
 273       if(eval { require Sys::SigAction }) {
 274           Sys::SigAction->import( 'set_sig_handler' );
 275       }
 276       else {
 277         skip "Sys::SigAction is not available", 6;
 278       }
 279
 280       my ($timed_out, $artist2);
 281
 282       for my $t (
 283         {
 284           # Make sure that an error was raised, and that the update failed
 285           update_lock => 1,
 286           test_sub => sub {
 287             ok($timed_out, "update from second schema times out");
 288             ok($artist2->is_column_changed('name'), "'name' column is still dirty from second schema");
 289           },
 290         },
 291         {
 292           # Make sure that an error was NOT raised, and that the update succeeded
 293           update_lock => 0,
 294           test_sub => sub {
 295             ok(! $timed_out, "update from second schema DOES NOT timeout");
 296             ok(! $artist2->is_column_changed('name'), "'name' column is NOT dirty from second schema");
 297           },
 298         },
 299       ) {
 300         # create a new schema
 301         my $schema2 = DBICTest::Schema->connect($dsn, $user, $pass);
 302         $schema2->source("Artist")->name("dbic_t_schema.artist");
 303
 304         $schema->txn_do( sub {
 305           my $rs = $schema->resultset('Artist')->search(
 306               {
 307                   artistid => 1
 308               },
 309               $t->{update_lock} ? { for => 'update' } : {}
 310           );
 311           ok ($rs->count, 'Count works');
 312
 313           my $artist = $rs->next;
 314           is($artist->artistid, 1, "select returns artistid = 1");
 315
 316           $timed_out = 0;
 317           eval {
 318               my $h = set_sig_handler( 'ALRM', sub { die "DBICTestTimeout" } );
 319               alarm(2);
 320               $artist2 = $schema2->resultset('Artist')->find(1);
 321               $artist2->name('fooey');
 322               $artist2->update;
 323               alarm(0);
 324           };
 325           $timed_out = $@ =~ /DBICTestTimeout/;
 326         });
 327
 328         $t->{test_sub}->();
 329       }
 330   }
 331
 332
 333 ######## other older Auto-pk tests
 334
 335   $schema->source("SequenceTest")->name("dbic_t_schema.sequence_test");
 336   for (1..5) {
 337       my $st = $schema->resultset('SequenceTest')->create({ name => 'foo' });
 338       is($st->pkid1, $_, "Auto-PK for sequence without default: First primary key");
 339       is($st->pkid2, $_ + 9, "Auto-PK for sequence without default: Second primary key");
 340       is($st->nonpkid, $_ + 19, "Auto-PK for sequence without default: Non-primary key");
 341   }
 342   my $st = $schema->resultset('SequenceTest')->create({ name => 'foo', pkid1 => 55 });
 343   is($st->pkid1, 55, "Auto-PK for sequence without default: First primary key set manually");
 344
 345
 346 ######## test non-serial auto-pk
 347
 348   if ($schema->storage->_use_insert_returning) {
 349     $schema->source('TimestampPrimaryKey')->name('dbic_t_schema.timestamp_primary_key_test');
 350     my $row = $schema->resultset('TimestampPrimaryKey')->create({});
 351     ok $row->id;
 352   }
 353
 354 ######## test with_deferred_fk_checks
 355
 356   $schema->source('CD')->name('dbic_t_schema.cd');
 357   $schema->source('Track')->name('dbic_t_schema.track');
 358   lives_ok {
 359     $schema->storage->with_deferred_fk_checks(sub {
 360       $schema->resultset('Track')->create({
 361         trackid => 999, cd => 999, position => 1, title => 'deferred FK track'
 362       });
 363       $schema->resultset('CD')->create({
 364         artist => 1, cdid => 999, year => '2003', title => 'deferred FK cd'
 365       });
 366     });
 367   } 'with_deferred_fk_checks code survived';
 368
 369   is eval { $schema->resultset('Track')->find(999)->title }, 'deferred FK track',
 370      'code in with_deferred_fk_checks worked';
 371
 372   throws_ok {
 373     $schema->resultset('Track')->create({
 374       trackid => 1, cd => 9999, position => 1, title => 'Track1'
 375     });
 376   } qr/constraint/i, 'with_deferred_fk_checks is off';
 377 }
 378
 379 done_testing;
 380
 381 END {
 382     return unless $schema;
 383     drop_test_schema($schema);
 384     eapk_drop_all( $schema)
 385 };
 386
 387
 388 ######### SUBROUTINES
 389
 390 sub create_test_schema {
 391     my $schema = shift;
 392     $schema->storage->dbh_do(sub {
 393       my (undef,$dbh) = @_;
 394
 395       local $dbh->{Warn} = 0;
 396
 397       my $std_artist_table = <<EOS;
 398 (
 399   artistid serial PRIMARY KEY
 400   , name VARCHAR(100)
 401   , rank INTEGER NOT NULL DEFAULT '13'
 402   , charfield CHAR(10)
 403   , arrayfield INTEGER[]
 404 )
 405 EOS
 406
 407       $dbh->do("CREATE SCHEMA dbic_t_schema");
 408       $dbh->do("CREATE TABLE dbic_t_schema.artist $std_artist_table");
 409
 410       $dbh->do(<<EOS);
 411 CREATE TABLE dbic_t_schema.timestamp_primary_key_test (
 412   id timestamp default current_timestamp
 413 )
 414 EOS
 415       $dbh->do(<<EOS);
 416 CREATE TABLE dbic_t_schema.cd (
 417   cdid int PRIMARY KEY,
 418   artist int,
 419   title varchar(255),
 420   year varchar(4),
 421   genreid int,
 422   single_track int
 423 )
 424 EOS
 425       $dbh->do(<<EOS);
 426 CREATE TABLE dbic_t_schema.track (
 427   trackid int,
 428   cd int REFERENCES dbic_t_schema.cd(cdid) DEFERRABLE,
 429   position int,
 430   title varchar(255),
 431   last_updated_on date,
 432   last_updated_at date,
 433   small_dt date
 434 )
 435 EOS
 436
 437       $dbh->do(<<EOS);
 438 CREATE TABLE dbic_t_schema.sequence_test (
 439     pkid1 integer
 440     , pkid2 integer
 441     , nonpkid integer
 442     , name VARCHAR(100)
 443     , CONSTRAINT pk PRIMARY KEY(pkid1, pkid2)
 444 )
 445 EOS
 446       $dbh->do("CREATE SEQUENCE pkid1_seq START 1 MAXVALUE 999999 MINVALUE 0");
 447       $dbh->do("CREATE SEQUENCE pkid2_seq START 10 MAXVALUE 999999 MINVALUE 0");
 448       $dbh->do("CREATE SEQUENCE nonpkid_seq START 20 MAXVALUE 999999 MINVALUE 0");
 449       $dbh->do(<<EOS);
 450 CREATE TABLE dbic_t_schema.casecheck (
 451     id serial PRIMARY KEY
 452     , "name" VARCHAR(1)
 453     , "NAME" VARCHAR(2)
 454     , "UC_NAME" VARCHAR(3)
 455 )
 456 EOS
 457       $dbh->do(<<EOS);
 458 CREATE TABLE dbic_t_schema.array_test (
 459     id serial PRIMARY KEY
 460     , arrayfield INTEGER[]
 461 )
 462 EOS
 463       $dbh->do("CREATE SCHEMA dbic_t_schema_2");
 464       $dbh->do("CREATE TABLE dbic_t_schema_2.artist $std_artist_table");
 465       $dbh->do("CREATE SCHEMA dbic_t_schema_3");
 466       $dbh->do("CREATE TABLE dbic_t_schema_3.artist $std_artist_table");
 467       $dbh->do('set search_path=dbic_t_schema,public');
 468       $dbh->do("CREATE SCHEMA dbic_t_schema_4");
 469       $dbh->do("CREATE SCHEMA dbic_t_schema_5");
 470       $dbh->do(<<EOS);
 471  CREATE TABLE dbic_t_schema_4.artist
 472  (
 473    artistid integer not null default nextval('artist_artistid_seq'::regclass) PRIMARY KEY
 474    , name VARCHAR(100)
 475    , rank INTEGER NOT NULL DEFAULT '13'
 476    , charfield CHAR(10)
 477    , arrayfield INTEGER[]
 478  );
 479 EOS
 480       $dbh->do('set search_path=public,dbic_t_schema,dbic_t_schema_3');
 481       $dbh->do('create sequence public.artist_artistid_seq'); #< in the public schema
 482       $dbh->do(<<EOS);
 483  CREATE TABLE dbic_t_schema_5.artist
 484  (
 485    artistid integer not null default nextval('public.artist_artistid_seq'::regclass) PRIMARY KEY
 486    , name VARCHAR(100)
 487    , rank INTEGER NOT NULL DEFAULT '13'
 488    , charfield CHAR(10)
 489    , arrayfield INTEGER[]
 490  );
 491 EOS
 492       $dbh->do('set search_path=dbic_t_schema,public');
 493   });
 494 }
 495
 496
 497
 498 sub drop_test_schema {
 499     my ( $schema, $warn_exceptions ) = @_;
 500
 501     $schema->storage->dbh_do(sub {
 502         my (undef,$dbh) = @_;
 503
 504         local $dbh->{Warn} = 0;
 505
 506         for my $stat (
 507                       'DROP SCHEMA dbic_t_schema_5 CASCADE',
 508                       'DROP SEQUENCE public.artist_artistid_seq',
 509                       'DROP SCHEMA dbic_t_schema_4 CASCADE',
 510                       'DROP SCHEMA dbic_t_schema CASCADE',
 511                       'DROP SEQUENCE pkid1_seq',
 512                       'DROP SEQUENCE pkid2_seq',
 513                       'DROP SEQUENCE nonpkid_seq',
 514                       'DROP SCHEMA dbic_t_schema_2 CASCADE',
 515                       'DROP SCHEMA dbic_t_schema_3 CASCADE',
 516                      ) {
 517             eval { $dbh->do ($stat) };
 518             diag $@ if $@ && $warn_exceptions;
 519         }
 520     });
 521 }
 522
 523
 524 ###  auto-pk / last_insert_id / sequence discovery
 525 sub run_apk_tests {
 526     my $schema = shift;
 527
 528     # This is in Core now, but it's here just to test that it doesn't break
 529     $schema->class('Artist')->load_components('PK::Auto');
 530     cmp_ok( $schema->resultset('Artist')->count, '==', 0, 'this should start with an empty artist table');
 531
 532     # test that auto-pk also works with the defined search path by
 533     # un-schema-qualifying the table name
 534     apk_t_set($schema,'artist');
 535
 536     my $unq_new;
 537     lives_ok {
 538         $unq_new = $schema->resultset('Artist')->create({ name => 'baz' });
 539     } 'insert into unqualified, shadowed table succeeds';
 540
 541     is($unq_new && $unq_new->artistid, 1, "and got correct artistid");
 542
 543     my @test_schemas = ( [qw| dbic_t_schema_2    1  |],
 544                          [qw| dbic_t_schema_3    1  |],
 545                          [qw| dbic_t_schema_4    2  |],
 546                          [qw| dbic_t_schema_5    1  |],
 547                        );
 548     foreach my $t ( @test_schemas ) {
 549         my ($sch_name, $start_num) = @$t;
 550         #test with dbic_t_schema_2
 551         apk_t_set($schema,"$sch_name.artist");
 552         my $another_new;
 553         lives_ok {
 554             $another_new = $schema->resultset('Artist')->create({ name => 'Tollbooth Willy'});
 555             is( $another_new->artistid,$start_num, "got correct artistid for $sch_name")
 556                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 557         } "$sch_name liid 1 did not die"
 558             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 559         lives_ok {
 560             $another_new = $schema->resultset('Artist')->create({ name => 'Adam Sandler'});
 561             is( $another_new->artistid,$start_num+1, "got correct artistid for $sch_name")
 562                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 563         } "$sch_name liid 2 did not die"
 564             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 565
 566     }
 567
 568     lives_ok {
 569         apk_t_set($schema,'dbic_t_schema.artist');
 570         my $new = $schema->resultset('Artist')->create({ name => 'foo' });
 571         is($new->artistid, 4, "Auto-PK worked");
 572         $new = $schema->resultset('Artist')->create({ name => 'bar' });
 573         is($new->artistid, 5, "Auto-PK worked");
 574     } 'old auto-pk tests did not die either';
 575 }
 576
 577 # sets the artist table name and clears sequence name cache
 578 sub apk_t_set {
 579     my ( $s, $n ) = @_;
 580     $s->source("Artist")->name($n);
 581     $s->source('Artist')->column_info('artistid')->{sequence} = undef; #< clear sequence name cache
 582 }
 583
 584
 585 ######## EXTENDED AUTO-PK TESTS
 586
 587 my @eapk_id_columns;
 588 BEGIN {
 589   package DBICTest::Schema::ExtAPK;
 590   push @main::test_classes, __PACKAGE__;
 591
 592   use strict;
 593   use warnings;
 594   use base 'DBIx::Class::Core';
 595
 596   __PACKAGE__->table('apk');
 597
 598   @eapk_id_columns = qw( id1 id2 id3 id4 );
 599   __PACKAGE__->add_columns(
 600     map { $_ => { data_type => 'integer', is_auto_increment => 1 } }
 601        @eapk_id_columns
 602   );
 603
 604   __PACKAGE__->set_primary_key('id2'); #< note the SECOND column is
 605                                        #the primary key
 606 }
 607
 608 my @eapk_schemas;
 609 BEGIN{ @eapk_schemas = map "dbic_apk_$_", 0..5 }
 610 my %seqs; #< hash of schema.table.col => currval of its (DBIC) primary key sequence
 611
 612 sub run_extended_apk_tests {
 613   my $schema = shift;
 614
 615   #save the search path and reset it at the end
 616   my $search_path_save = eapk_get_search_path($schema);
 617
 618   eapk_drop_all($schema);
 619   %seqs = ();
 620
 621   # make the test schemas and sequences
 622   $schema->storage->dbh_do(sub {
 623     my ( undef, $dbh ) = @_;
 624
 625     $dbh->do("CREATE SCHEMA $_")
 626         for @eapk_schemas;
 627
 628     $dbh->do("CREATE SEQUENCE $eapk_schemas[5].fooseq");
 629     $dbh->do("SELECT setval('$eapk_schemas[5].fooseq',400)");
 630     $seqs{"$eapk_schemas[1].apk.id2"} = 400;
 631
 632     $dbh->do("CREATE SEQUENCE $eapk_schemas[4].fooseq");
 633     $dbh->do("SELECT setval('$eapk_schemas[4].fooseq',300)");
 634     $seqs{"$eapk_schemas[3].apk.id2"} = 300;
 635
 636     $dbh->do("CREATE SEQUENCE $eapk_schemas[3].fooseq");
 637     $dbh->do("SELECT setval('$eapk_schemas[3].fooseq',200)");
 638     $seqs{"$eapk_schemas[4].apk.id2"} = 200;
 639
 640     $dbh->do("SET search_path = ".join ',', reverse @eapk_schemas );
 641   });
 642
 643   # clear our search_path cache
 644   $schema->storage->{_pg_search_path} = undef;
 645
 646   eapk_create( $schema,
 647                with_search_path => [0,1],
 648              );
 649   eapk_create( $schema,
 650                with_search_path => [1,0,'public'],
 651                nextval => "$eapk_schemas[5].fooseq",
 652              );
 653   eapk_create( $schema,
 654                with_search_path => ['public',0,1],
 655                qualify_table => 2,
 656              );
 657   eapk_create( $schema,
 658                with_search_path => [3,1,0,'public'],
 659                nextval => "$eapk_schemas[4].fooseq",
 660              );
 661   eapk_create( $schema,
 662                with_search_path => [3,1,0,'public'],
 663                nextval => "$eapk_schemas[3].fooseq",
 664                qualify_table => 4,
 665              );
 666
 667   eapk_poke( $schema );
 668   eapk_poke( $schema, 0 );
 669   eapk_poke( $schema, 2 );
 670   eapk_poke( $schema, 4 );
 671   eapk_poke( $schema, 1 );
 672   eapk_poke( $schema, 0 );
 673   eapk_poke( $schema, 1 );
 674   eapk_poke( $schema );
 675   eapk_poke( $schema, 4 );
 676   eapk_poke( $schema, 3 );
 677   eapk_poke( $schema, 1 );
 678   eapk_poke( $schema, 2 );
 679   eapk_poke( $schema, 0 );
 680
 681   # set our search path back
 682   eapk_set_search_path( $schema, @$search_path_save );
 683 }
 684
 685 # do a DBIC create on the apk table in the given schema number (which is an
 686 # index of @eapk_schemas)
 687
 688 sub eapk_poke {
 689   my ($s, $schema_num) = @_;
 690
 691   my $schema_name = defined $schema_num
 692       ? $eapk_schemas[$schema_num]
 693       : '';
 694
 695   my $schema_name_actual = $schema_name || eapk_find_visible_schema($s);
 696
 697   $s->source('ExtAPK')->name($schema_name ? $schema_name.'.apk' : 'apk');
 698   #< clear sequence name cache
 699   $s->source('ExtAPK')->column_info($_)->{sequence} = undef
 700       for @eapk_id_columns;
 701
 702   no warnings 'uninitialized';
 703   lives_ok {
 704     my $new;
 705     for my $inc (1,2,3) {
 706       $new = $schema->resultset('ExtAPK')->create({ id1 => 1});
 707       my $proper_seqval = ++$seqs{"$schema_name_actual.apk.id2"};
 708       is( $new->id2, $proper_seqval, "$schema_name_actual.apk.id2 correct inc $inc" )
 709           or eapk_seq_diag($s,$schema_name);
 710       $new->discard_changes;
 711       is( $new->id1, 1 );
 712       for my $id ('id3','id4') {
 713         my $proper_seqval = ++$seqs{"$schema_name_actual.apk.$id"};
 714         is( $new->$id, $proper_seqval, "$schema_name_actual.apk.$id correct inc $inc" )
 715             or eapk_seq_diag($s,$schema_name);
 716       }
 717     }
 718   } "create in schema '$schema_name' lives"
 719       or eapk_seq_diag($s,$schema_name);
 720 }
 721
 722 # print diagnostic info on which sequences were found in the ExtAPK
 723 # class
 724 sub eapk_seq_diag {
 725     my $s = shift;
 726     my $schema = shift || eapk_find_visible_schema($s);
 727
 728     diag "$schema.apk sequences: ",
 729         join(', ',
 730              map "$_:".($s->source('ExtAPK')->column_info($_)->{sequence} || '<none>'),
 731              @eapk_id_columns
 732             );
 733 }
 734
 735 # get the postgres search path as an arrayref
 736 sub eapk_get_search_path {
 737     my ( $s ) = @_;
 738     # cache the search path as ['schema','schema',...] in the storage
 739     # obj
 740
 741     return $s->storage->dbh_do(sub {
 742         my (undef, $dbh) = @_;
 743         my @search_path;
 744         my ($sp_string) = $dbh->selectrow_array('SHOW search_path');
 745         while ( $sp_string =~ s/("[^"]+"|[^,]+),?// ) {
 746             unless( defined $1 and length $1 ) {
 747                 die "search path sanity check failed: '$1'";
 748             }
 749             push @search_path, $1;
 750         }
 751         \@search_path
 752     });
 753 }
 754 sub eapk_set_search_path {
 755     my ($s,@sp) = @_;
 756     my $sp = join ',',@sp;
 757     $s->storage->dbh_do( sub { $_[1]->do("SET search_path = $sp") } );
 758 }
 759
 760 # create the apk table in the given schema, can set whether the table name is qualified, what the nextval is for the second ID
 761 sub eapk_create {
 762     my ($schema, %a) = @_;
 763
 764     $schema->storage->dbh_do(sub {
 765         my (undef,$dbh) = @_;
 766
 767         my $searchpath_save;
 768         if ( $a{with_search_path} ) {
 769             ($searchpath_save) = $dbh->selectrow_array('SHOW search_path');
 770
 771             my $search_path = join ',',map {/\D/ ? $_ : $eapk_schemas[$_]} @{$a{with_search_path}};
 772
 773             $dbh->do("SET search_path = $search_path");
 774         }
 775
 776         my $table_name = $a{qualify_table}
 777             ? ($eapk_schemas[$a{qualify_table}] || die). ".apk"
 778             : 'apk';
 779         local $_[1]->{Warn} = 0;
 780
 781         my $id_def = $a{nextval}
 782             ? "integer not null default nextval('$a{nextval}'::regclass)"
 783             : 'serial';
 784         $dbh->do(<<EOS);
 785 CREATE TABLE $table_name (
 786   id1 serial
 787   , id2 $id_def
 788   , id3 serial primary key
 789   , id4 serial
 790 )
 791 EOS
 792
 793         if( $searchpath_save ) {
 794             $dbh->do("SET search_path = $searchpath_save");
 795         }
 796     });
 797 }
 798
 799 sub eapk_drop_all {
 800     my ( $schema, $warn_exceptions ) = @_;
 801
 802     $schema->storage->dbh_do(sub {
 803         my (undef,$dbh) = @_;
 804
 805         local $dbh->{Warn} = 0;
 806
 807         # drop the test schemas
 808         for (@eapk_schemas ) {
 809             eval{ $dbh->do("DROP SCHEMA $_ CASCADE") };
 810             diag $@ if $@ && $warn_exceptions;
 811         }
 812
 813
 814     });
 815 }
 816
 817 sub eapk_find_visible_schema {
 818     my ($s) = @_;
 819
 820     my ($schema) =
 821         $s->storage->dbh_do(sub {
 822             $_[1]->selectrow_array(<<EOS);
 823 SELECT n.nspname
 824 FROM pg_catalog.pg_namespace n
 825 JOIN pg_catalog.pg_class c ON c.relnamespace = n.oid
 826 WHERE c.relname = 'apk'
 827   AND pg_catalog.pg_table_is_visible(c.oid)
 828 EOS
 829         });
 830     return $schema;
 831 }