t/72pg.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use Sub::Name;
   7 use lib qw(t/lib);
   8 use DBICTest;
   9
  10
  11 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
  12
  13 plan skip_all => <<'EOM' unless $dsn && $user;
  14 Set $ENV{DBICTEST_PG_DSN}, _USER and _PASS to run this test
  15 ( NOTE: This test drops and creates tables called 'artist', 'cd',
  16 'timestamp_primary_key_test', 'track', 'casecheck', 'array_test' and
  17 'sequence_test' as well as following sequences: 'pkid1_seq', 'pkid2_seq' and
  18 'nonpkid_seq'. as well as following schemas: 'dbic_t_schema',
  19 'dbic_t_schema_2', 'dbic_t_schema_3', 'dbic_t_schema_4', and 'dbic_t_schema_5')
  20 EOM
  21
  22 ### load any test classes that are defined further down in the file via BEGIN blocks
  23
  24 our @test_classes; #< array that will be pushed into by test classes defined in this file
  25 DBICTest::Schema->load_classes( map {s/.+:://;$_} @test_classes ) if @test_classes;
  26
  27 ###  pre-connect tests (keep each test separate as to make sure rebless() runs)
  28   {
  29     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  30
  31     ok (!$s->storage->_dbh, 'definitely not connected');
  32
  33     # Check that datetime_parser returns correctly before we explicitly connect.
  34     SKIP: {
  35         skip (
  36           "Pg parser detection test needs " . DBIx::Class::Optional::Dependencies->req_missing_for ('test_dt_pg'),
  37           2
  38         ) unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_dt_pg');
  39
  40         my $store = ref $s->storage;
  41         is($store, 'DBIx::Class::Storage::DBI', 'Started with generic storage');
  42
  43         my $parser = $s->storage->datetime_parser;
  44         is( $parser, 'DateTime::Format::Pg', 'datetime_parser is as expected');
  45     }
  46
  47     ok (!$s->storage->_dbh, 'still not connected');
  48   }
  49
  50   {
  51     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  52     # make sure sqlt_type overrides work (::Storage::DBI::Pg does this)
  53     ok (!$s->storage->_dbh, 'definitely not connected');
  54     is ($s->storage->sqlt_type, 'PostgreSQL', 'sqlt_type correct pre-connection');
  55     ok (!$s->storage->_dbh, 'still not connected');
  56   }
  57
  58 # test LIMIT support
  59 {
  60   my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
  61   drop_test_schema($schema);
  62   create_test_schema($schema);
  63   for (1..6) {
  64     $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
  65   }
  66   my $it = $schema->resultset('Artist')->search( {},
  67     { rows => 3,
  68       offset => 2,
  69       order_by => 'artistid' }
  70   );
  71   is( $it->count, 3, "LIMIT count ok" );  # ask for 3 rows out of 6 artists
  72   is( $it->next->name, "Artist 3", "iterator->next ok" );
  73   $it->next;
  74   $it->next;
  75   $it->next;
  76   is( $it->next, undef, "next past end of resultset ok" );
  77
  78   # Limit with select-lock
  79   lives_ok {
  80     $schema->txn_do (sub {
  81       isa_ok (
  82         $schema->resultset('Artist')->find({artistid => 1}, {for => 'update', rows => 1}),
  83         'DBICTest::Schema::Artist',
  84       );
  85     });
  86   } 'Limited FOR UPDATE select works';
  87 }
  88
  89 # check if we indeed do support stuff
  90 my $test_server_supports_insert_returning = do {
  91   my $v = DBICTest::Schema->connect($dsn, $user, $pass)
  92                    ->storage
  93                     ->_get_dbh
  94                      ->get_info(18);
  95   $v =~ /^(\d+)\.(\d+)/
  96     or die "Unparseable Pg server version: $v\n";
  97
  98   ( sprintf ('%d.%d', $1, $2) >= 8.2 ) ? 1 : 0;
  99 };
 100 is (
 101   DBICTest::Schema->connect($dsn, $user, $pass)->storage->_use_insert_returning,
 102   $test_server_supports_insert_returning,
 103   'insert returning capability guessed correctly'
 104 );
 105
 106 my $schema;
 107 for my $use_insert_returning ($test_server_supports_insert_returning
 108   ? (0,1)
 109   : (0)
 110 ) {
 111
 112   no warnings qw/once/;
 113   local *DBICTest::Schema::connection = subname 'DBICTest::Schema::connection' => sub {
 114     my $s = shift->next::method (@_);
 115     $s->storage->_use_insert_returning ($use_insert_returning);
 116     $s;
 117   };
 118
 119 ### test capability override
 120   {
 121     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
 122
 123     ok (!$s->storage->_dbh, 'definitely not connected');
 124
 125     ok (
 126       ! ($s->storage->_use_insert_returning xor $use_insert_returning),
 127       'insert returning capability set correctly',
 128     );
 129     ok (!$s->storage->_dbh, 'still not connected (capability override works)');
 130   }
 131
 132 ### connect, create postgres-specific test schema
 133
 134   $schema = DBICTest::Schema->connect($dsn, $user, $pass);
 135   $schema->storage->ensure_connected;
 136
 137   drop_test_schema($schema);
 138   create_test_schema($schema);
 139
 140 ### begin main tests
 141
 142 # run a BIG bunch of tests for last-insert-id / Auto-PK / sequence
 143 # discovery
 144   run_apk_tests($schema); #< older set of auto-pk tests
 145   run_extended_apk_tests($schema); #< new extended set of auto-pk tests
 146
 147 ### type_info tests
 148
 149   my $test_type_info = {
 150       'artistid' => {
 151           'data_type' => 'integer',
 152           'is_nullable' => 0,
 153           'size' => 4,
 154       },
 155       'name' => {
 156           'data_type' => 'character varying',
 157           'is_nullable' => 1,
 158           'size' => 100,
 159           'default_value' => undef,
 160       },
 161       'rank' => {
 162           'data_type' => 'integer',
 163           'is_nullable' => 0,
 164           'size' => 4,
 165           'default_value' => 13,
 166
 167       },
 168       'charfield' => {
 169           'data_type' => 'character',
 170           'is_nullable' => 1,
 171           'size' => 10,
 172           'default_value' => undef,
 173       },
 174       'arrayfield' => {
 175           'data_type' => 'integer[]',
 176           'is_nullable' => 1,
 177           'size' => undef,
 178           'default_value' => undef,
 179       },
 180   };
 181
 182   my $type_info = $schema->storage->columns_info_for('dbic_t_schema.artist');
 183   my $artistid_defval = delete $type_info->{artistid}->{default_value};
 184   like($artistid_defval,
 185        qr/^nextval\('([^\.]*\.){0,1}artist_artistid_seq'::(?:text|regclass)\)/,
 186        'columns_info_for - sequence matches Pg get_autoinc_seq expectations');
 187   is_deeply($type_info, $test_type_info,
 188             'columns_info_for - column data types');
 189
 190
 191
 192
 193 ####### Array tests
 194
 195   BEGIN {
 196     package DBICTest::Schema::ArrayTest;
 197     push @main::test_classes, __PACKAGE__;
 198
 199     use strict;
 200     use warnings;
 201     use base 'DBIx::Class::Core';
 202
 203     __PACKAGE__->table('dbic_t_schema.array_test');
 204     __PACKAGE__->add_columns(qw/id arrayfield/);
 205     __PACKAGE__->column_info_from_storage(1);
 206     __PACKAGE__->set_primary_key('id');
 207
 208   }
 209   SKIP: {
 210     skip "Need DBD::Pg 2.9.2 or newer for array tests", 4 if $DBD::Pg::VERSION < 2.009002;
 211
 212     lives_ok {
 213       $schema->resultset('ArrayTest')->create({
 214         arrayfield => [1, 2],
 215       });
 216     } 'inserting arrayref as pg array data';
 217
 218     lives_ok {
 219       $schema->resultset('ArrayTest')->update({
 220         arrayfield => [3, 4],
 221       });
 222     } 'updating arrayref as pg array data';
 223
 224     $schema->resultset('ArrayTest')->create({
 225       arrayfield => [5, 6],
 226     });
 227
 228     my $count;
 229     lives_ok {
 230       $count = $schema->resultset('ArrayTest')->search({
 231         arrayfield => \[ '= ?' => [arrayfield => [3, 4]] ],   #Todo anything less ugly than this?
 232       })->count;
 233     } 'comparing arrayref to pg array data does not blow up';
 234     is($count, 1, 'comparing arrayref to pg array data gives correct result');
 235   }
 236
 237
 238
 239 ########## Case check
 240
 241   BEGIN {
 242     package DBICTest::Schema::Casecheck;
 243     push @main::test_classes, __PACKAGE__;
 244
 245     use strict;
 246     use warnings;
 247     use base 'DBIx::Class::Core';
 248
 249     __PACKAGE__->table('dbic_t_schema.casecheck');
 250     __PACKAGE__->add_columns(qw/id name NAME uc_name/);
 251     __PACKAGE__->column_info_from_storage(1);
 252     __PACKAGE__->set_primary_key('id');
 253   }
 254
 255   my $name_info = $schema->source('Casecheck')->column_info( 'name' );
 256   is( $name_info->{size}, 1, "Case sensitive matching info for 'name'" );
 257
 258   my $NAME_info = $schema->source('Casecheck')->column_info( 'NAME' );
 259   is( $NAME_info->{size}, 2, "Case sensitive matching info for 'NAME'" );
 260
 261   my $uc_name_info = $schema->source('Casecheck')->column_info( 'uc_name' );
 262   is( $uc_name_info->{size}, 3, "Case insensitive matching info for 'uc_name'" );
 263
 264
 265 ## Test ResultSet->update
 266 my $artist = $schema->resultset('Artist')->first;
 267 my $cds = $artist->cds_unordered->search({
 268     year => { '!=' => 2010 }
 269 }, { prefetch => 'liner_notes' });
 270 lives_ok { $cds->update({ year => '2010' }) } 'Update on prefetched rs';
 271
 272 ## Test SELECT ... FOR UPDATE
 273
 274   SKIP: {
 275       if(eval { require Sys::SigAction }) {
 276           Sys::SigAction->import( 'set_sig_handler' );
 277       }
 278       else {
 279         skip "Sys::SigAction is not available", 6;
 280       }
 281
 282       my ($timed_out, $artist2);
 283
 284       for my $t (
 285         {
 286           # Make sure that an error was raised, and that the update failed
 287           update_lock => 1,
 288           test_sub => sub {
 289             ok($timed_out, "update from second schema times out");
 290             ok($artist2->is_column_changed('name'), "'name' column is still dirty from second schema");
 291           },
 292         },
 293         {
 294           # Make sure that an error was NOT raised, and that the update succeeded
 295           update_lock => 0,
 296           test_sub => sub {
 297             ok(! $timed_out, "update from second schema DOES NOT timeout");
 298             ok(! $artist2->is_column_changed('name'), "'name' column is NOT dirty from second schema");
 299           },
 300         },
 301       ) {
 302         # create a new schema
 303         my $schema2 = DBICTest::Schema->connect($dsn, $user, $pass);
 304         $schema2->source("Artist")->name("dbic_t_schema.artist");
 305
 306         $schema->txn_do( sub {
 307           my $rs = $schema->resultset('Artist')->search(
 308               {
 309                   artistid => 1
 310               },
 311               $t->{update_lock} ? { for => 'update' } : {}
 312           );
 313           ok ($rs->count, 'Count works');
 314
 315           my $artist = $rs->next;
 316           is($artist->artistid, 1, "select returns artistid = 1");
 317
 318           $timed_out = 0;
 319           eval {
 320               my $h = set_sig_handler( 'ALRM', sub { die "DBICTestTimeout" } );
 321               alarm(2);
 322               $artist2 = $schema2->resultset('Artist')->find(1);
 323               $artist2->name('fooey');
 324               $artist2->update;
 325               alarm(0);
 326           };
 327           $timed_out = $@ =~ /DBICTestTimeout/;
 328         });
 329
 330         $t->{test_sub}->();
 331       }
 332   }
 333
 334
 335 ######## other older Auto-pk tests
 336
 337   $schema->source("SequenceTest")->name("dbic_t_schema.sequence_test");
 338   for (1..5) {
 339       my $st = $schema->resultset('SequenceTest')->create({ name => 'foo' });
 340       is($st->pkid1, $_, "Auto-PK for sequence without default: First primary key");
 341       is($st->pkid2, $_ + 9, "Auto-PK for sequence without default: Second primary key");
 342       is($st->nonpkid, $_ + 19, "Auto-PK for sequence without default: Non-primary key");
 343   }
 344   my $st = $schema->resultset('SequenceTest')->create({ name => 'foo', pkid1 => 55 });
 345   is($st->pkid1, 55, "Auto-PK for sequence without default: First primary key set manually");
 346
 347
 348 ######## test non-serial auto-pk
 349
 350   if ($schema->storage->_use_insert_returning) {
 351     $schema->source('TimestampPrimaryKey')->name('dbic_t_schema.timestamp_primary_key_test');
 352     my $row = $schema->resultset('TimestampPrimaryKey')->create({});
 353     ok $row->id;
 354   }
 355
 356 ######## test with_deferred_fk_checks
 357
 358   $schema->source('CD')->name('dbic_t_schema.cd');
 359   $schema->source('Track')->name('dbic_t_schema.track');
 360   lives_ok {
 361     $schema->storage->with_deferred_fk_checks(sub {
 362       $schema->resultset('Track')->create({
 363         trackid => 999, cd => 999, position => 1, title => 'deferred FK track'
 364       });
 365       $schema->resultset('CD')->create({
 366         artist => 1, cdid => 999, year => '2003', title => 'deferred FK cd'
 367       });
 368     });
 369   } 'with_deferred_fk_checks code survived';
 370
 371   is eval { $schema->resultset('Track')->find(999)->title }, 'deferred FK track',
 372      'code in with_deferred_fk_checks worked';
 373
 374   throws_ok {
 375     $schema->resultset('Track')->create({
 376       trackid => 1, cd => 9999, position => 1, title => 'Track1'
 377     });
 378   } qr/constraint/i, 'with_deferred_fk_checks is off';
 379 }
 380
 381 done_testing;
 382
 383 END {
 384     return unless $schema;
 385     drop_test_schema($schema);
 386     eapk_drop_all( $schema)
 387 };
 388
 389
 390 ######### SUBROUTINES
 391
 392 sub create_test_schema {
 393     my $schema = shift;
 394     $schema->storage->dbh_do(sub {
 395       my (undef,$dbh) = @_;
 396
 397       local $dbh->{Warn} = 0;
 398
 399       my $std_artist_table = <<EOS;
 400 (
 401   artistid serial PRIMARY KEY
 402   , name VARCHAR(100)
 403   , rank INTEGER NOT NULL DEFAULT '13'
 404   , charfield CHAR(10)
 405   , arrayfield INTEGER[]
 406 )
 407 EOS
 408
 409       $dbh->do("CREATE SCHEMA dbic_t_schema");
 410       $dbh->do("CREATE TABLE dbic_t_schema.artist $std_artist_table");
 411
 412       $dbh->do(<<EOS);
 413 CREATE TABLE dbic_t_schema.timestamp_primary_key_test (
 414   id timestamp default current_timestamp
 415 )
 416 EOS
 417       $dbh->do(<<EOS);
 418 CREATE TABLE dbic_t_schema.cd (
 419   cdid int PRIMARY KEY,
 420   artist int,
 421   title varchar(255),
 422   year varchar(4),
 423   genreid int,
 424   single_track int
 425 )
 426 EOS
 427       $dbh->do(<<EOS);
 428 CREATE TABLE dbic_t_schema.track (
 429   trackid int,
 430   cd int REFERENCES dbic_t_schema.cd(cdid) DEFERRABLE,
 431   position int,
 432   title varchar(255),
 433   last_updated_on date,
 434   last_updated_at date,
 435   small_dt date
 436 )
 437 EOS
 438
 439       $dbh->do(<<EOS);
 440 CREATE TABLE dbic_t_schema.sequence_test (
 441     pkid1 integer
 442     , pkid2 integer
 443     , nonpkid integer
 444     , name VARCHAR(100)
 445     , CONSTRAINT pk PRIMARY KEY(pkid1, pkid2)
 446 )
 447 EOS
 448       $dbh->do("CREATE SEQUENCE pkid1_seq START 1 MAXVALUE 999999 MINVALUE 0");
 449       $dbh->do("CREATE SEQUENCE pkid2_seq START 10 MAXVALUE 999999 MINVALUE 0");
 450       $dbh->do("CREATE SEQUENCE nonpkid_seq START 20 MAXVALUE 999999 MINVALUE 0");
 451       $dbh->do(<<EOS);
 452 CREATE TABLE dbic_t_schema.casecheck (
 453     id serial PRIMARY KEY
 454     , "name" VARCHAR(1)
 455     , "NAME" VARCHAR(2)
 456     , "UC_NAME" VARCHAR(3)
 457 )
 458 EOS
 459       $dbh->do(<<EOS);
 460 CREATE TABLE dbic_t_schema.array_test (
 461     id serial PRIMARY KEY
 462     , arrayfield INTEGER[]
 463 )
 464 EOS
 465       $dbh->do("CREATE SCHEMA dbic_t_schema_2");
 466       $dbh->do("CREATE TABLE dbic_t_schema_2.artist $std_artist_table");
 467       $dbh->do("CREATE SCHEMA dbic_t_schema_3");
 468       $dbh->do("CREATE TABLE dbic_t_schema_3.artist $std_artist_table");
 469       $dbh->do('set search_path=dbic_t_schema,public');
 470       $dbh->do("CREATE SCHEMA dbic_t_schema_4");
 471       $dbh->do("CREATE SCHEMA dbic_t_schema_5");
 472       $dbh->do(<<EOS);
 473  CREATE TABLE dbic_t_schema_4.artist
 474  (
 475    artistid integer not null default nextval('artist_artistid_seq'::regclass) PRIMARY KEY
 476    , name VARCHAR(100)
 477    , rank INTEGER NOT NULL DEFAULT '13'
 478    , charfield CHAR(10)
 479    , arrayfield INTEGER[]
 480  );
 481 EOS
 482       $dbh->do('set search_path=public,dbic_t_schema,dbic_t_schema_3');
 483       $dbh->do('create sequence public.artist_artistid_seq'); #< in the public schema
 484       $dbh->do(<<EOS);
 485  CREATE TABLE dbic_t_schema_5.artist
 486  (
 487    artistid integer not null default nextval('public.artist_artistid_seq'::regclass) PRIMARY KEY
 488    , name VARCHAR(100)
 489    , rank INTEGER NOT NULL DEFAULT '13'
 490    , charfield CHAR(10)
 491    , arrayfield INTEGER[]
 492  );
 493 EOS
 494       $dbh->do('set search_path=dbic_t_schema,public');
 495   });
 496 }
 497
 498
 499
 500 sub drop_test_schema {
 501     my ( $schema, $warn_exceptions ) = @_;
 502
 503     $schema->storage->dbh_do(sub {
 504         my (undef,$dbh) = @_;
 505
 506         local $dbh->{Warn} = 0;
 507
 508         for my $stat (
 509                       'DROP SCHEMA dbic_t_schema_5 CASCADE',
 510                       'DROP SEQUENCE public.artist_artistid_seq',
 511                       'DROP SCHEMA dbic_t_schema_4 CASCADE',
 512                       'DROP SCHEMA dbic_t_schema CASCADE',
 513                       'DROP SEQUENCE pkid1_seq',
 514                       'DROP SEQUENCE pkid2_seq',
 515                       'DROP SEQUENCE nonpkid_seq',
 516                       'DROP SCHEMA dbic_t_schema_2 CASCADE',
 517                       'DROP SCHEMA dbic_t_schema_3 CASCADE',
 518                      ) {
 519             eval { $dbh->do ($stat) };
 520             diag $@ if $@ && $warn_exceptions;
 521         }
 522     });
 523 }
 524
 525
 526 ###  auto-pk / last_insert_id / sequence discovery
 527 sub run_apk_tests {
 528     my $schema = shift;
 529
 530     # This is in Core now, but it's here just to test that it doesn't break
 531     $schema->class('Artist')->load_components('PK::Auto');
 532     cmp_ok( $schema->resultset('Artist')->count, '==', 0, 'this should start with an empty artist table');
 533
 534     # test that auto-pk also works with the defined search path by
 535     # un-schema-qualifying the table name
 536     apk_t_set($schema,'artist');
 537
 538     my $unq_new;
 539     lives_ok {
 540         $unq_new = $schema->resultset('Artist')->create({ name => 'baz' });
 541     } 'insert into unqualified, shadowed table succeeds';
 542
 543     is($unq_new && $unq_new->artistid, 1, "and got correct artistid");
 544
 545     my @test_schemas = ( [qw| dbic_t_schema_2    1  |],
 546                          [qw| dbic_t_schema_3    1  |],
 547                          [qw| dbic_t_schema_4    2  |],
 548                          [qw| dbic_t_schema_5    1  |],
 549                        );
 550     foreach my $t ( @test_schemas ) {
 551         my ($sch_name, $start_num) = @$t;
 552         #test with dbic_t_schema_2
 553         apk_t_set($schema,"$sch_name.artist");
 554         my $another_new;
 555         lives_ok {
 556             $another_new = $schema->resultset('Artist')->create({ name => 'Tollbooth Willy'});
 557             is( $another_new->artistid,$start_num, "got correct artistid for $sch_name")
 558                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 559         } "$sch_name liid 1 did not die"
 560             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 561         lives_ok {
 562             $another_new = $schema->resultset('Artist')->create({ name => 'Adam Sandler'});
 563             is( $another_new->artistid,$start_num+1, "got correct artistid for $sch_name")
 564                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 565         } "$sch_name liid 2 did not die"
 566             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 567
 568     }
 569
 570     lives_ok {
 571         apk_t_set($schema,'dbic_t_schema.artist');
 572         my $new = $schema->resultset('Artist')->create({ name => 'foo' });
 573         is($new->artistid, 4, "Auto-PK worked");
 574         $new = $schema->resultset('Artist')->create({ name => 'bar' });
 575         is($new->artistid, 5, "Auto-PK worked");
 576     } 'old auto-pk tests did not die either';
 577 }
 578
 579 # sets the artist table name and clears sequence name cache
 580 sub apk_t_set {
 581     my ( $s, $n ) = @_;
 582     $s->source("Artist")->name($n);
 583     $s->source('Artist')->column_info('artistid')->{sequence} = undef; #< clear sequence name cache
 584 }
 585
 586
 587 ######## EXTENDED AUTO-PK TESTS
 588
 589 my @eapk_id_columns;
 590 BEGIN {
 591   package DBICTest::Schema::ExtAPK;
 592   push @main::test_classes, __PACKAGE__;
 593
 594   use strict;
 595   use warnings;
 596   use base 'DBIx::Class::Core';
 597
 598   __PACKAGE__->table('apk');
 599
 600   @eapk_id_columns = qw( id1 id2 id3 id4 );
 601   __PACKAGE__->add_columns(
 602     map { $_ => { data_type => 'integer', is_auto_increment => 1 } }
 603        @eapk_id_columns
 604   );
 605
 606   __PACKAGE__->set_primary_key('id2'); #< note the SECOND column is
 607                                        #the primary key
 608 }
 609
 610 my @eapk_schemas;
 611 BEGIN{ @eapk_schemas = map "dbic_apk_$_", 0..5 }
 612 my %seqs; #< hash of schema.table.col => currval of its (DBIC) primary key sequence
 613
 614 sub run_extended_apk_tests {
 615   my $schema = shift;
 616
 617   #save the search path and reset it at the end
 618   my $search_path_save = eapk_get_search_path($schema);
 619
 620   eapk_drop_all($schema);
 621   %seqs = ();
 622
 623   # make the test schemas and sequences
 624   $schema->storage->dbh_do(sub {
 625     my ( undef, $dbh ) = @_;
 626
 627     $dbh->do("CREATE SCHEMA $_")
 628         for @eapk_schemas;
 629
 630     $dbh->do("CREATE SEQUENCE $eapk_schemas[5].fooseq");
 631     $dbh->do("SELECT setval('$eapk_schemas[5].fooseq',400)");
 632     $seqs{"$eapk_schemas[1].apk.id2"} = 400;
 633
 634     $dbh->do("CREATE SEQUENCE $eapk_schemas[4].fooseq");
 635     $dbh->do("SELECT setval('$eapk_schemas[4].fooseq',300)");
 636     $seqs{"$eapk_schemas[3].apk.id2"} = 300;
 637
 638     $dbh->do("CREATE SEQUENCE $eapk_schemas[3].fooseq");
 639     $dbh->do("SELECT setval('$eapk_schemas[3].fooseq',200)");
 640     $seqs{"$eapk_schemas[4].apk.id2"} = 200;
 641
 642     $dbh->do("SET search_path = ".join ',', reverse @eapk_schemas );
 643   });
 644
 645   # clear our search_path cache
 646   $schema->storage->{_pg_search_path} = undef;
 647
 648   eapk_create( $schema,
 649                with_search_path => [0,1],
 650              );
 651   eapk_create( $schema,
 652                with_search_path => [1,0,'public'],
 653                nextval => "$eapk_schemas[5].fooseq",
 654              );
 655   eapk_create( $schema,
 656                with_search_path => ['public',0,1],
 657                qualify_table => 2,
 658              );
 659   eapk_create( $schema,
 660                with_search_path => [3,1,0,'public'],
 661                nextval => "$eapk_schemas[4].fooseq",
 662              );
 663   eapk_create( $schema,
 664                with_search_path => [3,1,0,'public'],
 665                nextval => "$eapk_schemas[3].fooseq",
 666                qualify_table => 4,
 667              );
 668
 669   eapk_poke( $schema );
 670   eapk_poke( $schema, 0 );
 671   eapk_poke( $schema, 2 );
 672   eapk_poke( $schema, 4 );
 673   eapk_poke( $schema, 1 );
 674   eapk_poke( $schema, 0 );
 675   eapk_poke( $schema, 1 );
 676   eapk_poke( $schema );
 677   eapk_poke( $schema, 4 );
 678   eapk_poke( $schema, 3 );
 679   eapk_poke( $schema, 1 );
 680   eapk_poke( $schema, 2 );
 681   eapk_poke( $schema, 0 );
 682
 683   # set our search path back
 684   eapk_set_search_path( $schema, @$search_path_save );
 685 }
 686
 687 # do a DBIC create on the apk table in the given schema number (which is an
 688 # index of @eapk_schemas)
 689
 690 sub eapk_poke {
 691   my ($s, $schema_num) = @_;
 692
 693   my $schema_name = defined $schema_num
 694       ? $eapk_schemas[$schema_num]
 695       : '';
 696
 697   my $schema_name_actual = $schema_name || eapk_find_visible_schema($s);
 698
 699   $s->source('ExtAPK')->name($schema_name ? $schema_name.'.apk' : 'apk');
 700   #< clear sequence name cache
 701   $s->source('ExtAPK')->column_info($_)->{sequence} = undef
 702       for @eapk_id_columns;
 703
 704   no warnings 'uninitialized';
 705   lives_ok {
 706     my $new;
 707     for my $inc (1,2,3) {
 708       $new = $schema->resultset('ExtAPK')->create({ id1 => 1});
 709       my $proper_seqval = ++$seqs{"$schema_name_actual.apk.id2"};
 710       is( $new->id2, $proper_seqval, "$schema_name_actual.apk.id2 correct inc $inc" )
 711           or eapk_seq_diag($s,$schema_name);
 712       $new->discard_changes;
 713       is( $new->id1, 1 );
 714       for my $id ('id3','id4') {
 715         my $proper_seqval = ++$seqs{"$schema_name_actual.apk.$id"};
 716         is( $new->$id, $proper_seqval, "$schema_name_actual.apk.$id correct inc $inc" )
 717             or eapk_seq_diag($s,$schema_name);
 718       }
 719     }
 720   } "create in schema '$schema_name' lives"
 721       or eapk_seq_diag($s,$schema_name);
 722 }
 723
 724 # print diagnostic info on which sequences were found in the ExtAPK
 725 # class
 726 sub eapk_seq_diag {
 727     my $s = shift;
 728     my $schema = shift || eapk_find_visible_schema($s);
 729
 730     diag "$schema.apk sequences: ",
 731         join(', ',
 732              map "$_:".($s->source('ExtAPK')->column_info($_)->{sequence} || '<none>'),
 733              @eapk_id_columns
 734             );
 735 }
 736
 737 # get the postgres search path as an arrayref
 738 sub eapk_get_search_path {
 739     my ( $s ) = @_;
 740     # cache the search path as ['schema','schema',...] in the storage
 741     # obj
 742
 743     return $s->storage->dbh_do(sub {
 744         my (undef, $dbh) = @_;
 745         my @search_path;
 746         my ($sp_string) = $dbh->selectrow_array('SHOW search_path');
 747         while ( $sp_string =~ s/("[^"]+"|[^,]+),?// ) {
 748             unless( defined $1 and length $1 ) {
 749                 die "search path sanity check failed: '$1'";
 750             }
 751             push @search_path, $1;
 752         }
 753         \@search_path
 754     });
 755 }
 756 sub eapk_set_search_path {
 757     my ($s,@sp) = @_;
 758     my $sp = join ',',@sp;
 759     $s->storage->dbh_do( sub { $_[1]->do("SET search_path = $sp") } );
 760 }
 761
 762 # create the apk table in the given schema, can set whether the table name is qualified, what the nextval is for the second ID
 763 sub eapk_create {
 764     my ($schema, %a) = @_;
 765
 766     $schema->storage->dbh_do(sub {
 767         my (undef,$dbh) = @_;
 768
 769         my $searchpath_save;
 770         if ( $a{with_search_path} ) {
 771             ($searchpath_save) = $dbh->selectrow_array('SHOW search_path');
 772
 773             my $search_path = join ',',map {/\D/ ? $_ : $eapk_schemas[$_]} @{$a{with_search_path}};
 774
 775             $dbh->do("SET search_path = $search_path");
 776         }
 777
 778         my $table_name = $a{qualify_table}
 779             ? ($eapk_schemas[$a{qualify_table}] || die). ".apk"
 780             : 'apk';
 781         local $_[1]->{Warn} = 0;
 782
 783         my $id_def = $a{nextval}
 784             ? "integer not null default nextval('$a{nextval}'::regclass)"
 785             : 'serial';
 786         $dbh->do(<<EOS);
 787 CREATE TABLE $table_name (
 788   id1 serial
 789   , id2 $id_def
 790   , id3 serial primary key
 791   , id4 serial
 792 )
 793 EOS
 794
 795         if( $searchpath_save ) {
 796             $dbh->do("SET search_path = $searchpath_save");
 797         }
 798     });
 799 }
 800
 801 sub eapk_drop_all {
 802     my ( $schema, $warn_exceptions ) = @_;
 803
 804     $schema->storage->dbh_do(sub {
 805         my (undef,$dbh) = @_;
 806
 807         local $dbh->{Warn} = 0;
 808
 809         # drop the test schemas
 810         for (@eapk_schemas ) {
 811             eval{ $dbh->do("DROP SCHEMA $_ CASCADE") };
 812             diag $@ if $@ && $warn_exceptions;
 813         }
 814
 815
 816     });
 817 }
 818
 819 sub eapk_find_visible_schema {
 820     my ($s) = @_;
 821
 822     my ($schema) =
 823         $s->storage->dbh_do(sub {
 824             $_[1]->selectrow_array(<<EOS);
 825 SELECT n.nspname
 826 FROM pg_catalog.pg_namespace n
 827 JOIN pg_catalog.pg_class c ON c.relnamespace = n.oid
 828 WHERE c.relname = 'apk'
 829   AND pg_catalog.pg_table_is_visible(c.oid)
 830 EOS
 831         });
 832     return $schema;
 833 }