t/72pg.t

   1 use DBIx::Class::Optional::Dependencies -skip_all_without => 'test_rdbms_pg';
   2
   3 use strict;
   4 use warnings;
   5
   6 use Test::More;
   7 use Test::Exception;
   8 use Sub::Name;
   9 use Config;
  10 use DBIx::Class::Optional::Dependencies ();
  11 use lib qw(t/lib);
  12 use DBICTest;
  13 use SQL::Abstract 'is_literal_value';
  14 use DBIx::Class::_Util 'is_exception';
  15
  16 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
  17
  18 ### load any test classes that are defined further down in the file via BEGIN blocks
  19 our @test_classes; #< array that will be pushed into by test classes defined in this file
  20 DBICTest::Schema->load_classes( map {s/.+:://;$_} @test_classes ) if @test_classes;
  21
  22 ###  pre-connect tests (keep each test separate as to make sure rebless() runs)
  23   {
  24     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  25
  26     ok (!$s->storage->_dbh, 'definitely not connected');
  27
  28     # Check that datetime_parser returns correctly before we explicitly connect.
  29     SKIP: {
  30         skip (
  31           "Pg parser detection test needs " . DBIx::Class::Optional::Dependencies->req_missing_for ('test_dt_pg'),
  32           2
  33         ) unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_dt_pg');
  34
  35         my $store = ref $s->storage;
  36         is($store, 'DBIx::Class::Storage::DBI', 'Started with generic storage');
  37
  38         my $parser = $s->storage->datetime_parser;
  39         is( $parser, 'DateTime::Format::Pg', 'datetime_parser is as expected');
  40     }
  41
  42     ok (!$s->storage->_dbh, 'still not connected');
  43   }
  44
  45   {
  46     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  47     # make sure sqlt_type overrides work (::Storage::DBI::Pg does this)
  48     ok (!$s->storage->_dbh, 'definitely not connected');
  49     is ($s->storage->sqlt_type, 'PostgreSQL', 'sqlt_type correct pre-connection');
  50     ok (!$s->storage->_dbh, 'still not connected');
  51   }
  52
  53 # test LIMIT support
  54 {
  55   my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
  56   drop_test_schema($schema);
  57   create_test_schema($schema);
  58   for (1..6) {
  59     $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
  60   }
  61   my $it = $schema->resultset('Artist')->search( {},
  62     { rows => 3,
  63       offset => 2,
  64       order_by => 'artistid' }
  65   );
  66   is( $it->count, 3, "LIMIT count ok" );  # ask for 3 rows out of 6 artists
  67   is( $it->next->name, "Artist 3", "iterator->next ok" );
  68   $it->next;
  69   $it->next;
  70   $it->next;
  71   is( $it->next, undef, "next past end of resultset ok" );
  72
  73   # Limit with select-lock
  74   lives_ok {
  75     $schema->txn_do (sub {
  76       isa_ok (
  77         $schema->resultset('Artist')->find({artistid => 1}, {for => 'update', rows => 1}),
  78         'DBICTest::Schema::Artist',
  79       );
  80     });
  81   } 'Limited FOR UPDATE select works';
  82 }
  83
  84 # check if we indeed do support stuff
  85 my $test_server_supports_insert_returning = do {
  86
  87   my $si = DBICTest::Schema->connect($dsn, $user, $pass)->storage->_server_info;
  88   die "Unparseable Pg server version: $si->{dbms_version}\n"
  89     unless $si->{normalized_dbms_version};
  90
  91   $si->{normalized_dbms_version} < 8.002 ? 0 : 1;
  92 };
  93 is (
  94   DBICTest::Schema->connect($dsn, $user, $pass)->storage->_use_insert_returning,
  95   $test_server_supports_insert_returning,
  96   'insert returning capability guessed correctly'
  97 );
  98
  99 my $schema;
 100 for my $use_insert_returning ($test_server_supports_insert_returning
 101   ? (0,1)
 102   : (0)
 103 ) {
 104
 105   no warnings qw/once redefine/;
 106   my $old_connection = DBICTest::Schema->can('connection');
 107   local *DBICTest::Schema::connection = subname 'DBICTest::Schema::connection' => sub {
 108     my $s = shift->$old_connection(@_);
 109     $s->storage->_use_insert_returning ($use_insert_returning);
 110     $s;
 111   };
 112
 113 ### test capability override
 114   {
 115     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
 116
 117     ok (!$s->storage->_dbh, 'definitely not connected');
 118
 119     ok (
 120       ! ($s->storage->_use_insert_returning xor $use_insert_returning),
 121       'insert returning capability set correctly',
 122     );
 123     ok (!$s->storage->_dbh, 'still not connected (capability override works)');
 124   }
 125
 126 ### connect, create postgres-specific test schema
 127
 128   $schema = DBICTest::Schema->connect($dsn, $user, $pass);
 129   $schema->storage->ensure_connected;
 130
 131   drop_test_schema($schema);
 132   create_test_schema($schema);
 133
 134 ### begin main tests
 135
 136 # run a BIG bunch of tests for last-insert-id / Auto-PK / sequence
 137 # discovery
 138   run_apk_tests($schema); #< older set of auto-pk tests
 139   run_extended_apk_tests($schema); #< new extended set of auto-pk tests
 140
 141
 142 ######## test the pg-specific syntax from https://rt.cpan.org/Ticket/Display.html?id=99503
 143   lives_ok {
 144     is(
 145       $schema->resultset('Artist')->search({ artistid => { -in => \ '(select 4) union (select 5)' } })->count,
 146       2,
 147       'Two expected artists found on subselect union within IN',
 148     );
 149   };
 150
 151 ### type_info tests
 152
 153   my $test_type_info = {
 154       'artistid' => {
 155           'data_type' => 'integer',
 156           'is_nullable' => 0,
 157           'size' => 4,
 158       },
 159       'name' => {
 160           'data_type' => 'character varying',
 161           'is_nullable' => 1,
 162           'size' => 100,
 163           'default_value' => undef,
 164       },
 165       'rank' => {
 166           'data_type' => 'integer',
 167           'is_nullable' => 0,
 168           'size' => 4,
 169           'default_value' => 13,
 170
 171       },
 172       'charfield' => {
 173           'data_type' => 'character',
 174           'is_nullable' => 1,
 175           'size' => 10,
 176           'default_value' => undef,
 177       },
 178       'arrayfield' => {
 179           'data_type' => 'integer[]',
 180           'is_nullable' => 1,
 181           'size' => undef,
 182           'default_value' => undef,
 183       },
 184   };
 185
 186   my $type_info = $schema->storage->columns_info_for('dbic_t_schema.artist');
 187   my $artistid_defval = delete $type_info->{artistid}->{default_value};
 188
 189   # The curor info is too radically different from what is in the column_info
 190   # call - just punt it (DBD::SQLite tests the codepath plenty enough)
 191   unless (DBIx::Class::_ENV_::STRESSTEST_COLUMN_INFO_UNAWARE_STORAGE) {
 192     like(
 193       $artistid_defval,
 194       qr/^nextval\('([^\.]*\.){0,1}artist_artistid_seq'::(?:text|regclass)\)/,
 195       'columns_info_for - sequence matches Pg get_autoinc_seq expectations'
 196     );
 197
 198     is_deeply($type_info, $test_type_info,
 199             'columns_info_for - column data types');
 200   }
 201
 202 ####### Array tests
 203
 204   BEGIN {
 205     package DBICTest::Schema::ArrayTest;
 206     push @main::test_classes, __PACKAGE__;
 207
 208     use strict;
 209     use warnings;
 210     use base 'DBICTest::BaseResult';
 211
 212     __PACKAGE__->table('dbic_t_schema.array_test');
 213     __PACKAGE__->add_columns(qw/id arrayfield/);
 214     __PACKAGE__->column_info_from_storage(1);
 215     __PACKAGE__->set_primary_key('id');
 216
 217   }
 218   SKIP: {
 219     skip "Need DBD::Pg 2.9.2 or newer for array tests", 4 if $DBD::Pg::VERSION < 2.009002;
 220
 221     my $arr_rs = $schema->resultset('ArrayTest');
 222
 223     lives_ok {
 224       $arr_rs->create({
 225         arrayfield => [1, 2],
 226       });
 227     } 'inserting arrayref as pg array data';
 228
 229     lives_ok {
 230       $arr_rs->update({
 231         arrayfield => [3, 4],
 232       });
 233     } 'updating arrayref as pg array data';
 234
 235     $arr_rs->create({
 236       arrayfield => [5, 6],
 237     });
 238
 239     lives_ok {
 240       $schema->populate('ArrayTest', [
 241         [ qw/arrayfield/ ],
 242         [ [0,0]          ],
 243       ]);
 244     } 'inserting arrayref using void ctx populate';
 245
 246     # Search using arrays
 247     lives_ok {
 248       is_deeply (
 249         $arr_rs->search({ arrayfield => { -value => [3,4] } })->first->arrayfield,
 250         [3,4],
 251         'Array value matches'
 252       );
 253     } 'searching by arrayref';
 254
 255     lives_ok {
 256       is_deeply (
 257         $arr_rs->search({ arrayfield => { '=' => { -value => [3,4] }} })->first->arrayfield,
 258         [3,4],
 259         'Array value matches explicit equal'
 260       );
 261     } 'searching by arrayref (explicit equal sign)';
 262
 263     lives_ok {
 264       is_deeply (
 265         $arr_rs->search({ arrayfield => { '>' => { -value => [3,1] }} })->first->arrayfield,
 266         [3,4],
 267         'Array value matches greater than'
 268       );
 269     } 'searching by arrayref (greater than)';
 270
 271     lives_ok {
 272       is (
 273         $arr_rs->search({ arrayfield => { '>' => { -value => [3,7] }} })->count,
 274         1,
 275         'Greater than search found [5,6]',
 276       );
 277     } 'searching by arrayref (greater than)';
 278
 279     # Find using arrays
 280     lives_ok {
 281       is_deeply (
 282         $arr_rs->find({ arrayfield => { -value => [3,4] } })->arrayfield,
 283         [3,4],
 284         'Array value matches implicit equal'
 285       );
 286     } 'find by arrayref';
 287
 288     lives_ok {
 289       is_deeply (
 290         $arr_rs->find({ arrayfield => { '=' => { -value => [3,4] }} })->arrayfield,
 291         [3,4],
 292         'Array value matches explicit equal'
 293       );
 294     } 'find by arrayref (equal)';
 295
 296     # test inferred condition for creation
 297     for my $cond (
 298       { -value => [3,4] },
 299       \[ '= ?' => [arrayfield => [3, 4]] ],
 300     ) {
 301       local $TODO = 'No introspection of complex literal conditions :('
 302         if is_literal_value $cond;
 303
 304
 305       my $arr_rs_cond = $arr_rs->search({ arrayfield => $cond });
 306
 307       my $row = $arr_rs_cond->create({});
 308       is_deeply ($row->arrayfield, [3,4], 'Array value taken from $rs condition');
 309       $row->discard_changes;
 310       is_deeply ($row->arrayfield, [3,4], 'Array value made it to storage');
 311     }
 312   }
 313
 314 ########## Case check
 315
 316   BEGIN {
 317     package DBICTest::Schema::Casecheck;
 318     push @main::test_classes, __PACKAGE__;
 319
 320     use strict;
 321     use warnings;
 322     use base 'DBIx::Class::Core';
 323
 324     __PACKAGE__->table('dbic_t_schema.casecheck');
 325     __PACKAGE__->add_columns(qw/id name NAME uc_name/);
 326     __PACKAGE__->column_info_from_storage(1);
 327     __PACKAGE__->set_primary_key('id');
 328   }
 329
 330   my $name_info = $schema->source('Casecheck')->column_info( 'name' );
 331   is( $name_info->{size}, 1, "Case sensitive matching info for 'name'" );
 332
 333   my $NAME_info = $schema->source('Casecheck')->column_info( 'NAME' );
 334   is( $NAME_info->{size}, 2, "Case sensitive matching info for 'NAME'" );
 335
 336   my $uc_name_info = $schema->source('Casecheck')->column_info( 'uc_name' );
 337   is( $uc_name_info->{size}, 3, "Case insensitive matching info for 'uc_name'" );
 338
 339
 340 ## Test ResultSet->update
 341 my $artist = $schema->resultset('Artist')->first;
 342 my $cds = $artist->cds_unordered->search({
 343     year => { '!=' => 2010 }
 344 }, { prefetch => 'liner_notes' });
 345 lives_ok { $cds->update({ year => '2010' }) } 'Update on prefetched rs';
 346
 347 ## Test SELECT ... FOR UPDATE
 348   SKIP: {
 349       skip "Your system does not support unsafe signals (d_sigaction) - unable to run deadlock test", 1
 350         unless eval { $Config{d_sigaction} and require POSIX };
 351
 352       my ($timed_out, $artist2);
 353
 354       for my $t (
 355         {
 356           # Make sure that an error was raised, and that the update failed
 357           update_lock => 1,
 358           test_sub => sub {
 359             ok($timed_out, "update from second schema times out");
 360             ok($artist2->is_column_changed('name'), "'name' column is still dirty from second schema");
 361           },
 362         },
 363         {
 364           # Make sure that an error was NOT raised, and that the update succeeded
 365           update_lock => 0,
 366           test_sub => sub {
 367             ok(! $timed_out, "update from second schema DOES NOT timeout");
 368             ok(! $artist2->is_column_changed('name'), "'name' column is NOT dirty from second schema");
 369           },
 370         },
 371       ) {
 372         # create a new schema
 373         my $schema2 = DBICTest::Schema->connect($dsn, $user, $pass);
 374         $schema2->source("Artist")->name("dbic_t_schema.artist");
 375
 376         $schema->txn_do( sub {
 377           my $rs = $schema->resultset('Artist')->search(
 378               {
 379                   artistid => 1
 380               },
 381               $t->{update_lock} ? { for => 'update' } : {}
 382           );
 383           ok ($rs->count, 'Count works');
 384
 385           my $artist = $rs->next;
 386           is($artist->artistid, 1, "select returns artistid = 1");
 387
 388           $timed_out = 0;
 389
 390           eval {
 391               # can not use %SIG assignment directly - we need sigaction below
 392               # localization to a block still works however
 393               local $SIG{ALRM};
 394
 395               POSIX::sigaction( POSIX::SIGALRM() => POSIX::SigAction->new(
 396                 sub { die "DBICTestTimeout" },
 397               ));
 398
 399               $artist2 = $schema2->resultset('Artist')->find(1);
 400               $artist2->name('fooey');
 401
 402               # FIXME - this needs to go away in lieu of a non-retrying runner
 403               # ( i.e. after solving RT#47005 )
 404               local *DBIx::Class::Storage::DBI::_ping = sub { 1 }, DBIx::Class::_ENV_::OLD_MRO && Class::C3->reinitialize()
 405                 if DBIx::Class::_Util::modver_gt_or_eq( 'DBD::Pg' => '3.5.0' );
 406
 407               alarm(1);
 408               $artist2->update;
 409           };
 410
 411           alarm(0);
 412
 413           if (is_exception($@)) {
 414             $timed_out = $@ =~ /DBICTestTimeout/
 415               or die $@;
 416           }
 417         });
 418
 419         $t->{test_sub}->();
 420       }
 421   }
 422
 423
 424 ######## other older Auto-pk tests
 425
 426   $schema->source("SequenceTest")->name("dbic_t_schema.sequence_test");
 427   for (1..5) {
 428       my $st = $schema->resultset('SequenceTest')->create({ name => 'foo' });
 429       is($st->pkid1, $_, "Auto-PK for sequence without default: First primary key");
 430       is($st->pkid2, $_ + 9, "Auto-PK for sequence without default: Second primary key");
 431       is($st->nonpkid, $_ + 19, "Auto-PK for sequence without default: Non-primary key");
 432   }
 433   my $st = $schema->resultset('SequenceTest')->create({ name => 'foo', pkid1 => 55 });
 434   is($st->pkid1, 55, "Auto-PK for sequence without default: First primary key set manually");
 435
 436
 437 ######## test non-serial auto-pk
 438
 439   if ($schema->storage->_use_insert_returning) {
 440     $schema->source('TimestampPrimaryKey')->name('dbic_t_schema.timestamp_primary_key_test');
 441     my $row = $schema->resultset('TimestampPrimaryKey')->create({});
 442     ok $row->id;
 443   }
 444
 445 ######## test with_deferred_fk_checks
 446
 447   $schema->source('CD')->name('dbic_t_schema.cd');
 448   $schema->source('Track')->name('dbic_t_schema.track');
 449   lives_ok {
 450     $schema->storage->with_deferred_fk_checks(sub {
 451       $schema->resultset('Track')->create({
 452         trackid => 999, cd => 999, position => 1, title => 'deferred FK track'
 453       });
 454       $schema->resultset('CD')->create({
 455         artist => 1, cdid => 999, year => '2003', title => 'deferred FK cd'
 456       });
 457     });
 458   } 'with_deferred_fk_checks code survived';
 459
 460   is eval { $schema->resultset('Track')->find(999)->title }, 'deferred FK track',
 461      'code in with_deferred_fk_checks worked';
 462
 463   throws_ok {
 464     $schema->resultset('Track')->create({
 465       trackid => 1, cd => 9999, position => 1, title => 'Track1'
 466     });
 467   } qr/constraint/i, 'with_deferred_fk_checks is off';
 468 }
 469
 470 done_testing;
 471
 472 END {
 473     return unless $schema;
 474     drop_test_schema($schema);
 475     eapk_drop_all($schema);
 476     undef $schema;
 477 };
 478
 479
 480 ######### SUBROUTINES
 481
 482 sub create_test_schema {
 483     my $schema = shift;
 484     $schema->storage->dbh_do(sub {
 485       my (undef,$dbh) = @_;
 486
 487       local $dbh->{Warn} = 0;
 488
 489       my $std_artist_table = <<EOS;
 490 (
 491   artistid serial PRIMARY KEY
 492   , name VARCHAR(100)
 493   , rank INTEGER NOT NULL DEFAULT '13'
 494   , charfield CHAR(10)
 495   , arrayfield INTEGER[]
 496 )
 497 EOS
 498
 499       $dbh->do("CREATE SCHEMA dbic_t_schema");
 500       $dbh->do("CREATE TABLE dbic_t_schema.artist $std_artist_table");
 501
 502       $dbh->do(<<EOS);
 503 CREATE TABLE dbic_t_schema.timestamp_primary_key_test (
 504   id timestamp default current_timestamp
 505 )
 506 EOS
 507       $dbh->do(<<EOS);
 508 CREATE TABLE dbic_t_schema.cd (
 509   cdid int PRIMARY KEY,
 510   artist int,
 511   title varchar(255),
 512   year varchar(4),
 513   genreid int,
 514   single_track int
 515 )
 516 EOS
 517       $dbh->do(<<EOS);
 518 CREATE TABLE dbic_t_schema.track (
 519   trackid int,
 520   cd int REFERENCES dbic_t_schema.cd(cdid) DEFERRABLE,
 521   position int,
 522   title varchar(255),
 523   last_updated_on date,
 524   last_updated_at date
 525 )
 526 EOS
 527
 528       $dbh->do(<<EOS);
 529 CREATE TABLE dbic_t_schema.sequence_test (
 530     pkid1 integer
 531     , pkid2 integer
 532     , nonpkid integer
 533     , name VARCHAR(100)
 534     , CONSTRAINT pk PRIMARY KEY(pkid1, pkid2)
 535 )
 536 EOS
 537       $dbh->do("CREATE SEQUENCE pkid1_seq START 1 MAXVALUE 999999 MINVALUE 0");
 538       $dbh->do("CREATE SEQUENCE pkid2_seq START 10 MAXVALUE 999999 MINVALUE 0");
 539       $dbh->do("CREATE SEQUENCE nonpkid_seq START 20 MAXVALUE 999999 MINVALUE 0");
 540       $dbh->do(<<EOS);
 541 CREATE TABLE dbic_t_schema.casecheck (
 542     id serial PRIMARY KEY
 543     , "name" VARCHAR(1)
 544     , "NAME" VARCHAR(2)
 545     , "UC_NAME" VARCHAR(3)
 546 )
 547 EOS
 548       $dbh->do(<<EOS);
 549 CREATE TABLE dbic_t_schema.array_test (
 550     id serial PRIMARY KEY
 551     , arrayfield INTEGER[]
 552 )
 553 EOS
 554       $dbh->do("CREATE SCHEMA dbic_t_schema_2");
 555       $dbh->do("CREATE TABLE dbic_t_schema_2.artist $std_artist_table");
 556       $dbh->do("CREATE SCHEMA dbic_t_schema_3");
 557       $dbh->do("CREATE TABLE dbic_t_schema_3.artist $std_artist_table");
 558       $dbh->do('set search_path=dbic_t_schema,public');
 559       $dbh->do("CREATE SCHEMA dbic_t_schema_4");
 560       $dbh->do("CREATE SCHEMA dbic_t_schema_5");
 561       $dbh->do(<<EOS);
 562  CREATE TABLE dbic_t_schema_4.artist
 563  (
 564    artistid integer not null default nextval('artist_artistid_seq'::regclass) PRIMARY KEY
 565    , name VARCHAR(100)
 566    , rank INTEGER NOT NULL DEFAULT '13'
 567    , charfield CHAR(10)
 568    , arrayfield INTEGER[]
 569  );
 570 EOS
 571       $dbh->do('set search_path=public,dbic_t_schema,dbic_t_schema_3');
 572       $dbh->do('create sequence public.artist_artistid_seq'); #< in the public schema
 573       $dbh->do(<<EOS);
 574  CREATE TABLE dbic_t_schema_5.artist
 575  (
 576    artistid integer not null default nextval('public.artist_artistid_seq'::regclass) PRIMARY KEY
 577    , name VARCHAR(100)
 578    , rank INTEGER NOT NULL DEFAULT '13'
 579    , charfield CHAR(10)
 580    , arrayfield INTEGER[]
 581  );
 582 EOS
 583       $dbh->do('set search_path=dbic_t_schema,public');
 584   });
 585 }
 586
 587
 588
 589 sub drop_test_schema {
 590     my ( $schema, $warn_exceptions ) = @_;
 591
 592     $schema->storage->dbh_do(sub {
 593         my (undef,$dbh) = @_;
 594
 595         local $dbh->{Warn} = 0;
 596
 597         for my $stat (
 598                       'DROP SCHEMA dbic_t_schema_5 CASCADE',
 599                       'DROP SEQUENCE public.artist_artistid_seq CASCADE',
 600                       'DROP SCHEMA dbic_t_schema_4 CASCADE',
 601                       'DROP SCHEMA dbic_t_schema CASCADE',
 602                       'DROP SEQUENCE pkid1_seq CASCADE',
 603                       'DROP SEQUENCE pkid2_seq CASCADE',
 604                       'DROP SEQUENCE nonpkid_seq CASCADE',
 605                       'DROP SCHEMA dbic_t_schema_2 CASCADE',
 606                       'DROP SCHEMA dbic_t_schema_3 CASCADE',
 607                      ) {
 608             eval { $dbh->do ($stat) };
 609             diag $@ if $@ && $warn_exceptions;
 610         }
 611     });
 612 }
 613
 614
 615 ###  auto-pk / last_insert_id / sequence discovery
 616 sub run_apk_tests {
 617     my $schema = shift;
 618
 619     # This is in Core now, but it's here just to test that it doesn't break
 620     $schema->class('Artist')->load_components('PK::Auto');
 621     cmp_ok( $schema->resultset('Artist')->count, '==', 0, 'this should start with an empty artist table');
 622
 623     # test that auto-pk also works with the defined search path by
 624     # un-schema-qualifying the table name
 625     apk_t_set($schema,'artist');
 626
 627     my $unq_new;
 628     lives_ok {
 629         $unq_new = $schema->resultset('Artist')->create({ name => 'baz' });
 630     } 'insert into unqualified, shadowed table succeeds';
 631
 632     is($unq_new && $unq_new->artistid, 1, "and got correct artistid");
 633
 634     my @test_schemas = ( [qw| dbic_t_schema_2    1  |],
 635                          [qw| dbic_t_schema_3    1  |],
 636                          [qw| dbic_t_schema_4    2  |],
 637                          [qw| dbic_t_schema_5    1  |],
 638                        );
 639     foreach my $t ( @test_schemas ) {
 640         my ($sch_name, $start_num) = @$t;
 641         #test with dbic_t_schema_2
 642         apk_t_set($schema,"$sch_name.artist");
 643         my $another_new;
 644         lives_ok {
 645             $another_new = $schema->resultset('Artist')->create({ name => 'Tollbooth Willy'});
 646             is( $another_new->artistid,$start_num, "got correct artistid for $sch_name")
 647                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 648         } "$sch_name liid 1 did not die"
 649             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 650         lives_ok {
 651             $another_new = $schema->resultset('Artist')->create({ name => 'Adam Sandler'});
 652             is( $another_new->artistid,$start_num+1, "got correct artistid for $sch_name")
 653                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 654         } "$sch_name liid 2 did not die"
 655             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 656
 657     }
 658
 659     lives_ok {
 660         apk_t_set($schema,'dbic_t_schema.artist');
 661         my $new = $schema->resultset('Artist')->create({ name => 'foo' });
 662         is($new->artistid, 4, "Auto-PK worked");
 663         $new = $schema->resultset('Artist')->create({ name => 'bar' });
 664         is($new->artistid, 5, "Auto-PK worked");
 665     } 'old auto-pk tests did not die either';
 666 }
 667
 668 # sets the artist table name and clears sequence name cache
 669 sub apk_t_set {
 670     my ( $s, $n ) = @_;
 671     $s->source("Artist")->name($n);
 672     $s->source('Artist')->column_info('artistid')->{sequence} = undef; #< clear sequence name cache
 673 }
 674
 675
 676 ######## EXTENDED AUTO-PK TESTS
 677
 678 my @eapk_id_columns;
 679 BEGIN {
 680   package DBICTest::Schema::ExtAPK;
 681   push @main::test_classes, __PACKAGE__;
 682
 683   use strict;
 684   use warnings;
 685   use base 'DBIx::Class::Core';
 686
 687   __PACKAGE__->table('apk');
 688
 689   @eapk_id_columns = qw( id1 id2 id3 id4 );
 690   __PACKAGE__->add_columns(
 691     map { $_ => { data_type => 'integer', is_auto_increment => 1 } }
 692        @eapk_id_columns
 693   );
 694
 695   __PACKAGE__->set_primary_key('id2'); #< note the SECOND column is
 696                                        #the primary key
 697 }
 698
 699 my @eapk_schemas;
 700 BEGIN{ @eapk_schemas = map "dbic_apk_$_", 0..5 }
 701 my %seqs; #< hash of schema.table.col => currval of its (DBIC) primary key sequence
 702
 703 sub run_extended_apk_tests {
 704   my $schema = shift;
 705
 706   #save the search path and reset it at the end
 707   my $search_path_save = eapk_get_search_path($schema);
 708
 709   eapk_drop_all($schema);
 710   %seqs = ();
 711
 712   # make the test schemas and sequences
 713   $schema->storage->dbh_do(sub {
 714     my ( undef, $dbh ) = @_;
 715
 716     $dbh->do("CREATE SCHEMA $_")
 717         for @eapk_schemas;
 718
 719     $dbh->do("CREATE SEQUENCE $eapk_schemas[5].fooseq");
 720     $dbh->do("SELECT setval('$eapk_schemas[5].fooseq',400)");
 721     $seqs{"$eapk_schemas[1].apk.id2"} = 400;
 722
 723     $dbh->do("CREATE SEQUENCE $eapk_schemas[4].fooseq");
 724     $dbh->do("SELECT setval('$eapk_schemas[4].fooseq',300)");
 725     $seqs{"$eapk_schemas[3].apk.id2"} = 300;
 726
 727     $dbh->do("CREATE SEQUENCE $eapk_schemas[3].fooseq");
 728     $dbh->do("SELECT setval('$eapk_schemas[3].fooseq',200)");
 729     $seqs{"$eapk_schemas[4].apk.id2"} = 200;
 730
 731     $dbh->do("SET search_path = ".join ',', reverse @eapk_schemas );
 732   });
 733
 734   # clear our search_path cache
 735   $schema->storage->{_pg_search_path} = undef;
 736
 737   eapk_create( $schema,
 738                with_search_path => [0,1],
 739              );
 740   eapk_create( $schema,
 741                with_search_path => [1,0,'public'],
 742                nextval => "$eapk_schemas[5].fooseq",
 743              );
 744   eapk_create( $schema,
 745                with_search_path => ['public',0,1],
 746                qualify_table => 2,
 747              );
 748   eapk_create( $schema,
 749                with_search_path => [3,1,0,'public'],
 750                nextval => "$eapk_schemas[4].fooseq",
 751              );
 752   eapk_create( $schema,
 753                with_search_path => [3,1,0,'public'],
 754                nextval => "$eapk_schemas[3].fooseq",
 755                qualify_table => 4,
 756              );
 757
 758   eapk_poke( $schema );
 759   eapk_poke( $schema, 0 );
 760   eapk_poke( $schema, 2 );
 761   eapk_poke( $schema, 4 );
 762   eapk_poke( $schema, 1 );
 763   eapk_poke( $schema, 0 );
 764   eapk_poke( $schema, 1 );
 765   eapk_poke( $schema );
 766   eapk_poke( $schema, 4 );
 767   eapk_poke( $schema, 3 );
 768   eapk_poke( $schema, 1 );
 769   eapk_poke( $schema, 2 );
 770   eapk_poke( $schema, 0 );
 771
 772   # set our search path back
 773   eapk_set_search_path( $schema, @$search_path_save );
 774 }
 775
 776 # do a DBIC create on the apk table in the given schema number (which is an
 777 # index of @eapk_schemas)
 778
 779 sub eapk_poke {
 780   my ($s, $schema_num) = @_;
 781
 782   my $schema_name = defined $schema_num
 783       ? $eapk_schemas[$schema_num]
 784       : '';
 785
 786   my $schema_name_actual = $schema_name || eapk_find_visible_schema($s);
 787
 788   $s->source('ExtAPK')->name($schema_name ? $schema_name.'.apk' : 'apk');
 789   #< clear sequence name cache
 790   $s->source('ExtAPK')->column_info($_)->{sequence} = undef
 791       for @eapk_id_columns;
 792
 793   no warnings 'uninitialized';
 794   lives_ok {
 795     my $new;
 796     for my $inc (1,2,3) {
 797       $new = $schema->resultset('ExtAPK')->create({ id1 => 1});
 798       my $proper_seqval = ++$seqs{"$schema_name_actual.apk.id2"};
 799       is( $new->id2, $proper_seqval, "$schema_name_actual.apk.id2 correct inc $inc" )
 800           or eapk_seq_diag($s,$schema_name);
 801       $new->discard_changes;
 802       is( $new->id1, 1 );
 803       for my $id ('id3','id4') {
 804         my $proper_seqval = ++$seqs{"$schema_name_actual.apk.$id"};
 805         is( $new->$id, $proper_seqval, "$schema_name_actual.apk.$id correct inc $inc" )
 806             or eapk_seq_diag($s,$schema_name);
 807       }
 808     }
 809   } "create in schema '$schema_name' lives"
 810       or eapk_seq_diag($s,$schema_name);
 811 }
 812
 813 # print diagnostic info on which sequences were found in the ExtAPK
 814 # class
 815 sub eapk_seq_diag {
 816     my $s = shift;
 817     my $schema = shift || eapk_find_visible_schema($s);
 818
 819     diag "$schema.apk sequences: ",
 820         join(', ',
 821              map "$_:".($s->source('ExtAPK')->column_info($_)->{sequence} || '<none>'),
 822              @eapk_id_columns
 823             );
 824 }
 825
 826 # get the postgres search path as an arrayref
 827 sub eapk_get_search_path {
 828     my ( $s ) = @_;
 829     # cache the search path as ['schema','schema',...] in the storage
 830     # obj
 831
 832     return $s->storage->dbh_do(sub {
 833         my (undef, $dbh) = @_;
 834         my @search_path;
 835         my ($sp_string) = $dbh->selectrow_array('SHOW search_path');
 836         while ( $sp_string =~ s/("[^"]+"|[^,]+),?// ) {
 837             unless( defined $1 and length $1 ) {
 838                 die "search path sanity check failed: '$1'";
 839             }
 840             push @search_path, $1;
 841         }
 842         \@search_path
 843     });
 844 }
 845 sub eapk_set_search_path {
 846     my ($s,@sp) = @_;
 847     my $sp = join ',',@sp;
 848     $s->storage->dbh_do( sub { $_[1]->do("SET search_path = $sp") } );
 849 }
 850
 851 # create the apk table in the given schema, can set whether the table name is qualified, what the nextval is for the second ID
 852 sub eapk_create {
 853     my ($schema, %a) = @_;
 854
 855     $schema->storage->dbh_do(sub {
 856         my (undef,$dbh) = @_;
 857
 858         my $searchpath_save;
 859         if ( $a{with_search_path} ) {
 860             ($searchpath_save) = $dbh->selectrow_array('SHOW search_path');
 861
 862             my $search_path = join ',',map {/\D/ ? $_ : $eapk_schemas[$_]} @{$a{with_search_path}};
 863
 864             $dbh->do("SET search_path = $search_path");
 865         }
 866
 867         my $table_name = $a{qualify_table}
 868             ? ($eapk_schemas[$a{qualify_table}] || die). ".apk"
 869             : 'apk';
 870         local $_[1]->{Warn} = 0;
 871
 872         my $id_def = $a{nextval}
 873             ? "integer not null default nextval('$a{nextval}'::regclass)"
 874             : 'serial';
 875         $dbh->do(<<EOS);
 876 CREATE TABLE $table_name (
 877   id1 serial
 878   , id2 $id_def
 879   , id3 serial primary key
 880   , id4 serial
 881 )
 882 EOS
 883
 884         if( $searchpath_save ) {
 885             $dbh->do("SET search_path = $searchpath_save");
 886         }
 887     });
 888 }
 889
 890 sub eapk_drop_all {
 891     my ( $schema, $warn_exceptions ) = @_;
 892
 893     $schema->storage->dbh_do(sub {
 894         my (undef,$dbh) = @_;
 895
 896         local $dbh->{Warn} = 0;
 897
 898         # drop the test schemas
 899         for (@eapk_schemas ) {
 900             eval{ $dbh->do("DROP SCHEMA $_ CASCADE") };
 901             diag $@ if $@ && $warn_exceptions;
 902         }
 903
 904
 905     });
 906 }
 907
 908 sub eapk_find_visible_schema {
 909     my ($s) = @_;
 910
 911     my ($schema) =
 912         $s->storage->dbh_do(sub {
 913             $_[1]->selectrow_array(<<EOS);
 914 SELECT n.nspname
 915 FROM pg_catalog.pg_namespace n
 916 JOIN pg_catalog.pg_class c ON c.relnamespace = n.oid
 917 WHERE c.relname = 'apk'
 918   AND pg_catalog.pg_table_is_visible(c.oid)
 919 EOS
 920         });
 921     return $schema;
 922 }