t/72pg.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use Sub::Name;
   7 use Config;
   8 use DBIx::Class::Optional::Dependencies ();
   9 use lib qw(t/lib);
  10 use DBICTest;
  11 use SQL::Abstract 'is_literal_value';
  12 use DBIx::Class::_Util 'is_exception';
  13
  14 plan skip_all => 'Test needs ' . DBIx::Class::Optional::Dependencies->req_missing_for ('test_rdbms_pg')
  15   unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_rdbms_pg');
  16
  17 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
  18
  19 plan skip_all => <<'EOM' unless $dsn && $user;
  20 Set $ENV{DBICTEST_PG_DSN}, _USER and _PASS to run this test
  21 ( NOTE: This test drops and creates tables called 'artist', 'cd',
  22 'timestamp_primary_key_test', 'track', 'casecheck', 'array_test' and
  23 'sequence_test' as well as following sequences: 'pkid1_seq', 'pkid2_seq' and
  24 'nonpkid_seq'. as well as following schemas: 'dbic_t_schema',
  25 'dbic_t_schema_2', 'dbic_t_schema_3', 'dbic_t_schema_4', and 'dbic_t_schema_5')
  26 EOM
  27
  28 ### load any test classes that are defined further down in the file via BEGIN blocks
  29
  30 our @test_classes; #< array that will be pushed into by test classes defined in this file
  31 DBICTest::Schema->load_classes( map {s/.+:://;$_} @test_classes ) if @test_classes;
  32
  33 ###  pre-connect tests (keep each test separate as to make sure rebless() runs)
  34   {
  35     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  36
  37     ok (!$s->storage->_dbh, 'definitely not connected');
  38
  39     # Check that datetime_parser returns correctly before we explicitly connect.
  40     SKIP: {
  41         skip (
  42           "Pg parser detection test needs " . DBIx::Class::Optional::Dependencies->req_missing_for ('test_dt_pg'),
  43           2
  44         ) unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_dt_pg');
  45
  46         my $store = ref $s->storage;
  47         is($store, 'DBIx::Class::Storage::DBI', 'Started with generic storage');
  48
  49         my $parser = $s->storage->datetime_parser;
  50         is( $parser, 'DateTime::Format::Pg', 'datetime_parser is as expected');
  51     }
  52
  53     ok (!$s->storage->_dbh, 'still not connected');
  54   }
  55
  56   {
  57     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  58     # make sure sqlt_type overrides work (::Storage::DBI::Pg does this)
  59     ok (!$s->storage->_dbh, 'definitely not connected');
  60     is ($s->storage->sqlt_type, 'PostgreSQL', 'sqlt_type correct pre-connection');
  61     ok (!$s->storage->_dbh, 'still not connected');
  62   }
  63
  64 # test LIMIT support
  65 {
  66   my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
  67   drop_test_schema($schema);
  68   create_test_schema($schema);
  69   for (1..6) {
  70     $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
  71   }
  72   my $it = $schema->resultset('Artist')->search( {},
  73     { rows => 3,
  74       offset => 2,
  75       order_by => 'artistid' }
  76   );
  77   is( $it->count, 3, "LIMIT count ok" );  # ask for 3 rows out of 6 artists
  78   is( $it->next->name, "Artist 3", "iterator->next ok" );
  79   $it->next;
  80   $it->next;
  81   $it->next;
  82   is( $it->next, undef, "next past end of resultset ok" );
  83
  84   # Limit with select-lock
  85   lives_ok {
  86     $schema->txn_do (sub {
  87       isa_ok (
  88         $schema->resultset('Artist')->find({artistid => 1}, {for => 'update', rows => 1}),
  89         'DBICTest::Schema::Artist',
  90       );
  91     });
  92   } 'Limited FOR UPDATE select works';
  93 }
  94
  95 # check if we indeed do support stuff
  96 my $test_server_supports_insert_returning = do {
  97
  98   my $si = DBICTest::Schema->connect($dsn, $user, $pass)->storage->_server_info;
  99   die "Unparseable Pg server version: $si->{dbms_version}\n"
 100     unless $si->{normalized_dbms_version};
 101
 102   $si->{normalized_dbms_version} < 8.002 ? 0 : 1;
 103 };
 104 is (
 105   DBICTest::Schema->connect($dsn, $user, $pass)->storage->_use_insert_returning,
 106   $test_server_supports_insert_returning,
 107   'insert returning capability guessed correctly'
 108 );
 109
 110 my $schema;
 111 for my $use_insert_returning ($test_server_supports_insert_returning
 112   ? (0,1)
 113   : (0)
 114 ) {
 115
 116   no warnings qw/once redefine/;
 117   my $old_connection = DBICTest::Schema->can('connection');
 118   local *DBICTest::Schema::connection = subname 'DBICTest::Schema::connection' => sub {
 119     my $s = shift->$old_connection(@_);
 120     $s->storage->_use_insert_returning ($use_insert_returning);
 121     $s;
 122   };
 123
 124 ### test capability override
 125   {
 126     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
 127
 128     ok (!$s->storage->_dbh, 'definitely not connected');
 129
 130     ok (
 131       ! ($s->storage->_use_insert_returning xor $use_insert_returning),
 132       'insert returning capability set correctly',
 133     );
 134     ok (!$s->storage->_dbh, 'still not connected (capability override works)');
 135   }
 136
 137 ### connect, create postgres-specific test schema
 138
 139   $schema = DBICTest::Schema->connect($dsn, $user, $pass);
 140   $schema->storage->ensure_connected;
 141
 142   drop_test_schema($schema);
 143   create_test_schema($schema);
 144
 145 ### begin main tests
 146
 147 # run a BIG bunch of tests for last-insert-id / Auto-PK / sequence
 148 # discovery
 149   run_apk_tests($schema); #< older set of auto-pk tests
 150   run_extended_apk_tests($schema); #< new extended set of auto-pk tests
 151
 152
 153 ######## test the pg-specific syntax from https://rt.cpan.org/Ticket/Display.html?id=99503
 154   lives_ok {
 155     is(
 156       $schema->resultset('Artist')->search({ artistid => { -in => \ '(select 4) union (select 5)' } })->count,
 157       2,
 158       'Two expected artists found on subselect union within IN',
 159     );
 160   };
 161
 162 ### type_info tests
 163
 164   my $test_type_info = {
 165       'artistid' => {
 166           'data_type' => 'integer',
 167           'is_nullable' => 0,
 168           'size' => 4,
 169       },
 170       'name' => {
 171           'data_type' => 'character varying',
 172           'is_nullable' => 1,
 173           'size' => 100,
 174           'default_value' => undef,
 175       },
 176       'rank' => {
 177           'data_type' => 'integer',
 178           'is_nullable' => 0,
 179           'size' => 4,
 180           'default_value' => 13,
 181
 182       },
 183       'charfield' => {
 184           'data_type' => 'character',
 185           'is_nullable' => 1,
 186           'size' => 10,
 187           'default_value' => undef,
 188       },
 189       'arrayfield' => {
 190           'data_type' => 'integer[]',
 191           'is_nullable' => 1,
 192           'size' => undef,
 193           'default_value' => undef,
 194       },
 195   };
 196
 197   my $type_info = $schema->storage->columns_info_for('dbic_t_schema.artist');
 198   my $artistid_defval = delete $type_info->{artistid}->{default_value};
 199
 200   # The curor info is too radically different from what is in the column_info
 201   # call - just punt it (DBD::SQLite tests the codepath plenty enough)
 202   unless (DBIx::Class::_ENV_::STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE) {
 203     like(
 204       $artistid_defval,
 205       qr/^nextval\('([^\.]*\.){0,1}artist_artistid_seq'::(?:text|regclass)\)/,
 206       'columns_info_for - sequence matches Pg get_autoinc_seq expectations'
 207     );
 208
 209     is_deeply($type_info, $test_type_info,
 210             'columns_info_for - column data types');
 211   }
 212
 213 ####### Array tests
 214
 215   BEGIN {
 216     package DBICTest::Schema::ArrayTest;
 217     push @main::test_classes, __PACKAGE__;
 218
 219     use strict;
 220     use warnings;
 221     use base 'DBICTest::BaseResult';
 222
 223     __PACKAGE__->table('dbic_t_schema.array_test');
 224     __PACKAGE__->add_columns(qw/id arrayfield/);
 225     __PACKAGE__->column_info_from_storage(1);
 226     __PACKAGE__->set_primary_key('id');
 227
 228   }
 229   SKIP: {
 230     skip "Need DBD::Pg 2.9.2 or newer for array tests", 4 if $DBD::Pg::VERSION < 2.009002;
 231
 232     my $arr_rs = $schema->resultset('ArrayTest');
 233
 234     lives_ok {
 235       $arr_rs->create({
 236         arrayfield => [1, 2],
 237       });
 238     } 'inserting arrayref as pg array data';
 239
 240     lives_ok {
 241       $arr_rs->update({
 242         arrayfield => [3, 4],
 243       });
 244     } 'updating arrayref as pg array data';
 245
 246     $arr_rs->create({
 247       arrayfield => [5, 6],
 248     });
 249
 250     lives_ok {
 251       $schema->populate('ArrayTest', [
 252         [ qw/arrayfield/ ],
 253         [ [0,0]          ],
 254       ]);
 255     } 'inserting arrayref using void ctx populate';
 256
 257     # Search using arrays
 258     lives_ok {
 259       is_deeply (
 260         $arr_rs->search({ arrayfield => { -value => [3,4] } })->first->arrayfield,
 261         [3,4],
 262         'Array value matches'
 263       );
 264     } 'searching by arrayref';
 265
 266     lives_ok {
 267       is_deeply (
 268         $arr_rs->search({ arrayfield => { '=' => { -value => [3,4] }} })->first->arrayfield,
 269         [3,4],
 270         'Array value matches explicit equal'
 271       );
 272     } 'searching by arrayref (explicit equal sign)';
 273
 274     lives_ok {
 275       is_deeply (
 276         $arr_rs->search({ arrayfield => { '>' => { -value => [3,1] }} })->first->arrayfield,
 277         [3,4],
 278         'Array value matches greater than'
 279       );
 280     } 'searching by arrayref (greater than)';
 281
 282     lives_ok {
 283       is (
 284         $arr_rs->search({ arrayfield => { '>' => { -value => [3,7] }} })->count,
 285         1,
 286         'Greater than search found [5,6]',
 287       );
 288     } 'searching by arrayref (greater than)';
 289
 290     # Find using arrays
 291     lives_ok {
 292       is_deeply (
 293         $arr_rs->find({ arrayfield => { -value => [3,4] } })->arrayfield,
 294         [3,4],
 295         'Array value matches implicit equal'
 296       );
 297     } 'find by arrayref';
 298
 299     lives_ok {
 300       is_deeply (
 301         $arr_rs->find({ arrayfield => { '=' => { -value => [3,4] }} })->arrayfield,
 302         [3,4],
 303         'Array value matches explicit equal'
 304       );
 305     } 'find by arrayref (equal)';
 306
 307     # test inferred condition for creation
 308     for my $cond (
 309       { -value => [3,4] },
 310       \[ '= ?' => [arrayfield => [3, 4]] ],
 311     ) {
 312       local $TODO = 'No introspection of complex literal conditions :('
 313         if is_literal_value $cond;
 314
 315
 316       my $arr_rs_cond = $arr_rs->search({ arrayfield => $cond });
 317
 318       my $row = $arr_rs_cond->create({});
 319       is_deeply ($row->arrayfield, [3,4], 'Array value taken from $rs condition');
 320       $row->discard_changes;
 321       is_deeply ($row->arrayfield, [3,4], 'Array value made it to storage');
 322     }
 323   }
 324
 325 ########## Case check
 326
 327   BEGIN {
 328     package DBICTest::Schema::Casecheck;
 329     push @main::test_classes, __PACKAGE__;
 330
 331     use strict;
 332     use warnings;
 333     use base 'DBIx::Class::Core';
 334
 335     __PACKAGE__->table('dbic_t_schema.casecheck');
 336     __PACKAGE__->add_columns(qw/id name NAME uc_name/);
 337     __PACKAGE__->column_info_from_storage(1);
 338     __PACKAGE__->set_primary_key('id');
 339   }
 340
 341   my $name_info = $schema->source('Casecheck')->column_info( 'name' );
 342   is( $name_info->{size}, 1, "Case sensitive matching info for 'name'" );
 343
 344   my $NAME_info = $schema->source('Casecheck')->column_info( 'NAME' );
 345   is( $NAME_info->{size}, 2, "Case sensitive matching info for 'NAME'" );
 346
 347   my $uc_name_info = $schema->source('Casecheck')->column_info( 'uc_name' );
 348   is( $uc_name_info->{size}, 3, "Case insensitive matching info for 'uc_name'" );
 349
 350
 351 ## Test ResultSet->update
 352 my $artist = $schema->resultset('Artist')->first;
 353 my $cds = $artist->cds_unordered->search({
 354     year => { '!=' => 2010 }
 355 }, { prefetch => 'liner_notes' });
 356 lives_ok { $cds->update({ year => '2010' }) } 'Update on prefetched rs';
 357
 358 ## Test SELECT ... FOR UPDATE
 359   SKIP: {
 360       skip "Your system does not support unsafe signals (d_sigaction) - unable to run deadlock test", 1
 361         unless eval { $Config{d_sigaction} and require POSIX };
 362
 363       my ($timed_out, $artist2);
 364
 365       for my $t (
 366         {
 367           # Make sure that an error was raised, and that the update failed
 368           update_lock => 1,
 369           test_sub => sub {
 370             ok($timed_out, "update from second schema times out");
 371             ok($artist2->is_column_changed('name'), "'name' column is still dirty from second schema");
 372           },
 373         },
 374         {
 375           # Make sure that an error was NOT raised, and that the update succeeded
 376           update_lock => 0,
 377           test_sub => sub {
 378             ok(! $timed_out, "update from second schema DOES NOT timeout");
 379             ok(! $artist2->is_column_changed('name'), "'name' column is NOT dirty from second schema");
 380           },
 381         },
 382       ) {
 383         # create a new schema
 384         my $schema2 = DBICTest::Schema->connect($dsn, $user, $pass);
 385         $schema2->source("Artist")->name("dbic_t_schema.artist");
 386
 387         $schema->txn_do( sub {
 388           my $rs = $schema->resultset('Artist')->search(
 389               {
 390                   artistid => 1
 391               },
 392               $t->{update_lock} ? { for => 'update' } : {}
 393           );
 394           ok ($rs->count, 'Count works');
 395
 396           my $artist = $rs->next;
 397           is($artist->artistid, 1, "select returns artistid = 1");
 398
 399           $timed_out = 0;
 400
 401           eval {
 402               # can not use %SIG assignment directly - we need sigaction below
 403               # localization to a block still works however
 404               local $SIG{ALRM};
 405
 406               POSIX::sigaction( POSIX::SIGALRM() => POSIX::SigAction->new(
 407                 sub { die "DBICTestTimeout" },
 408               ));
 409
 410               $artist2 = $schema2->resultset('Artist')->find(1);
 411               $artist2->name('fooey');
 412
 413               # FIXME - this needs to go away in lieu of a non-retrying runner
 414               # ( i.e. after solving RT#47005 )
 415               local *DBIx::Class::Storage::DBI::_ping = sub { 1 }, DBIx::Class::_ENV_::OLD_MRO && Class::C3->reinitialize()
 416                 if DBIx::Class::_Util::modver_gt_or_eq( 'DBD::Pg' => '3.5.0' );
 417
 418               alarm(1);
 419               $artist2->update;
 420           };
 421
 422           alarm(0);
 423
 424           if (is_exception($@)) {
 425             $timed_out = $@ =~ /DBICTestTimeout/
 426               or die $@;
 427           }
 428         });
 429
 430         $t->{test_sub}->();
 431       }
 432   }
 433
 434
 435 ######## other older Auto-pk tests
 436
 437   $schema->source("SequenceTest")->name("dbic_t_schema.sequence_test");
 438   for (1..5) {
 439       my $st = $schema->resultset('SequenceTest')->create({ name => 'foo' });
 440       is($st->pkid1, $_, "Auto-PK for sequence without default: First primary key");
 441       is($st->pkid2, $_ + 9, "Auto-PK for sequence without default: Second primary key");
 442       is($st->nonpkid, $_ + 19, "Auto-PK for sequence without default: Non-primary key");
 443   }
 444   my $st = $schema->resultset('SequenceTest')->create({ name => 'foo', pkid1 => 55 });
 445   is($st->pkid1, 55, "Auto-PK for sequence without default: First primary key set manually");
 446
 447
 448 ######## test non-serial auto-pk
 449
 450   if ($schema->storage->_use_insert_returning) {
 451     $schema->source('TimestampPrimaryKey')->name('dbic_t_schema.timestamp_primary_key_test');
 452     my $row = $schema->resultset('TimestampPrimaryKey')->create({});
 453     ok $row->id;
 454   }
 455
 456 ######## test with_deferred_fk_checks
 457
 458   $schema->source('CD')->name('dbic_t_schema.cd');
 459   $schema->source('Track')->name('dbic_t_schema.track');
 460   lives_ok {
 461     $schema->storage->with_deferred_fk_checks(sub {
 462       $schema->resultset('Track')->create({
 463         trackid => 999, cd => 999, position => 1, title => 'deferred FK track'
 464       });
 465       $schema->resultset('CD')->create({
 466         artist => 1, cdid => 999, year => '2003', title => 'deferred FK cd'
 467       });
 468     });
 469   } 'with_deferred_fk_checks code survived';
 470
 471   is eval { $schema->resultset('Track')->find(999)->title }, 'deferred FK track',
 472      'code in with_deferred_fk_checks worked';
 473
 474   throws_ok {
 475     $schema->resultset('Track')->create({
 476       trackid => 1, cd => 9999, position => 1, title => 'Track1'
 477     });
 478   } qr/constraint/i, 'with_deferred_fk_checks is off';
 479 }
 480
 481 done_testing;
 482
 483 END {
 484     return unless $schema;
 485     drop_test_schema($schema);
 486     eapk_drop_all($schema);
 487     undef $schema;
 488 };
 489
 490
 491 ######### SUBROUTINES
 492
 493 sub create_test_schema {
 494     my $schema = shift;
 495     $schema->storage->dbh_do(sub {
 496       my (undef,$dbh) = @_;
 497
 498       local $dbh->{Warn} = 0;
 499
 500       my $std_artist_table = <<EOS;
 501 (
 502   artistid serial PRIMARY KEY
 503   , name VARCHAR(100)
 504   , rank INTEGER NOT NULL DEFAULT '13'
 505   , charfield CHAR(10)
 506   , arrayfield INTEGER[]
 507 )
 508 EOS
 509
 510       $dbh->do("CREATE SCHEMA dbic_t_schema");
 511       $dbh->do("CREATE TABLE dbic_t_schema.artist $std_artist_table");
 512
 513       $dbh->do(<<EOS);
 514 CREATE TABLE dbic_t_schema.timestamp_primary_key_test (
 515   id timestamp default current_timestamp
 516 )
 517 EOS
 518       $dbh->do(<<EOS);
 519 CREATE TABLE dbic_t_schema.cd (
 520   cdid int PRIMARY KEY,
 521   artist int,
 522   title varchar(255),
 523   year varchar(4),
 524   genreid int,
 525   single_track int
 526 )
 527 EOS
 528       $dbh->do(<<EOS);
 529 CREATE TABLE dbic_t_schema.track (
 530   trackid int,
 531   cd int REFERENCES dbic_t_schema.cd(cdid) DEFERRABLE,
 532   position int,
 533   title varchar(255),
 534   last_updated_on date,
 535   last_updated_at date
 536 )
 537 EOS
 538
 539       $dbh->do(<<EOS);
 540 CREATE TABLE dbic_t_schema.sequence_test (
 541     pkid1 integer
 542     , pkid2 integer
 543     , nonpkid integer
 544     , name VARCHAR(100)
 545     , CONSTRAINT pk PRIMARY KEY(pkid1, pkid2)
 546 )
 547 EOS
 548       $dbh->do("CREATE SEQUENCE pkid1_seq START 1 MAXVALUE 999999 MINVALUE 0");
 549       $dbh->do("CREATE SEQUENCE pkid2_seq START 10 MAXVALUE 999999 MINVALUE 0");
 550       $dbh->do("CREATE SEQUENCE nonpkid_seq START 20 MAXVALUE 999999 MINVALUE 0");
 551       $dbh->do(<<EOS);
 552 CREATE TABLE dbic_t_schema.casecheck (
 553     id serial PRIMARY KEY
 554     , "name" VARCHAR(1)
 555     , "NAME" VARCHAR(2)
 556     , "UC_NAME" VARCHAR(3)
 557 )
 558 EOS
 559       $dbh->do(<<EOS);
 560 CREATE TABLE dbic_t_schema.array_test (
 561     id serial PRIMARY KEY
 562     , arrayfield INTEGER[]
 563 )
 564 EOS
 565       $dbh->do("CREATE SCHEMA dbic_t_schema_2");
 566       $dbh->do("CREATE TABLE dbic_t_schema_2.artist $std_artist_table");
 567       $dbh->do("CREATE SCHEMA dbic_t_schema_3");
 568       $dbh->do("CREATE TABLE dbic_t_schema_3.artist $std_artist_table");
 569       $dbh->do('set search_path=dbic_t_schema,public');
 570       $dbh->do("CREATE SCHEMA dbic_t_schema_4");
 571       $dbh->do("CREATE SCHEMA dbic_t_schema_5");
 572       $dbh->do(<<EOS);
 573  CREATE TABLE dbic_t_schema_4.artist
 574  (
 575    artistid integer not null default nextval('artist_artistid_seq'::regclass) PRIMARY KEY
 576    , name VARCHAR(100)
 577    , rank INTEGER NOT NULL DEFAULT '13'
 578    , charfield CHAR(10)
 579    , arrayfield INTEGER[]
 580  );
 581 EOS
 582       $dbh->do('set search_path=public,dbic_t_schema,dbic_t_schema_3');
 583       $dbh->do('create sequence public.artist_artistid_seq'); #< in the public schema
 584       $dbh->do(<<EOS);
 585  CREATE TABLE dbic_t_schema_5.artist
 586  (
 587    artistid integer not null default nextval('public.artist_artistid_seq'::regclass) PRIMARY KEY
 588    , name VARCHAR(100)
 589    , rank INTEGER NOT NULL DEFAULT '13'
 590    , charfield CHAR(10)
 591    , arrayfield INTEGER[]
 592  );
 593 EOS
 594       $dbh->do('set search_path=dbic_t_schema,public');
 595   });
 596 }
 597
 598
 599
 600 sub drop_test_schema {
 601     my ( $schema, $warn_exceptions ) = @_;
 602
 603     $schema->storage->dbh_do(sub {
 604         my (undef,$dbh) = @_;
 605
 606         local $dbh->{Warn} = 0;
 607
 608         for my $stat (
 609                       'DROP SCHEMA dbic_t_schema_5 CASCADE',
 610                       'DROP SEQUENCE public.artist_artistid_seq CASCADE',
 611                       'DROP SCHEMA dbic_t_schema_4 CASCADE',
 612                       'DROP SCHEMA dbic_t_schema CASCADE',
 613                       'DROP SEQUENCE pkid1_seq CASCADE',
 614                       'DROP SEQUENCE pkid2_seq CASCADE',
 615                       'DROP SEQUENCE nonpkid_seq CASCADE',
 616                       'DROP SCHEMA dbic_t_schema_2 CASCADE',
 617                       'DROP SCHEMA dbic_t_schema_3 CASCADE',
 618                      ) {
 619             eval { $dbh->do ($stat) };
 620             diag $@ if $@ && $warn_exceptions;
 621         }
 622     });
 623 }
 624
 625
 626 ###  auto-pk / last_insert_id / sequence discovery
 627 sub run_apk_tests {
 628     my $schema = shift;
 629
 630     # This is in Core now, but it's here just to test that it doesn't break
 631     $schema->class('Artist')->load_components('PK::Auto');
 632     cmp_ok( $schema->resultset('Artist')->count, '==', 0, 'this should start with an empty artist table');
 633
 634     # test that auto-pk also works with the defined search path by
 635     # un-schema-qualifying the table name
 636     apk_t_set($schema,'artist');
 637
 638     my $unq_new;
 639     lives_ok {
 640         $unq_new = $schema->resultset('Artist')->create({ name => 'baz' });
 641     } 'insert into unqualified, shadowed table succeeds';
 642
 643     is($unq_new && $unq_new->artistid, 1, "and got correct artistid");
 644
 645     my @test_schemas = ( [qw| dbic_t_schema_2    1  |],
 646                          [qw| dbic_t_schema_3    1  |],
 647                          [qw| dbic_t_schema_4    2  |],
 648                          [qw| dbic_t_schema_5    1  |],
 649                        );
 650     foreach my $t ( @test_schemas ) {
 651         my ($sch_name, $start_num) = @$t;
 652         #test with dbic_t_schema_2
 653         apk_t_set($schema,"$sch_name.artist");
 654         my $another_new;
 655         lives_ok {
 656             $another_new = $schema->resultset('Artist')->create({ name => 'Tollbooth Willy'});
 657             is( $another_new->artistid,$start_num, "got correct artistid for $sch_name")
 658                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 659         } "$sch_name liid 1 did not die"
 660             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 661         lives_ok {
 662             $another_new = $schema->resultset('Artist')->create({ name => 'Adam Sandler'});
 663             is( $another_new->artistid,$start_num+1, "got correct artistid for $sch_name")
 664                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 665         } "$sch_name liid 2 did not die"
 666             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 667
 668     }
 669
 670     lives_ok {
 671         apk_t_set($schema,'dbic_t_schema.artist');
 672         my $new = $schema->resultset('Artist')->create({ name => 'foo' });
 673         is($new->artistid, 4, "Auto-PK worked");
 674         $new = $schema->resultset('Artist')->create({ name => 'bar' });
 675         is($new->artistid, 5, "Auto-PK worked");
 676     } 'old auto-pk tests did not die either';
 677 }
 678
 679 # sets the artist table name and clears sequence name cache
 680 sub apk_t_set {
 681     my ( $s, $n ) = @_;
 682     $s->source("Artist")->name($n);
 683     $s->source('Artist')->column_info('artistid')->{sequence} = undef; #< clear sequence name cache
 684 }
 685
 686
 687 ######## EXTENDED AUTO-PK TESTS
 688
 689 my @eapk_id_columns;
 690 BEGIN {
 691   package DBICTest::Schema::ExtAPK;
 692   push @main::test_classes, __PACKAGE__;
 693
 694   use strict;
 695   use warnings;
 696   use base 'DBIx::Class::Core';
 697
 698   __PACKAGE__->table('apk');
 699
 700   @eapk_id_columns = qw( id1 id2 id3 id4 );
 701   __PACKAGE__->add_columns(
 702     map { $_ => { data_type => 'integer', is_auto_increment => 1 } }
 703        @eapk_id_columns
 704   );
 705
 706   __PACKAGE__->set_primary_key('id2'); #< note the SECOND column is
 707                                        #the primary key
 708 }
 709
 710 my @eapk_schemas;
 711 BEGIN{ @eapk_schemas = map "dbic_apk_$_", 0..5 }
 712 my %seqs; #< hash of schema.table.col => currval of its (DBIC) primary key sequence
 713
 714 sub run_extended_apk_tests {
 715   my $schema = shift;
 716
 717   #save the search path and reset it at the end
 718   my $search_path_save = eapk_get_search_path($schema);
 719
 720   eapk_drop_all($schema);
 721   %seqs = ();
 722
 723   # make the test schemas and sequences
 724   $schema->storage->dbh_do(sub {
 725     my ( undef, $dbh ) = @_;
 726
 727     $dbh->do("CREATE SCHEMA $_")
 728         for @eapk_schemas;
 729
 730     $dbh->do("CREATE SEQUENCE $eapk_schemas[5].fooseq");
 731     $dbh->do("SELECT setval('$eapk_schemas[5].fooseq',400)");
 732     $seqs{"$eapk_schemas[1].apk.id2"} = 400;
 733
 734     $dbh->do("CREATE SEQUENCE $eapk_schemas[4].fooseq");
 735     $dbh->do("SELECT setval('$eapk_schemas[4].fooseq',300)");
 736     $seqs{"$eapk_schemas[3].apk.id2"} = 300;
 737
 738     $dbh->do("CREATE SEQUENCE $eapk_schemas[3].fooseq");
 739     $dbh->do("SELECT setval('$eapk_schemas[3].fooseq',200)");
 740     $seqs{"$eapk_schemas[4].apk.id2"} = 200;
 741
 742     $dbh->do("SET search_path = ".join ',', reverse @eapk_schemas );
 743   });
 744
 745   # clear our search_path cache
 746   $schema->storage->{_pg_search_path} = undef;
 747
 748   eapk_create( $schema,
 749                with_search_path => [0,1],
 750              );
 751   eapk_create( $schema,
 752                with_search_path => [1,0,'public'],
 753                nextval => "$eapk_schemas[5].fooseq",
 754              );
 755   eapk_create( $schema,
 756                with_search_path => ['public',0,1],
 757                qualify_table => 2,
 758              );
 759   eapk_create( $schema,
 760                with_search_path => [3,1,0,'public'],
 761                nextval => "$eapk_schemas[4].fooseq",
 762              );
 763   eapk_create( $schema,
 764                with_search_path => [3,1,0,'public'],
 765                nextval => "$eapk_schemas[3].fooseq",
 766                qualify_table => 4,
 767              );
 768
 769   eapk_poke( $schema );
 770   eapk_poke( $schema, 0 );
 771   eapk_poke( $schema, 2 );
 772   eapk_poke( $schema, 4 );
 773   eapk_poke( $schema, 1 );
 774   eapk_poke( $schema, 0 );
 775   eapk_poke( $schema, 1 );
 776   eapk_poke( $schema );
 777   eapk_poke( $schema, 4 );
 778   eapk_poke( $schema, 3 );
 779   eapk_poke( $schema, 1 );
 780   eapk_poke( $schema, 2 );
 781   eapk_poke( $schema, 0 );
 782
 783   # set our search path back
 784   eapk_set_search_path( $schema, @$search_path_save );
 785 }
 786
 787 # do a DBIC create on the apk table in the given schema number (which is an
 788 # index of @eapk_schemas)
 789
 790 sub eapk_poke {
 791   my ($s, $schema_num) = @_;
 792
 793   my $schema_name = defined $schema_num
 794       ? $eapk_schemas[$schema_num]
 795       : '';
 796
 797   my $schema_name_actual = $schema_name || eapk_find_visible_schema($s);
 798
 799   $s->source('ExtAPK')->name($schema_name ? $schema_name.'.apk' : 'apk');
 800   #< clear sequence name cache
 801   $s->source('ExtAPK')->column_info($_)->{sequence} = undef
 802       for @eapk_id_columns;
 803
 804   no warnings 'uninitialized';
 805   lives_ok {
 806     my $new;
 807     for my $inc (1,2,3) {
 808       $new = $schema->resultset('ExtAPK')->create({ id1 => 1});
 809       my $proper_seqval = ++$seqs{"$schema_name_actual.apk.id2"};
 810       is( $new->id2, $proper_seqval, "$schema_name_actual.apk.id2 correct inc $inc" )
 811           or eapk_seq_diag($s,$schema_name);
 812       $new->discard_changes;
 813       is( $new->id1, 1 );
 814       for my $id ('id3','id4') {
 815         my $proper_seqval = ++$seqs{"$schema_name_actual.apk.$id"};
 816         is( $new->$id, $proper_seqval, "$schema_name_actual.apk.$id correct inc $inc" )
 817             or eapk_seq_diag($s,$schema_name);
 818       }
 819     }
 820   } "create in schema '$schema_name' lives"
 821       or eapk_seq_diag($s,$schema_name);
 822 }
 823
 824 # print diagnostic info on which sequences were found in the ExtAPK
 825 # class
 826 sub eapk_seq_diag {
 827     my $s = shift;
 828     my $schema = shift || eapk_find_visible_schema($s);
 829
 830     diag "$schema.apk sequences: ",
 831         join(', ',
 832              map "$_:".($s->source('ExtAPK')->column_info($_)->{sequence} || '<none>'),
 833              @eapk_id_columns
 834             );
 835 }
 836
 837 # get the postgres search path as an arrayref
 838 sub eapk_get_search_path {
 839     my ( $s ) = @_;
 840     # cache the search path as ['schema','schema',...] in the storage
 841     # obj
 842
 843     return $s->storage->dbh_do(sub {
 844         my (undef, $dbh) = @_;
 845         my @search_path;
 846         my ($sp_string) = $dbh->selectrow_array('SHOW search_path');
 847         while ( $sp_string =~ s/("[^"]+"|[^,]+),?// ) {
 848             unless( defined $1 and length $1 ) {
 849                 die "search path sanity check failed: '$1'";
 850             }
 851             push @search_path, $1;
 852         }
 853         \@search_path
 854     });
 855 }
 856 sub eapk_set_search_path {
 857     my ($s,@sp) = @_;
 858     my $sp = join ',',@sp;
 859     $s->storage->dbh_do( sub { $_[1]->do("SET search_path = $sp") } );
 860 }
 861
 862 # create the apk table in the given schema, can set whether the table name is qualified, what the nextval is for the second ID
 863 sub eapk_create {
 864     my ($schema, %a) = @_;
 865
 866     $schema->storage->dbh_do(sub {
 867         my (undef,$dbh) = @_;
 868
 869         my $searchpath_save;
 870         if ( $a{with_search_path} ) {
 871             ($searchpath_save) = $dbh->selectrow_array('SHOW search_path');
 872
 873             my $search_path = join ',',map {/\D/ ? $_ : $eapk_schemas[$_]} @{$a{with_search_path}};
 874
 875             $dbh->do("SET search_path = $search_path");
 876         }
 877
 878         my $table_name = $a{qualify_table}
 879             ? ($eapk_schemas[$a{qualify_table}] || die). ".apk"
 880             : 'apk';
 881         local $_[1]->{Warn} = 0;
 882
 883         my $id_def = $a{nextval}
 884             ? "integer not null default nextval('$a{nextval}'::regclass)"
 885             : 'serial';
 886         $dbh->do(<<EOS);
 887 CREATE TABLE $table_name (
 888   id1 serial
 889   , id2 $id_def
 890   , id3 serial primary key
 891   , id4 serial
 892 )
 893 EOS
 894
 895         if( $searchpath_save ) {
 896             $dbh->do("SET search_path = $searchpath_save");
 897         }
 898     });
 899 }
 900
 901 sub eapk_drop_all {
 902     my ( $schema, $warn_exceptions ) = @_;
 903
 904     $schema->storage->dbh_do(sub {
 905         my (undef,$dbh) = @_;
 906
 907         local $dbh->{Warn} = 0;
 908
 909         # drop the test schemas
 910         for (@eapk_schemas ) {
 911             eval{ $dbh->do("DROP SCHEMA $_ CASCADE") };
 912             diag $@ if $@ && $warn_exceptions;
 913         }
 914
 915
 916     });
 917 }
 918
 919 sub eapk_find_visible_schema {
 920     my ($s) = @_;
 921
 922     my ($schema) =
 923         $s->storage->dbh_do(sub {
 924             $_[1]->selectrow_array(<<EOS);
 925 SELECT n.nspname
 926 FROM pg_catalog.pg_namespace n
 927 JOIN pg_catalog.pg_class c ON c.relnamespace = n.oid
 928 WHERE c.relname = 'apk'
 929   AND pg_catalog.pg_table_is_visible(c.oid)
 930 EOS
 931         });
 932     return $schema;
 933 }