t/72pg.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use Sub::Name;
   7 use Config;
   8 use DBIx::Class::Optional::Dependencies ();
   9 use lib qw(t/lib);
  10 use DBICTest;
  11 use SQL::Abstract 'is_literal_value';
  12 use DBIx::Class::_Util 'is_exception';
  13
  14 plan skip_all => 'Test needs ' . DBIx::Class::Optional::Dependencies->req_missing_for ('test_rdbms_pg')
  15   unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_rdbms_pg');
  16
  17 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
  18
  19 plan skip_all => <<'EOM' unless $dsn && $user;
  20 Set $ENV{DBICTEST_PG_DSN}, _USER and _PASS to run this test
  21 ( NOTE: This test drops and creates tables called 'artist', 'cd',
  22 'timestamp_primary_key_test', 'track', 'casecheck', 'array_test' and
  23 'sequence_test' as well as following sequences: 'pkid1_seq', 'pkid2_seq' and
  24 'nonpkid_seq'. as well as following schemas: 'dbic_t_schema',
  25 'dbic_t_schema_2', 'dbic_t_schema_3', 'dbic_t_schema_4', and 'dbic_t_schema_5')
  26 EOM
  27
  28 ### load any test classes that are defined further down in the file via BEGIN blocks
  29
  30 our @test_classes; #< array that will be pushed into by test classes defined in this file
  31 DBICTest::Schema->load_classes( map {s/.+:://;$_} @test_classes ) if @test_classes;
  32
  33 ###  pre-connect tests (keep each test separate as to make sure rebless() runs)
  34   {
  35     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  36
  37     ok (!$s->storage->_dbh, 'definitely not connected');
  38
  39     # Check that datetime_parser returns correctly before we explicitly connect.
  40     SKIP: {
  41         skip (
  42           "Pg parser detection test needs " . DBIx::Class::Optional::Dependencies->req_missing_for ('test_dt_pg'),
  43           2
  44         ) unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_dt_pg');
  45
  46         my $store = ref $s->storage;
  47         is($store, 'DBIx::Class::Storage::DBI', 'Started with generic storage');
  48
  49         my $parser = $s->storage->datetime_parser;
  50         is( $parser, 'DateTime::Format::Pg', 'datetime_parser is as expected');
  51     }
  52
  53     ok (!$s->storage->_dbh, 'still not connected');
  54   }
  55
  56   {
  57     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  58     # make sure sqlt_type overrides work (::Storage::DBI::Pg does this)
  59     ok (!$s->storage->_dbh, 'definitely not connected');
  60     is ($s->storage->sqlt_type, 'PostgreSQL', 'sqlt_type correct pre-connection');
  61     ok (!$s->storage->_dbh, 'still not connected');
  62   }
  63
  64 # test LIMIT support
  65 {
  66   my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
  67   drop_test_schema($schema);
  68   create_test_schema($schema);
  69   for (1..6) {
  70     $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
  71   }
  72   my $it = $schema->resultset('Artist')->search( {},
  73     { rows => 3,
  74       offset => 2,
  75       order_by => 'artistid' }
  76   );
  77   is( $it->count, 3, "LIMIT count ok" );  # ask for 3 rows out of 6 artists
  78   is( $it->next->name, "Artist 3", "iterator->next ok" );
  79   $it->next;
  80   $it->next;
  81   $it->next;
  82   is( $it->next, undef, "next past end of resultset ok" );
  83
  84   # Limit with select-lock
  85   lives_ok {
  86     $schema->txn_do (sub {
  87       isa_ok (
  88         $schema->resultset('Artist')->find({artistid => 1}, {for => 'update', rows => 1}),
  89         'DBICTest::Schema::Artist',
  90       );
  91     });
  92   } 'Limited FOR UPDATE select works';
  93 }
  94
  95 # check if we indeed do support stuff
  96 my $test_server_supports_insert_returning = do {
  97
  98   my $si = DBICTest::Schema->connect($dsn, $user, $pass)->storage->_server_info;
  99   die "Unparseable Pg server version: $si->{dbms_version}\n"
 100     unless $si->{normalized_dbms_version};
 101
 102   $si->{normalized_dbms_version} < 8.002 ? 0 : 1;
 103 };
 104 is (
 105   DBICTest::Schema->connect($dsn, $user, $pass)->storage->_use_insert_returning,
 106   $test_server_supports_insert_returning,
 107   'insert returning capability guessed correctly'
 108 );
 109
 110 my $schema;
 111 for my $use_insert_returning ($test_server_supports_insert_returning
 112   ? (0,1)
 113   : (0)
 114 ) {
 115
 116   no warnings qw/once redefine/;
 117   my $old_connection = DBICTest::Schema->can('connection');
 118   local *DBICTest::Schema::connection = subname 'DBICTest::Schema::connection' => sub {
 119     my $s = shift->$old_connection(@_);
 120     $s->storage->_use_insert_returning ($use_insert_returning);
 121     $s;
 122   };
 123
 124 ### test capability override
 125   {
 126     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
 127
 128     ok (!$s->storage->_dbh, 'definitely not connected');
 129
 130     ok (
 131       ! ($s->storage->_use_insert_returning xor $use_insert_returning),
 132       'insert returning capability set correctly',
 133     );
 134     ok (!$s->storage->_dbh, 'still not connected (capability override works)');
 135   }
 136
 137 ### connect, create postgres-specific test schema
 138
 139   $schema = DBICTest::Schema->connect($dsn, $user, $pass);
 140   $schema->storage->ensure_connected;
 141
 142   drop_test_schema($schema);
 143   create_test_schema($schema);
 144
 145 ### begin main tests
 146
 147 # run a BIG bunch of tests for last-insert-id / Auto-PK / sequence
 148 # discovery
 149   run_apk_tests($schema); #< older set of auto-pk tests
 150   run_extended_apk_tests($schema); #< new extended set of auto-pk tests
 151
 152
 153 ######## test the pg-specific syntax from https://rt.cpan.org/Ticket/Display.html?id=99503
 154   lives_ok {
 155     is(
 156       $schema->resultset('Artist')->search({ artistid => { -in => \ '(select 4) union (select 5)' } })->count,
 157       2,
 158       'Two expected artists found on subselect union within IN',
 159     );
 160   };
 161
 162 ### type_info tests
 163
 164   my $test_type_info = {
 165       'artistid' => {
 166           'data_type' => 'integer',
 167           'is_nullable' => 0,
 168           'size' => 4,
 169       },
 170       'name' => {
 171           'data_type' => 'character varying',
 172           'is_nullable' => 1,
 173           'size' => 100,
 174           'default_value' => undef,
 175       },
 176       'rank' => {
 177           'data_type' => 'integer',
 178           'is_nullable' => 0,
 179           'size' => 4,
 180           'default_value' => 13,
 181
 182       },
 183       'charfield' => {
 184           'data_type' => 'character',
 185           'is_nullable' => 1,
 186           'size' => 10,
 187           'default_value' => undef,
 188       },
 189       'arrayfield' => {
 190           'data_type' => 'integer[]',
 191           'is_nullable' => 1,
 192           'size' => undef,
 193           'default_value' => undef,
 194       },
 195   };
 196
 197   my $type_info = $schema->storage->columns_info_for('dbic_t_schema.artist');
 198   my $artistid_defval = delete $type_info->{artistid}->{default_value};
 199   like($artistid_defval,
 200        qr/^nextval\('([^\.]*\.){0,1}artist_artistid_seq'::(?:text|regclass)\)/,
 201        'columns_info_for - sequence matches Pg get_autoinc_seq expectations');
 202   is_deeply($type_info, $test_type_info,
 203             'columns_info_for - column data types');
 204
 205
 206
 207
 208 ####### Array tests
 209
 210   BEGIN {
 211     package DBICTest::Schema::ArrayTest;
 212     push @main::test_classes, __PACKAGE__;
 213
 214     use strict;
 215     use warnings;
 216     use base 'DBICTest::BaseResult';
 217
 218     __PACKAGE__->table('dbic_t_schema.array_test');
 219     __PACKAGE__->add_columns(qw/id arrayfield/);
 220     __PACKAGE__->column_info_from_storage(1);
 221     __PACKAGE__->set_primary_key('id');
 222
 223   }
 224   SKIP: {
 225     skip "Need DBD::Pg 2.9.2 or newer for array tests", 4 if $DBD::Pg::VERSION < 2.009002;
 226
 227     my $arr_rs = $schema->resultset('ArrayTest');
 228
 229     lives_ok {
 230       $arr_rs->create({
 231         arrayfield => [1, 2],
 232       });
 233     } 'inserting arrayref as pg array data';
 234
 235     lives_ok {
 236       $arr_rs->update({
 237         arrayfield => [3, 4],
 238       });
 239     } 'updating arrayref as pg array data';
 240
 241     $arr_rs->create({
 242       arrayfield => [5, 6],
 243     });
 244
 245     lives_ok {
 246       $schema->populate('ArrayTest', [
 247         [ qw/arrayfield/ ],
 248         [ [0,0]          ],
 249       ]);
 250     } 'inserting arrayref using void ctx populate';
 251
 252     # Search using arrays
 253     lives_ok {
 254       is_deeply (
 255         $arr_rs->search({ arrayfield => { -value => [3,4] } })->first->arrayfield,
 256         [3,4],
 257         'Array value matches'
 258       );
 259     } 'searching by arrayref';
 260
 261     lives_ok {
 262       is_deeply (
 263         $arr_rs->search({ arrayfield => { '=' => { -value => [3,4] }} })->first->arrayfield,
 264         [3,4],
 265         'Array value matches explicit equal'
 266       );
 267     } 'searching by arrayref (explicit equal sign)';
 268
 269     lives_ok {
 270       is_deeply (
 271         $arr_rs->search({ arrayfield => { '>' => { -value => [3,1] }} })->first->arrayfield,
 272         [3,4],
 273         'Array value matches greater than'
 274       );
 275     } 'searching by arrayref (greater than)';
 276
 277     lives_ok {
 278       is (
 279         $arr_rs->search({ arrayfield => { '>' => { -value => [3,7] }} })->count,
 280         1,
 281         'Greater than search found [5,6]',
 282       );
 283     } 'searching by arrayref (greater than)';
 284
 285     # Find using arrays
 286     lives_ok {
 287       is_deeply (
 288         $arr_rs->find({ arrayfield => { -value => [3,4] } })->arrayfield,
 289         [3,4],
 290         'Array value matches implicit equal'
 291       );
 292     } 'find by arrayref';
 293
 294     lives_ok {
 295       is_deeply (
 296         $arr_rs->find({ arrayfield => { '=' => { -value => [3,4] }} })->arrayfield,
 297         [3,4],
 298         'Array value matches explicit equal'
 299       );
 300     } 'find by arrayref (equal)';
 301
 302     # test inferred condition for creation
 303     for my $cond (
 304       { -value => [3,4] },
 305       \[ '= ?' => [arrayfield => [3, 4]] ],
 306     ) {
 307       local $TODO = 'No introspection of complex literal conditions :('
 308         if is_literal_value $cond;
 309
 310
 311       my $arr_rs_cond = $arr_rs->search({ arrayfield => $cond });
 312
 313       my $row = $arr_rs_cond->create({});
 314       is_deeply ($row->arrayfield, [3,4], 'Array value taken from $rs condition');
 315       $row->discard_changes;
 316       is_deeply ($row->arrayfield, [3,4], 'Array value made it to storage');
 317     }
 318   }
 319
 320 ########## Case check
 321
 322   BEGIN {
 323     package DBICTest::Schema::Casecheck;
 324     push @main::test_classes, __PACKAGE__;
 325
 326     use strict;
 327     use warnings;
 328     use base 'DBIx::Class::Core';
 329
 330     __PACKAGE__->table('dbic_t_schema.casecheck');
 331     __PACKAGE__->add_columns(qw/id name NAME uc_name/);
 332     __PACKAGE__->column_info_from_storage(1);
 333     __PACKAGE__->set_primary_key('id');
 334   }
 335
 336   my $name_info = $schema->source('Casecheck')->column_info( 'name' );
 337   is( $name_info->{size}, 1, "Case sensitive matching info for 'name'" );
 338
 339   my $NAME_info = $schema->source('Casecheck')->column_info( 'NAME' );
 340   is( $NAME_info->{size}, 2, "Case sensitive matching info for 'NAME'" );
 341
 342   my $uc_name_info = $schema->source('Casecheck')->column_info( 'uc_name' );
 343   is( $uc_name_info->{size}, 3, "Case insensitive matching info for 'uc_name'" );
 344
 345
 346 ## Test ResultSet->update
 347 my $artist = $schema->resultset('Artist')->first;
 348 my $cds = $artist->cds_unordered->search({
 349     year => { '!=' => 2010 }
 350 }, { prefetch => 'liner_notes' });
 351 lives_ok { $cds->update({ year => '2010' }) } 'Update on prefetched rs';
 352
 353 ## Test SELECT ... FOR UPDATE
 354   SKIP: {
 355       skip "Your system does not support unsafe signals (d_sigaction) - unable to run deadlock test", 1
 356         unless eval { $Config{d_sigaction} and require POSIX };
 357
 358       my ($timed_out, $artist2);
 359
 360       for my $t (
 361         {
 362           # Make sure that an error was raised, and that the update failed
 363           update_lock => 1,
 364           test_sub => sub {
 365             ok($timed_out, "update from second schema times out");
 366             ok($artist2->is_column_changed('name'), "'name' column is still dirty from second schema");
 367           },
 368         },
 369         {
 370           # Make sure that an error was NOT raised, and that the update succeeded
 371           update_lock => 0,
 372           test_sub => sub {
 373             ok(! $timed_out, "update from second schema DOES NOT timeout");
 374             ok(! $artist2->is_column_changed('name'), "'name' column is NOT dirty from second schema");
 375           },
 376         },
 377       ) {
 378         # create a new schema
 379         my $schema2 = DBICTest::Schema->connect($dsn, $user, $pass);
 380         $schema2->source("Artist")->name("dbic_t_schema.artist");
 381
 382         $schema->txn_do( sub {
 383           my $rs = $schema->resultset('Artist')->search(
 384               {
 385                   artistid => 1
 386               },
 387               $t->{update_lock} ? { for => 'update' } : {}
 388           );
 389           ok ($rs->count, 'Count works');
 390
 391           my $artist = $rs->next;
 392           is($artist->artistid, 1, "select returns artistid = 1");
 393
 394           $timed_out = 0;
 395
 396           eval {
 397               # can not use %SIG assignment directly - we need sigaction below
 398               # localization to a block still works however
 399               local $SIG{ALRM};
 400
 401               POSIX::sigaction( POSIX::SIGALRM() => POSIX::SigAction->new(
 402                 sub { die "DBICTestTimeout" },
 403               ));
 404
 405               alarm(2);
 406               $artist2 = $schema2->resultset('Artist')->find(1);
 407               $artist2->name('fooey');
 408               $artist2->update;
 409           };
 410
 411           alarm(0);
 412
 413           if (is_exception($@)) {
 414             $timed_out = $@ =~ /DBICTestTimeout/
 415               or die $@;
 416           }
 417         });
 418
 419         $t->{test_sub}->();
 420       }
 421   }
 422
 423
 424 ######## other older Auto-pk tests
 425
 426   $schema->source("SequenceTest")->name("dbic_t_schema.sequence_test");
 427   for (1..5) {
 428       my $st = $schema->resultset('SequenceTest')->create({ name => 'foo' });
 429       is($st->pkid1, $_, "Auto-PK for sequence without default: First primary key");
 430       is($st->pkid2, $_ + 9, "Auto-PK for sequence without default: Second primary key");
 431       is($st->nonpkid, $_ + 19, "Auto-PK for sequence without default: Non-primary key");
 432   }
 433   my $st = $schema->resultset('SequenceTest')->create({ name => 'foo', pkid1 => 55 });
 434   is($st->pkid1, 55, "Auto-PK for sequence without default: First primary key set manually");
 435
 436
 437 ######## test non-serial auto-pk
 438
 439   if ($schema->storage->_use_insert_returning) {
 440     $schema->source('TimestampPrimaryKey')->name('dbic_t_schema.timestamp_primary_key_test');
 441     my $row = $schema->resultset('TimestampPrimaryKey')->create({});
 442     ok $row->id;
 443   }
 444
 445 ######## test with_deferred_fk_checks
 446
 447   $schema->source('CD')->name('dbic_t_schema.cd');
 448   $schema->source('Track')->name('dbic_t_schema.track');
 449   lives_ok {
 450     $schema->storage->with_deferred_fk_checks(sub {
 451       $schema->resultset('Track')->create({
 452         trackid => 999, cd => 999, position => 1, title => 'deferred FK track'
 453       });
 454       $schema->resultset('CD')->create({
 455         artist => 1, cdid => 999, year => '2003', title => 'deferred FK cd'
 456       });
 457     });
 458   } 'with_deferred_fk_checks code survived';
 459
 460   is eval { $schema->resultset('Track')->find(999)->title }, 'deferred FK track',
 461      'code in with_deferred_fk_checks worked';
 462
 463   throws_ok {
 464     $schema->resultset('Track')->create({
 465       trackid => 1, cd => 9999, position => 1, title => 'Track1'
 466     });
 467   } qr/constraint/i, 'with_deferred_fk_checks is off';
 468 }
 469
 470 done_testing;
 471
 472 END {
 473     return unless $schema;
 474     drop_test_schema($schema);
 475     eapk_drop_all($schema);
 476     undef $schema;
 477 };
 478
 479
 480 ######### SUBROUTINES
 481
 482 sub create_test_schema {
 483     my $schema = shift;
 484     $schema->storage->dbh_do(sub {
 485       my (undef,$dbh) = @_;
 486
 487       local $dbh->{Warn} = 0;
 488
 489       my $std_artist_table = <<EOS;
 490 (
 491   artistid serial PRIMARY KEY
 492   , name VARCHAR(100)
 493   , rank INTEGER NOT NULL DEFAULT '13'
 494   , charfield CHAR(10)
 495   , arrayfield INTEGER[]
 496 )
 497 EOS
 498
 499       $dbh->do("CREATE SCHEMA dbic_t_schema");
 500       $dbh->do("CREATE TABLE dbic_t_schema.artist $std_artist_table");
 501
 502       $dbh->do(<<EOS);
 503 CREATE TABLE dbic_t_schema.timestamp_primary_key_test (
 504   id timestamp default current_timestamp
 505 )
 506 EOS
 507       $dbh->do(<<EOS);
 508 CREATE TABLE dbic_t_schema.cd (
 509   cdid int PRIMARY KEY,
 510   artist int,
 511   title varchar(255),
 512   year varchar(4),
 513   genreid int,
 514   single_track int
 515 )
 516 EOS
 517       $dbh->do(<<EOS);
 518 CREATE TABLE dbic_t_schema.track (
 519   trackid int,
 520   cd int REFERENCES dbic_t_schema.cd(cdid) DEFERRABLE,
 521   position int,
 522   title varchar(255),
 523   last_updated_on date,
 524   last_updated_at date
 525 )
 526 EOS
 527
 528       $dbh->do(<<EOS);
 529 CREATE TABLE dbic_t_schema.sequence_test (
 530     pkid1 integer
 531     , pkid2 integer
 532     , nonpkid integer
 533     , name VARCHAR(100)
 534     , CONSTRAINT pk PRIMARY KEY(pkid1, pkid2)
 535 )
 536 EOS
 537       $dbh->do("CREATE SEQUENCE pkid1_seq START 1 MAXVALUE 999999 MINVALUE 0");
 538       $dbh->do("CREATE SEQUENCE pkid2_seq START 10 MAXVALUE 999999 MINVALUE 0");
 539       $dbh->do("CREATE SEQUENCE nonpkid_seq START 20 MAXVALUE 999999 MINVALUE 0");
 540       $dbh->do(<<EOS);
 541 CREATE TABLE dbic_t_schema.casecheck (
 542     id serial PRIMARY KEY
 543     , "name" VARCHAR(1)
 544     , "NAME" VARCHAR(2)
 545     , "UC_NAME" VARCHAR(3)
 546 )
 547 EOS
 548       $dbh->do(<<EOS);
 549 CREATE TABLE dbic_t_schema.array_test (
 550     id serial PRIMARY KEY
 551     , arrayfield INTEGER[]
 552 )
 553 EOS
 554       $dbh->do("CREATE SCHEMA dbic_t_schema_2");
 555       $dbh->do("CREATE TABLE dbic_t_schema_2.artist $std_artist_table");
 556       $dbh->do("CREATE SCHEMA dbic_t_schema_3");
 557       $dbh->do("CREATE TABLE dbic_t_schema_3.artist $std_artist_table");
 558       $dbh->do('set search_path=dbic_t_schema,public');
 559       $dbh->do("CREATE SCHEMA dbic_t_schema_4");
 560       $dbh->do("CREATE SCHEMA dbic_t_schema_5");
 561       $dbh->do(<<EOS);
 562  CREATE TABLE dbic_t_schema_4.artist
 563  (
 564    artistid integer not null default nextval('artist_artistid_seq'::regclass) PRIMARY KEY
 565    , name VARCHAR(100)
 566    , rank INTEGER NOT NULL DEFAULT '13'
 567    , charfield CHAR(10)
 568    , arrayfield INTEGER[]
 569  );
 570 EOS
 571       $dbh->do('set search_path=public,dbic_t_schema,dbic_t_schema_3');
 572       $dbh->do('create sequence public.artist_artistid_seq'); #< in the public schema
 573       $dbh->do(<<EOS);
 574  CREATE TABLE dbic_t_schema_5.artist
 575  (
 576    artistid integer not null default nextval('public.artist_artistid_seq'::regclass) PRIMARY KEY
 577    , name VARCHAR(100)
 578    , rank INTEGER NOT NULL DEFAULT '13'
 579    , charfield CHAR(10)
 580    , arrayfield INTEGER[]
 581  );
 582 EOS
 583       $dbh->do('set search_path=dbic_t_schema,public');
 584   });
 585 }
 586
 587
 588
 589 sub drop_test_schema {
 590     my ( $schema, $warn_exceptions ) = @_;
 591
 592     $schema->storage->dbh_do(sub {
 593         my (undef,$dbh) = @_;
 594
 595         local $dbh->{Warn} = 0;
 596
 597         for my $stat (
 598                       'DROP SCHEMA dbic_t_schema_5 CASCADE',
 599                       'DROP SEQUENCE public.artist_artistid_seq CASCADE',
 600                       'DROP SCHEMA dbic_t_schema_4 CASCADE',
 601                       'DROP SCHEMA dbic_t_schema CASCADE',
 602                       'DROP SEQUENCE pkid1_seq CASCADE',
 603                       'DROP SEQUENCE pkid2_seq CASCADE',
 604                       'DROP SEQUENCE nonpkid_seq CASCADE',
 605                       'DROP SCHEMA dbic_t_schema_2 CASCADE',
 606                       'DROP SCHEMA dbic_t_schema_3 CASCADE',
 607                      ) {
 608             eval { $dbh->do ($stat) };
 609             diag $@ if $@ && $warn_exceptions;
 610         }
 611     });
 612 }
 613
 614
 615 ###  auto-pk / last_insert_id / sequence discovery
 616 sub run_apk_tests {
 617     my $schema = shift;
 618
 619     # This is in Core now, but it's here just to test that it doesn't break
 620     $schema->class('Artist')->load_components('PK::Auto');
 621     cmp_ok( $schema->resultset('Artist')->count, '==', 0, 'this should start with an empty artist table');
 622
 623     # test that auto-pk also works with the defined search path by
 624     # un-schema-qualifying the table name
 625     apk_t_set($schema,'artist');
 626
 627     my $unq_new;
 628     lives_ok {
 629         $unq_new = $schema->resultset('Artist')->create({ name => 'baz' });
 630     } 'insert into unqualified, shadowed table succeeds';
 631
 632     is($unq_new && $unq_new->artistid, 1, "and got correct artistid");
 633
 634     my @test_schemas = ( [qw| dbic_t_schema_2    1  |],
 635                          [qw| dbic_t_schema_3    1  |],
 636                          [qw| dbic_t_schema_4    2  |],
 637                          [qw| dbic_t_schema_5    1  |],
 638                        );
 639     foreach my $t ( @test_schemas ) {
 640         my ($sch_name, $start_num) = @$t;
 641         #test with dbic_t_schema_2
 642         apk_t_set($schema,"$sch_name.artist");
 643         my $another_new;
 644         lives_ok {
 645             $another_new = $schema->resultset('Artist')->create({ name => 'Tollbooth Willy'});
 646             is( $another_new->artistid,$start_num, "got correct artistid for $sch_name")
 647                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 648         } "$sch_name liid 1 did not die"
 649             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 650         lives_ok {
 651             $another_new = $schema->resultset('Artist')->create({ name => 'Adam Sandler'});
 652             is( $another_new->artistid,$start_num+1, "got correct artistid for $sch_name")
 653                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 654         } "$sch_name liid 2 did not die"
 655             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 656
 657     }
 658
 659     lives_ok {
 660         apk_t_set($schema,'dbic_t_schema.artist');
 661         my $new = $schema->resultset('Artist')->create({ name => 'foo' });
 662         is($new->artistid, 4, "Auto-PK worked");
 663         $new = $schema->resultset('Artist')->create({ name => 'bar' });
 664         is($new->artistid, 5, "Auto-PK worked");
 665     } 'old auto-pk tests did not die either';
 666 }
 667
 668 # sets the artist table name and clears sequence name cache
 669 sub apk_t_set {
 670     my ( $s, $n ) = @_;
 671     $s->source("Artist")->name($n);
 672     $s->source('Artist')->column_info('artistid')->{sequence} = undef; #< clear sequence name cache
 673 }
 674
 675
 676 ######## EXTENDED AUTO-PK TESTS
 677
 678 my @eapk_id_columns;
 679 BEGIN {
 680   package DBICTest::Schema::ExtAPK;
 681   push @main::test_classes, __PACKAGE__;
 682
 683   use strict;
 684   use warnings;
 685   use base 'DBIx::Class::Core';
 686
 687   __PACKAGE__->table('apk');
 688
 689   @eapk_id_columns = qw( id1 id2 id3 id4 );
 690   __PACKAGE__->add_columns(
 691     map { $_ => { data_type => 'integer', is_auto_increment => 1 } }
 692        @eapk_id_columns
 693   );
 694
 695   __PACKAGE__->set_primary_key('id2'); #< note the SECOND column is
 696                                        #the primary key
 697 }
 698
 699 my @eapk_schemas;
 700 BEGIN{ @eapk_schemas = map "dbic_apk_$_", 0..5 }
 701 my %seqs; #< hash of schema.table.col => currval of its (DBIC) primary key sequence
 702
 703 sub run_extended_apk_tests {
 704   my $schema = shift;
 705
 706   #save the search path and reset it at the end
 707   my $search_path_save = eapk_get_search_path($schema);
 708
 709   eapk_drop_all($schema);
 710   %seqs = ();
 711
 712   # make the test schemas and sequences
 713   $schema->storage->dbh_do(sub {
 714     my ( undef, $dbh ) = @_;
 715
 716     $dbh->do("CREATE SCHEMA $_")
 717         for @eapk_schemas;
 718
 719     $dbh->do("CREATE SEQUENCE $eapk_schemas[5].fooseq");
 720     $dbh->do("SELECT setval('$eapk_schemas[5].fooseq',400)");
 721     $seqs{"$eapk_schemas[1].apk.id2"} = 400;
 722
 723     $dbh->do("CREATE SEQUENCE $eapk_schemas[4].fooseq");
 724     $dbh->do("SELECT setval('$eapk_schemas[4].fooseq',300)");
 725     $seqs{"$eapk_schemas[3].apk.id2"} = 300;
 726
 727     $dbh->do("CREATE SEQUENCE $eapk_schemas[3].fooseq");
 728     $dbh->do("SELECT setval('$eapk_schemas[3].fooseq',200)");
 729     $seqs{"$eapk_schemas[4].apk.id2"} = 200;
 730
 731     $dbh->do("SET search_path = ".join ',', reverse @eapk_schemas );
 732   });
 733
 734   # clear our search_path cache
 735   $schema->storage->{_pg_search_path} = undef;
 736
 737   eapk_create( $schema,
 738                with_search_path => [0,1],
 739              );
 740   eapk_create( $schema,
 741                with_search_path => [1,0,'public'],
 742                nextval => "$eapk_schemas[5].fooseq",
 743              );
 744   eapk_create( $schema,
 745                with_search_path => ['public',0,1],
 746                qualify_table => 2,
 747              );
 748   eapk_create( $schema,
 749                with_search_path => [3,1,0,'public'],
 750                nextval => "$eapk_schemas[4].fooseq",
 751              );
 752   eapk_create( $schema,
 753                with_search_path => [3,1,0,'public'],
 754                nextval => "$eapk_schemas[3].fooseq",
 755                qualify_table => 4,
 756              );
 757
 758   eapk_poke( $schema );
 759   eapk_poke( $schema, 0 );
 760   eapk_poke( $schema, 2 );
 761   eapk_poke( $schema, 4 );
 762   eapk_poke( $schema, 1 );
 763   eapk_poke( $schema, 0 );
 764   eapk_poke( $schema, 1 );
 765   eapk_poke( $schema );
 766   eapk_poke( $schema, 4 );
 767   eapk_poke( $schema, 3 );
 768   eapk_poke( $schema, 1 );
 769   eapk_poke( $schema, 2 );
 770   eapk_poke( $schema, 0 );
 771
 772   # set our search path back
 773   eapk_set_search_path( $schema, @$search_path_save );
 774 }
 775
 776 # do a DBIC create on the apk table in the given schema number (which is an
 777 # index of @eapk_schemas)
 778
 779 sub eapk_poke {
 780   my ($s, $schema_num) = @_;
 781
 782   my $schema_name = defined $schema_num
 783       ? $eapk_schemas[$schema_num]
 784       : '';
 785
 786   my $schema_name_actual = $schema_name || eapk_find_visible_schema($s);
 787
 788   $s->source('ExtAPK')->name($schema_name ? $schema_name.'.apk' : 'apk');
 789   #< clear sequence name cache
 790   $s->source('ExtAPK')->column_info($_)->{sequence} = undef
 791       for @eapk_id_columns;
 792
 793   no warnings 'uninitialized';
 794   lives_ok {
 795     my $new;
 796     for my $inc (1,2,3) {
 797       $new = $schema->resultset('ExtAPK')->create({ id1 => 1});
 798       my $proper_seqval = ++$seqs{"$schema_name_actual.apk.id2"};
 799       is( $new->id2, $proper_seqval, "$schema_name_actual.apk.id2 correct inc $inc" )
 800           or eapk_seq_diag($s,$schema_name);
 801       $new->discard_changes;
 802       is( $new->id1, 1 );
 803       for my $id ('id3','id4') {
 804         my $proper_seqval = ++$seqs{"$schema_name_actual.apk.$id"};
 805         is( $new->$id, $proper_seqval, "$schema_name_actual.apk.$id correct inc $inc" )
 806             or eapk_seq_diag($s,$schema_name);
 807       }
 808     }
 809   } "create in schema '$schema_name' lives"
 810       or eapk_seq_diag($s,$schema_name);
 811 }
 812
 813 # print diagnostic info on which sequences were found in the ExtAPK
 814 # class
 815 sub eapk_seq_diag {
 816     my $s = shift;
 817     my $schema = shift || eapk_find_visible_schema($s);
 818
 819     diag "$schema.apk sequences: ",
 820         join(', ',
 821              map "$_:".($s->source('ExtAPK')->column_info($_)->{sequence} || '<none>'),
 822              @eapk_id_columns
 823             );
 824 }
 825
 826 # get the postgres search path as an arrayref
 827 sub eapk_get_search_path {
 828     my ( $s ) = @_;
 829     # cache the search path as ['schema','schema',...] in the storage
 830     # obj
 831
 832     return $s->storage->dbh_do(sub {
 833         my (undef, $dbh) = @_;
 834         my @search_path;
 835         my ($sp_string) = $dbh->selectrow_array('SHOW search_path');
 836         while ( $sp_string =~ s/("[^"]+"|[^,]+),?// ) {
 837             unless( defined $1 and length $1 ) {
 838                 die "search path sanity check failed: '$1'";
 839             }
 840             push @search_path, $1;
 841         }
 842         \@search_path
 843     });
 844 }
 845 sub eapk_set_search_path {
 846     my ($s,@sp) = @_;
 847     my $sp = join ',',@sp;
 848     $s->storage->dbh_do( sub { $_[1]->do("SET search_path = $sp") } );
 849 }
 850
 851 # create the apk table in the given schema, can set whether the table name is qualified, what the nextval is for the second ID
 852 sub eapk_create {
 853     my ($schema, %a) = @_;
 854
 855     $schema->storage->dbh_do(sub {
 856         my (undef,$dbh) = @_;
 857
 858         my $searchpath_save;
 859         if ( $a{with_search_path} ) {
 860             ($searchpath_save) = $dbh->selectrow_array('SHOW search_path');
 861
 862             my $search_path = join ',',map {/\D/ ? $_ : $eapk_schemas[$_]} @{$a{with_search_path}};
 863
 864             $dbh->do("SET search_path = $search_path");
 865         }
 866
 867         my $table_name = $a{qualify_table}
 868             ? ($eapk_schemas[$a{qualify_table}] || die). ".apk"
 869             : 'apk';
 870         local $_[1]->{Warn} = 0;
 871
 872         my $id_def = $a{nextval}
 873             ? "integer not null default nextval('$a{nextval}'::regclass)"
 874             : 'serial';
 875         $dbh->do(<<EOS);
 876 CREATE TABLE $table_name (
 877   id1 serial
 878   , id2 $id_def
 879   , id3 serial primary key
 880   , id4 serial
 881 )
 882 EOS
 883
 884         if( $searchpath_save ) {
 885             $dbh->do("SET search_path = $searchpath_save");
 886         }
 887     });
 888 }
 889
 890 sub eapk_drop_all {
 891     my ( $schema, $warn_exceptions ) = @_;
 892
 893     $schema->storage->dbh_do(sub {
 894         my (undef,$dbh) = @_;
 895
 896         local $dbh->{Warn} = 0;
 897
 898         # drop the test schemas
 899         for (@eapk_schemas ) {
 900             eval{ $dbh->do("DROP SCHEMA $_ CASCADE") };
 901             diag $@ if $@ && $warn_exceptions;
 902         }
 903
 904
 905     });
 906 }
 907
 908 sub eapk_find_visible_schema {
 909     my ($s) = @_;
 910
 911     my ($schema) =
 912         $s->storage->dbh_do(sub {
 913             $_[1]->selectrow_array(<<EOS);
 914 SELECT n.nspname
 915 FROM pg_catalog.pg_namespace n
 916 JOIN pg_catalog.pg_class c ON c.relnamespace = n.oid
 917 WHERE c.relname = 'apk'
 918   AND pg_catalog.pg_table_is_visible(c.oid)
 919 EOS
 920         });
 921     return $schema;
 922 }