t/72pg.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use Sub::Name;
   7 use DBIx::Class::Optional::Dependencies ();
   8 use lib qw(t/lib);
   9 use DBICTest;
  10
  11 plan skip_all => 'Test needs ' . DBIx::Class::Optional::Dependencies->req_missing_for ('test_rdbms_pg')
  12   unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_rdbms_pg');
  13
  14 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
  15
  16 plan skip_all => <<'EOM' unless $dsn && $user;
  17 Set $ENV{DBICTEST_PG_DSN}, _USER and _PASS to run this test
  18 ( NOTE: This test drops and creates tables called 'artist', 'cd',
  19 'timestamp_primary_key_test', 'track', 'casecheck', 'array_test' and
  20 'sequence_test' as well as following sequences: 'pkid1_seq', 'pkid2_seq' and
  21 'nonpkid_seq'. as well as following schemas: 'dbic_t_schema',
  22 'dbic_t_schema_2', 'dbic_t_schema_3', 'dbic_t_schema_4', and 'dbic_t_schema_5')
  23 EOM
  24
  25 ### load any test classes that are defined further down in the file via BEGIN blocks
  26
  27 our @test_classes; #< array that will be pushed into by test classes defined in this file
  28 DBICTest::Schema->load_classes( map {s/.+:://;$_} @test_classes ) if @test_classes;
  29
  30 ###  pre-connect tests (keep each test separate as to make sure rebless() runs)
  31   {
  32     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  33
  34     ok (!$s->storage->_dbh, 'definitely not connected');
  35
  36     # Check that datetime_parser returns correctly before we explicitly connect.
  37     SKIP: {
  38         skip (
  39           "Pg parser detection test needs " . DBIx::Class::Optional::Dependencies->req_missing_for ('test_dt_pg'),
  40           2
  41         ) unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_dt_pg');
  42
  43         my $store = ref $s->storage;
  44         is($store, 'DBIx::Class::Storage::DBI', 'Started with generic storage');
  45
  46         my $parser = $s->storage->datetime_parser;
  47         is( $parser, 'DateTime::Format::Pg', 'datetime_parser is as expected');
  48     }
  49
  50     ok (!$s->storage->_dbh, 'still not connected');
  51   }
  52
  53   {
  54     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  55     # make sure sqlt_type overrides work (::Storage::DBI::Pg does this)
  56     ok (!$s->storage->_dbh, 'definitely not connected');
  57     is ($s->storage->sqlt_type, 'PostgreSQL', 'sqlt_type correct pre-connection');
  58     ok (!$s->storage->_dbh, 'still not connected');
  59   }
  60
  61 # test LIMIT support
  62 {
  63   my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
  64   drop_test_schema($schema);
  65   create_test_schema($schema);
  66   for (1..6) {
  67     $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
  68   }
  69   my $it = $schema->resultset('Artist')->search( {},
  70     { rows => 3,
  71       offset => 2,
  72       order_by => 'artistid' }
  73   );
  74   is( $it->count, 3, "LIMIT count ok" );  # ask for 3 rows out of 6 artists
  75   is( $it->next->name, "Artist 3", "iterator->next ok" );
  76   $it->next;
  77   $it->next;
  78   $it->next;
  79   is( $it->next, undef, "next past end of resultset ok" );
  80
  81   # Limit with select-lock
  82   lives_ok {
  83     $schema->txn_do (sub {
  84       isa_ok (
  85         $schema->resultset('Artist')->find({artistid => 1}, {for => 'update', rows => 1}),
  86         'DBICTest::Schema::Artist',
  87       );
  88     });
  89   } 'Limited FOR UPDATE select works';
  90 }
  91
  92 # check if we indeed do support stuff
  93 my $test_server_supports_insert_returning = do {
  94
  95   my $si = DBICTest::Schema->connect($dsn, $user, $pass)->storage->_server_info;
  96   die "Unparseable Pg server version: $si->{dbms_version}\n"
  97     unless $si->{normalized_dbms_version};
  98
  99   $si->{normalized_dbms_version} < 8.002 ? 0 : 1;
 100 };
 101 is (
 102   DBICTest::Schema->connect($dsn, $user, $pass)->storage->_use_insert_returning,
 103   $test_server_supports_insert_returning,
 104   'insert returning capability guessed correctly'
 105 );
 106
 107 my $schema;
 108 for my $use_insert_returning ($test_server_supports_insert_returning
 109   ? (0,1)
 110   : (0)
 111 ) {
 112
 113   no warnings qw/once redefine/;
 114   my $old_connection = DBICTest::Schema->can('connection');
 115   local *DBICTest::Schema::connection = subname 'DBICTest::Schema::connection' => sub {
 116     my $s = shift->$old_connection(@_);
 117     $s->storage->_use_insert_returning ($use_insert_returning);
 118     $s;
 119   };
 120
 121 ### test capability override
 122   {
 123     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
 124
 125     ok (!$s->storage->_dbh, 'definitely not connected');
 126
 127     ok (
 128       ! ($s->storage->_use_insert_returning xor $use_insert_returning),
 129       'insert returning capability set correctly',
 130     );
 131     ok (!$s->storage->_dbh, 'still not connected (capability override works)');
 132   }
 133
 134 ### connect, create postgres-specific test schema
 135
 136   $schema = DBICTest::Schema->connect($dsn, $user, $pass);
 137   $schema->storage->ensure_connected;
 138
 139   drop_test_schema($schema);
 140   create_test_schema($schema);
 141
 142 ### begin main tests
 143
 144 # run a BIG bunch of tests for last-insert-id / Auto-PK / sequence
 145 # discovery
 146   run_apk_tests($schema); #< older set of auto-pk tests
 147   run_extended_apk_tests($schema); #< new extended set of auto-pk tests
 148
 149 ### type_info tests
 150
 151   my $test_type_info = {
 152       'artistid' => {
 153           'data_type' => 'integer',
 154           'is_nullable' => 0,
 155           'size' => 4,
 156       },
 157       'name' => {
 158           'data_type' => 'character varying',
 159           'is_nullable' => 1,
 160           'size' => 100,
 161           'default_value' => undef,
 162       },
 163       'rank' => {
 164           'data_type' => 'integer',
 165           'is_nullable' => 0,
 166           'size' => 4,
 167           'default_value' => 13,
 168
 169       },
 170       'charfield' => {
 171           'data_type' => 'character',
 172           'is_nullable' => 1,
 173           'size' => 10,
 174           'default_value' => undef,
 175       },
 176       'arrayfield' => {
 177           'data_type' => 'integer[]',
 178           'is_nullable' => 1,
 179           'size' => undef,
 180           'default_value' => undef,
 181       },
 182   };
 183
 184   my $type_info = $schema->storage->columns_info_for('dbic_t_schema.artist');
 185   my $artistid_defval = delete $type_info->{artistid}->{default_value};
 186   like($artistid_defval,
 187        qr/^nextval\('([^\.]*\.){0,1}artist_artistid_seq'::(?:text|regclass)\)/,
 188        'columns_info_for - sequence matches Pg get_autoinc_seq expectations');
 189   is_deeply($type_info, $test_type_info,
 190             'columns_info_for - column data types');
 191
 192
 193
 194
 195 ####### Array tests
 196
 197   BEGIN {
 198     package DBICTest::Schema::ArrayTest;
 199     push @main::test_classes, __PACKAGE__;
 200
 201     use strict;
 202     use warnings;
 203     use base 'DBICTest::BaseResult';
 204
 205     __PACKAGE__->table('dbic_t_schema.array_test');
 206     __PACKAGE__->add_columns(qw/id arrayfield/);
 207     __PACKAGE__->column_info_from_storage(1);
 208     __PACKAGE__->set_primary_key('id');
 209
 210   }
 211   SKIP: {
 212     skip "Need DBD::Pg 2.9.2 or newer for array tests", 4 if $DBD::Pg::VERSION < 2.009002;
 213
 214     my $arr_rs = $schema->resultset('ArrayTest');
 215
 216     lives_ok {
 217       $arr_rs->create({
 218         arrayfield => [1, 2],
 219       });
 220     } 'inserting arrayref as pg array data';
 221
 222     lives_ok {
 223       $arr_rs->update({
 224         arrayfield => [3, 4],
 225       });
 226     } 'updating arrayref as pg array data';
 227
 228     $arr_rs->create({
 229       arrayfield => [5, 6],
 230     });
 231
 232     lives_ok {
 233       $schema->populate('ArrayTest', [
 234         [ qw/arrayfield/ ],
 235         [ [0,0]          ],
 236       ]);
 237     } 'inserting arrayref using void ctx populate';
 238
 239     # Search using arrays
 240     lives_ok {
 241       is_deeply (
 242         $arr_rs->search({ arrayfield => { -value => [3,4] } })->first->arrayfield,
 243         [3,4],
 244         'Array value matches'
 245       );
 246     } 'searching by arrayref';
 247
 248     lives_ok {
 249       is_deeply (
 250         $arr_rs->search({ arrayfield => { '=' => { -value => [3,4] }} })->first->arrayfield,
 251         [3,4],,
 252         'Array value matches explicit equal'
 253       );
 254     } 'searching by arrayref (explicit equal sign)';
 255
 256     lives_ok {
 257       is_deeply (
 258         $arr_rs->search({ arrayfield => { '>' => { -value => [3,1] }} })->first->arrayfield,
 259         [3,4],
 260         'Array value matches greater than'
 261       );
 262     } 'searching by arrayref (greater than)';
 263
 264     lives_ok {
 265       is (
 266         $arr_rs->search({ arrayfield => { '>' => { -value => [3,7] }} })->count,
 267         1,
 268         'Greater than search found [5,6]',
 269       );
 270     } 'searching by arrayref (greater than)';
 271
 272     # Find using arrays
 273     lives_ok {
 274       is_deeply (
 275         $arr_rs->find({ arrayfield => { -value => [3,4] } })->arrayfield,
 276         [3,4],
 277         'Array value matches implicit equal'
 278       );
 279     } 'find by arrayref';
 280
 281     lives_ok {
 282       is_deeply (
 283         $arr_rs->find({ arrayfield => { '=' => { -value => [3,4] }} })->arrayfield,
 284         [3,4],
 285         'Array value matches explicit equal'
 286       );
 287     } 'find by arrayref (equal)';
 288
 289     # test inferred condition for creation
 290     for my $cond (
 291       { -value => [3,4] },
 292       \[ '= ?' => [arrayfield => [3, 4]] ],
 293     ) {
 294       local $TODO = 'No introspection of complex conditions :(';
 295       my $arr_rs_cond = $arr_rs->search({ arrayfield => $cond });
 296
 297       my $row = $arr_rs_cond->create({});
 298       is_deeply ($row->arrayfield, [3,4], 'Array value taken from $rs condition');
 299       $row->discard_changes;
 300       is_deeply ($row->arrayfield, [3,4], 'Array value made it to storage');
 301     }
 302   }
 303
 304 ########## Case check
 305
 306   BEGIN {
 307     package DBICTest::Schema::Casecheck;
 308     push @main::test_classes, __PACKAGE__;
 309
 310     use strict;
 311     use warnings;
 312     use base 'DBIx::Class::Core';
 313
 314     __PACKAGE__->table('dbic_t_schema.casecheck');
 315     __PACKAGE__->add_columns(qw/id name NAME uc_name/);
 316     __PACKAGE__->column_info_from_storage(1);
 317     __PACKAGE__->set_primary_key('id');
 318   }
 319
 320   my $name_info = $schema->source('Casecheck')->column_info( 'name' );
 321   is( $name_info->{size}, 1, "Case sensitive matching info for 'name'" );
 322
 323   my $NAME_info = $schema->source('Casecheck')->column_info( 'NAME' );
 324   is( $NAME_info->{size}, 2, "Case sensitive matching info for 'NAME'" );
 325
 326   my $uc_name_info = $schema->source('Casecheck')->column_info( 'uc_name' );
 327   is( $uc_name_info->{size}, 3, "Case insensitive matching info for 'uc_name'" );
 328
 329
 330 ## Test ResultSet->update
 331 my $artist = $schema->resultset('Artist')->first;
 332 my $cds = $artist->cds_unordered->search({
 333     year => { '!=' => 2010 }
 334 }, { prefetch => 'liner_notes' });
 335 lives_ok { $cds->update({ year => '2010' }) } 'Update on prefetched rs';
 336
 337 ## Test SELECT ... FOR UPDATE
 338
 339   SKIP: {
 340       if(eval { require Sys::SigAction }) {
 341           Sys::SigAction->import( 'set_sig_handler' );
 342       }
 343       else {
 344         skip "Sys::SigAction is not available", 6;
 345       }
 346
 347       my ($timed_out, $artist2);
 348
 349       for my $t (
 350         {
 351           # Make sure that an error was raised, and that the update failed
 352           update_lock => 1,
 353           test_sub => sub {
 354             ok($timed_out, "update from second schema times out");
 355             ok($artist2->is_column_changed('name'), "'name' column is still dirty from second schema");
 356           },
 357         },
 358         {
 359           # Make sure that an error was NOT raised, and that the update succeeded
 360           update_lock => 0,
 361           test_sub => sub {
 362             ok(! $timed_out, "update from second schema DOES NOT timeout");
 363             ok(! $artist2->is_column_changed('name'), "'name' column is NOT dirty from second schema");
 364           },
 365         },
 366       ) {
 367         # create a new schema
 368         my $schema2 = DBICTest::Schema->connect($dsn, $user, $pass);
 369         $schema2->source("Artist")->name("dbic_t_schema.artist");
 370
 371         $schema->txn_do( sub {
 372           my $rs = $schema->resultset('Artist')->search(
 373               {
 374                   artistid => 1
 375               },
 376               $t->{update_lock} ? { for => 'update' } : {}
 377           );
 378           ok ($rs->count, 'Count works');
 379
 380           my $artist = $rs->next;
 381           is($artist->artistid, 1, "select returns artistid = 1");
 382
 383           $timed_out = 0;
 384           eval {
 385               my $h = set_sig_handler( 'ALRM', sub { die "DBICTestTimeout" } );
 386               alarm(2);
 387               $artist2 = $schema2->resultset('Artist')->find(1);
 388               $artist2->name('fooey');
 389               $artist2->update;
 390               alarm(0);
 391           };
 392           $timed_out = $@ =~ /DBICTestTimeout/;
 393         });
 394
 395         $t->{test_sub}->();
 396       }
 397   }
 398
 399
 400 ######## other older Auto-pk tests
 401
 402   $schema->source("SequenceTest")->name("dbic_t_schema.sequence_test");
 403   for (1..5) {
 404       my $st = $schema->resultset('SequenceTest')->create({ name => 'foo' });
 405       is($st->pkid1, $_, "Auto-PK for sequence without default: First primary key");
 406       is($st->pkid2, $_ + 9, "Auto-PK for sequence without default: Second primary key");
 407       is($st->nonpkid, $_ + 19, "Auto-PK for sequence without default: Non-primary key");
 408   }
 409   my $st = $schema->resultset('SequenceTest')->create({ name => 'foo', pkid1 => 55 });
 410   is($st->pkid1, 55, "Auto-PK for sequence without default: First primary key set manually");
 411
 412
 413 ######## test non-serial auto-pk
 414
 415   if ($schema->storage->_use_insert_returning) {
 416     $schema->source('TimestampPrimaryKey')->name('dbic_t_schema.timestamp_primary_key_test');
 417     my $row = $schema->resultset('TimestampPrimaryKey')->create({});
 418     ok $row->id;
 419   }
 420
 421 ######## test with_deferred_fk_checks
 422
 423   $schema->source('CD')->name('dbic_t_schema.cd');
 424   $schema->source('Track')->name('dbic_t_schema.track');
 425   lives_ok {
 426     $schema->storage->with_deferred_fk_checks(sub {
 427       $schema->resultset('Track')->create({
 428         trackid => 999, cd => 999, position => 1, title => 'deferred FK track'
 429       });
 430       $schema->resultset('CD')->create({
 431         artist => 1, cdid => 999, year => '2003', title => 'deferred FK cd'
 432       });
 433     });
 434   } 'with_deferred_fk_checks code survived';
 435
 436   is eval { $schema->resultset('Track')->find(999)->title }, 'deferred FK track',
 437      'code in with_deferred_fk_checks worked';
 438
 439   throws_ok {
 440     $schema->resultset('Track')->create({
 441       trackid => 1, cd => 9999, position => 1, title => 'Track1'
 442     });
 443   } qr/constraint/i, 'with_deferred_fk_checks is off';
 444 }
 445
 446 done_testing;
 447
 448 END {
 449     return unless $schema;
 450     drop_test_schema($schema);
 451     eapk_drop_all($schema);
 452     undef $schema;
 453 };
 454
 455
 456 ######### SUBROUTINES
 457
 458 sub create_test_schema {
 459     my $schema = shift;
 460     $schema->storage->dbh_do(sub {
 461       my (undef,$dbh) = @_;
 462
 463       local $dbh->{Warn} = 0;
 464
 465       my $std_artist_table = <<EOS;
 466 (
 467   artistid serial PRIMARY KEY
 468   , name VARCHAR(100)
 469   , rank INTEGER NOT NULL DEFAULT '13'
 470   , charfield CHAR(10)
 471   , arrayfield INTEGER[]
 472 )
 473 EOS
 474
 475       $dbh->do("CREATE SCHEMA dbic_t_schema");
 476       $dbh->do("CREATE TABLE dbic_t_schema.artist $std_artist_table");
 477
 478       $dbh->do(<<EOS);
 479 CREATE TABLE dbic_t_schema.timestamp_primary_key_test (
 480   id timestamp default current_timestamp
 481 )
 482 EOS
 483       $dbh->do(<<EOS);
 484 CREATE TABLE dbic_t_schema.cd (
 485   cdid int PRIMARY KEY,
 486   artist int,
 487   title varchar(255),
 488   year varchar(4),
 489   genreid int,
 490   single_track int
 491 )
 492 EOS
 493       $dbh->do(<<EOS);
 494 CREATE TABLE dbic_t_schema.track (
 495   trackid int,
 496   cd int REFERENCES dbic_t_schema.cd(cdid) DEFERRABLE,
 497   position int,
 498   title varchar(255),
 499   last_updated_on date,
 500   last_updated_at date
 501 )
 502 EOS
 503
 504       $dbh->do(<<EOS);
 505 CREATE TABLE dbic_t_schema.sequence_test (
 506     pkid1 integer
 507     , pkid2 integer
 508     , nonpkid integer
 509     , name VARCHAR(100)
 510     , CONSTRAINT pk PRIMARY KEY(pkid1, pkid2)
 511 )
 512 EOS
 513       $dbh->do("CREATE SEQUENCE pkid1_seq START 1 MAXVALUE 999999 MINVALUE 0");
 514       $dbh->do("CREATE SEQUENCE pkid2_seq START 10 MAXVALUE 999999 MINVALUE 0");
 515       $dbh->do("CREATE SEQUENCE nonpkid_seq START 20 MAXVALUE 999999 MINVALUE 0");
 516       $dbh->do(<<EOS);
 517 CREATE TABLE dbic_t_schema.casecheck (
 518     id serial PRIMARY KEY
 519     , "name" VARCHAR(1)
 520     , "NAME" VARCHAR(2)
 521     , "UC_NAME" VARCHAR(3)
 522 )
 523 EOS
 524       $dbh->do(<<EOS);
 525 CREATE TABLE dbic_t_schema.array_test (
 526     id serial PRIMARY KEY
 527     , arrayfield INTEGER[]
 528 )
 529 EOS
 530       $dbh->do("CREATE SCHEMA dbic_t_schema_2");
 531       $dbh->do("CREATE TABLE dbic_t_schema_2.artist $std_artist_table");
 532       $dbh->do("CREATE SCHEMA dbic_t_schema_3");
 533       $dbh->do("CREATE TABLE dbic_t_schema_3.artist $std_artist_table");
 534       $dbh->do('set search_path=dbic_t_schema,public');
 535       $dbh->do("CREATE SCHEMA dbic_t_schema_4");
 536       $dbh->do("CREATE SCHEMA dbic_t_schema_5");
 537       $dbh->do(<<EOS);
 538  CREATE TABLE dbic_t_schema_4.artist
 539  (
 540    artistid integer not null default nextval('artist_artistid_seq'::regclass) PRIMARY KEY
 541    , name VARCHAR(100)
 542    , rank INTEGER NOT NULL DEFAULT '13'
 543    , charfield CHAR(10)
 544    , arrayfield INTEGER[]
 545  );
 546 EOS
 547       $dbh->do('set search_path=public,dbic_t_schema,dbic_t_schema_3');
 548       $dbh->do('create sequence public.artist_artistid_seq'); #< in the public schema
 549       $dbh->do(<<EOS);
 550  CREATE TABLE dbic_t_schema_5.artist
 551  (
 552    artistid integer not null default nextval('public.artist_artistid_seq'::regclass) PRIMARY KEY
 553    , name VARCHAR(100)
 554    , rank INTEGER NOT NULL DEFAULT '13'
 555    , charfield CHAR(10)
 556    , arrayfield INTEGER[]
 557  );
 558 EOS
 559       $dbh->do('set search_path=dbic_t_schema,public');
 560   });
 561 }
 562
 563
 564
 565 sub drop_test_schema {
 566     my ( $schema, $warn_exceptions ) = @_;
 567
 568     $schema->storage->dbh_do(sub {
 569         my (undef,$dbh) = @_;
 570
 571         local $dbh->{Warn} = 0;
 572
 573         for my $stat (
 574                       'DROP SCHEMA dbic_t_schema_5 CASCADE',
 575                       'DROP SEQUENCE public.artist_artistid_seq CASCADE',
 576                       'DROP SCHEMA dbic_t_schema_4 CASCADE',
 577                       'DROP SCHEMA dbic_t_schema CASCADE',
 578                       'DROP SEQUENCE pkid1_seq CASCADE',
 579                       'DROP SEQUENCE pkid2_seq CASCADE',
 580                       'DROP SEQUENCE nonpkid_seq CASCADE',
 581                       'DROP SCHEMA dbic_t_schema_2 CASCADE',
 582                       'DROP SCHEMA dbic_t_schema_3 CASCADE',
 583                      ) {
 584             eval { $dbh->do ($stat) };
 585             diag $@ if $@ && $warn_exceptions;
 586         }
 587     });
 588 }
 589
 590
 591 ###  auto-pk / last_insert_id / sequence discovery
 592 sub run_apk_tests {
 593     my $schema = shift;
 594
 595     # This is in Core now, but it's here just to test that it doesn't break
 596     $schema->class('Artist')->load_components('PK::Auto');
 597     cmp_ok( $schema->resultset('Artist')->count, '==', 0, 'this should start with an empty artist table');
 598
 599     # test that auto-pk also works with the defined search path by
 600     # un-schema-qualifying the table name
 601     apk_t_set($schema,'artist');
 602
 603     my $unq_new;
 604     lives_ok {
 605         $unq_new = $schema->resultset('Artist')->create({ name => 'baz' });
 606     } 'insert into unqualified, shadowed table succeeds';
 607
 608     is($unq_new && $unq_new->artistid, 1, "and got correct artistid");
 609
 610     my @test_schemas = ( [qw| dbic_t_schema_2    1  |],
 611                          [qw| dbic_t_schema_3    1  |],
 612                          [qw| dbic_t_schema_4    2  |],
 613                          [qw| dbic_t_schema_5    1  |],
 614                        );
 615     foreach my $t ( @test_schemas ) {
 616         my ($sch_name, $start_num) = @$t;
 617         #test with dbic_t_schema_2
 618         apk_t_set($schema,"$sch_name.artist");
 619         my $another_new;
 620         lives_ok {
 621             $another_new = $schema->resultset('Artist')->create({ name => 'Tollbooth Willy'});
 622             is( $another_new->artistid,$start_num, "got correct artistid for $sch_name")
 623                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 624         } "$sch_name liid 1 did not die"
 625             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 626         lives_ok {
 627             $another_new = $schema->resultset('Artist')->create({ name => 'Adam Sandler'});
 628             is( $another_new->artistid,$start_num+1, "got correct artistid for $sch_name")
 629                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 630         } "$sch_name liid 2 did not die"
 631             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 632
 633     }
 634
 635     lives_ok {
 636         apk_t_set($schema,'dbic_t_schema.artist');
 637         my $new = $schema->resultset('Artist')->create({ name => 'foo' });
 638         is($new->artistid, 4, "Auto-PK worked");
 639         $new = $schema->resultset('Artist')->create({ name => 'bar' });
 640         is($new->artistid, 5, "Auto-PK worked");
 641     } 'old auto-pk tests did not die either';
 642 }
 643
 644 # sets the artist table name and clears sequence name cache
 645 sub apk_t_set {
 646     my ( $s, $n ) = @_;
 647     $s->source("Artist")->name($n);
 648     $s->source('Artist')->column_info('artistid')->{sequence} = undef; #< clear sequence name cache
 649 }
 650
 651
 652 ######## EXTENDED AUTO-PK TESTS
 653
 654 my @eapk_id_columns;
 655 BEGIN {
 656   package DBICTest::Schema::ExtAPK;
 657   push @main::test_classes, __PACKAGE__;
 658
 659   use strict;
 660   use warnings;
 661   use base 'DBIx::Class::Core';
 662
 663   __PACKAGE__->table('apk');
 664
 665   @eapk_id_columns = qw( id1 id2 id3 id4 );
 666   __PACKAGE__->add_columns(
 667     map { $_ => { data_type => 'integer', is_auto_increment => 1 } }
 668        @eapk_id_columns
 669   );
 670
 671   __PACKAGE__->set_primary_key('id2'); #< note the SECOND column is
 672                                        #the primary key
 673 }
 674
 675 my @eapk_schemas;
 676 BEGIN{ @eapk_schemas = map "dbic_apk_$_", 0..5 }
 677 my %seqs; #< hash of schema.table.col => currval of its (DBIC) primary key sequence
 678
 679 sub run_extended_apk_tests {
 680   my $schema = shift;
 681
 682   #save the search path and reset it at the end
 683   my $search_path_save = eapk_get_search_path($schema);
 684
 685   eapk_drop_all($schema);
 686   %seqs = ();
 687
 688   # make the test schemas and sequences
 689   $schema->storage->dbh_do(sub {
 690     my ( undef, $dbh ) = @_;
 691
 692     $dbh->do("CREATE SCHEMA $_")
 693         for @eapk_schemas;
 694
 695     $dbh->do("CREATE SEQUENCE $eapk_schemas[5].fooseq");
 696     $dbh->do("SELECT setval('$eapk_schemas[5].fooseq',400)");
 697     $seqs{"$eapk_schemas[1].apk.id2"} = 400;
 698
 699     $dbh->do("CREATE SEQUENCE $eapk_schemas[4].fooseq");
 700     $dbh->do("SELECT setval('$eapk_schemas[4].fooseq',300)");
 701     $seqs{"$eapk_schemas[3].apk.id2"} = 300;
 702
 703     $dbh->do("CREATE SEQUENCE $eapk_schemas[3].fooseq");
 704     $dbh->do("SELECT setval('$eapk_schemas[3].fooseq',200)");
 705     $seqs{"$eapk_schemas[4].apk.id2"} = 200;
 706
 707     $dbh->do("SET search_path = ".join ',', reverse @eapk_schemas );
 708   });
 709
 710   # clear our search_path cache
 711   $schema->storage->{_pg_search_path} = undef;
 712
 713   eapk_create( $schema,
 714                with_search_path => [0,1],
 715              );
 716   eapk_create( $schema,
 717                with_search_path => [1,0,'public'],
 718                nextval => "$eapk_schemas[5].fooseq",
 719              );
 720   eapk_create( $schema,
 721                with_search_path => ['public',0,1],
 722                qualify_table => 2,
 723              );
 724   eapk_create( $schema,
 725                with_search_path => [3,1,0,'public'],
 726                nextval => "$eapk_schemas[4].fooseq",
 727              );
 728   eapk_create( $schema,
 729                with_search_path => [3,1,0,'public'],
 730                nextval => "$eapk_schemas[3].fooseq",
 731                qualify_table => 4,
 732              );
 733
 734   eapk_poke( $schema );
 735   eapk_poke( $schema, 0 );
 736   eapk_poke( $schema, 2 );
 737   eapk_poke( $schema, 4 );
 738   eapk_poke( $schema, 1 );
 739   eapk_poke( $schema, 0 );
 740   eapk_poke( $schema, 1 );
 741   eapk_poke( $schema );
 742   eapk_poke( $schema, 4 );
 743   eapk_poke( $schema, 3 );
 744   eapk_poke( $schema, 1 );
 745   eapk_poke( $schema, 2 );
 746   eapk_poke( $schema, 0 );
 747
 748   # set our search path back
 749   eapk_set_search_path( $schema, @$search_path_save );
 750 }
 751
 752 # do a DBIC create on the apk table in the given schema number (which is an
 753 # index of @eapk_schemas)
 754
 755 sub eapk_poke {
 756   my ($s, $schema_num) = @_;
 757
 758   my $schema_name = defined $schema_num
 759       ? $eapk_schemas[$schema_num]
 760       : '';
 761
 762   my $schema_name_actual = $schema_name || eapk_find_visible_schema($s);
 763
 764   $s->source('ExtAPK')->name($schema_name ? $schema_name.'.apk' : 'apk');
 765   #< clear sequence name cache
 766   $s->source('ExtAPK')->column_info($_)->{sequence} = undef
 767       for @eapk_id_columns;
 768
 769   no warnings 'uninitialized';
 770   lives_ok {
 771     my $new;
 772     for my $inc (1,2,3) {
 773       $new = $schema->resultset('ExtAPK')->create({ id1 => 1});
 774       my $proper_seqval = ++$seqs{"$schema_name_actual.apk.id2"};
 775       is( $new->id2, $proper_seqval, "$schema_name_actual.apk.id2 correct inc $inc" )
 776           or eapk_seq_diag($s,$schema_name);
 777       $new->discard_changes;
 778       is( $new->id1, 1 );
 779       for my $id ('id3','id4') {
 780         my $proper_seqval = ++$seqs{"$schema_name_actual.apk.$id"};
 781         is( $new->$id, $proper_seqval, "$schema_name_actual.apk.$id correct inc $inc" )
 782             or eapk_seq_diag($s,$schema_name);
 783       }
 784     }
 785   } "create in schema '$schema_name' lives"
 786       or eapk_seq_diag($s,$schema_name);
 787 }
 788
 789 # print diagnostic info on which sequences were found in the ExtAPK
 790 # class
 791 sub eapk_seq_diag {
 792     my $s = shift;
 793     my $schema = shift || eapk_find_visible_schema($s);
 794
 795     diag "$schema.apk sequences: ",
 796         join(', ',
 797              map "$_:".($s->source('ExtAPK')->column_info($_)->{sequence} || '<none>'),
 798              @eapk_id_columns
 799             );
 800 }
 801
 802 # get the postgres search path as an arrayref
 803 sub eapk_get_search_path {
 804     my ( $s ) = @_;
 805     # cache the search path as ['schema','schema',...] in the storage
 806     # obj
 807
 808     return $s->storage->dbh_do(sub {
 809         my (undef, $dbh) = @_;
 810         my @search_path;
 811         my ($sp_string) = $dbh->selectrow_array('SHOW search_path');
 812         while ( $sp_string =~ s/("[^"]+"|[^,]+),?// ) {
 813             unless( defined $1 and length $1 ) {
 814                 die "search path sanity check failed: '$1'";
 815             }
 816             push @search_path, $1;
 817         }
 818         \@search_path
 819     });
 820 }
 821 sub eapk_set_search_path {
 822     my ($s,@sp) = @_;
 823     my $sp = join ',',@sp;
 824     $s->storage->dbh_do( sub { $_[1]->do("SET search_path = $sp") } );
 825 }
 826
 827 # create the apk table in the given schema, can set whether the table name is qualified, what the nextval is for the second ID
 828 sub eapk_create {
 829     my ($schema, %a) = @_;
 830
 831     $schema->storage->dbh_do(sub {
 832         my (undef,$dbh) = @_;
 833
 834         my $searchpath_save;
 835         if ( $a{with_search_path} ) {
 836             ($searchpath_save) = $dbh->selectrow_array('SHOW search_path');
 837
 838             my $search_path = join ',',map {/\D/ ? $_ : $eapk_schemas[$_]} @{$a{with_search_path}};
 839
 840             $dbh->do("SET search_path = $search_path");
 841         }
 842
 843         my $table_name = $a{qualify_table}
 844             ? ($eapk_schemas[$a{qualify_table}] || die). ".apk"
 845             : 'apk';
 846         local $_[1]->{Warn} = 0;
 847
 848         my $id_def = $a{nextval}
 849             ? "integer not null default nextval('$a{nextval}'::regclass)"
 850             : 'serial';
 851         $dbh->do(<<EOS);
 852 CREATE TABLE $table_name (
 853   id1 serial
 854   , id2 $id_def
 855   , id3 serial primary key
 856   , id4 serial
 857 )
 858 EOS
 859
 860         if( $searchpath_save ) {
 861             $dbh->do("SET search_path = $searchpath_save");
 862         }
 863     });
 864 }
 865
 866 sub eapk_drop_all {
 867     my ( $schema, $warn_exceptions ) = @_;
 868
 869     $schema->storage->dbh_do(sub {
 870         my (undef,$dbh) = @_;
 871
 872         local $dbh->{Warn} = 0;
 873
 874         # drop the test schemas
 875         for (@eapk_schemas ) {
 876             eval{ $dbh->do("DROP SCHEMA $_ CASCADE") };
 877             diag $@ if $@ && $warn_exceptions;
 878         }
 879
 880
 881     });
 882 }
 883
 884 sub eapk_find_visible_schema {
 885     my ($s) = @_;
 886
 887     my ($schema) =
 888         $s->storage->dbh_do(sub {
 889             $_[1]->selectrow_array(<<EOS);
 890 SELECT n.nspname
 891 FROM pg_catalog.pg_namespace n
 892 JOIN pg_catalog.pg_class c ON c.relnamespace = n.oid
 893 WHERE c.relname = 'apk'
 894   AND pg_catalog.pg_table_is_visible(c.oid)
 895 EOS
 896         });
 897     return $schema;
 898 }