t/72pg.t

   1 use strict;
   2 use warnings;
   3
   4 use Test::More;
   5 use Test::Exception;
   6 use Sub::Name;
   7 use Config;
   8 use DBIx::Class::Optional::Dependencies ();
   9 use lib qw(t/lib);
  10 use DBICTest;
  11 use SQL::Abstract 'is_literal_value';
  12 use DBIx::Class::_Util 'is_exception';
  13
  14 plan skip_all => 'Test needs ' . DBIx::Class::Optional::Dependencies->req_missing_for ('test_rdbms_pg')
  15   unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_rdbms_pg');
  16
  17 my ($dsn, $user, $pass) = @ENV{map { "DBICTEST_PG_${_}" } qw/DSN USER PASS/};
  18
  19 plan skip_all => <<'EOM' unless $dsn && $user;
  20 Set $ENV{DBICTEST_PG_DSN}, _USER and _PASS to run this test
  21 ( NOTE: This test drops and creates tables called 'artist', 'cd',
  22 'timestamp_primary_key_test', 'track', 'casecheck', 'array_test' and
  23 'sequence_test' as well as following sequences: 'pkid1_seq', 'pkid2_seq' and
  24 'nonpkid_seq'. as well as following schemas: 'dbic_t_schema',
  25 'dbic_t_schema_2', 'dbic_t_schema_3', 'dbic_t_schema_4', and 'dbic_t_schema_5')
  26 EOM
  27
  28 ### load any test classes that are defined further down in the file via BEGIN blocks
  29
  30 our @test_classes; #< array that will be pushed into by test classes defined in this file
  31 DBICTest::Schema->load_classes( map {s/.+:://;$_} @test_classes ) if @test_classes;
  32
  33 ###  pre-connect tests (keep each test separate as to make sure rebless() runs)
  34   {
  35     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  36
  37     ok (!$s->storage->_dbh, 'definitely not connected');
  38
  39     # Check that datetime_parser returns correctly before we explicitly connect.
  40     SKIP: {
  41         skip (
  42           "Pg parser detection test needs " . DBIx::Class::Optional::Dependencies->req_missing_for ('test_dt_pg'),
  43           2
  44         ) unless DBIx::Class::Optional::Dependencies->req_ok_for ('test_dt_pg');
  45
  46         my $store = ref $s->storage;
  47         is($store, 'DBIx::Class::Storage::DBI', 'Started with generic storage');
  48
  49         my $parser = $s->storage->datetime_parser;
  50         is( $parser, 'DateTime::Format::Pg', 'datetime_parser is as expected');
  51     }
  52
  53     ok (!$s->storage->_dbh, 'still not connected');
  54   }
  55
  56   {
  57     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
  58     # make sure sqlt_type overrides work (::Storage::DBI::Pg does this)
  59     ok (!$s->storage->_dbh, 'definitely not connected');
  60     is ($s->storage->sqlt_type, 'PostgreSQL', 'sqlt_type correct pre-connection');
  61     ok (!$s->storage->_dbh, 'still not connected');
  62   }
  63
  64 # test LIMIT support
  65 {
  66   my $schema = DBICTest::Schema->connect($dsn, $user, $pass);
  67   drop_test_schema($schema);
  68   create_test_schema($schema);
  69   for (1..6) {
  70     $schema->resultset('Artist')->create({ name => 'Artist ' . $_ });
  71   }
  72   my $it = $schema->resultset('Artist')->search( {},
  73     { rows => 3,
  74       offset => 2,
  75       order_by => 'artistid' }
  76   );
  77   is( $it->count, 3, "LIMIT count ok" );  # ask for 3 rows out of 6 artists
  78   is( $it->next->name, "Artist 3", "iterator->next ok" );
  79   $it->next;
  80   $it->next;
  81   $it->next;
  82   is( $it->next, undef, "next past end of resultset ok" );
  83
  84   # Limit with select-lock
  85   lives_ok {
  86     $schema->txn_do (sub {
  87       isa_ok (
  88         $schema->resultset('Artist')->find({artistid => 1}, {for => 'update', rows => 1}),
  89         'DBICTest::Schema::Artist',
  90       );
  91     });
  92   } 'Limited FOR UPDATE select works';
  93 }
  94
  95 # check if we indeed do support stuff
  96 my $test_server_supports_insert_returning = do {
  97
  98   my $si = DBICTest::Schema->connect($dsn, $user, $pass)->storage->_server_info;
  99   die "Unparseable Pg server version: $si->{dbms_version}\n"
 100     unless $si->{normalized_dbms_version};
 101
 102   $si->{normalized_dbms_version} < 8.002 ? 0 : 1;
 103 };
 104 is (
 105   DBICTest::Schema->connect($dsn, $user, $pass)->storage->_use_insert_returning,
 106   $test_server_supports_insert_returning,
 107   'insert returning capability guessed correctly'
 108 );
 109
 110 my $schema;
 111 for my $use_insert_returning ($test_server_supports_insert_returning
 112   ? (0,1)
 113   : (0)
 114 ) {
 115
 116   no warnings qw/once redefine/;
 117   my $old_connection = DBICTest::Schema->can('connection');
 118   local *DBICTest::Schema::connection = subname 'DBICTest::Schema::connection' => sub {
 119     my $s = shift->$old_connection(@_);
 120     $s->storage->_use_insert_returning ($use_insert_returning);
 121     $s;
 122   };
 123
 124 ### test capability override
 125   {
 126     my $s = DBICTest::Schema->connect($dsn, $user, $pass);
 127
 128     ok (!$s->storage->_dbh, 'definitely not connected');
 129
 130     ok (
 131       ! ($s->storage->_use_insert_returning xor $use_insert_returning),
 132       'insert returning capability set correctly',
 133     );
 134     ok (!$s->storage->_dbh, 'still not connected (capability override works)');
 135   }
 136
 137 ### connect, create postgres-specific test schema
 138
 139   $schema = DBICTest::Schema->connect($dsn, $user, $pass);
 140   $schema->storage->ensure_connected;
 141
 142   drop_test_schema($schema);
 143   create_test_schema($schema);
 144
 145 ### begin main tests
 146
 147 # run a BIG bunch of tests for last-insert-id / Auto-PK / sequence
 148 # discovery
 149   run_apk_tests($schema); #< older set of auto-pk tests
 150   run_extended_apk_tests($schema); #< new extended set of auto-pk tests
 151
 152 ### type_info tests
 153
 154   my $test_type_info = {
 155       'artistid' => {
 156           'data_type' => 'integer',
 157           'is_nullable' => 0,
 158           'size' => 4,
 159       },
 160       'name' => {
 161           'data_type' => 'character varying',
 162           'is_nullable' => 1,
 163           'size' => 100,
 164           'default_value' => undef,
 165       },
 166       'rank' => {
 167           'data_type' => 'integer',
 168           'is_nullable' => 0,
 169           'size' => 4,
 170           'default_value' => 13,
 171
 172       },
 173       'charfield' => {
 174           'data_type' => 'character',
 175           'is_nullable' => 1,
 176           'size' => 10,
 177           'default_value' => undef,
 178       },
 179       'arrayfield' => {
 180           'data_type' => 'integer[]',
 181           'is_nullable' => 1,
 182           'size' => undef,
 183           'default_value' => undef,
 184       },
 185   };
 186
 187   my $type_info = $schema->storage->columns_info_for('dbic_t_schema.artist');
 188   my $artistid_defval = delete $type_info->{artistid}->{default_value};
 189   like($artistid_defval,
 190        qr/^nextval\('([^\.]*\.){0,1}artist_artistid_seq'::(?:text|regclass)\)/,
 191        'columns_info_for - sequence matches Pg get_autoinc_seq expectations');
 192   is_deeply($type_info, $test_type_info,
 193             'columns_info_for - column data types');
 194
 195
 196
 197
 198 ####### Array tests
 199
 200   BEGIN {
 201     package DBICTest::Schema::ArrayTest;
 202     push @main::test_classes, __PACKAGE__;
 203
 204     use strict;
 205     use warnings;
 206     use base 'DBICTest::BaseResult';
 207
 208     __PACKAGE__->table('dbic_t_schema.array_test');
 209     __PACKAGE__->add_columns(qw/id arrayfield/);
 210     __PACKAGE__->column_info_from_storage(1);
 211     __PACKAGE__->set_primary_key('id');
 212
 213   }
 214   SKIP: {
 215     skip "Need DBD::Pg 2.9.2 or newer for array tests", 4 if $DBD::Pg::VERSION < 2.009002;
 216
 217     my $arr_rs = $schema->resultset('ArrayTest');
 218
 219     lives_ok {
 220       $arr_rs->create({
 221         arrayfield => [1, 2],
 222       });
 223     } 'inserting arrayref as pg array data';
 224
 225     lives_ok {
 226       $arr_rs->update({
 227         arrayfield => [3, 4],
 228       });
 229     } 'updating arrayref as pg array data';
 230
 231     $arr_rs->create({
 232       arrayfield => [5, 6],
 233     });
 234
 235     lives_ok {
 236       $schema->populate('ArrayTest', [
 237         [ qw/arrayfield/ ],
 238         [ [0,0]          ],
 239       ]);
 240     } 'inserting arrayref using void ctx populate';
 241
 242     # Search using arrays
 243     lives_ok {
 244       is_deeply (
 245         $arr_rs->search({ arrayfield => { -value => [3,4] } })->first->arrayfield,
 246         [3,4],
 247         'Array value matches'
 248       );
 249     } 'searching by arrayref';
 250
 251     lives_ok {
 252       is_deeply (
 253         $arr_rs->search({ arrayfield => { '=' => { -value => [3,4] }} })->first->arrayfield,
 254         [3,4],
 255         'Array value matches explicit equal'
 256       );
 257     } 'searching by arrayref (explicit equal sign)';
 258
 259     lives_ok {
 260       is_deeply (
 261         $arr_rs->search({ arrayfield => { '>' => { -value => [3,1] }} })->first->arrayfield,
 262         [3,4],
 263         'Array value matches greater than'
 264       );
 265     } 'searching by arrayref (greater than)';
 266
 267     lives_ok {
 268       is (
 269         $arr_rs->search({ arrayfield => { '>' => { -value => [3,7] }} })->count,
 270         1,
 271         'Greater than search found [5,6]',
 272       );
 273     } 'searching by arrayref (greater than)';
 274
 275     # Find using arrays
 276     lives_ok {
 277       is_deeply (
 278         $arr_rs->find({ arrayfield => { -value => [3,4] } })->arrayfield,
 279         [3,4],
 280         'Array value matches implicit equal'
 281       );
 282     } 'find by arrayref';
 283
 284     lives_ok {
 285       is_deeply (
 286         $arr_rs->find({ arrayfield => { '=' => { -value => [3,4] }} })->arrayfield,
 287         [3,4],
 288         'Array value matches explicit equal'
 289       );
 290     } 'find by arrayref (equal)';
 291
 292     # test inferred condition for creation
 293     for my $cond (
 294       { -value => [3,4] },
 295       \[ '= ?' => [arrayfield => [3, 4]] ],
 296     ) {
 297       local $TODO = 'No introspection of complex literal conditions :('
 298         if is_literal_value $cond;
 299
 300
 301       my $arr_rs_cond = $arr_rs->search({ arrayfield => $cond });
 302
 303       my $row = $arr_rs_cond->create({});
 304       is_deeply ($row->arrayfield, [3,4], 'Array value taken from $rs condition');
 305       $row->discard_changes;
 306       is_deeply ($row->arrayfield, [3,4], 'Array value made it to storage');
 307     }
 308   }
 309
 310 ########## Case check
 311
 312   BEGIN {
 313     package DBICTest::Schema::Casecheck;
 314     push @main::test_classes, __PACKAGE__;
 315
 316     use strict;
 317     use warnings;
 318     use base 'DBIx::Class::Core';
 319
 320     __PACKAGE__->table('dbic_t_schema.casecheck');
 321     __PACKAGE__->add_columns(qw/id name NAME uc_name/);
 322     __PACKAGE__->column_info_from_storage(1);
 323     __PACKAGE__->set_primary_key('id');
 324   }
 325
 326   my $name_info = $schema->source('Casecheck')->column_info( 'name' );
 327   is( $name_info->{size}, 1, "Case sensitive matching info for 'name'" );
 328
 329   my $NAME_info = $schema->source('Casecheck')->column_info( 'NAME' );
 330   is( $NAME_info->{size}, 2, "Case sensitive matching info for 'NAME'" );
 331
 332   my $uc_name_info = $schema->source('Casecheck')->column_info( 'uc_name' );
 333   is( $uc_name_info->{size}, 3, "Case insensitive matching info for 'uc_name'" );
 334
 335
 336 ## Test ResultSet->update
 337 my $artist = $schema->resultset('Artist')->first;
 338 my $cds = $artist->cds_unordered->search({
 339     year => { '!=' => 2010 }
 340 }, { prefetch => 'liner_notes' });
 341 lives_ok { $cds->update({ year => '2010' }) } 'Update on prefetched rs';
 342
 343 ## Test SELECT ... FOR UPDATE
 344   SKIP: {
 345       skip "Your system does not support unsafe signals (d_sigaction) - unable to run deadlock test", 1
 346         unless eval { $Config{d_sigaction} and require POSIX };
 347
 348       my ($timed_out, $artist2);
 349
 350       for my $t (
 351         {
 352           # Make sure that an error was raised, and that the update failed
 353           update_lock => 1,
 354           test_sub => sub {
 355             ok($timed_out, "update from second schema times out");
 356             ok($artist2->is_column_changed('name'), "'name' column is still dirty from second schema");
 357           },
 358         },
 359         {
 360           # Make sure that an error was NOT raised, and that the update succeeded
 361           update_lock => 0,
 362           test_sub => sub {
 363             ok(! $timed_out, "update from second schema DOES NOT timeout");
 364             ok(! $artist2->is_column_changed('name'), "'name' column is NOT dirty from second schema");
 365           },
 366         },
 367       ) {
 368         # create a new schema
 369         my $schema2 = DBICTest::Schema->connect($dsn, $user, $pass);
 370         $schema2->source("Artist")->name("dbic_t_schema.artist");
 371
 372         $schema->txn_do( sub {
 373           my $rs = $schema->resultset('Artist')->search(
 374               {
 375                   artistid => 1
 376               },
 377               $t->{update_lock} ? { for => 'update' } : {}
 378           );
 379           ok ($rs->count, 'Count works');
 380
 381           my $artist = $rs->next;
 382           is($artist->artistid, 1, "select returns artistid = 1");
 383
 384           $timed_out = 0;
 385
 386           eval {
 387               # can not use %SIG assignment directly - we need sigaction below
 388               # localization to a block still works however
 389               local $SIG{ALRM};
 390
 391               POSIX::sigaction( POSIX::SIGALRM() => POSIX::SigAction->new(
 392                 sub { die "DBICTestTimeout" },
 393               ));
 394
 395               $artist2 = $schema2->resultset('Artist')->find(1);
 396               $artist2->name('fooey');
 397
 398               # FIXME - this needs to go away in lieu of a non-retrying runner
 399               # ( i.e. after solving RT#47005 )
 400               local *DBIx::Class::Storage::DBI::_ping = sub { 1 }, DBIx::Class::_ENV_::OLD_MRO && Class::C3->reinitialize()
 401                 if DBIx::Class::_Util::modver_gt_or_eq( 'DBD::Pg' => '3.5.0' );
 402
 403               alarm(1);
 404               $artist2->update;
 405           };
 406
 407           alarm(0);
 408
 409           if (is_exception($@)) {
 410             $timed_out = $@ =~ /DBICTestTimeout/
 411               or die $@;
 412           }
 413         });
 414
 415         $t->{test_sub}->();
 416       }
 417   }
 418
 419
 420 ######## other older Auto-pk tests
 421
 422   $schema->source("SequenceTest")->name("dbic_t_schema.sequence_test");
 423   for (1..5) {
 424       my $st = $schema->resultset('SequenceTest')->create({ name => 'foo' });
 425       is($st->pkid1, $_, "Auto-PK for sequence without default: First primary key");
 426       is($st->pkid2, $_ + 9, "Auto-PK for sequence without default: Second primary key");
 427       is($st->nonpkid, $_ + 19, "Auto-PK for sequence without default: Non-primary key");
 428   }
 429   my $st = $schema->resultset('SequenceTest')->create({ name => 'foo', pkid1 => 55 });
 430   is($st->pkid1, 55, "Auto-PK for sequence without default: First primary key set manually");
 431
 432
 433 ######## test non-serial auto-pk
 434
 435   if ($schema->storage->_use_insert_returning) {
 436     $schema->source('TimestampPrimaryKey')->name('dbic_t_schema.timestamp_primary_key_test');
 437     my $row = $schema->resultset('TimestampPrimaryKey')->create({});
 438     ok $row->id;
 439   }
 440
 441 ######## test with_deferred_fk_checks
 442
 443   $schema->source('CD')->name('dbic_t_schema.cd');
 444   $schema->source('Track')->name('dbic_t_schema.track');
 445   lives_ok {
 446     $schema->storage->with_deferred_fk_checks(sub {
 447       $schema->resultset('Track')->create({
 448         trackid => 999, cd => 999, position => 1, title => 'deferred FK track'
 449       });
 450       $schema->resultset('CD')->create({
 451         artist => 1, cdid => 999, year => '2003', title => 'deferred FK cd'
 452       });
 453     });
 454   } 'with_deferred_fk_checks code survived';
 455
 456   is eval { $schema->resultset('Track')->find(999)->title }, 'deferred FK track',
 457      'code in with_deferred_fk_checks worked';
 458
 459   throws_ok {
 460     $schema->resultset('Track')->create({
 461       trackid => 1, cd => 9999, position => 1, title => 'Track1'
 462     });
 463   } qr/constraint/i, 'with_deferred_fk_checks is off';
 464 }
 465
 466 done_testing;
 467
 468 END {
 469     return unless $schema;
 470     drop_test_schema($schema);
 471     eapk_drop_all($schema);
 472     undef $schema;
 473 };
 474
 475
 476 ######### SUBROUTINES
 477
 478 sub create_test_schema {
 479     my $schema = shift;
 480     $schema->storage->dbh_do(sub {
 481       my (undef,$dbh) = @_;
 482
 483       local $dbh->{Warn} = 0;
 484
 485       my $std_artist_table = <<EOS;
 486 (
 487   artistid serial PRIMARY KEY
 488   , name VARCHAR(100)
 489   , rank INTEGER NOT NULL DEFAULT '13'
 490   , charfield CHAR(10)
 491   , arrayfield INTEGER[]
 492 )
 493 EOS
 494
 495       $dbh->do("CREATE SCHEMA dbic_t_schema");
 496       $dbh->do("CREATE TABLE dbic_t_schema.artist $std_artist_table");
 497
 498       $dbh->do(<<EOS);
 499 CREATE TABLE dbic_t_schema.timestamp_primary_key_test (
 500   id timestamp default current_timestamp
 501 )
 502 EOS
 503       $dbh->do(<<EOS);
 504 CREATE TABLE dbic_t_schema.cd (
 505   cdid int PRIMARY KEY,
 506   artist int,
 507   title varchar(255),
 508   year varchar(4),
 509   genreid int,
 510   single_track int
 511 )
 512 EOS
 513       $dbh->do(<<EOS);
 514 CREATE TABLE dbic_t_schema.track (
 515   trackid int,
 516   cd int REFERENCES dbic_t_schema.cd(cdid) DEFERRABLE,
 517   position int,
 518   title varchar(255),
 519   last_updated_on date,
 520   last_updated_at date
 521 )
 522 EOS
 523
 524       $dbh->do(<<EOS);
 525 CREATE TABLE dbic_t_schema.sequence_test (
 526     pkid1 integer
 527     , pkid2 integer
 528     , nonpkid integer
 529     , name VARCHAR(100)
 530     , CONSTRAINT pk PRIMARY KEY(pkid1, pkid2)
 531 )
 532 EOS
 533       $dbh->do("CREATE SEQUENCE pkid1_seq START 1 MAXVALUE 999999 MINVALUE 0");
 534       $dbh->do("CREATE SEQUENCE pkid2_seq START 10 MAXVALUE 999999 MINVALUE 0");
 535       $dbh->do("CREATE SEQUENCE nonpkid_seq START 20 MAXVALUE 999999 MINVALUE 0");
 536       $dbh->do(<<EOS);
 537 CREATE TABLE dbic_t_schema.casecheck (
 538     id serial PRIMARY KEY
 539     , "name" VARCHAR(1)
 540     , "NAME" VARCHAR(2)
 541     , "UC_NAME" VARCHAR(3)
 542 )
 543 EOS
 544       $dbh->do(<<EOS);
 545 CREATE TABLE dbic_t_schema.array_test (
 546     id serial PRIMARY KEY
 547     , arrayfield INTEGER[]
 548 )
 549 EOS
 550       $dbh->do("CREATE SCHEMA dbic_t_schema_2");
 551       $dbh->do("CREATE TABLE dbic_t_schema_2.artist $std_artist_table");
 552       $dbh->do("CREATE SCHEMA dbic_t_schema_3");
 553       $dbh->do("CREATE TABLE dbic_t_schema_3.artist $std_artist_table");
 554       $dbh->do('set search_path=dbic_t_schema,public');
 555       $dbh->do("CREATE SCHEMA dbic_t_schema_4");
 556       $dbh->do("CREATE SCHEMA dbic_t_schema_5");
 557       $dbh->do(<<EOS);
 558  CREATE TABLE dbic_t_schema_4.artist
 559  (
 560    artistid integer not null default nextval('artist_artistid_seq'::regclass) PRIMARY KEY
 561    , name VARCHAR(100)
 562    , rank INTEGER NOT NULL DEFAULT '13'
 563    , charfield CHAR(10)
 564    , arrayfield INTEGER[]
 565  );
 566 EOS
 567       $dbh->do('set search_path=public,dbic_t_schema,dbic_t_schema_3');
 568       $dbh->do('create sequence public.artist_artistid_seq'); #< in the public schema
 569       $dbh->do(<<EOS);
 570  CREATE TABLE dbic_t_schema_5.artist
 571  (
 572    artistid integer not null default nextval('public.artist_artistid_seq'::regclass) PRIMARY KEY
 573    , name VARCHAR(100)
 574    , rank INTEGER NOT NULL DEFAULT '13'
 575    , charfield CHAR(10)
 576    , arrayfield INTEGER[]
 577  );
 578 EOS
 579       $dbh->do('set search_path=dbic_t_schema,public');
 580   });
 581 }
 582
 583
 584
 585 sub drop_test_schema {
 586     my ( $schema, $warn_exceptions ) = @_;
 587
 588     $schema->storage->dbh_do(sub {
 589         my (undef,$dbh) = @_;
 590
 591         local $dbh->{Warn} = 0;
 592
 593         for my $stat (
 594                       'DROP SCHEMA dbic_t_schema_5 CASCADE',
 595                       'DROP SEQUENCE public.artist_artistid_seq CASCADE',
 596                       'DROP SCHEMA dbic_t_schema_4 CASCADE',
 597                       'DROP SCHEMA dbic_t_schema CASCADE',
 598                       'DROP SEQUENCE pkid1_seq CASCADE',
 599                       'DROP SEQUENCE pkid2_seq CASCADE',
 600                       'DROP SEQUENCE nonpkid_seq CASCADE',
 601                       'DROP SCHEMA dbic_t_schema_2 CASCADE',
 602                       'DROP SCHEMA dbic_t_schema_3 CASCADE',
 603                      ) {
 604             eval { $dbh->do ($stat) };
 605             diag $@ if $@ && $warn_exceptions;
 606         }
 607     });
 608 }
 609
 610
 611 ###  auto-pk / last_insert_id / sequence discovery
 612 sub run_apk_tests {
 613     my $schema = shift;
 614
 615     # This is in Core now, but it's here just to test that it doesn't break
 616     $schema->class('Artist')->load_components('PK::Auto');
 617     cmp_ok( $schema->resultset('Artist')->count, '==', 0, 'this should start with an empty artist table');
 618
 619     # test that auto-pk also works with the defined search path by
 620     # un-schema-qualifying the table name
 621     apk_t_set($schema,'artist');
 622
 623     my $unq_new;
 624     lives_ok {
 625         $unq_new = $schema->resultset('Artist')->create({ name => 'baz' });
 626     } 'insert into unqualified, shadowed table succeeds';
 627
 628     is($unq_new && $unq_new->artistid, 1, "and got correct artistid");
 629
 630     my @test_schemas = ( [qw| dbic_t_schema_2    1  |],
 631                          [qw| dbic_t_schema_3    1  |],
 632                          [qw| dbic_t_schema_4    2  |],
 633                          [qw| dbic_t_schema_5    1  |],
 634                        );
 635     foreach my $t ( @test_schemas ) {
 636         my ($sch_name, $start_num) = @$t;
 637         #test with dbic_t_schema_2
 638         apk_t_set($schema,"$sch_name.artist");
 639         my $another_new;
 640         lives_ok {
 641             $another_new = $schema->resultset('Artist')->create({ name => 'Tollbooth Willy'});
 642             is( $another_new->artistid,$start_num, "got correct artistid for $sch_name")
 643                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 644         } "$sch_name liid 1 did not die"
 645             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 646         lives_ok {
 647             $another_new = $schema->resultset('Artist')->create({ name => 'Adam Sandler'});
 648             is( $another_new->artistid,$start_num+1, "got correct artistid for $sch_name")
 649                 or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 650         } "$sch_name liid 2 did not die"
 651             or diag "USED SEQUENCE: ".($schema->source('Artist')->column_info('artistid')->{sequence} || '<none>');
 652
 653     }
 654
 655     lives_ok {
 656         apk_t_set($schema,'dbic_t_schema.artist');
 657         my $new = $schema->resultset('Artist')->create({ name => 'foo' });
 658         is($new->artistid, 4, "Auto-PK worked");
 659         $new = $schema->resultset('Artist')->create({ name => 'bar' });
 660         is($new->artistid, 5, "Auto-PK worked");
 661     } 'old auto-pk tests did not die either';
 662 }
 663
 664 # sets the artist table name and clears sequence name cache
 665 sub apk_t_set {
 666     my ( $s, $n ) = @_;
 667     $s->source("Artist")->name($n);
 668     $s->source('Artist')->column_info('artistid')->{sequence} = undef; #< clear sequence name cache
 669 }
 670
 671
 672 ######## EXTENDED AUTO-PK TESTS
 673
 674 my @eapk_id_columns;
 675 BEGIN {
 676   package DBICTest::Schema::ExtAPK;
 677   push @main::test_classes, __PACKAGE__;
 678
 679   use strict;
 680   use warnings;
 681   use base 'DBIx::Class::Core';
 682
 683   __PACKAGE__->table('apk');
 684
 685   @eapk_id_columns = qw( id1 id2 id3 id4 );
 686   __PACKAGE__->add_columns(
 687     map { $_ => { data_type => 'integer', is_auto_increment => 1 } }
 688        @eapk_id_columns
 689   );
 690
 691   __PACKAGE__->set_primary_key('id2'); #< note the SECOND column is
 692                                        #the primary key
 693 }
 694
 695 my @eapk_schemas;
 696 BEGIN{ @eapk_schemas = map "dbic_apk_$_", 0..5 }
 697 my %seqs; #< hash of schema.table.col => currval of its (DBIC) primary key sequence
 698
 699 sub run_extended_apk_tests {
 700   my $schema = shift;
 701
 702   #save the search path and reset it at the end
 703   my $search_path_save = eapk_get_search_path($schema);
 704
 705   eapk_drop_all($schema);
 706   %seqs = ();
 707
 708   # make the test schemas and sequences
 709   $schema->storage->dbh_do(sub {
 710     my ( undef, $dbh ) = @_;
 711
 712     $dbh->do("CREATE SCHEMA $_")
 713         for @eapk_schemas;
 714
 715     $dbh->do("CREATE SEQUENCE $eapk_schemas[5].fooseq");
 716     $dbh->do("SELECT setval('$eapk_schemas[5].fooseq',400)");
 717     $seqs{"$eapk_schemas[1].apk.id2"} = 400;
 718
 719     $dbh->do("CREATE SEQUENCE $eapk_schemas[4].fooseq");
 720     $dbh->do("SELECT setval('$eapk_schemas[4].fooseq',300)");
 721     $seqs{"$eapk_schemas[3].apk.id2"} = 300;
 722
 723     $dbh->do("CREATE SEQUENCE $eapk_schemas[3].fooseq");
 724     $dbh->do("SELECT setval('$eapk_schemas[3].fooseq',200)");
 725     $seqs{"$eapk_schemas[4].apk.id2"} = 200;
 726
 727     $dbh->do("SET search_path = ".join ',', reverse @eapk_schemas );
 728   });
 729
 730   # clear our search_path cache
 731   $schema->storage->{_pg_search_path} = undef;
 732
 733   eapk_create( $schema,
 734                with_search_path => [0,1],
 735              );
 736   eapk_create( $schema,
 737                with_search_path => [1,0,'public'],
 738                nextval => "$eapk_schemas[5].fooseq",
 739              );
 740   eapk_create( $schema,
 741                with_search_path => ['public',0,1],
 742                qualify_table => 2,
 743              );
 744   eapk_create( $schema,
 745                with_search_path => [3,1,0,'public'],
 746                nextval => "$eapk_schemas[4].fooseq",
 747              );
 748   eapk_create( $schema,
 749                with_search_path => [3,1,0,'public'],
 750                nextval => "$eapk_schemas[3].fooseq",
 751                qualify_table => 4,
 752              );
 753
 754   eapk_poke( $schema );
 755   eapk_poke( $schema, 0 );
 756   eapk_poke( $schema, 2 );
 757   eapk_poke( $schema, 4 );
 758   eapk_poke( $schema, 1 );
 759   eapk_poke( $schema, 0 );
 760   eapk_poke( $schema, 1 );
 761   eapk_poke( $schema );
 762   eapk_poke( $schema, 4 );
 763   eapk_poke( $schema, 3 );
 764   eapk_poke( $schema, 1 );
 765   eapk_poke( $schema, 2 );
 766   eapk_poke( $schema, 0 );
 767
 768   # set our search path back
 769   eapk_set_search_path( $schema, @$search_path_save );
 770 }
 771
 772 # do a DBIC create on the apk table in the given schema number (which is an
 773 # index of @eapk_schemas)
 774
 775 sub eapk_poke {
 776   my ($s, $schema_num) = @_;
 777
 778   my $schema_name = defined $schema_num
 779       ? $eapk_schemas[$schema_num]
 780       : '';
 781
 782   my $schema_name_actual = $schema_name || eapk_find_visible_schema($s);
 783
 784   $s->source('ExtAPK')->name($schema_name ? $schema_name.'.apk' : 'apk');
 785   #< clear sequence name cache
 786   $s->source('ExtAPK')->column_info($_)->{sequence} = undef
 787       for @eapk_id_columns;
 788
 789   no warnings 'uninitialized';
 790   lives_ok {
 791     my $new;
 792     for my $inc (1,2,3) {
 793       $new = $schema->resultset('ExtAPK')->create({ id1 => 1});
 794       my $proper_seqval = ++$seqs{"$schema_name_actual.apk.id2"};
 795       is( $new->id2, $proper_seqval, "$schema_name_actual.apk.id2 correct inc $inc" )
 796           or eapk_seq_diag($s,$schema_name);
 797       $new->discard_changes;
 798       is( $new->id1, 1 );
 799       for my $id ('id3','id4') {
 800         my $proper_seqval = ++$seqs{"$schema_name_actual.apk.$id"};
 801         is( $new->$id, $proper_seqval, "$schema_name_actual.apk.$id correct inc $inc" )
 802             or eapk_seq_diag($s,$schema_name);
 803       }
 804     }
 805   } "create in schema '$schema_name' lives"
 806       or eapk_seq_diag($s,$schema_name);
 807 }
 808
 809 # print diagnostic info on which sequences were found in the ExtAPK
 810 # class
 811 sub eapk_seq_diag {
 812     my $s = shift;
 813     my $schema = shift || eapk_find_visible_schema($s);
 814
 815     diag "$schema.apk sequences: ",
 816         join(', ',
 817              map "$_:".($s->source('ExtAPK')->column_info($_)->{sequence} || '<none>'),
 818              @eapk_id_columns
 819             );
 820 }
 821
 822 # get the postgres search path as an arrayref
 823 sub eapk_get_search_path {
 824     my ( $s ) = @_;
 825     # cache the search path as ['schema','schema',...] in the storage
 826     # obj
 827
 828     return $s->storage->dbh_do(sub {
 829         my (undef, $dbh) = @_;
 830         my @search_path;
 831         my ($sp_string) = $dbh->selectrow_array('SHOW search_path');
 832         while ( $sp_string =~ s/("[^"]+"|[^,]+),?// ) {
 833             unless( defined $1 and length $1 ) {
 834                 die "search path sanity check failed: '$1'";
 835             }
 836             push @search_path, $1;
 837         }
 838         \@search_path
 839     });
 840 }
 841 sub eapk_set_search_path {
 842     my ($s,@sp) = @_;
 843     my $sp = join ',',@sp;
 844     $s->storage->dbh_do( sub { $_[1]->do("SET search_path = $sp") } );
 845 }
 846
 847 # create the apk table in the given schema, can set whether the table name is qualified, what the nextval is for the second ID
 848 sub eapk_create {
 849     my ($schema, %a) = @_;
 850
 851     $schema->storage->dbh_do(sub {
 852         my (undef,$dbh) = @_;
 853
 854         my $searchpath_save;
 855         if ( $a{with_search_path} ) {
 856             ($searchpath_save) = $dbh->selectrow_array('SHOW search_path');
 857
 858             my $search_path = join ',',map {/\D/ ? $_ : $eapk_schemas[$_]} @{$a{with_search_path}};
 859
 860             $dbh->do("SET search_path = $search_path");
 861         }
 862
 863         my $table_name = $a{qualify_table}
 864             ? ($eapk_schemas[$a{qualify_table}] || die). ".apk"
 865             : 'apk';
 866         local $_[1]->{Warn} = 0;
 867
 868         my $id_def = $a{nextval}
 869             ? "integer not null default nextval('$a{nextval}'::regclass)"
 870             : 'serial';
 871         $dbh->do(<<EOS);
 872 CREATE TABLE $table_name (
 873   id1 serial
 874   , id2 $id_def
 875   , id3 serial primary key
 876   , id4 serial
 877 )
 878 EOS
 879
 880         if( $searchpath_save ) {
 881             $dbh->do("SET search_path = $searchpath_save");
 882         }
 883     });
 884 }
 885
 886 sub eapk_drop_all {
 887     my ( $schema, $warn_exceptions ) = @_;
 888
 889     $schema->storage->dbh_do(sub {
 890         my (undef,$dbh) = @_;
 891
 892         local $dbh->{Warn} = 0;
 893
 894         # drop the test schemas
 895         for (@eapk_schemas ) {
 896             eval{ $dbh->do("DROP SCHEMA $_ CASCADE") };
 897             diag $@ if $@ && $warn_exceptions;
 898         }
 899
 900
 901     });
 902 }
 903
 904 sub eapk_find_visible_schema {
 905     my ($s) = @_;
 906
 907     my ($schema) =
 908         $s->storage->dbh_do(sub {
 909             $_[1]->selectrow_array(<<EOS);
 910 SELECT n.nspname
 911 FROM pg_catalog.pg_namespace n
 912 JOIN pg_catalog.pg_class c ON c.relnamespace = n.oid
 913 WHERE c.relname = 'apk'
 914   AND pg_catalog.pg_table_is_visible(c.oid)
 915 EOS
 916         });
 917     return $schema;
 918 }